code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2013 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.2.93)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 dnl Fairly arbitrary, older versions might work too.
  30 AM_INIT_AUTOMAKE(1.11)
  31
  32 dnl Support for --program-prefix, --program-suffix and
  33 dnl --program-transform-name options
  34 AC_ARG_PROGRAM
  35
  36 dnl It is important that variables on the RHS not be expanded here,
  37 dnl hence the single quotes.  This is per the GNU coding standards, see
  38 dnl (autoconf) Installation Directory Variables
  39 dnl See also epaths.h below.
  40 lispdir='${datadir}/emacs/${version}/lisp'
  41 leimdir='${datadir}/emacs/${version}/leim'
  42 standardlisppath='${lispdir}:${leimdir}'
  43 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  44 '${datadir}/emacs/site-lisp'
  45 lisppath='${locallisppath}:${standardlisppath}'
  46 etcdir='${datadir}/emacs/${version}/etc'
  47 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  48 docdir='${datadir}/emacs/${version}/etc'
  49 gamedir='${localstatedir}/games/emacs'
  50
  51 dnl Special option to disable the most of other options.
  52 AC_ARG_WITH(all,
  53 [AS_HELP_STRING([--without-all],
  54                 [omit almost all features and build
  55                 small executable with minimal dependencies])],
  56   with_features=$withval,
  57   with_features=yes)
  58
  59 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  60 dnl Create a new --with option that defaults to being disabled.
  61 dnl NAME is the base name of the option.  The shell variable with_NAME
  62 dnl   will be set to either the user's value (if the option is
  63 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  64 dnl   option is not specified).  Note that the shell variable name is
  65 dnl   constructed as autoconf does, by replacing non-alphanumeric
  66 dnl   characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  70     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  71 ])dnl
  72
  73 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  74 dnl Create a new --with option that defaults to $enable_features.
  75 dnl NAME is the base name of the option.  The shell variable with_NAME
  76 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  77 dnl   'yes' (if the option is not specified).  Note that the shell
  78 dnl   variable name is constructed as autoconf does, by replacing
  79 dnl   non-alphanumeric characters with "_".
  80 dnl HELP-STRING is the help text for the option.
  81 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  82   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  83    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
  84 ])dnl
  85
  86 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  87 if test "$with_pop" = yes; then
  88    AC_DEFINE(MAIL_USE_POP)
  89 fi
  90 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  91
  92 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  93 if test "$with_kerberos" != no; then
  94    AC_DEFINE(KERBEROS)
  95 fi
  96 AH_TEMPLATE(KERBEROS,
  97             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  98
  99 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 100 if test "${with_kerberos5}" != no; then
 101   if test "${with_kerberos}" = no; then
 102     with_kerberos=yes
 103     AC_DEFINE(KERBEROS)
 104   fi
 105   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 109 dnl FIXME hesiod support may not be present, so it seems like an error
 110 dnl to define, or at least use, this unconditionally.
 111 if test "$with_hesiod" != no; then
 112   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 113 fi
 114
 115 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 116 if test "$with_mmdf" != no; then
 117    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 118 fi
 119
 120 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 121 if test "$with_mail_unlink" != no; then
 122    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 123 fi
 124
 125 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 126     [string giving default POP mail host])],
 127     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 128
 129 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 130
 131 dnl FIXME currently it is not the last.
 132 dnl This should be the last --with option, because --with-x is
 133 dnl added later on when we find the path of X, and it's best to
 134 dnl keep them together visually.
 135 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 136  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 137 [         case "${withval}" in
 138             y | ye | yes )      val=gtk ;;
 139             n | no )            val=no  ;;
 140             l | lu | luc | luci | lucid )       val=lucid ;;
 141             a | at | ath | athe | athen | athena )      val=athena ;;
 142             m | mo | mot | moti | motif )       val=motif ;;
 143             g | gt | gtk  )     val=gtk ;;
 144             gtk2  )     val=gtk2 ;;
 145             gtk3  )     val=gtk3 ;;
 146             * )
 147 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 148 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 149 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 150 `athena' and `lucid' are synonyms.])
 151             ;;
 152           esac
 153           with_x_toolkit=$val
 154 ])
 155
 156 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 157 if test "$with_wide_int" = yes; then
 158   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 159 fi
 160
 161 dnl _ON results in a '--without' option in the --help output, so
 162 dnl the help text should refer to "don't compile", etc.
 163 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 164 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 165 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 166 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 167 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 168 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 169 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 170 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 171
 172 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 173 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 174 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 175
 176 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 177 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 178 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 179 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 180 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI])
 181
 182 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 183 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 184 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 185 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 186 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 187 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 188
 189 ## For the times when you want to build Emacs but don't have
 190 ## a suitable makeinfo, and can live without the manuals.
 191 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 192 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 193
 194 ## Makefile.in needs the cache file name.
 195 AC_SUBST(cache_file)
 196
 197 ## This is an option because I do not know if all info/man support
 198 ## compressed files, nor how to test if they do so.
 199 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 200 if test $with_compress_info = yes; then
 201    GZIP_INFO=yes
 202 else
 203    GZIP_INFO=
 204 fi
 205 AC_SUBST(GZIP_INFO)
 206
 207 AC_ARG_WITH([pkg-config-prog],dnl
 208 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 209                   [path to pkg-config for finding GTK and librsvg])])
 210 if test "X${with_pkg_config_prog}" != X; then
 211    if test "${with_pkg_config_prog}" != yes; then
 212       PKG_CONFIG="${with_pkg_config_prog}"
 213    fi
 214 fi
 215
 216 CRT_DIR=
 217 AC_ARG_WITH([crt-dir],dnl
 218 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 219 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 220 CRT_DIR="${with_crt_dir}"
 221
 222 AC_ARG_WITH(gameuser,dnl
 223 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 224 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 225   && gameuser="${with_gameuser}"
 226 test "X$gameuser" = X && gameuser=games
 227
 228 AC_ARG_WITH([gnustep-conf],dnl
 229 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 230 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 231   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 232 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 233      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 234
 235 AC_ARG_ENABLE(ns-self-contained,
 236 [AS_HELP_STRING([--disable-ns-self-contained],
 237                 [disable self contained build under NeXTstep])],
 238    EN_NS_SELF_CONTAINED=$enableval,
 239    EN_NS_SELF_CONTAINED=yes)
 240
 241 AC_ARG_ENABLE(locallisppath,
 242 [AS_HELP_STRING([--enable-locallisppath=PATH],
 243                 [directories Emacs should search for lisp files specific
 244                  to this site])],
 245 if test "${enableval}" = "no"; then
 246   locallisppath=
 247 elif test "${enableval}" != "yes"; then
 248   locallisppath=${enableval}
 249 fi)
 250
 251 AC_ARG_ENABLE(checking,
 252 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 253                 [enable expensive run-time checks.  With LIST,
 254                  enable only specific categories of checks.
 255                  Categories are: all,yes,no.
 256                  Flags are: stringbytes, stringoverrun, stringfreelist,
 257                  xmallocoverrun, conslist, glyphs])],
 258 [ac_checking_flags="${enableval}"],[])
 259 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 260 for check in $ac_checking_flags
 261 do
 262         case $check in
 263         # these set all the flags to specific states
 264         yes)            ac_enable_checking=1 ;;
 265         no)             ac_enable_checking= ;
 266                         ac_gc_check_stringbytes= ;
 267                         ac_gc_check_string_overrun= ;
 268                         ac_gc_check_string_free_list= ;
 269                         ac_xmalloc_overrun= ;
 270                         ac_gc_check_cons_list= ;
 271                         ac_glyphs_debug= ;;
 272         all)            ac_enable_checking=1 ;
 273                         ac_gc_check_stringbytes=1 ;
 274                         ac_gc_check_string_overrun=1 ;
 275                         ac_gc_check_string_free_list=1 ;
 276                         ac_xmalloc_overrun=1 ;
 277                         ac_gc_check_cons_list=1 ;
 278                         ac_glyphs_debug=1 ;;
 279         # these enable particular checks
 280         stringbytes)    ac_gc_check_stringbytes=1 ;;
 281         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 282         stringfreelist) ac_gc_check_string_free_list=1 ;;
 283         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 284         conslist)       ac_gc_check_cons_list=1 ;;
 285         glyphs)         ac_glyphs_debug=1 ;;
 286         *)      AC_MSG_ERROR(unknown check category $check) ;;
 287         esac
 288 done
 289 IFS="$ac_save_IFS"
 290
 291 if test x$ac_enable_checking != x ; then
 292   AC_DEFINE(ENABLE_CHECKING, 1,
 293 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 294 fi
 295 if test x$ac_gc_check_stringbytes != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 297 [Define this temporarily to hunt a bug.  If defined, the size of
 298    strings is redundantly recorded in sdata structures so that it can
 299    be compared to the sizes recorded in Lisp strings.])
 300 fi
 301 if test x$ac_gc_check_string_overrun != x ; then
 302   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 303 [Define this to check for short string overrun.])
 304 fi
 305 if test x$ac_gc_check_string_free_list != x ; then
 306   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 307 [Define this to check the string free list.])
 308 fi
 309 if test x$ac_xmalloc_overrun != x ; then
 310   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 311 [Define this to check for malloc buffer overrun.])
 312 fi
 313 if test x$ac_gc_check_cons_list != x ; then
 314   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 315 [Define this to check for errors in cons list.])
 316 fi
 317 if test x$ac_glyphs_debug != x ; then
 318   AC_DEFINE(GLYPH_DEBUG, 1,
 319 [Define this to enable glyphs debugging code.])
 320 fi
 321
 322 AC_ARG_ENABLE(check-lisp-object-type,
 323 [AS_HELP_STRING([--enable-check-lisp-object-type],
 324                 [enable compile time checks for the Lisp_Object data type.
 325                 This is useful for development for catching certain types of bugs.])],
 326 if test "${enableval}" != "no"; then
 327    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 328    [Define this to enable compile time checks for the Lisp_Object data type.])
 329 fi)
 330
 331
 332 dnl The name of this option is unfortunate.  It predates, and has no
 333 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 334 dnl Actually, it stops it working.
 335 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 336 AC_ARG_ENABLE(profiling,
 337 [AS_HELP_STRING([--enable-profiling],
 338                 [build emacs with low-level, gprof profiling support.
 339                 Mainly useful for debugging Emacs itself.  May not work on
 340                 all platforms.  Stops profiler.el working.])],
 341 [ac_enable_profiling="${enableval}"],[])
 342 if test x$ac_enable_profiling != x ; then
 343    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 344 else
 345    PROFILING_CFLAGS=
 346 fi
 347 AC_SUBST(PROFILING_CFLAGS)
 348
 349 AC_ARG_ENABLE(autodepend,
 350 [AS_HELP_STRING([--enable-autodepend],
 351                 [automatically generate dependencies to .h-files.
 352                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 353                  found])],
 354 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 355
 356 #### Make srcdir absolute, if it isn't already.  It's important to
 357 #### avoid running the path through pwd unnecessarily, since pwd can
 358 #### give you automounter prefixes, which can go away.  We do all this
 359 #### so Emacs can find its files when run uninstalled.
 360 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 361 unset CDPATH
 362 case "${srcdir}" in
 363   /* ) ;;
 364   . )
 365     ## We may be able to use the $PWD environment variable to make this
 366     ## absolute.  But sometimes PWD is inaccurate.
 367     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 368     ## but that tested only for a well-formed and valid PWD,
 369     ## it did not object when PWD was well-formed and valid but just wrong.
 370     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 371     then
 372       srcdir="$PWD"
 373     else
 374       srcdir="`(cd ${srcdir}; pwd)`"
 375     fi
 376   ;;
 377   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 378 esac
 379
 380 ### Canonicalize the configuration name.
 381
 382 AC_CANONICAL_HOST
 383 canonical=$host
 384 configuration=${host_alias-${build_alias-$host}}
 385
 386 dnl This used to use changequote, but, apart from `changequote is evil'
 387 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 388 dnl the great gob of text.  Thus it's not processed for possible expansion.
 389 dnl Just make sure the brackets remain balanced.
 390 dnl
 391 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 392 dnl indicated by comments.
 393 dnl quotation begins
 394 [
 395
 396 ### If you add support for a new configuration, add code to this
 397 ### switch statement to recognize your configuration name and select
 398 ### the appropriate operating system file.
 399
 400 ### You would hope that you could choose an s/*.h
 401 ### file based on the operating system portion.  However, it turns out
 402 ### that each s/*.h file is pretty manufacturer-specific.
 403 ### So we basically have to have a special case for each
 404 ### configuration name.
 405 ###
 406 ### As far as handling version numbers on operating systems is
 407 ### concerned, make sure things will fail in a fixable way.  If
 408 ### /etc/MACHINES doesn't say anything about version numbers, be
 409 ### prepared to handle anything reasonably.  If version numbers
 410 ### matter, be sure /etc/MACHINES says something about it.
 411
 412 opsys='' unported=no
 413 case "${canonical}" in
 414
 415   ## GNU/Linux and similar ports
 416   *-*-linux* )
 417     opsys=gnu-linux
 418   ;;
 419
 420   ## FreeBSD ports
 421   *-*-freebsd* )
 422     opsys=freebsd
 423   ;;
 424
 425   ## FreeBSD kernel + glibc based userland
 426   *-*-kfreebsd*gnu* )
 427     opsys=gnu-kfreebsd
 428   ;;
 429
 430   ## NetBSD ports
 431   *-*-netbsd* )
 432     opsys=netbsd
 433   ;;
 434
 435   ## OpenBSD ports
 436   *-*-openbsd* )
 437     opsys=openbsd
 438   ;;
 439
 440   ## Apple Darwin / Mac OS X
 441   *-apple-darwin* )
 442     case "${canonical}" in
 443       i[3456]86-* )  ;;
 444       powerpc-* )    ;;
 445       x86_64-* )     ;;
 446       * )            unported=yes ;;
 447     esac
 448     opsys=darwin
 449     ## Use fink packages if available.
 450     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 451 ##    if test -d /sw/include && test -d /sw/lib; then
 452 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 453 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 454 ##    fi
 455   ;;
 456
 457   ## HP 9000 series 700 and 800, running HP/UX
 458   hppa*-hp-hpux10.2* )
 459     opsys=hpux10-20
 460   ;;
 461   hppa*-hp-hpux1[1-9]* )
 462     opsys=hpux11
 463     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 464   ;;
 465
 466   ## IBM machines
 467   rs6000-ibm-aix4.[23]* )
 468     opsys=aix4-2
 469   ;;
 470   powerpc-ibm-aix4.[23]*  )
 471     opsys=aix4-2
 472   ;;
 473   rs6000-ibm-aix[56]* )
 474     opsys=aix4-2
 475   ;;
 476   powerpc-ibm-aix[56]*  )
 477     opsys=aix4-2
 478   ;;
 479
 480   ## Silicon Graphics machines
 481   ## Iris 4D
 482   mips-sgi-irix6.5 )
 483     opsys=irix6-5
 484     # Without defining _LANGUAGE_C, things get masked out in the headers
 485     # so that, for instance, grepping for `free' in stdlib.h fails and
 486     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 487     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 488   ;;
 489
 490   ## Suns
 491   *-sun-solaris* \
 492     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 493     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 494     case "${canonical}" in
 495       i[3456]86-*-* )   ;;
 496       amd64-*-*|x86_64-*-*) ;;
 497       sparc* )          ;;
 498       * )               unported=yes ;;
 499     esac
 500     case "${canonical}" in
 501       *-sunos5.6* | *-solaris2.6* )
 502                 opsys=sol2-6
 503                 RANLIB="ar -ts"
 504                 ;;
 505       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 506                 opsys=sol2-6
 507                 emacs_check_sunpro_c=yes
 508                 ;;
 509       *-sunos5* | *-solaris* )
 510                 opsys=sol2-10
 511                 emacs_check_sunpro_c=yes
 512                 ;;
 513     esac
 514     ## Watch out for a compiler that we know will not work.
 515     case "${canonical}" in
 516      *-solaris* | *-sunos5* )
 517                 if [ "x$CC" = x/usr/ucb/cc ]; then
 518                   ## /usr/ucb/cc doesn't work;
 519                   ## we should find some other compiler that does work.
 520                   unset CC
 521                 fi
 522                 ;;
 523       *) ;;
 524     esac
 525   ;;
 526
 527   ## Intel 386 machines where we don't care about the manufacturer.
 528   i[3456]86-*-* )
 529     case "${canonical}" in
 530       *-cygwin )                opsys=cygwin ;;
 531       *-darwin* )               opsys=darwin ;;
 532       *-sysv4.2uw* )            opsys=unixware ;;
 533       *-sysv5uw* )              opsys=unixware ;;
 534       *-sysv5OpenUNIX* )        opsys=unixware ;;
 535       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 536     esac
 537   ;;
 538
 539   * )
 540     unported=yes
 541   ;;
 542 esac
 543
 544 ### If the code above didn't choose an operating system, just choose
 545 ### an operating system based on the configuration name.  You really
 546 ### only want to use this when you have no idea what the right
 547 ### operating system is; if you know what operating systems a machine
 548 ### runs, it's cleaner to make it explicit in the case statement
 549 ### above.
 550 if test x"${opsys}" = x; then
 551   case "${canonical}" in
 552     *-gnu* )                            opsys=gnu ;;
 553     * )
 554       unported=yes
 555     ;;
 556   esac
 557 fi
 558
 559 ]
 560 dnl quotation ends
 561
 562 if test $unported = yes; then
 563   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 564 Check `etc/MACHINES' for recognized configuration names.])
 565 fi
 566
 567
 568 #### Choose a compiler.
 569
 570 dnl Sets GCC=yes if using gcc.
 571 AC_PROG_CC
 572 AM_PROG_CC_C_O
 573
 574 if test x$GCC = xyes; then
 575   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 576 else
 577   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 578 fi
 579
 580 # Avoid gnulib's threadlib module, as we do threads our own way.
 581 AC_DEFUN([gl_THREADLIB])
 582
 583 # Initialize gnulib right after choosing the compiler.
 584 dnl Amongst other things, this sets AR and ARFLAGS.
 585 gl_EARLY
 586
 587 # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 588 # if -g3 works and the user does not specify CFLAGS.
 589 # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 590 if test "$ac_test_CFLAGS" != set; then
 591   case $CFLAGS in
 592     '-g')
 593       emacs_g3_CFLAGS='-g3';;
 594     '-g -O2')
 595       emacs_g3_CFLAGS='-g3 -O2';;
 596     *)
 597       emacs_g3_CFLAGS='';;
 598   esac
 599   if test -n "$emacs_g3_CFLAGS"; then
 600     emacs_save_CFLAGS=$CFLAGS
 601     CFLAGS=$emacs_g3_CFLAGS
 602     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 603       [emacs_cv_prog_cc_g3],
 604       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 605          [emacs_cv_prog_cc_g3=yes],
 606          [emacs_cv_prog_cc_g3=no])])
 607     if test $emacs_cv_prog_cc_g3 = yes; then
 608       CFLAGS=$emacs_g3_CFLAGS
 609     else
 610       CFLAGS=$emacs_save_CFLAGS
 611     fi
 612   fi
 613 fi
 614
 615 AC_ARG_ENABLE([gcc-warnings],
 616   [AS_HELP_STRING([--enable-gcc-warnings],
 617                   [turn on lots of GCC warnings/errors. This is intended for
 618                    developers, and may generate false alarms when used
 619                    with older or non-GNU development tools.])],
 620   [case $enableval in
 621      yes|no) ;;
 622      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 623    esac
 624    gl_gcc_warnings=$enableval],
 625   [gl_gcc_warnings=no]
 626 )
 627
 628 AC_ARG_ENABLE(link-time-optimization,
 629 [AS_HELP_STRING([--enable-link-time-optimization],
 630                 [build emacs with link-time optimization.
 631                  This is supported only for GCC since 4.5.0.])],
 632 if test "${enableval}" != "no"; then
 633    AC_MSG_CHECKING([whether link-time optimization is supported])
 634    ac_lto_supported=no
 635    if test x$GCC = xyes; then
 636       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 637       if test x$CPUS != x; then
 638          LTO="-flto=$CPUS"
 639       else
 640          LTO="-flto"
 641       fi
 642       old_CFLAGS=$CFLAGS
 643       CFLAGS="$CFLAGS $LTO"
 644       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 645         [ac_lto_supported=yes], [ac_lto_supported=no])
 646       CFLAGS="$old_CFLAGS"
 647    fi
 648    AC_MSG_RESULT([$ac_lto_supported])
 649    if test "$ac_lto_supported" = "yes"; then
 650       CFLAGS="$CFLAGS $LTO"
 651    fi
 652 fi)
 653
 654 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 655 # ------------------------------------------------
 656 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 657 # Otherwise, run RUN-IF-NOT-FOUND.
 658 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 659   [AC_PREPROC_IFELSE(
 660     [AC_LANG_PROGRAM(
 661       [[
 662 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 663 /* ok */
 664 #else
 665 # error "your version of gcc is older than $1.$2"
 666 #endif
 667       ]]),
 668     ], [$3], [$4])
 669   ]
 670 )
 671
 672 # When compiling with GCC, prefer -isystem to -I when including system
 673 # include files, to avoid generating useless diagnostics for the files.
 674 if test "$gl_gcc_warnings" != yes; then
 675   isystem='-I'
 676 else
 677   isystem='-isystem '
 678
 679   # This, $nw, is the list of warnings we disable.
 680   nw=
 681
 682   case $with_x_toolkit in
 683     lucid | athena | motif)
 684        # Old toolkits mishandle 'const'.
 685        nw="$nw -Wwrite-strings"
 686        ;;
 687     *)
 688        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 689        ;;
 690   esac
 691   AC_SUBST([WERROR_CFLAGS])
 692
 693   nw="$nw -Waggregate-return"       # anachronistic
 694   nw="$nw -Wlong-long"              # C90 is anachronistic
 695   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 696   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 697   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 698   nw="$nw -Wcast-qual"              # Too many warnings for now
 699   nw="$nw -Wconversion"             # Too many warnings for now
 700   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 701   nw="$nw -Wsign-conversion"        # Too many warnings for now
 702   nw="$nw -Woverlength-strings"     # Not a problem these days
 703   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 704   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 705   nw="$nw -Wpadded"                 # Our structs are not padded
 706   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 707   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 708   nw="$nw -Wformat-nonliteral"      # we do this a lot
 709   nw="$nw -Wvla"                    # warnings in gettext.h
 710   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 711   nw="$nw -Wswitch-enum"            # Too many warnings for now
 712   nw="$nw -Wswitch-default"         # Too many warnings for now
 713   nw="$nw -Wfloat-equal"            # warns about high-quality code
 714   nw="$nw -Winline"                 # OK to ignore 'inline'
 715   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 716   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 717   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 718
 719   # Emacs doesn't care about shadowing; see
 720   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 721   nw="$nw -Wshadow"
 722
 723   # The following lines should be removable at some point.
 724   nw="$nw -Wstack-protector"
 725   nw="$nw -Wstrict-overflow"
 726   nw="$nw -Wsuggest-attribute=pure"
 727
 728   gl_MANYWARN_ALL_GCC([ws])
 729   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 730   for w in $ws; do
 731     gl_WARN_ADD([$w])
 732   done
 733   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 734   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 735   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 736   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 737   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 738   gl_WARN_ADD([-Wno-format-nonliteral])
 739
 740   # In spite of excluding -Wlogical-op above, it is enabled, as of
 741   # gcc 4.5.0 20090517.
 742   gl_WARN_ADD([-Wno-logical-op])
 743
 744   gl_WARN_ADD([-fdiagnostics-show-option])
 745   gl_WARN_ADD([-funit-at-a-time])
 746
 747   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 748   AH_VERBATIM([FORTIFY_SOURCE],
 749   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 750       without upsetting glibc 2.15+. */
 751    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 752    # define _FORTIFY_SOURCE 2
 753    #endif
 754   ])
 755   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 756
 757   # We use a slightly smaller set of warning options for lib/.
 758   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 759   nw=
 760   nw="$nw -Wunused-macros"
 761
 762   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 763   AC_SUBST([GNULIB_WARN_CFLAGS])
 764 fi
 765
 766
 767
 768 dnl Some other nice autoconf tests.
 769 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 770 dnl AC_PROG_INSTALL
 771 dnl AC_PROG_MKDIR_P
 772 dnl if test "x$RANLIB" = x; then
 773 dnl   AC_PROG_RANLIB
 774 dnl fi
 775 AC_PROG_LN_S
 776
 777 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 778   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 779 dnl Don't use GZIP, which is used by gzip for additional parameters.
 780 AC_PATH_PROG(GZIP_PROG, gzip)
 781
 782 if test $opsys = gnu-linux; then
 783   AC_PATH_PROG(PAXCTL, paxctl,,
 784     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 785   if test "X$PAXCTL" != X; then
 786     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 787     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 788       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 789       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 790   fi
 791 fi
 792
 793 ## Need makeinfo >= 4.7 (?) to build the manuals.
 794 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 795 dnl By this stage, configure has already checked for egrep and set EGREP,
 796 dnl or exited with an error if no egrep was found.
 797 if test "$MAKEINFO" != "no" && \
 798   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 799    MAKEINFO=no
 800 fi
 801
 802 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 803 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 804 ## therefore in the category of "special tools" not normally required, which
 805 ## configure does not have to check for (eg autoconf itself).
 806 ## In a Bazaar checkout on the other hand, the manuals are not included.
 807 ## So makeinfo is a requirement to build from Bazaar, and configure
 808 ## should test for it as it does for any other build requirement.
 809 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 810 ## with pre-built manuals, from a Bazaar checkout.
 811 HAVE_MAKEINFO=yes
 812
 813 if test "$MAKEINFO" = "no"; then
 814   MAKEINFO=makeinfo
 815   if test "x${with_makeinfo}" = "xno"; then
 816     HAVE_MAKEINFO=no
 817   elif test ! -e $srcdir/info/emacs && test ! -e $srcdir/info/emacs.info; then
 818     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 819 source tree does not seem to have pre-built manuals in the `info' directory.
 820 Either install a suitable version of makeinfo, or re-run configure
 821 with the `--without-makeinfo' option to build without the manuals.] )
 822   fi
 823 fi
 824 AC_SUBST(HAVE_MAKEINFO)
 825
 826 dnl Just so that there is only a single place we need to edit.
 827 INFO_EXT=.info
 828 INFO_OPTS=--no-split
 829 AC_SUBST(INFO_EXT)
 830 AC_SUBST(INFO_OPTS)
 831
 832 dnl Add our options to ac_link now, after it is set up.
 833
 834 if test x$GCC = xyes; then
 835   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 836     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 837 else
 838   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 839     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 840 fi
 841
 842 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 843 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 844 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 845 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 846 dnl if not built to support GNU ld.
 847
 848 late_LDFLAGS=$LDFLAGS
 849 if test x$GCC = xyes; then
 850   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 851 else
 852   LDFLAGS="$LDFLAGS -znocombreloc"
 853 fi
 854
 855 AC_MSG_CHECKING([for -znocombreloc])
 856 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 857   [AC_MSG_RESULT(yes)],
 858   LDFLAGS=$late_LDFLAGS
 859   [AC_MSG_RESULT(no)])
 860
 861
 862 dnl The function dump-emacs will not be defined and temacs will do
 863 dnl (load "loadup") automatically unless told otherwise.
 864 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 865 case "$opsys" in
 866   your-opsys-here) CANNOT_DUMP=yes ;;
 867 esac
 868
 869 test "$CANNOT_DUMP" = "yes" && \
 870   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 871
 872 AC_SUBST(CANNOT_DUMP)
 873
 874
 875 UNEXEC_OBJ=unexelf.o
 876 case "$opsys" in
 877   # MSDOS uses unexcoff.o
 878   # MSWindows uses unexw32.o
 879   aix4-2)
 880    UNEXEC_OBJ=unexaix.o
 881    ;;
 882   cygwin)
 883    UNEXEC_OBJ=unexcw.o
 884    ;;
 885   darwin)
 886    UNEXEC_OBJ=unexmacosx.o
 887    ;;
 888   hpux10-20 | hpux11)
 889    UNEXEC_OBJ=unexhp9k800.o
 890    ;;
 891   sol2-10)
 892    # Use the Solaris dldump() function, called from unexsol.c, to dump
 893    # emacs, instead of the generic ELF dump code found in unexelf.c.
 894    # The resulting binary has a complete symbol table, and is better
 895    # for debugging and other observability tools (debuggers, pstack, etc).
 896    #
 897    # If you encounter a problem using dldump(), please consider sending
 898    # a message to the OpenSolaris tools-linking mailing list:
 899    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 900    #
 901    # It is likely that dldump() works with older Solaris too, but this has
 902    # not been tested, so for now this change is for Solaris 10 or newer.
 903    UNEXEC_OBJ=unexsol.o
 904    ;;
 905 esac
 906
 907 LD_SWITCH_SYSTEM=
 908 case "$opsys" in
 909   freebsd)
 910    ## Let `ld' find image libs and similar things in /usr/local/lib.
 911    ## The system compiler, GCC, has apparently been modified to not
 912    ## look there, contrary to what a stock GCC would do.
 913 ### It's not our place to do this.  See bug#10313#17.
 914 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 915       :
 916    ;;
 917
 918   gnu-linux)
 919    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 920    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 921    ;;
 922
 923   netbsd)
 924 ### It's not our place to do this.  See bug#10313#17.
 925 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 926       :
 927    ;;
 928
 929   openbsd)
 930    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 931    ## otherwise Emacs dumps core on elf systems.
 932    LD_SWITCH_SYSTEM="-Z"
 933    ;;
 934 esac
 935 AC_SUBST(LD_SWITCH_SYSTEM)
 936
 937 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 938
 939 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 940 ## which has not been defined yet.  When this was handled with cpp,
 941 ## it was expanded to null when configure sourced the s/*.h file.
 942 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 943 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 944 ## (or somesuch), but because it is supposed to go at the _front_
 945 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 946 ## Compare with the gnu-linux case below, which added to the end
 947 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 948 ## LD_SWITCH_SYSTEM_TEMACS.
 949 case "$opsys" in
 950   netbsd|openbsd)
 951    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 952 esac
 953
 954
 955 C_SWITCH_MACHINE=
 956 case $canonical in
 957  alpha*)
 958   AC_CHECK_DECL([__ELF__])
 959   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 960     ## With ELF, make sure that all common symbols get allocated to in the
 961     ## data section.  Otherwise, the dump of temacs may miss variables in
 962     ## the shared library that have been initialized.  For example, with
 963     ## GNU libc, __malloc_initialized would normally be resolved to the
 964     ## shared library's .bss section, which is fatal.
 965     if test "x$GCC" = "xyes"; then
 966       C_SWITCH_MACHINE="-fno-common"
 967     else
 968       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 969     fi
 970   else
 971     UNEXEC_OBJ=unexalpha.o
 972   fi
 973   ;;
 974 esac
 975 AC_SUBST(C_SWITCH_MACHINE)
 976
 977 AC_SUBST(UNEXEC_OBJ)
 978
 979 C_SWITCH_SYSTEM=
 980 ## Some programs in src produce warnings saying certain subprograms
 981 ## are too complex and need a MAXMEM value greater than 2000 for
 982 ## additional optimization.  --nils@exp-math.uni-essen.de
 983 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 984   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 985 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 986 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 987 AC_SUBST(C_SWITCH_SYSTEM)
 988
 989
 990 LIBS_SYSTEM=
 991 case "$opsys" in
 992   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 993   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 994
 995   freebsd) LIBS_SYSTEM="-lutil" ;;
 996
 997   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 998
 999   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1000
1001   ## Motif needs -lgen.
1002   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1003 esac
1004 AC_SUBST(LIBS_SYSTEM)
1005
1006
1007 ### Make sure subsequent tests use flags consistent with the build flags.
1008
1009 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1010   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1011 else
1012   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1013 fi
1014
1015 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1016 AC_DEFUN([AC_TYPE_SIZE_T])
1017 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1018 AC_DEFUN([AC_TYPE_UID_T])
1019
1020
1021 LIB_MATH=-lm
1022 LIB_STANDARD=
1023 START_FILES=
1024 dnl Current possibilities handled by sed (aix4-2 -> aix,
1025 dnl gnu-linux -> gnu/linux, etc.):
1026 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1027 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1028 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1029
1030 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1031 case $opsys in
1032   cygwin )
1033     LIB_MATH=
1034     START_FILES='pre-crt0.o'
1035     ;;
1036   darwin )
1037     ## Adding -lm confuses the dynamic linker, so omit it.
1038     LIB_MATH=
1039     START_FILES='pre-crt0.o'
1040     ;;
1041   freebsd )
1042     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1043     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1044     SYSTEM_TYPE=berkeley-unix
1045     ;;
1046   gnu-linux | gnu-kfreebsd )
1047     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1048     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1049     ;;
1050   hpux10-20 | hpux11 )
1051     LIB_STANDARD=-lc
1052     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1053     ;;
1054   dnl NB this may be adjusted below.
1055   netbsd | openbsd )
1056     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1057     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1058     SYSTEM_TYPE=berkeley-unix
1059     ;;
1060
1061   sol2* | unixware )
1062     SYSTEM_TYPE=usg-unix-v
1063     ;;
1064
1065 esac
1066
1067 AC_SUBST(LIB_MATH)
1068 AC_SUBST(START_FILES)
1069 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1070   [The type of system you are compiling for; sets `system-type'.])
1071
1072 dnl Not all platforms use crtn.o files.  Check if the current one does.
1073 crt_files=
1074
1075 for file in x $LIB_STANDARD $START_FILES; do
1076   case "$file" in
1077     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1078   esac
1079 done
1080
1081 if test "x$crt_files" != x; then
1082
1083   ## If user specified a crt-dir, use that unconditionally.
1084   crt_gcc=no
1085
1086   if test "X$CRT_DIR" = "X"; then
1087
1088     CRT_DIR=/usr/lib            # default
1089
1090     case "$canonical" in
1091       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1092       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1093       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1094       ## For anything else (eg /usr/lib32), it is up the user to specify
1095       ## the location (bug#5655).
1096       ## Test for crtn.o, not just the directory, because sometimes the
1097       ## directory exists but does not have the relevant files (bug#1287).
1098       ## FIXME better to test for binary compatibility somehow.
1099       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1100       ;;
1101
1102       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1103     esac
1104
1105     case "$opsys" in
1106       hpux10-20) CRT_DIR=/lib ;;
1107     esac
1108
1109     test "x${GCC}" = xyes && crt_gcc=yes
1110
1111   fi                            # CRT_DIR = ""
1112
1113   crt_missing=
1114
1115   for file in $crt_files; do
1116
1117     ## If we're using gcc, try to determine it automatically by asking
1118     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1119     ## system-dependent default from above.]
1120     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1121
1122        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1123        case "$crt_file" in
1124          */*)
1125            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1126            ;;
1127        esac
1128     fi
1129
1130     dnl We expect all the files to be in a single directory, so after the
1131     dnl first there is no point asking gcc.
1132     crt_gcc=no
1133
1134     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1135   done                          # $crt_files
1136
1137   test "x$crt_missing" = x || \
1138     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1139 Try using the --with-crt-dir option.])
1140
1141 fi                              # crt_files != ""
1142
1143 AC_SUBST(CRT_DIR)
1144
1145 case $opsys in
1146   netbsd | openbsd )
1147     if test -f $CRT_DIR/crti.o; then
1148
1149         test -f $CRT_DIR/crtn.o || \
1150           AC_MSG_ERROR([Required file not found: crtn.o])
1151
1152         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1153         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1154     fi
1155     ;;
1156 esac
1157
1158
1159 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1160 pre_PKG_CONFIG_LIBS=$LIBS
1161
1162 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1163
1164 dnl This function definition taken from Gnome 2.0
1165 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1166 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1167 dnl also defines GSTUFF_PKG_ERRORS on error
1168 AC_DEFUN([PKG_CHECK_MODULES], [
1169   succeeded=no
1170
1171   if test "$PKG_CONFIG" = "no" ; then
1172      ifelse([$4], , [AC_MSG_ERROR([
1173       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1174   else
1175      PKG_CONFIG_MIN_VERSION=0.9.0
1176      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1177         AC_MSG_CHECKING(for $2)
1178
1179         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1180            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1181            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1182             edit_cflags="
1183               s,///*,/,g
1184               s/^/ /
1185               s/ -I/ $isystem/g
1186               s/^ //
1187             "
1188             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1189             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1190             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1191             succeeded=yes
1192         else
1193             AC_MSG_RESULT(no)
1194             $1_CFLAGS=""
1195             $1_LIBS=""
1196             ## If we have a custom action on failure, don't print errors, but
1197             ## do set a variable so people can do so.  Do it in a subshell
1198             ## to capture any diagnostics in invoking pkg-config.
1199             $1_PKG_ERRORS=`($PKG_CONFIG --print-errors "$2") 2>&1`
1200             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1201         fi
1202
1203         AC_SUBST($1_CFLAGS)
1204         AC_SUBST($1_LIBS)
1205      else
1206         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1207         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1208      fi
1209   fi
1210
1211   if test $succeeded = yes; then
1212      ifelse([$3], , :, [$3])
1213   else
1214      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1215   fi
1216 ])
1217
1218
1219 if test "${with_sound}" != "no"; then
1220   # Sound support for GNU/Linux and the free BSDs.
1221   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1222     have_sound_header=yes)
1223   # Emulation library used on NetBSD.
1224   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1225   AC_SUBST(LIBSOUND)
1226
1227   ALSA_REQUIRED=1.0.0
1228   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1229   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1230   if test $HAVE_ALSA = yes; then
1231     SAVE_CFLAGS="$CFLAGS"
1232     SAVE_LIBS="$LIBS"
1233     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1234     LIBS="$ALSA_LIBS $LIBS"
1235     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1236                     emacs_alsa_normal=yes,
1237                     emacs_alsa_normal=no)
1238     if test "$emacs_alsa_normal" != yes; then
1239       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1240                      [[snd_lib_error_set_handler (0);]])],
1241                      emacs_alsa_subdir=yes,
1242                      emacs_alsa_subdir=no)
1243       if test "$emacs_alsa_subdir" != yes; then
1244         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1245       fi
1246       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1247     fi
1248
1249     CFLAGS="$SAVE_CFLAGS"
1250     LIBS="$SAVE_LIBS"
1251     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1252     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1253     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1254   fi
1255
1256   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1257   dnl compiles only on the specified platforms.  For others, it
1258   dnl probably doesn't make sense to try.
1259   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1260      case "$opsys" in
1261        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1262        gnu-linux|freebsd|netbsd)
1263          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1264          ;;
1265      esac
1266   fi
1267
1268   AC_SUBST(CFLAGS_SOUND)
1269 fi
1270
1271 dnl checks for header files
1272 AC_CHECK_HEADERS_ONCE(
1273   linux/version.h sys/systeminfo.h
1274   stdio_ext.h fcntl.h coff.h pty.h
1275   sys/vlimit.h sys/resource.h
1276   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1277
1278 AC_MSG_CHECKING(if personality LINUX32 can be set)
1279 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1280                emacs_cv_personality_linux32=yes,
1281                emacs_cv_personality_linux32=no)
1282 AC_MSG_RESULT($emacs_cv_personality_linux32)
1283
1284 if test $emacs_cv_personality_linux32 = yes; then
1285   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1286             [Define to 1 if personality LINUX32 can be set.])
1287 fi
1288
1289 dnl On Solaris 8 there's a compilation warning for term.h because
1290 dnl it doesn't define `bool'.
1291 AC_CHECK_HEADERS(term.h, , , -)
1292 AC_HEADER_TIME
1293 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1294                                       ]])
1295 if test $ac_cv_have_decl_sys_siglist != yes; then
1296   # For Tru64, at least:
1297   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1298                                           ]])
1299   if test $ac_cv_have_decl___sys_siglist = yes; then
1300     AC_DEFINE(sys_siglist, __sys_siglist,
1301               [Define to any substitute for sys_siglist.])
1302   fi
1303 fi
1304 AC_HEADER_SYS_WAIT
1305
1306 dnl Check for speed_t typedef.
1307 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1308   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1309     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1310 if test $emacs_cv_speed_t = yes; then
1311   AC_DEFINE(HAVE_SPEED_T, 1,
1312            [Define to 1 if `speed_t' is declared by <termios.h>.])
1313 fi
1314
1315 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1316 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1317 #if HAVE_SYS_SOCKET_H
1318 #include <sys/socket.h>
1319 #endif])
1320 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1321 #if HAVE_SYS_SOCKET_H
1322 #include <sys/socket.h>
1323 #endif])
1324 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1325 #if HAVE_SYS_SOCKET_H
1326 #include <sys/socket.h>
1327 #endif])
1328
1329 dnl checks for structure members
1330 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1331                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1332                   struct ifreq.ifr_addr,
1333                   struct ifreq.ifr_addr.sa_len], , ,
1334                  [AC_INCLUDES_DEFAULT
1335 #if HAVE_SYS_SOCKET_H
1336 #include <sys/socket.h>
1337 #endif
1338 #if HAVE_NET_IF_H
1339 #include <net/if.h>
1340 #endif])
1341
1342 dnl Check for endianness.
1343 dnl AC_C_BIGENDIAN is done by gnulib.
1344
1345 dnl check for Make feature
1346 dnl AC_PROG_MAKE_SET is done by Automake.
1347
1348 DEPFLAGS=
1349 MKDEPDIR=":"
1350 deps_frag=deps.mk
1351 dnl check for GNU Make if we have GCC and autodepend is on.
1352 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1353    AC_MSG_CHECKING([whether we are using GNU Make])
1354    HAVE_GNU_MAKE=no
1355    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1356    if test "x$testval" != x; then
1357       HAVE_GNU_MAKE=yes
1358    else
1359       ac_enable_autodepend=no
1360    fi
1361    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1362    if test $HAVE_GNU_MAKE = yes; then
1363       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1364       SAVE_CFLAGS="$CFLAGS"
1365       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1366       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1367       CFLAGS="$SAVE_CFLAGS"
1368       test -f deps.d || ac_enable_autodepend=no
1369       rm -rf deps.d
1370       AC_MSG_RESULT([$ac_enable_autodepend])
1371    fi
1372    if test $ac_enable_autodepend = yes; then
1373       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1374       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1375       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1376       deps_frag=autodeps.mk
1377    fi
1378 fi
1379 deps_frag=$srcdir/src/$deps_frag
1380 AC_SUBST(MKDEPDIR)
1381 AC_SUBST(DEPFLAGS)
1382 AC_SUBST_FILE(deps_frag)
1383
1384
1385 lisp_frag=$srcdir/src/lisp.mk
1386 AC_SUBST_FILE(lisp_frag)
1387
1388
1389 dnl checks for operating system services
1390 AC_SYS_LONG_FILE_NAMES
1391
1392 #### Choose a window system.
1393
1394 ## We leave window_system equal to none if
1395 ## we end up building without one.  Any new window system should
1396 ## set window_system to an appropriate value and add objects to
1397 ## window-system-specific substs.
1398
1399 window_system=none
1400 AC_PATH_X
1401 if test "$no_x" != yes; then
1402   window_system=x11
1403 fi
1404
1405 LD_SWITCH_X_SITE_RPATH=
1406 if test "${x_libraries}" != NONE; then
1407   if test -n "${x_libraries}"; then
1408     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1409     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1410   fi
1411   x_default_search_path=""
1412   x_search_path=${x_libraries}
1413   if test -z "${x_search_path}"; then
1414     x_search_path=/usr/lib
1415   fi
1416   for x_library in `echo ${x_search_path}: | \
1417                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1418     x_search_path="\
1419 ${x_library}/X11/%L/%T/%N%C%S:\
1420 ${x_library}/X11/%l/%T/%N%C%S:\
1421 ${x_library}/X11/%T/%N%C%S:\
1422 ${x_library}/X11/%L/%T/%N%S:\
1423 ${x_library}/X11/%l/%T/%N%S:\
1424 ${x_library}/X11/%T/%N%S"
1425     if test x"${x_default_search_path}" = x; then
1426       x_default_search_path=${x_search_path}
1427     else
1428       x_default_search_path="${x_search_path}:${x_default_search_path}"
1429     fi
1430   done
1431 fi
1432 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1433
1434 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1435   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1436 fi
1437
1438 if test x"${x_includes}" = x; then
1439   bitmapdir=/usr/include/X11/bitmaps
1440 else
1441   # accumulate include directories that have X11 bitmap subdirectories
1442   bmd_acc="dummyval"
1443   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1444     if test -d "${bmd}/X11/bitmaps"; then
1445       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1446     fi
1447     if test -d "${bmd}/bitmaps"; then
1448       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1449     fi
1450   done
1451   if test ${bmd_acc} != "dummyval"; then
1452     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1453   fi
1454 fi
1455
1456 HAVE_NS=no
1457 NS_IMPL_COCOA=no
1458 NS_IMPL_GNUSTEP=no
1459 tmp_CPPFLAGS="$CPPFLAGS"
1460 tmp_CFLAGS="$CFLAGS"
1461 CPPFLAGS="$CPPFLAGS -x objective-c"
1462 CFLAGS="$CFLAGS -x objective-c"
1463 GNU_OBJC_CFLAGS=
1464 LIBS_GNUSTEP=
1465 if test "${with_ns}" != no; then
1466   if test "${opsys}" = darwin; then
1467      NS_IMPL_COCOA=yes
1468      ns_appdir=`pwd`/nextstep/Emacs.app
1469      ns_appbindir=${ns_appdir}/Contents/MacOS
1470      ns_appresdir=${ns_appdir}/Contents/Resources
1471      ns_appsrc=Cocoa/Emacs.base
1472   elif test -f $GNUSTEP_CONFIG_FILE; then
1473      NS_IMPL_GNUSTEP=yes
1474      ns_appdir=`pwd`/nextstep/Emacs.app
1475      ns_appbindir=${ns_appdir}
1476      ns_appresdir=${ns_appdir}/Resources
1477      ns_appsrc=GNUstep/Emacs.base
1478      dnl FIXME sourcing this several times in subshells seems inefficient.
1479      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1480      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1481      dnl I seemed to need these as well with GNUstep-startup 0.25.
1482      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1483      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1484      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1485        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1486      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1487        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1488      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1489      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1490      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1491      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1492      LIB_STANDARD=
1493      START_FILES=
1494      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1495      dnl If they had chosen to either define it or not, we could have
1496      dnl just used AC_CHECK_DECL here.
1497      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1498        emacs_cv_objc_exceptions,
1499 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1500 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1501 1;
1502 #else
1503 fail;
1504 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1505      if test $emacs_cv_objc_exceptions = yes; then
1506        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1507        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1508          [Define if GNUstep uses ObjC exceptions.])
1509        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1510      fi
1511   fi
1512
1513   dnl This is only used while we test the NS headers, it gets reset below.
1514   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1515
1516   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1517                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1518   files are missing or cannot be compiled.])])
1519
1520   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1521                                      [
1522 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1523 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1524  ; /* OK */
1525 #else
1526 #error "OSX 10.4 or newer required"
1527 #endif
1528 #endif
1529                     ])],
1530                     ns_osx_have_104=yes,
1531                     ns_osx_have_104=no)
1532   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1533                                      [NSInteger i;])],
1534                     ns_have_nsinteger=yes,
1535                     ns_have_nsinteger=no)
1536   if test $ns_osx_have_104 = no; then
1537      AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1538   fi
1539   if test $ns_have_nsinteger = yes; then
1540     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1541   fi
1542 fi
1543
1544 AC_SUBST(LIBS_GNUSTEP)
1545
1546 INSTALL_ARCH_INDEP_EXTRA=install-etc
1547 ns_self_contained=no
1548 NS_OBJ=
1549 NS_OBJC_OBJ=
1550 if test "${HAVE_NS}" = yes; then
1551   if test "$with_toolkit_scroll_bars" = "no"; then
1552     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1553   fi
1554
1555   window_system=nextstep
1556   # set up packaging dirs
1557   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1558      ns_self_contained=yes
1559      prefix=${ns_appresdir}
1560      exec_prefix=${ns_appbindir}
1561      dnl This one isn't really used, only archlibdir is.
1562      libexecdir="\${ns_appbindir}/libexec"
1563      archlibdir="\${ns_appbindir}/libexec"
1564      docdir="\${ns_appresdir}/etc"
1565      etcdir="\${ns_appresdir}/etc"
1566      dnl FIXME maybe set datarootdir instead.
1567      dnl That would also get applications, icons, man.
1568      infodir="\${ns_appresdir}/info"
1569      mandir="\${ns_appresdir}/man"
1570      lispdir="\${ns_appresdir}/lisp"
1571      leimdir="\${ns_appresdir}/leim"
1572      INSTALL_ARCH_INDEP_EXTRA=
1573   fi
1574   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1575 fi
1576 CFLAGS="$tmp_CFLAGS"
1577 CPPFLAGS="$tmp_CPPFLAGS"
1578 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1579 AC_SUBST(ns_self_contained)
1580 AC_SUBST(NS_OBJ)
1581 AC_SUBST(NS_OBJC_OBJ)
1582 AC_SUBST(LIB_STANDARD)
1583
1584 HAVE_W32=no
1585 W32_OBJ=
1586 W32_LIBS=
1587 if test "${with_w32}" != no; then
1588   if test "${opsys}" != "cygwin"; then
1589     AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin.])
1590   fi
1591   AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1592                   [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1593                   cannot be found.])])
1594   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1595   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1596   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1597   W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1598   W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1599 fi
1600 AC_SUBST(W32_OBJ)
1601 AC_SUBST(W32_LIBS)
1602
1603 if test "${HAVE_W32}" = "yes"; then
1604   window_system=w32
1605   with_xft=no
1606 fi
1607
1608 ## $window_system is now set to the window system we will
1609 ## ultimately use.
1610
1611 term_header=
1612 HAVE_X_WINDOWS=no
1613 HAVE_X11=no
1614 USE_X_TOOLKIT=none
1615
1616 case "${window_system}" in
1617   x11 )
1618     HAVE_X_WINDOWS=yes
1619     HAVE_X11=yes
1620     term_header=xterm.h
1621     case "${with_x_toolkit}" in
1622       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1623       motif ) USE_X_TOOLKIT=MOTIF ;;
1624       gtk ) with_gtk=yes
1625             term_header=gtkutil.h
1626 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1627 dnl USE_X_TOOLKIT is set.
1628             USE_X_TOOLKIT=none ;;
1629       gtk2 ) with_gtk2=yes
1630              term_header=gtkutil.h
1631              USE_X_TOOLKIT=none ;;
1632       gtk3 ) with_gtk3=yes
1633              term_header=gtkutil.h
1634              USE_X_TOOLKIT=none ;;
1635       no ) USE_X_TOOLKIT=none ;;
1636 dnl If user did not say whether to use a toolkit, make this decision later:
1637 dnl use the toolkit if we have gtk, or X11R5 or newer.
1638       * ) USE_X_TOOLKIT=maybe ;;
1639     esac
1640   ;;
1641   nextstep )
1642     term_header=nsterm.h
1643   ;;
1644   w32 )
1645     term_header=w32term.h
1646   ;;
1647 esac
1648
1649 if test -n "${term_header}"; then
1650     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
1651         [Define to the header for the built-in window system.])
1652 fi
1653
1654 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1655    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1656    if test "$HAVE_XSERVER" = true ||
1657       test -n "$DISPLAY" ||
1658       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1659         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1660 were found.  You should install the relevant development files for X
1661 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1662 sure you have development files for image handling, i.e.
1663 tiff, gif, jpeg, png and xpm.
1664 If you are sure you want Emacs compiled without X window support, pass
1665   --without-x
1666 to configure.])
1667    fi
1668 fi
1669
1670 ### If we're using X11, we should use the X menu package.
1671 HAVE_MENUS=no
1672 case ${HAVE_X11} in
1673   yes ) HAVE_MENUS=yes ;;
1674 esac
1675
1676 # Does the opsystem file prohibit the use of the GNU malloc?
1677 # Assume not, until told otherwise.
1678 GNU_MALLOC=yes
1679
1680 AC_CACHE_CHECK(
1681   [whether malloc is Doug Lea style],
1682   [emacs_cv_var_doug_lea_malloc],
1683   [AC_LINK_IFELSE(
1684      [AC_LANG_PROGRAM(
1685         [[#include <malloc.h>
1686           static void hook (void) {}]],
1687         [[malloc_set_state (malloc_get_state ());
1688           __after_morecore_hook = hook;
1689           __malloc_initialize_hook = hook;]])],
1690      [emacs_cv_var_doug_lea_malloc=yes],
1691      [emacs_cv_var_doug_lea_malloc=no])])
1692 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1693
1694
1695 dnl See comments in aix4-2.h about maybe using system malloc there.
1696 system_malloc=no
1697 case "$opsys" in
1698   ## darwin ld insists on the use of malloc routines in the System framework.
1699   darwin|sol2-10) system_malloc=yes ;;
1700 esac
1701
1702 if test "${system_malloc}" = "yes"; then
1703   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1704   GNU_MALLOC=no
1705   GNU_MALLOC_reason="
1706     (The GNU allocators don't work with this system configuration.)"
1707   GMALLOC_OBJ=
1708   VMLIMIT_OBJ=
1709 else
1710   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1711   VMLIMIT_OBJ=vm-limit.o
1712 fi
1713 AC_SUBST(GMALLOC_OBJ)
1714 AC_SUBST(VMLIMIT_OBJ)
1715
1716 if test "$doug_lea_malloc" = "yes" ; then
1717   if test "$GNU_MALLOC" = yes ; then
1718     GNU_MALLOC_reason="
1719       (Using Doug Lea's new malloc from the GNU C Library.)"
1720   fi
1721   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1722             [Define to 1 if you are using the GNU C Library.])
1723
1724   ## Use mmap directly for allocating larger buffers.
1725   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1726   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1727   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1728   case "$opsys" in
1729     gnu*) REL_ALLOC=no ;;
1730   esac
1731 fi
1732
1733 if test x"${REL_ALLOC}" = x; then
1734   REL_ALLOC=${GNU_MALLOC}
1735 fi
1736
1737 use_mmap_for_buffers=no
1738 case "$opsys" in
1739   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1740 esac
1741
1742 AC_FUNC_MMAP
1743 if test $use_mmap_for_buffers = yes; then
1744   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1745   REL_ALLOC=no
1746 fi
1747
1748 LIBS="$LIBS_SYSTEM $LIBS"
1749
1750 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1751 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1752 AC_CHECK_LIB(dnet, dnet_ntoa)
1753 dnl This causes -lresolv to get used in subsequent tests,
1754 dnl which causes failures on some systems such as HPUX 9.
1755 dnl AC_CHECK_LIB(resolv, gethostbyname)
1756
1757 dnl FIXME replace main with a function we actually want from this library.
1758 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1759
1760 dnl Check if pthreads is available.
1761 LIB_PTHREAD=
1762 AC_CHECK_HEADERS_ONCE(pthread.h)
1763 if test "$ac_cv_header_pthread_h"; then
1764   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1765   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1766   dnl testing for pthread_self if Emacs uses gmalloc.c.
1767   if test "$GMALLOC_OBJ" = gmalloc.o; then
1768     emacs_pthread_function=pthread_atfork
1769   else
1770     emacs_pthread_function=pthread_self
1771   fi
1772   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1773 fi
1774 if test "$HAVE_PTHREAD" = yes; then
1775   case "${canonical}" in
1776     *-hpux*) ;;
1777     *) LIB_PTHREAD="-lpthread"
1778        LIBS="$LIB_PTHREAD $LIBS" ;;
1779   esac
1780   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1781 fi
1782 AC_SUBST([LIB_PTHREAD])
1783
1784 AC_CHECK_LIB(pthreads, cma_open)
1785
1786 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1787 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1788 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1789 ## added to LIBS in configure would never contain the pthreads part,
1790 ## but the value used in Makefiles might.  FIXME?
1791 ##
1792 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1793 ## be harmless on older versions of X where it happens to exist.
1794 test "$opsys" = "aix4-2" && \
1795   test $ac_cv_lib_pthreads_cma_open = yes && \
1796   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1797
1798 dnl Check for need for bigtoc support on IBM AIX
1799
1800 case ${host_os} in
1801 aix*)
1802   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1803     case $GCC in
1804     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1805     *) gdb_cv_bigtoc=-bbigtoc ;;
1806     esac
1807
1808     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1809     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1810   ])
1811   ;;
1812 esac
1813
1814 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1815 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1816 # REAL_CPPFLAGS later on.
1817
1818 REAL_CFLAGS="$CFLAGS"
1819 REAL_CPPFLAGS="$CPPFLAGS"
1820
1821 if test "${HAVE_X11}" = "yes"; then
1822   DEFS="$C_SWITCH_X_SITE $DEFS"
1823   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1824   LIBS="-lX11 $LIBS"
1825   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1826   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1827
1828   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1829   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1830   # but it's more convenient here to set LD_RUN_PATH since this
1831   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1832   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1833     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1834     export LD_RUN_PATH
1835   fi
1836
1837   if test "${opsys}" = "gnu-linux"; then
1838     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1839     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1840      [[XOpenDisplay ("foo");]])],
1841      [xgnu_linux_first_failure=no],
1842      [xgnu_linux_first_failure=yes])
1843     if test "${xgnu_linux_first_failure}" = "yes"; then
1844       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1845       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1846       OLD_CPPFLAGS="$CPPFLAGS"
1847       OLD_LIBS="$LIBS"
1848       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1849       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1850       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1851       LIBS="$LIBS -b i486-linuxaout"
1852       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1853        [[XOpenDisplay ("foo");]])],
1854        [xgnu_linux_second_failure=no],
1855        [xgnu_linux_second_failure=yes])
1856       if test "${xgnu_linux_second_failure}" = "yes"; then
1857         # If we get the same failure with -b, there is no use adding -b.
1858         # So take it out.  This plays safe.
1859         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1860         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1861         CPPFLAGS="$OLD_CPPFLAGS"
1862         LIBS="$OLD_LIBS"
1863         AC_MSG_RESULT(no)
1864       else
1865         AC_MSG_RESULT(yes)
1866       fi
1867     else
1868       AC_MSG_RESULT(no)
1869     fi
1870   fi
1871
1872   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1873   # header files included from there.
1874   AC_MSG_CHECKING(for Xkb)
1875   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1876 #include <X11/XKBlib.h>]],
1877         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1878         emacs_xkb=yes, emacs_xkb=no)
1879   AC_MSG_RESULT($emacs_xkb)
1880   if test $emacs_xkb = yes; then
1881     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1882   fi
1883
1884   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1885 XScreenNumberOfScreen)
1886 fi
1887
1888 if test "${window_system}" = "x11"; then
1889   AC_MSG_CHECKING(X11 version 6)
1890   AC_CACHE_VAL(emacs_cv_x11_version_6,
1891   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1892 [[#if XlibSpecificationRelease < 6
1893 fail;
1894 #endif
1895 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1896   if test $emacs_cv_x11_version_6 = yes; then
1897     AC_MSG_RESULT(6 or newer)
1898     AC_DEFINE(HAVE_X11R6, 1,
1899               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1900     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1901     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1902     ## XIM support.
1903     case "$opsys" in
1904       sol2-*) : ;;
1905       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1906            [Define if you have usable X11R6-style XIM support.])
1907          ;;
1908     esac
1909   else
1910     AC_MSG_RESULT(before 6)
1911   fi
1912 fi
1913
1914
1915 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1916 HAVE_RSVG=no
1917 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1918   if test "${with_rsvg}" != "no"; then
1919     RSVG_REQUIRED=2.11.0
1920     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1921
1922     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1923     AC_SUBST(RSVG_CFLAGS)
1924     AC_SUBST(RSVG_LIBS)
1925
1926     if test $HAVE_RSVG = yes; then
1927       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1928       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1929       LIBS="$RSVG_LIBS $LIBS"
1930     fi
1931   fi
1932 fi
1933
1934 HAVE_IMAGEMAGICK=no
1935 if test "${HAVE_X11}" = "yes"; then
1936   if test "${with_imagemagick}" != "no"; then
1937     ## 6.2.8 is the earliest version known to work, but earlier versions
1938     ## might work - let us know if you find one.
1939     ## 6.0.7 does not work.  See bug#7955.
1940     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1941     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1942     AC_SUBST(IMAGEMAGICK_CFLAGS)
1943     AC_SUBST(IMAGEMAGICK_LIBS)
1944
1945     if test $HAVE_IMAGEMAGICK = yes; then
1946       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1947       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1948       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1949       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1950     fi
1951   fi
1952 fi
1953
1954
1955 HAVE_GTK=no
1956 GTK_OBJ=
1957 check_gtk2=no
1958 gtk3_pkg_errors=
1959 if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1960   GLIB_REQUIRED=2.28
1961   GTK_REQUIRED=3.0
1962   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1963
1964   dnl Checks for libraries.
1965   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1966   if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
1967      AC_MSG_ERROR($GTK_PKG_ERRORS)
1968   fi
1969   if test "$pkg_check_gtk" = "yes"; then
1970      AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1971      GTK_OBJ=emacsgtkfixed.o
1972      term_header=gtkutil.h
1973      USE_GTK_TOOLKIT="GTK3"
1974   else
1975      check_gtk2=yes
1976      gtk3_pkg_errors="$GTK_PKG_ERRORS "
1977   fi
1978 fi
1979
1980 if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
1981   GLIB_REQUIRED=2.10
1982   GTK_REQUIRED=2.10
1983   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1984
1985   dnl Checks for libraries.
1986   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1987   if test "$pkg_check_gtk" = "no" &&
1988      { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
1989   then
1990     AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
1991   fi
1992   test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
1993 fi
1994
1995 if test x"$pkg_check_gtk" = xyes; then
1996
1997   AC_SUBST(GTK_CFLAGS)
1998   AC_SUBST(GTK_LIBS)
1999   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2000   CFLAGS="$CFLAGS $GTK_CFLAGS"
2001   LIBS="$GTK_LIBS $LIBS"
2002   dnl Try to compile a simple GTK program.
2003   GTK_COMPILES=no
2004   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
2005   if test "${GTK_COMPILES}" != "yes"; then
2006     if test "$USE_X_TOOLKIT" != "maybe"; then
2007       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2008     fi
2009   else
2010     HAVE_GTK=yes
2011     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2012     GTK_OBJ="gtkutil.o $GTK_OBJ"
2013     USE_X_TOOLKIT=none
2014     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
2015       :
2016     else
2017       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2018        closing open displays.  This is no problem if you just use
2019        one display, but if you use more than one and close one of them
2020        Emacs may crash.]])
2021       sleep 3
2022     fi
2023   fi
2024
2025 fi
2026 AC_SUBST(GTK_OBJ)
2027
2028
2029 if test "${HAVE_GTK}" = "yes"; then
2030
2031   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2032   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2033   if test "$with_toolkit_scroll_bars" != no; then
2034     with_toolkit_scroll_bars=yes
2035   fi
2036
2037   dnl  Check if we have the old file selection dialog declared and
2038   dnl  in the link library.  In 2.x it may be in the library,
2039   dnl  but not declared if deprecated featured has been selected out.
2040   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2041   HAVE_GTK_FILE_SELECTION=no
2042   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2043                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2044 #include <gtk/gtk.h>])
2045   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2046     AC_CHECK_FUNCS(gtk_file_selection_new)
2047   fi
2048
2049
2050   dnl Check for functions introduced in 2.14 and later.
2051   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2052                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2053                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2054                  gtk_orientable_set_orientation \
2055                  gtk_window_set_has_resize_grip)
2056
2057  term_header=gtkutil.h
2058 fi
2059
2060 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2061 dnl other platforms.
2062 HAVE_DBUS=no
2063 DBUS_OBJ=
2064 if test "${with_dbus}" = "yes"; then
2065    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2066    if test "$HAVE_DBUS" = yes; then
2067      LIBS="$LIBS $DBUS_LIBS"
2068      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2069      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2070      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2071      dnl D-Bus 1.5.12.
2072      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2073                     dbus_type_is_valid \
2074                     dbus_validate_bus_name \
2075                     dbus_validate_path \
2076                     dbus_validate_interface \
2077                     dbus_validate_member)
2078      DBUS_OBJ=dbusbind.o
2079    fi
2080 fi
2081 AC_SUBST(DBUS_OBJ)
2082
2083 dnl GSettings has been tested under GNU/Linux only.
2084 HAVE_GSETTINGS=no
2085 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2086    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2087    if test "$HAVE_GSETTINGS" = "yes"; then
2088       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2089       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2090       SETTINGS_LIBS="$GSETTINGS_LIBS"
2091    fi
2092 fi
2093
2094 dnl GConf has been tested under GNU/Linux only.
2095 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2096 HAVE_GCONF=no
2097 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2098    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2099    if test "$HAVE_GCONF" = yes; then
2100       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2101       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2102       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2103       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2104    fi
2105 fi
2106
2107 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2108     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2109     if test "$HAVE_GOBJECT" = "yes"; then
2110        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2111        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2112     fi
2113     SAVE_CFLAGS="$CFLAGS"
2114     SAVE_LIBS="$LIBS"
2115     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2116     LIBS="$SETTINGS_LIBS $LIBS"
2117     AC_CHECK_FUNCS([g_type_init])
2118     CFLAGS="$SAVE_CFLAGS"
2119     LIBS="$SAVE_LIBS"
2120 fi
2121 AC_SUBST(SETTINGS_CFLAGS)
2122 AC_SUBST(SETTINGS_LIBS)
2123
2124
2125 dnl SELinux is available for GNU/Linux only.
2126 HAVE_LIBSELINUX=no
2127 LIBSELINUX_LIBS=
2128 if test "${with_selinux}" = "yes"; then
2129    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2130    if test "$HAVE_LIBSELINUX" = yes; then
2131       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2132       LIBSELINUX_LIBS=-lselinux
2133    fi
2134 fi
2135 AC_SUBST(LIBSELINUX_LIBS)
2136
2137 HAVE_GNUTLS=no
2138 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2139 if test "${with_gnutls}" = "yes" ; then
2140   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2141   if test "${HAVE_GNUTLS}" = "yes"; then
2142     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2143   fi
2144
2145   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2146   LIBS="$LIBGNUTLS_LIBS $LIBS"
2147   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2148
2149   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2150     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2151   fi
2152 fi
2153
2154 AC_SUBST(LIBGNUTLS_LIBS)
2155 AC_SUBST(LIBGNUTLS_CFLAGS)
2156
2157 dnl Do not put whitespace before the #include statements below.
2158 dnl Older compilers (eg sunos4 cc) choke on it.
2159 HAVE_XAW3D=no
2160 LUCID_LIBW=
2161 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2162   if test "$with_xaw3d" != no; then
2163     AC_CACHE_VAL(emacs_cv_xaw3d,
2164     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2165 #include <X11/Intrinsic.h>
2166 #include <X11/Xaw3d/Simple.h>]],
2167       [[]])],
2168       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2169                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2170       emacs_cv_xaw3d=no)])
2171   else
2172     emacs_cv_xaw3d=no
2173   fi
2174   if test $emacs_cv_xaw3d = yes; then
2175     AC_MSG_CHECKING(for xaw3d)
2176     AC_MSG_RESULT([yes; using Lucid toolkit])
2177     USE_X_TOOLKIT=LUCID
2178     HAVE_XAW3D=yes
2179     LUCID_LIBW=-lXaw3d
2180     AC_DEFINE(HAVE_XAW3D, 1,
2181               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2182   else
2183     AC_MSG_CHECKING(for xaw3d)
2184     AC_MSG_RESULT(no)
2185     AC_MSG_CHECKING(for libXaw)
2186     AC_CACHE_VAL(emacs_cv_xaw,
2187     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2188 #include <X11/Intrinsic.h>
2189 #include <X11/Xaw/Simple.h>]],
2190       [[]])],
2191       emacs_cv_xaw=yes,
2192       emacs_cv_xaw=no)])
2193     if test $emacs_cv_xaw = yes; then
2194       AC_MSG_RESULT([yes; using Lucid toolkit])
2195       USE_X_TOOLKIT=LUCID
2196       LUCID_LIBW=-lXaw
2197     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2198       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2199     else
2200       AC_MSG_ERROR([No X toolkit could be found.
2201 If you are sure you want Emacs compiled without an X toolkit, pass
2202   --with-x-toolkit=no
2203 to configure.  Otherwise, install the development libraries for the toolkit
2204 that you want to use (e.g. Gtk+) and re-run configure.])
2205     fi
2206   fi
2207 fi
2208
2209 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2210
2211 LIBXTR6=
2212 if test "${USE_X_TOOLKIT}" != "none"; then
2213   AC_MSG_CHECKING(X11 toolkit version)
2214   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2215   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2216 [[#if XtSpecificationRelease < 6
2217 fail;
2218 #endif
2219 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2220   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2221   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2222     AC_MSG_RESULT(6 or newer)
2223     AC_DEFINE(HAVE_X11XTR6, 1,
2224               [Define to 1 if you have the X11R6 or newer version of Xt.])
2225     LIBXTR6="-lSM -lICE"
2226     case "$opsys" in
2227       ## Use libw.a along with X11R6 Xt.
2228       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2229     esac
2230   else
2231     AC_MSG_RESULT(before 6)
2232   fi
2233
2234 dnl If using toolkit, check whether libXmu.a exists.
2235 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2236   OLDLIBS="$LIBS"
2237   if test x$HAVE_X11XTR6 = xyes; then
2238     LIBS="-lXt -lSM -lICE $LIBS"
2239   else
2240     LIBS="-lXt $LIBS"
2241   fi
2242   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2243   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2244   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2245 fi
2246 AC_SUBST(LIBXTR6)
2247
2248 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2249 dnl Why not just test for libxmu in the normal way?
2250 LIBXMU=-lXmu
2251 case $opsys in
2252   ## These systems don't supply Xmu.
2253   hpux* | aix4-2 )
2254     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2255     ;;
2256 esac
2257 AC_SUBST(LIBXMU)
2258
2259 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2260 if test "${HAVE_X11}" = "yes"; then
2261   if test "${USE_X_TOOLKIT}" != "none"; then
2262     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2263   fi
2264 fi
2265
2266 LIBXP=
2267 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2268   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2269   if test -d /usr/include/openmotif; then
2270     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2271     emacs_cv_openmotif=yes
2272     case "$canonical" in
2273       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2274       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2275       ;;
2276       *)
2277       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2278     esac
2279   else
2280     emacs_cv_openmotif=no
2281   fi
2282   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2283   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2284     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2285 int x = 5;
2286 #else
2287 Motif version prior to 2.1.
2288 #endif]])],
2289     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2290   if test $emacs_cv_motif_version_2_1 = yes; then
2291     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2292     if test x$emacs_cv_openmotif = xyes; then
2293       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2294     fi
2295   else
2296     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2297     # We put this in CFLAGS temporarily to precede other -I options
2298     # that might be in CFLAGS temporarily.
2299     # We put this in CPPFLAGS where it precedes the other -I options.
2300     OLD_CPPFLAGS=$CPPFLAGS
2301     OLD_CFLAGS=$CFLAGS
2302     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2303     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2304     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2305       [[int x = 5;]])],
2306       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2307     if test $emacs_cv_lesstif = yes; then
2308       # Make sure this -I option remains in CPPFLAGS after it is set
2309       # back to REAL_CPPFLAGS.
2310       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2311       # have those other -I options anyway.  Ultimately, having this
2312       # directory ultimately in CPPFLAGS will be enough.
2313       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2314       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2315     else
2316       CFLAGS=$OLD_CFLAGS
2317       CPPFLAGS=$OLD_CPPFLAGS
2318     fi
2319   fi
2320   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2321     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2322 fi
2323
2324 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2325 dnl using Motif or Xaw3d is available, and unless
2326 dnl --with-toolkit-scroll-bars=no was specified.
2327
2328 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2329             [Define to 1 if we should use toolkit scroll bars.])dnl
2330 USE_TOOLKIT_SCROLL_BARS=no
2331 if test "${with_toolkit_scroll_bars}" != "no"; then
2332   if test "${USE_X_TOOLKIT}" != "none"; then
2333     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2334       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2335       HAVE_XAW3D=no
2336       USE_TOOLKIT_SCROLL_BARS=yes
2337     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2338       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2339       USE_TOOLKIT_SCROLL_BARS=yes
2340     fi
2341   elif test "${HAVE_GTK}" = "yes"; then
2342     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2343     USE_TOOLKIT_SCROLL_BARS=yes
2344   elif test "${HAVE_NS}" = "yes"; then
2345     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2346     USE_TOOLKIT_SCROLL_BARS=yes
2347   elif test "${HAVE_W32}" = "yes"; then
2348     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2349     USE_TOOLKIT_SCROLL_BARS=yes
2350   fi
2351 fi
2352
2353 dnl See if XIM is available.
2354 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2355           #include <X11/Xlib.h>
2356           #include <X11/Xresource.h>]],
2357          [[XIMProc  callback;]])],
2358          [HAVE_XIM=yes
2359          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2360          HAVE_XIM=no)
2361
2362 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2363
2364 if test "${with_xim}" != "no"; then
2365   AC_DEFINE(USE_XIM, 1,
2366             [Define to 1 if we should use XIM, if it is available.])
2367 fi
2368
2369
2370 if test "${HAVE_XIM}" != "no"; then
2371   late_CFLAGS=$CFLAGS
2372   if test "$GCC" = yes; then
2373     CFLAGS="$CFLAGS --pedantic-errors"
2374   fi
2375   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2376 #include <X11/Xlib.h>
2377 #include <X11/Xresource.h>]],
2378 [[Display *display;
2379 XrmDatabase db;
2380 char *res_name;
2381 char *res_class;
2382 XIMProc  callback;
2383 XPointer *client_data;
2384 #ifndef __GNUC__
2385 /* If we're not using GCC, it's probably not XFree86, and this is
2386    probably right, but we can't use something like --pedantic-errors.  */
2387 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2388                                            char*, XIMProc, XPointer*);
2389 #endif
2390 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2391    client_data);]])],
2392     [emacs_cv_arg6_star=yes])
2393   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2394          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2395 either XPointer or XPointer*.])dnl
2396   if test "$emacs_cv_arg6_star" = yes; then
2397     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2398   else
2399     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2400   fi
2401   CFLAGS=$late_CFLAGS
2402 fi
2403
2404 ### Start of font-backend (under any platform) section.
2405 # (nothing here yet -- this is a placeholder)
2406 ### End of font-backend (under any platform) section.
2407
2408 ### Start of font-backend (under X11) section.
2409 if test "${HAVE_X11}" = "yes"; then
2410    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2411
2412    ## Use -lXft if available, unless `--with-xft=no'.
2413    HAVE_XFT=maybe
2414     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2415       with_xft="no";
2416     fi
2417     if test "x${with_xft}" != "xno"; then
2418
2419       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2420       ## Because xftfont.c uses XRenderQueryExtension, we also
2421       ## need to link to -lXrender.
2422       HAVE_XRENDER=no
2423       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2424       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2425         OLD_CPPFLAGS="$CPPFLAGS"
2426         OLD_CFLAGS="$CFLAGS"
2427         OLD_LIBS="$LIBS"
2428         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2429         CFLAGS="$CFLAGS $XFT_CFLAGS"
2430         XFT_LIBS="-lXrender $XFT_LIBS"
2431         LIBS="$XFT_LIBS $LIBS"
2432         AC_CHECK_HEADER(X11/Xft/Xft.h,
2433           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2434
2435         if test "${HAVE_XFT}" = "yes"; then
2436           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2437             AC_SUBST(XFT_LIBS)
2438           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2439         else
2440           CPPFLAGS="$OLD_CPPFLAGS"
2441           CFLAGS="$OLD_CFLAGS"
2442           LIBS="$OLD_LIBS"
2443         fi                        # "${HAVE_XFT}" = "yes"
2444       fi                          # "$HAVE_XFT" != no
2445     fi                            # "x${with_xft}" != "xno"
2446
2447     ## We used to allow building with FreeType and without Xft.
2448     ## However, the ftx font backend driver is not in good shape.
2449     if test "$HAVE_XFT" != "yes"; then
2450        dnl For the "Does Emacs use" message at the end.
2451        HAVE_XFT=no
2452        HAVE_FREETYPE=no
2453     else
2454        dnl Strict linkers fail with
2455        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2456        dnl if -lfreetype is not specified.
2457        dnl The following is needed to set FREETYPE_LIBS.
2458        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2459                          HAVE_FREETYPE=no)
2460
2461        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2462     fi
2463
2464     HAVE_LIBOTF=no
2465     if test "${HAVE_FREETYPE}" = "yes"; then
2466       AC_DEFINE(HAVE_FREETYPE, 1,
2467                 [Define to 1 if using the freetype and fontconfig libraries.])
2468       if test "${with_libotf}" != "no"; then
2469         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2470                           HAVE_LIBOTF=no)
2471         if test "$HAVE_LIBOTF" = "yes"; then
2472           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2473           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2474                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2475                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2476           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2477             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2478                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2479           fi
2480         fi
2481       fi
2482     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2483     dnl Does the new font backend require it, or can it work without it?
2484     fi
2485
2486     HAVE_M17N_FLT=no
2487     if test "${HAVE_LIBOTF}" = yes; then
2488       if test "${with_m17n_flt}" != "no"; then
2489         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2490         if test "$HAVE_M17N_FLT" = "yes"; then
2491           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2492         fi
2493       fi
2494     fi
2495 else
2496     HAVE_XFT=no
2497     HAVE_FREETYPE=no
2498     HAVE_LIBOTF=no
2499     HAVE_M17N_FLT=no
2500 fi
2501
2502 ### End of font-backend (under X11) section.
2503
2504 AC_SUBST(FREETYPE_CFLAGS)
2505 AC_SUBST(FREETYPE_LIBS)
2506 AC_SUBST(FONTCONFIG_CFLAGS)
2507 AC_SUBST(FONTCONFIG_LIBS)
2508 AC_SUBST(LIBOTF_CFLAGS)
2509 AC_SUBST(LIBOTF_LIBS)
2510 AC_SUBST(M17N_FLT_CFLAGS)
2511 AC_SUBST(M17N_FLT_LIBS)
2512
2513 ### Use -lXpm if available, unless `--with-xpm=no'.
2514 HAVE_XPM=no
2515 LIBXPM=
2516
2517 if test "${HAVE_W32}" = "yes"; then
2518   if test "${with_xpm}" != "no"; then
2519     SAVE_CPPFLAGS="$CPPFLAGS"
2520     SAVE_LDFLAGS="$LDFLAGS"
2521     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2522     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2523     AC_CHECK_HEADER(X11/xpm.h,
2524       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2525     if test "${HAVE_XPM}" = "yes"; then
2526       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2527       AC_EGREP_CPP(no_return_alloc_pixels,
2528       [#include "X11/xpm.h"
2529 #ifndef XpmReturnAllocPixels
2530 no_return_alloc_pixels
2531 #endif
2532       ], HAVE_XPM=no, HAVE_XPM=yes)
2533
2534       if test "${HAVE_XPM}" = "yes"; then
2535         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2536         AC_MSG_RESULT(yes)
2537       else
2538         AC_MSG_RESULT(no)
2539         CPPFLAGS="$SAVE_CPPFLAGS"
2540         LDFLAGS="$SAVE_LDFLAGS"
2541       fi
2542     fi
2543   fi
2544
2545   if test "${HAVE_XPM}" = "yes"; then
2546     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2547     LIBXPM=-lXpm
2548   fi
2549 fi
2550
2551 if test "${HAVE_X11}" = "yes"; then
2552   if test "${with_xpm}" != "no"; then
2553     AC_CHECK_HEADER(X11/xpm.h,
2554       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2555     if test "${HAVE_XPM}" = "yes"; then
2556       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2557       AC_EGREP_CPP(no_return_alloc_pixels,
2558       [#include "X11/xpm.h"
2559 #ifndef XpmReturnAllocPixels
2560 no_return_alloc_pixels
2561 #endif
2562       ], HAVE_XPM=no, HAVE_XPM=yes)
2563
2564       if test "${HAVE_XPM}" = "yes"; then
2565         AC_MSG_RESULT(yes)
2566       else
2567         AC_MSG_RESULT(no)
2568       fi
2569     fi
2570   fi
2571
2572   if test "${HAVE_XPM}" = "yes"; then
2573     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2574     LIBXPM=-lXpm
2575   fi
2576 fi
2577
2578 AC_SUBST(LIBXPM)
2579
2580 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2581 HAVE_JPEG=no
2582 LIBJPEG=
2583 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2584   if test "${with_jpeg}" != "no"; then
2585     dnl Checking for jpeglib.h can lose because of a redefinition of
2586     dnl  HAVE_STDLIB_H.
2587     AC_CHECK_HEADER(jerror.h,
2588       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2589   fi
2590
2591   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2592   if test "${HAVE_JPEG}" = "yes"; then
2593     AC_DEFINE(HAVE_JPEG)
2594     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2595         [#include <jpeglib.h>
2596          version=JPEG_LIB_VERSION
2597 ],
2598         [AC_DEFINE(HAVE_JPEG)],
2599         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2600         HAVE_JPEG=no])
2601   fi
2602   if test "${HAVE_JPEG}" = "yes"; then
2603     LIBJPEG=-ljpeg
2604   fi
2605 fi
2606 AC_SUBST(LIBJPEG)
2607
2608 ### Use -lpng if available, unless `--with-png=no'.
2609 HAVE_PNG=no
2610 LIBPNG=
2611 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2612   if test "${with_png}" != "no"; then
2613     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2614     # in /usr/include/libpng.
2615     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2616     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2617       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2618     fi
2619   fi
2620
2621   if test "${HAVE_PNG}" = "yes"; then
2622     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2623     LIBPNG="-lpng -lz -lm"
2624
2625     AC_CHECK_DECL(png_longjmp,
2626       [],
2627       [AC_DEFINE(PNG_DEPSTRUCT, [],
2628          [Define to empty to suppress deprecation warnings when building
2629           with --enable-gcc-warnings and with libpng versions before 1.5,
2630           which lack png_longjmp.])],
2631       [[#ifdef HAVE_LIBPNG_PNG_H
2632         # include <libpng/png.h>
2633         #else
2634         # include <png.h>
2635         #endif
2636       ]])
2637   fi
2638 fi
2639 AC_SUBST(LIBPNG)
2640
2641 ### Use -ltiff if available, unless `--with-tiff=no'.
2642 HAVE_TIFF=no
2643 LIBTIFF=
2644 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2645   if test "${with_tiff}" != "no"; then
2646     AC_CHECK_HEADER(tiffio.h,
2647       [tifflibs="-lz -lm"
2648       # At least one tiff package requires the jpeg library.
2649       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2650       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2651   fi
2652
2653   if test "${HAVE_TIFF}" = "yes"; then
2654     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2655     dnl FIXME -lz -lm, as per libpng?
2656     LIBTIFF=-ltiff
2657   fi
2658 fi
2659 AC_SUBST(LIBTIFF)
2660
2661 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2662 HAVE_GIF=no
2663 LIBGIF=
2664 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
2665         || test "${HAVE_W32}" = "yes"; then
2666   AC_CHECK_HEADER(gif_lib.h,
2667 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2668 # Earlier versions can crash Emacs.
2669     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2670
2671   if test "$HAVE_GIF" = yes; then
2672     LIBGIF=-lgif
2673   elif test "$HAVE_GIF" = maybe; then
2674 # If gif_lib.h but no libgif, try libungif.
2675     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2676     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2677   fi
2678
2679   if test "${HAVE_GIF}" = "yes"; then
2680     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2681   fi
2682 fi
2683 AC_SUBST(LIBGIF)
2684
2685 dnl Check for required libraries.
2686 if test "${HAVE_X11}" = "yes"; then
2687   MISSING=""
2688   WITH_NO=""
2689   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2690     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2691   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2692     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2693   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2694     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2695   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2696     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2697   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2698     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2699
2700   if test "X${MISSING}" != X; then
2701     AC_MSG_ERROR([The following required libraries were not found:
2702     $MISSING
2703 Maybe some development libraries/packages are missing?
2704 If you don't want to link with them give
2705     $WITH_NO
2706 as options to configure])
2707   fi
2708 fi
2709
2710 ### Use -lgpm if available, unless `--with-gpm=no'.
2711 HAVE_GPM=no
2712 LIBGPM=
2713 if test "${with_gpm}" != "no"; then
2714   AC_CHECK_HEADER(gpm.h,
2715     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2716
2717   if test "${HAVE_GPM}" = "yes"; then
2718     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2719     LIBGPM=-lgpm
2720   fi
2721 fi
2722 AC_SUBST(LIBGPM)
2723
2724 dnl Check for malloc/malloc.h on darwin
2725 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2726
2727 GNUSTEP_CFLAGS=
2728 ### Use NeXTstep API to implement GUI.
2729 if test "${HAVE_NS}" = "yes"; then
2730   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2731   if test "${NS_IMPL_COCOA}" = "yes"; then
2732     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2733   fi
2734   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2735     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2736     # See also .m.o rule in Makefile.in */
2737     # FIXME: are all these flags really needed?  Document here why.  */
2738     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2739     ## Extra CFLAGS applied to src/*.m files.
2740     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2741   fi
2742   # We also have mouse menus.
2743   HAVE_MENUS=yes
2744   OTHER_FILES=ns-app
2745 fi
2746
2747 if test "${HAVE_W32}" = "yes"; then
2748   HAVE_MENUS=yes
2749 fi
2750
2751 ### Use session management (-lSM -lICE) if available
2752 HAVE_X_SM=no
2753 LIBXSM=
2754 if test "${HAVE_X11}" = "yes"; then
2755   AC_CHECK_HEADER(X11/SM/SMlib.h,
2756     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2757
2758   if test "${HAVE_X_SM}" = "yes"; then
2759     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2760     LIBXSM="-lSM -lICE"
2761     case "$LIBS" in
2762       *-lSM*) ;;
2763       *)      LIBS="$LIBXSM $LIBS" ;;
2764     esac
2765   fi
2766 fi
2767 AC_SUBST(LIBXSM)
2768
2769 ### Use libxml (-lxml2) if available
2770 HAVE_LIBXML2=no
2771 if test "${with_xml2}" != "no"; then
2772   ### I'm not sure what the version number should be, so I just guessed.
2773   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2774   if test "${HAVE_LIBXML2}" = "yes"; then
2775     LIBS="$LIBXML2_LIBS $LIBS"
2776     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2777     if test "${HAVE_LIBXML2}" = "yes"; then
2778       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2779     else
2780       LIBXML2_LIBS=""
2781       LIBXML2_CFLAGS=""
2782     fi
2783   fi
2784 fi
2785 AC_SUBST(LIBXML2_LIBS)
2786 AC_SUBST(LIBXML2_CFLAGS)
2787
2788 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2789 AC_CACHE_CHECK(whether netdb declares h_errno,
2790                emacs_cv_netdb_declares_h_errno,
2791 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2792   [[return h_errno;]])],
2793   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2794 if test $emacs_cv_netdb_declares_h_errno = yes; then
2795   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2796 fi
2797
2798 # sqrt and other floating-point functions such as fmod and frexp
2799 # are found in -lm on most systems.
2800 AC_CHECK_LIB(m, sqrt)
2801
2802 # Check for mail-locking functions in a "mail" library.  Probably this should
2803 # have the same check as for liblockfile below.
2804 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2805 if test $have_mail = yes; then
2806   LIBS_MAIL=-lmail
2807   LIBS="$LIBS_MAIL $LIBS"
2808   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2809 else
2810   LIBS_MAIL=
2811 fi
2812 dnl Debian, at least:
2813 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2814 if test $have_lockfile = yes; then
2815    LIBS_MAIL=-llockfile
2816    LIBS="$LIBS_MAIL $LIBS"
2817    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2818 else
2819 # If we have the shared liblockfile, assume we must use it for mail
2820 # locking (e.g. Debian).  If we couldn't link against liblockfile
2821 # (no liblockfile.a installed), ensure that we don't need to.
2822   dnl This works for files generally, not just executables.
2823   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2824   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2825                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2826   if test $ac_cv_prog_liblockfile = yes; then
2827     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2828 This probably means that movemail could lose mail.
2829 There may be a `development' package to install containing liblockfile.])
2830   fi
2831 fi
2832 AC_CHECK_HEADERS_ONCE(maillock.h)
2833 AC_SUBST(LIBS_MAIL)
2834
2835 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2836 ## interlock access to the mail spool.  The alternative is a lock file named
2837 ## /usr/spool/mail/$USER.lock.
2838 mail_lock=no
2839 case "$opsys" in
2840   aix4-2) mail_lock="lockf" ;;
2841
2842   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2843
2844   ## On GNU/Linux systems, both methods are used by various mail programs.
2845   ## I assume most people are using newer mailers that have heard of flock.
2846   ## Change this if you need to.
2847   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2848   ## configure gets the right answers, and that means *NOT* using flock.
2849   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2850   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2851   ## Debian maintainer hasn't provided a clean fix for Emacs.
2852   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2853   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2854   ## correct logic.  -- fx
2855   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2856   ## liblockfile is a Free Software replacement for libmail, used on
2857   ## Debian systems and elsewhere. -rfr.
2858   gnu-*)
2859     mail_lock="flock"
2860     if test $have_mail = yes || test $have_lockfile = yes; then
2861       test $ac_cv_header_maillock_h = yes && mail_lock=no
2862     fi
2863     ;;
2864 esac
2865
2866 BLESSMAIL_TARGET=
2867 case "$mail_lock" in
2868   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2869
2870   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2871
2872   *) BLESSMAIL_TARGET="need-blessmail" ;;
2873 esac
2874 AC_SUBST(BLESSMAIL_TARGET)
2875
2876
2877 AC_CHECK_FUNCS(gethostname \
2878 closedir getrusage get_current_dir_name \
2879 lrand48 setsid \
2880 fpathconf select euidaccess getpagesize setlocale \
2881 utimes getrlimit setrlimit setpgid getcwd shutdown getaddrinfo \
2882 __fpending strsignal setitimer \
2883 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2884 gai_strerror mkstemp getline getdelim fsync sync \
2885 difftime posix_memalign \
2886 getpwent endpwent getgrent endgrent \
2887 touchlock \
2888 cfmakeraw cfsetspeed copysign __executable_start)
2889
2890 dnl getwd appears to be buggy on SVR4.2, so we don't use it.
2891 if test $opsys = unixware; then
2892   dnl In case some other test ends up checking for getwd.
2893   AC_DEFINE(BROKEN_GETWD, 1, [Define if getwd should not be used.])
2894 else
2895   AC_CHECK_FUNCS(getwd)
2896 fi
2897
2898 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2899 ## has a broken `rint' in some library versions including math library
2900 ## version number A.09.05.
2901 ## You can fix the math library by installing patch number PHSS_4630.
2902 ## But we can fix it more reliably for Emacs by just not using rint.
2903 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
2904 case $opsys in
2905    hpux*) : ;;
2906    *) AC_CHECK_FUNCS(random rint) ;;
2907 esac
2908
2909 dnl Cannot use AC_CHECK_FUNCS
2910 AC_CACHE_CHECK([for __builtin_unwind_init],
2911                emacs_cv_func___builtin_unwind_init,
2912 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2913                 emacs_cv_func___builtin_unwind_init=yes,
2914                 emacs_cv_func___builtin_unwind_init=no)])
2915 if test $emacs_cv_func___builtin_unwind_init = yes; then
2916   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2917             [Define to 1 if you have the `__builtin_unwind_init' function.])
2918 fi
2919
2920 AC_CHECK_HEADERS_ONCE(sys/un.h)
2921
2922 AC_FUNC_FSEEKO
2923
2924 AC_FUNC_GETPGRP
2925
2926 # UNIX98 PTYs.
2927 AC_CHECK_FUNCS(grantpt)
2928
2929 # PTY-related GNU extensions.
2930 AC_CHECK_FUNCS(getpt posix_openpt)
2931
2932 # Check this now, so that we will NOT find the above functions in ncurses.
2933 # That is because we have not set up to link ncurses in lib-src.
2934 # It's better to believe a function is not available
2935 # than to expect to find it in ncurses.
2936 # Also we need tputs and friends to be able to build at all.
2937 AC_MSG_CHECKING([for library containing tputs])
2938 # Run a test program that contains a call to tputs, a call that is
2939 # never executed.  This tests whether a pre-'main' dynamic linker
2940 # works with the library.  It's too much trouble to actually call
2941 # tputs in the test program, due to portability hassles.  When
2942 # cross-compiling, assume the test program will run if it links.
2943 AC_DEFUN([tputs_link_source], [
2944   AC_LANG_SOURCE(
2945      [[extern void tputs (const char *, int, int (*)(int));
2946        int main (int argc, char **argv)
2947        {
2948           if (argc == 10000)
2949             tputs (argv[0], 0, 0);
2950           return 0;
2951        }]])
2952 ])
2953 # Maybe curses should be tried earlier?
2954 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2955 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2956   OLIBS=$LIBS
2957   if test -z "$tputs_library"; then
2958     LIBS_TERMCAP=
2959     msg='none required'
2960   else
2961     LIBS_TERMCAP=-l$tputs_library
2962     msg=$LIBS_TERMCAP
2963     LIBS="$LIBS_TERMCAP $LIBS"
2964   fi
2965   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2966     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2967   LIBS=$OLIBS
2968   if test "X$msg" != Xno; then
2969     break
2970   fi
2971 done
2972 AC_MSG_RESULT([$msg])
2973 if test "X$msg" = Xno; then
2974   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2975 The following libraries were tried (in order):
2976   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2977 Please try installing whichever of these libraries is most appropriate
2978 for your system, together with its header files.
2979 For example, a libncurses-dev(el) or similar package.])
2980 fi
2981
2982 ## Use termcap instead of terminfo?
2983 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2984 TERMINFO=yes
2985 ## FIXME?  In the cases below where we unconditionally set
2986 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2987 ## if that was found above to have tputs.
2988 ## Should we use the gnu* logic everywhere?
2989 case "$opsys" in
2990   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2991   ##  The ncurses library has been moved out of the System framework in
2992   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2993   ##  option to use it.
2994   darwin) LIBS_TERMCAP="-lncurses" ;;
2995
2996   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2997
2998   freebsd)
2999     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3000     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3001     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3002 [[#if __FreeBSD_version < 400000
3003 fail;
3004 #endif
3005 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3006
3007     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3008
3009     if test $emacs_cv_freebsd_terminfo = yes; then
3010       LIBS_TERMCAP="-lncurses"
3011     else
3012       TERMINFO=no
3013       LIBS_TERMCAP="-ltermcap"
3014     fi
3015     ;;
3016
3017   netbsd)
3018     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3019       TERMINFO=no
3020       LIBS_TERMCAP="-ltermcap"
3021     fi
3022     ;;
3023
3024   openbsd) LIBS_TERMCAP="-lncurses" ;;
3025
3026   ## hpux: Make sure we get select from libc rather than from libcurses
3027   ##  because libcurses on HPUX 10.10 has a broken version of select.
3028   ##  We used to use -lc -lcurses, but this may be cleaner.
3029   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3030   # set that way, now it uses the default).  Isn't this a contradiction?
3031   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3032
3033 esac
3034
3035 TERMCAP_OBJ=tparam.o
3036 if test $TERMINFO = yes; then
3037   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3038   TERMCAP_OBJ=terminfo.o
3039 fi
3040 AC_SUBST(LIBS_TERMCAP)
3041 AC_SUBST(TERMCAP_OBJ)
3042
3043
3044 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3045 # On Darwin, res_init appears not to be useful: see bug#562 and
3046 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3047 resolv=no
3048
3049 if test $opsys != darwin; then
3050
3051   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3052 #include <arpa/nameser.h>
3053 #include <resolv.h>]],
3054     [[return res_init();]])],
3055     have_res_init=yes, have_res_init=no)
3056   if test "$have_res_init" = no; then
3057     OLIBS="$LIBS"
3058     LIBS="$LIBS -lresolv"
3059     AC_MSG_CHECKING(for res_init with -lresolv)
3060     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3061 #include <arpa/nameser.h>
3062 #include <resolv.h>]],
3063       [[return res_init();]])],
3064       have_res_init=yes, have_res_init=no)
3065     AC_MSG_RESULT($have_res_init)
3066     if test "$have_res_init" = yes ; then
3067       resolv=yes
3068     fi
3069     LIBS="$OLIBS"
3070   fi
3071
3072   if test "$have_res_init" = yes; then
3073     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3074   fi
3075 fi                              dnl !darwin
3076
3077 # Do we need the Hesiod library to provide the support routines?
3078 dnl FIXME?  Should we be skipping this on Darwin too?
3079 LIBHESIOD=
3080 if test "$with_hesiod" != no ; then
3081   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3082   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3083      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3084                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3085   if test "$resolv" = yes ; then
3086     RESOLVLIB=-lresolv
3087   else
3088     RESOLVLIB=
3089   fi
3090   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3091         hesiod=yes, :, $RESOLVLIB)])
3092
3093   if test x"$hesiod" = xyes; then
3094     AC_DEFINE(HAVE_LIBHESIOD, 1,
3095               [Define to 1 if you have the hesiod library (-lhesiod).])
3096     LIBHESIOD=-lhesiod
3097   fi
3098 fi
3099 AC_SUBST(LIBHESIOD)
3100
3101 # Do we need libresolv (due to res_init or Hesiod)?
3102 if test "$resolv" = yes && test $opsys != darwin; then
3103   AC_DEFINE(HAVE_LIBRESOLV, 1,
3104             [Define to 1 if you have the resolv library (-lresolv).])
3105   LIBRESOLV=-lresolv
3106 else
3107   LIBRESOLV=
3108 fi
3109 AC_SUBST(LIBRESOLV)
3110
3111 # These tell us which Kerberos-related libraries to use.
3112 COM_ERRLIB=
3113 CRYPTOLIB=
3114 KRB5LIB=
3115 DESLIB=
3116 KRB4LIB=
3117
3118 if test "${with_kerberos}" != no; then
3119   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3120   if test $have_com_err = yes; then
3121     COM_ERRLIB=-lcom_err
3122     LIBS="$COM_ERRLIB $LIBS"
3123     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
3124   fi
3125   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3126   if test $have_crypto = yes; then
3127     CRYPTOLIB=-lcrypto
3128     LIBS="$CRYPTOLIB $LIBS"
3129     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3130   fi
3131   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3132   if test $have_k5crypto = yes; then
3133     CRYPTOLIB=-lk5crypto
3134     LIBS="$CRYPTOLIB $LIBS"
3135     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3136   fi
3137   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3138   if test $have_krb5=yes; then
3139     KRB5LIB=-lkrb5
3140     LIBS="$KRB5LIB $LIBS"
3141     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3142   fi
3143   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3144   if test "${with_kerberos5}" = no; then
3145     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3146     if test $have_des425 = yes; then
3147       DESLIB=-ldes425
3148       LIBS="$DESLIB $LIBS"
3149       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3150     else
3151       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3152       if test $have_des = yes; then
3153         DESLIB=-ldes
3154         LIBS="$DESLIB $LIBS"
3155         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3156       fi
3157     fi
3158     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3159     if test $have_krb4 = yes; then
3160       KRB4LIB=-lkrb4
3161       LIBS="$KRB4LIB $LIBS"
3162       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3163     else
3164       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3165       if test $have_krb = yes; then
3166         KRB4LIB=-lkrb
3167         LIBS="$KRB4LIB $LIBS"
3168         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3169       fi
3170     fi
3171   fi
3172
3173   if test "${with_kerberos5}" != no; then
3174     AC_CHECK_HEADERS(krb5.h,
3175       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3176                         [#include <krb5.h>])])
3177   else
3178     AC_CHECK_HEADERS(des.h,,
3179                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3180                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3181     AC_CHECK_HEADERS(krb.h,,
3182                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3183                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3184   fi
3185   AC_CHECK_HEADERS(com_err.h)
3186 fi
3187
3188 AC_SUBST(COM_ERRLIB)
3189 AC_SUBST(CRYPTOLIB)
3190 AC_SUBST(KRB5LIB)
3191 AC_SUBST(DESLIB)
3192 AC_SUBST(KRB4LIB)
3193
3194 AC_CHECK_FUNCS_ONCE(tzset)
3195 AC_MSG_CHECKING(whether localtime caches TZ)
3196 AC_CACHE_VAL(emacs_cv_localtime_cache,
3197 [if test x$ac_cv_func_tzset = xyes; then
3198 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3199 char TZ_GMT0[] = "TZ=GMT0";
3200 char TZ_PST8[] = "TZ=PST8";
3201 main()
3202 {
3203   time_t now = time ((time_t *) 0);
3204   int hour_GMT0, hour_unset;
3205   if (putenv (TZ_GMT0) != 0)
3206     exit (1);
3207   hour_GMT0 = localtime (&now)->tm_hour;
3208   unsetenv("TZ");
3209   hour_unset = localtime (&now)->tm_hour;
3210   if (putenv (TZ_PST8) != 0)
3211     exit (1);
3212   if (localtime (&now)->tm_hour == hour_GMT0)
3213     exit (1);
3214   unsetenv("TZ");
3215   if (localtime (&now)->tm_hour != hour_unset)
3216     exit (1);
3217   exit (0);
3218 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3219 [# If we have tzset, assume the worst when cross-compiling.
3220 emacs_cv_localtime_cache=yes])
3221 else
3222         # If we lack tzset, report that localtime does not cache TZ,
3223         # since we can't invalidate the cache if we don't have tzset.
3224         emacs_cv_localtime_cache=no
3225 fi])dnl
3226 AC_MSG_RESULT($emacs_cv_localtime_cache)
3227 if test $emacs_cv_localtime_cache = yes; then
3228   AC_DEFINE(LOCALTIME_CACHE, 1,
3229             [Define to 1 if localtime caches TZ.])
3230 fi
3231
3232 ok_so_far=yes
3233 AC_CHECK_FUNC(socket, , ok_so_far=no)
3234 if test $ok_so_far = yes; then
3235   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3236 fi
3237 if test $ok_so_far = yes; then
3238   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3239 fi
3240 if test $ok_so_far = yes; then
3241 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3242   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3243             [Define to 1 if you have inet sockets.])
3244 fi
3245
3246 if test -f /usr/lpp/X11/bin/smt.exp; then
3247   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3248             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3249 fi
3250
3251 AC_MSG_CHECKING(whether system supports dynamic ptys)
3252 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3253   AC_MSG_RESULT(yes)
3254   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3255 else
3256   AC_MSG_RESULT(no)
3257 fi
3258
3259 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3260 dnl This can be removed once we assume Autoconf 2.70.
3261 case $canonical in
3262   *-solaris2.4 | *-solaris2.4.*)
3263     dnl Disable the Autoconf-generated vfork test.
3264     : ${ac_cv_func_vfork_works=no};;
3265 esac
3266
3267 AC_FUNC_FORK
3268
3269 AC_CHECK_FUNCS(snprintf)
3270
3271 dnl Adapted from Haible's version.
3272 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3273   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3274     [[char* cs = nl_langinfo(CODESET);]])],
3275     emacs_cv_langinfo_codeset=yes,
3276     emacs_cv_langinfo_codeset=no)
3277   ])
3278 if test $emacs_cv_langinfo_codeset = yes; then
3279   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3280     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3281 fi
3282
3283 AC_TYPE_MBSTATE_T
3284
3285 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3286   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3287                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3288 if test "$emacs_cv_c_restrict_arr" = yes; then
3289   AC_DEFINE(__restrict_arr, __restrict,
3290     [Define to compiler's equivalent of C99 restrict keyword in array
3291      declarations.  Define as empty for no equivalent.])
3292 fi
3293
3294 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3295 dnl how the tty code is related to POSIX and/or other versions of termios.
3296 dnl The following looks like a useful start.
3297 dnl
3298 dnl AC_SYS_POSIX_TERMIOS
3299 dnl if test $ac_cv_sys_posix_termios = yes; then
3300 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3301 dnl                                and macros for terminal control.])
3302 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3303 dnl fi
3304
3305 dnl Turned on June 1996 supposing nobody will mind it.
3306 AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3307   in the full name stands for the login id.])
3308
3309 dnl Every platform that uses configure (ie every non-MS platform)
3310 dnl supports this.  There is a create-lockfiles option you can
3311 dnl customize if you do not want the lock files to be written.
3312 dnl So it is not clear that this #define still needs to exist.
3313 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3314   so that Emacs can tell instantly when you try to modify a file that
3315   someone else has modified in his/her Emacs.])
3316
3317 dnl Everybody supports this, except MS.
3318 dnl Seems like the kind of thing we should be testing for, though.
3319 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3320 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3321
3322 dnl Everybody supports this, except MS-DOS.
3323 dnl Seems like the kind of thing we should be testing for, though.
3324 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3325 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3326   4.2-compatible sockets.])
3327
3328 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3329
3330 AC_DEFINE(NULL_DEVICE, ["/dev/null"], [Name of the file to open to get
3331   a null file, or a data sink.])
3332
3333 AC_DEFINE(SEPCHAR, [':'], [Character that separates PATH elements.])
3334
3335 dnl Everybody supports this, except MS-DOS.
3336 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3337
3338 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3339
3340
3341 AC_DEFINE(DIRECTORY_SEP, ['/'],
3342   [Character that separates directories in a file name.])
3343
3344 dnl Only used on MS platforms.
3345 AH_TEMPLATE(DEVICE_SEP, [Character that separates a device in a file name.])
3346
3347 AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3348   [Returns true if character is a device separator.])
3349
3350 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3351   [Returns true if character is a directory separator.])
3352
3353 dnl On MS, this also accepts IS_DEVICE_SEP.
3354 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3355   [Returns true if character is any form of separator.])
3356
3357
3358 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3359
3360 case $opsys in
3361   aix4-2)
3362     dnl Unfortunately without libXmu we cannot support EditRes.
3363     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3364       AC_DEFINE(NO_EDITRES, 1)
3365     fi
3366     ;;
3367
3368   hpux*)
3369     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3370     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3371     AC_DEFINE(NO_EDITRES, 1)
3372     ;;
3373 esac
3374
3375
3376 case $opsys in
3377   irix6-5 | sol2* | unixware )
3378     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3379     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3380     dnl need the constant to dimension an array.  So wire in the appropriate
3381     dnl value here.
3382     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3383     ;;
3384 esac
3385
3386 emacs_broken_SIGIO=no
3387
3388 case $opsys in
3389   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3390   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3391   hpux* | irix6-5 | openbsd | sol2* | unixware )
3392     emacs_broken_SIGIO=yes
3393     ;;
3394
3395   aix4-2)
3396     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3397     dnl the way this system works, libc functions that return malloced
3398     dnl memory use the libc malloc implementation. Calling xfree or
3399     dnl xrealloc on the results of such functions results in a crash.
3400     dnl
3401     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3402     dnl but that does not currently work on this system.
3403     dnl
3404     dnl It is possible to completely override the malloc implementation on
3405     dnl AIX, but that involves putting the malloc functions in a shared
3406     dnl library and setting the MALLOCTYPE environment variable to point to
3407     dnl that shared library.
3408     dnl
3409     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3410     dnl to avoid a crash just use the Emacs implementation for that function.
3411     dnl
3412     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3413     dnl of this file, so that we do not check for get_current_dir_name
3414     dnl on AIX.  But that might be fragile if something else ends
3415     dnl up testing for get_current_dir_name as a dependency.
3416     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3417       get_current_dir_name should not be used.])
3418     ;;
3419
3420   freebsd)
3421     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3422     dnl writes/reads on a PTY, read(2) returns bogus data:
3423     dnl
3424     dnl write(2)  1022 bytes
3425     dnl write(2)   954 bytes, get EAGAIN
3426     dnl read(2)   1024 bytes in process_read_output
3427     dnl read(2)     11 bytes in process_read_output
3428     dnl
3429     dnl That is, read(2) returns more bytes than have ever been written
3430     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3431     dnl successfully after processing (for example with CRs added if the
3432     dnl terminal is set up that way which it is here).  The same bytes will
3433     dnl be seen again in a later read(2), without the CRs.
3434     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3435       work around an issue when reading from a PTY.])
3436     ;;
3437 esac
3438
3439 case $opsys in
3440   gnu-* | sol2-10 )
3441     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3442     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3443   ;;
3444 esac
3445
3446 case $opsys in
3447   darwin | freebsd | netbsd | openbsd )
3448     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3449       close a pty to make it a controlling terminal (it is already a
3450       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3451   ;;
3452 esac
3453
3454 dnl FIXME Surely we can test for this rather than hard-code it.
3455 case $opsys in
3456   netbsd | openbsd) sound_device="/dev/audio" ;;
3457   *) sound_device="/dev/dsp" ;;
3458 esac
3459
3460 dnl Used in sound.c
3461 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3462   [Name of the default sound device.])
3463
3464
3465 dnl Emacs can read input using SIGIO and buffering characters itself,
3466 dnl or using CBREAK mode and making C-g cause SIGINT.
3467 dnl The choice is controlled by the variable interrupt_input.
3468 dnl
3469 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3470 dnl
3471 dnl Emacs uses the presence of the USABLE_SIGIO macro
3472 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3473 dnl INTERRUPT_INPUT to decide whether to use it by default.
3474 dnl
3475 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3476 dnl CBREAK mode has two disadvantages
3477 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3478 dnl I hear that in system V this problem does not exist.
3479 dnl 2) Control-G causes output to be discarded.
3480 dnl I do not know whether this can be fixed in system V.
3481 dnl
3482 dnl Another method of doing input is planned but not implemented.
3483 dnl It would have Emacs fork off a separate process
3484 dnl to read the input and send it to the true Emacs process
3485 dnl through a pipe.
3486 case $opsys in
3487   darwin | gnu-linux | gnu-kfreebsd )
3488     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3489   ;;
3490 esac
3491
3492
3493 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3494 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3495 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3496 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3497 dnl taking float or double parameters.
3498 case $opsys in
3499   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3500     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3501       file defines `NeedWidePrototypes' as `NO'.])
3502   ;;
3503 esac
3504
3505
3506 dnl Used in process.c, this must be a loop, even if it only runs once.
3507 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3508 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3509 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3510 dnl trying suffixes 0-16.
3511 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3512   first PTY, if PTYs are supported.])
3513 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3514 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3515   end of a PTY, if non-standard.])
3516 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3517   end of a PTY, if non-standard.])
3518
3519 case $opsys in
3520   aix4-2 )
3521     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3522     dnl You allocate a pty by opening /dev/ptc to get the master side.
3523     dnl To get the name of the slave side, you just ttyname() the master side.
3524     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3525     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3526     ;;
3527
3528   cygwin )
3529     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3530     dnl multi-line AC_DEFINEs are hard. :(
3531     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (0)])
3532     AC_DEFINE(PTY_NAME_SPRINTF, [])
3533     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3534     ;;
3535
3536   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
3537   darwin )
3538     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3539     dnl Not used, because PTY_ITERATION is defined.
3540     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3541     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3542     dnl But we don't have to block SIGCHLD because it is blocked in the
3543     dnl implementation of grantpt.
3544     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3545     AC_DEFINE(PTY_NAME_SPRINTF, [])
3546     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3547     ;;
3548
3549   gnu | openbsd )
3550     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3551     ;;
3552
3553   gnu-linux | gnu-kfreebsd | freebsd | netbsd )
3554     dnl if HAVE_GRANTPT
3555     if test "x$ac_cv_func_grantpt" = xyes; then
3556       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3557       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3558       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3559       dnl to prevent sigchld_handler from intercepting the child's death.
3560       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3561       dnl if HAVE_POSIX_OPENPT
3562       if test "x$ac_cv_func_posix_openpt" = xyes; then
3563         AC_DEFINE(PTY_OPEN, [fd = posix_openpt (O_RDWR | O_NOCTTY)])
3564         AC_DEFINE(PTY_NAME_SPRINTF, [])
3565       dnl if HAVE_GETPT
3566       elif test "x$ac_cv_func_getpt" = xyes; then
3567         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3568         AC_DEFINE(PTY_NAME_SPRINTF, [])
3569       else
3570         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3571       fi
3572     else
3573       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3574     fi
3575     ;;
3576
3577   hpux*)
3578     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3579     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3580     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3581     ;;
3582
3583   irix6-5 )
3584     dnl It looks like this cannot be right, because it is not a loop.
3585     dnl However, process.c actually does this:
3586     dnl # ifndef __sgi
3587     dnl   continue;
3588     dnl # else
3589     dnl   return -1;
3590     dnl # endif
3591     dnl which presumably makes it OK, since irix == sgi (?).
3592     dnl FIXME it seems like this special treatment is unnecessary?
3593     dnl Why can't irix use a single-trip loop like eg cygwin?
3594     AC_DEFINE(PTY_ITERATION, [])
3595     dnl Not used, because PTY_ITERATION is defined.
3596     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3597     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
3598     dnl No need to get the pty name at all.
3599     AC_DEFINE(PTY_NAME_SPRINTF, [])
3600     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3601     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3602     ;;
3603
3604   sol2* )
3605     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3606     dnl from intercepting that death.  If any child but grantpt's should die
3607     dnl within, it should be caught after sigrelse(2).
3608     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3609     ;;
3610
3611   unixware )
3612     dnl Comments are as per sol2*.
3613     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3614     ;;
3615 esac
3616
3617
3618 case $opsys in
3619   sol2* | unixware )
3620     dnl This change means that we don't loop through allocate_pty too
3621     dnl many times in the (rare) event of a failure.
3622     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3623     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3624     dnl Push various streams modules onto a PTY channel.  Used in process.c.
3625     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
3626     ;;
3627 esac
3628
3629
3630 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3631 "typing" a signal character on the pty.])
3632
3633 case $opsys in
3634   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3635   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3636   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd | darwin )
3637     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3638     ;;
3639
3640   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3641   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3642   gnu-linux | gnu-kfreebsd )
3643
3644     AC_MSG_CHECKING([for signals via characters])
3645     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3646 #include <linux/version.h>
3647 #if LINUX_VERSION_CODE < 0x20400
3648 # error "Linux version too old"
3649 #endif
3650       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3651
3652     AC_MSG_RESULT([$emacs_signals_via_chars])
3653     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3654     ;;
3655 esac
3656
3657
3658 dnl Used in dispnew.c
3659 AH_TEMPLATE(PENDING_OUTPUT_COUNT, [Number of chars of output in the
3660   buffer of a stdio stream.])
3661
3662 AC_MSG_CHECKING([whether we are using the GNU C library])
3663 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3664 #include <features.h>
3665 #ifndef __GNU_LIBRARY__
3666 # error "this is not the GNU C library"
3667 #endif
3668   ]], [[]])], emacs_glibc=yes, emacs_glibc=no)
3669 AC_MSG_RESULT([$emacs_glibc])
3670
3671 if test $emacs_glibc = yes; then
3672
3673   emacs_pending_output=unknown
3674
3675   case $opsys in
3676     gnu | gnu-linux | gnu-kfreebsd )
3677       AC_MSG_CHECKING([for style of pending output formalism])
3678       dnl In autoconf 2.67 and later, we could use a single test
3679       dnl since the preprocessed output is accessible in "conftest.i".
3680       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3681 #include <stdio.h>
3682 #if !defined (_IO_STDIO_H) && !defined (_STDIO_USES_IOSTREAM)
3683 # error "stdio definitions not found"
3684 #endif
3685         ]], [[]])], emacs_pending_output=new, [])
3686
3687       if test $emacs_pending_output = unknown; then
3688         case $opsys in
3689           gnu-linux | gnu-kfreebsd)
3690             AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3691 #include <stdio.h>
3692 #ifndef __UCLIBC__
3693 # error "not using uclibc"
3694 #endif
3695             ]], [[]])], emacs_pending_output=uclibc, emacs_pending_output=old)
3696             ;;
3697         esac
3698       fi
3699
3700       AC_MSG_RESULT([$emacs_pending_output])
3701
3702       case $emacs_pending_output in
3703         new)
3704           dnl New C libio names.
3705           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3706             [((FILE)->_IO_write_ptr - (FILE)->_IO_write_base)])
3707           ;;
3708         uclibc)
3709           dnl Using the uClibc library.
3710           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3711             [((FILE)->__bufpos - (FILE)->__bufstart)])
3712           ;;
3713         old)
3714           dnl Old C++ iostream names.
3715           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3716             [((FILE)->_pptr - (FILE)->_pbase)])
3717           ;;
3718       esac
3719     ;;
3720   esac                          dnl opsys
3721
3722   if test $emacs_pending_output = unknown; then
3723     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__bufp - (FILE)->__buffer)])
3724   fi
3725
3726 else                            dnl !emacs_glibc
3727
3728   case $opsys in
3729     cygwin | darwin | freebsd | netbsd | openbsd )
3730       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_p - (FILE)->_bf._base)])
3731       ;;
3732
3733     unixware)
3734       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__ptr - (FILE)->__base)])
3735       ;;
3736
3737     *)
3738       dnl HAVE_STDIO_EXT_H && HAVE___FPENDING
3739       if test x$ac_cv_header_stdio_ext_h = xyes && \
3740         test x$ac_cv_func___fpending = xyes; then
3741         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [__fpending (FILE)])
3742         AC_DEFINE(DISPNEW_NEEDS_STDIO_EXT, 1,
3743           [Define if dispnew.c should include stdio_ext.h.])
3744       else
3745         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_ptr - (FILE)->_base)])
3746       fi
3747       ;;
3748   esac
3749 fi                              dnl emacs_glibc
3750
3751
3752 dnl Used in vm-limit.c
3753 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3754 dnl Used in lisp.h, emacs.c, mem-limits.h
3755 dnl NEWS.18 describes this as "a number which contains
3756 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3757 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3758 stored in a Lisp_Object.])
3759 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3760
3761 case $opsys in
3762   gnu)
3763     dnl libc defines data_start.
3764     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3765     ;;
3766
3767   aix*)
3768     dnl This works with 32-bit executables; Emacs doesn't support 64-bit.
3769     AC_DEFINE(DATA_START, [0x20000000])
3770     AC_DEFINE(DATA_SEG_BITS, [0x20000000])
3771     ;;
3772   hpux*)
3773     dnl The data segment on this machine always starts at address 0x40000000.
3774     AC_DEFINE(DATA_START, [0x40000000])
3775     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3776     ;;
3777   irix6-5)
3778     AC_DEFINE(DATA_START, [0x10000000])
3779     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3780     ;;
3781 esac
3782
3783
3784 AH_TEMPLATE(ULIMIT_BREAK_VALUE, [Undocumented.])
3785 AH_TEMPLATE(TAB3, [Undocumented.])
3786
3787 case $opsys in
3788   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3789
3790   gnu | freebsd | netbsd | openbsd )
3791     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
3792     AC_DEFINE(TAB3, OXTABS)
3793     ;;
3794
3795   gnu-linux | gnu-kfreebsd )
3796     dnl libc-linux/sysdeps/linux/i386/ulimit.c says that due to shared
3797     dnl library, we cannot get the maximum address for brk.
3798     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3799 #ifndef __i386__
3800 # error "not i386"
3801 #endif
3802       ]], [[]])], AC_DEFINE(ULIMIT_BREAK_VALUE, [(32*1024*1024)]), [])
3803
3804     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3805 #ifndef __ia64__
3806 # error "not ia64"
3807 #endif
3808       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
3809         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
3810         [Mark a secondary stack, like the register stack on the ia64.]), [])
3811     ;;
3812
3813   hpux*)
3814     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3815       run_time_remap; for HPUX.])
3816     ;;
3817
3818   irix6-5)
3819     dnl Ulimit(UL_GMEMLIM) is busted...
3820     AC_DEFINE(ULIMIT_BREAK_VALUE, [0x14000000])
3821     ;;
3822 esac
3823
3824
3825 dnl These won't be used automatically yet.  We also need to know, at least,
3826 dnl that the stack is continuous.
3827 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
3828   registers relevant for conservative garbage collection in the jmp_buf.])
3829
3830 AH_TEMPLATE(GC_MARK_STACK, [Define to GC_USE_GCPROS_AS_BEFORE if
3831   conservative garbage collection is not known to work.])
3832
3833
3834 case $opsys in
3835   hpux* | unixware)
3836     dnl Conservative garbage collection has not been tested, so for now
3837     dnl play it safe and stick with the old-fashioned way of marking.
3838     AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE])
3839     ;;
3840
3841   dnl Not all the architectures are tested, but there are Debian packages
3842   dnl for SCM and/or Guile on them, so the technique must work.  See also
3843   dnl comments in alloc.c concerning setjmp and gcc.
3844   dnl Fixme: it's probably safe to just use the GCC conditional below.
3845   gnu-linux | gnu-kfreebsd )
3846     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3847 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
3848   || defined __alpha__ || defined __mips__ || defined __s390__ \
3849   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
3850   || defined __ia64__ || defined __sh__
3851 /* ok */
3852 #else
3853 # error "setjmp not known to work on this arch"
3854 #endif
3855     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1),
3856       AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE]) )
3857     ;;
3858 esac
3859
3860
3861 if test x$GCC = xyes; then
3862    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
3863    AC_DEFINE(GC_SETJMP_WORKS, 1)
3864 else
3865   case $opsys in
3866     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
3867     freebsd | netbsd | openbsd | irix6-5 | sol2* )
3868       AC_DEFINE(GC_SETJMP_WORKS, 1)
3869       ;;
3870   esac
3871 fi                              dnl GCC?
3872
3873 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
3874   [AC_LINK_IFELSE(
3875      [AC_LANG_PROGRAM(
3876        [[#include <setjmp.h>
3877        ]],
3878        [[jmp_buf j;
3879          if (! _setjmp (j))
3880            _longjmp (j, 1);]])],
3881      [emacs_cv_func__setjmp=yes],
3882      [emacs_cv_func__setjmp=no])])
3883 if test $emacs_cv_func__setjmp = yes; then
3884   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
3885 else
3886   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
3887     [AC_LINK_IFELSE(
3888        [AC_LANG_PROGRAM(
3889          [[#include <setjmp.h>
3890          ]],
3891          [[sigjmp_buf j;
3892            if (! sigsetjmp (j, 1))
3893              siglongjmp (j, 1);]])],
3894        [emacs_cv_func_sigsetjmp=yes],
3895        [emacs_cv_func_sigsetjmp=no])])
3896   if test $emacs_cv_func_sigsetjmp = yes; then
3897     AC_DEFINE([HAVE_SIGSETJMP], 1,
3898       [Define to 1 if sigsetjmp and siglongjmp work.
3899        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
3900   fi
3901 fi
3902
3903 case $opsys in
3904   sol2* | unixware )
3905     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
3906     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
3907     dnl and this is all we need.
3908     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
3909     ;;
3910 esac
3911
3912
3913 case $opsys in
3914   hpux* | sol2* )
3915     dnl Used in xfaces.c.
3916     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3917       some systems, where it requires time.h.])
3918     ;;
3919 esac
3920
3921
3922 dnl Define symbols to identify the version of Unix this is.
3923 dnl Define all the symbols that apply correctly.
3924 AH_TEMPLATE(BSD4_2, [Define if the system is compatible with BSD 4.2.])
3925 AH_TEMPLATE(BSD_SYSTEM, [Define if the system is compatible with BSD 4.2.])
3926 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
3927 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
3928 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
3929 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
3930 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
3931
3932 case $opsys in
3933   aix4-2)
3934     AC_DEFINE(USG, [])
3935     AC_DEFINE(USG5, [])
3936     dnl This symbol should be defined on AIX Version 3  ???????
3937     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3938 #ifndef _AIX
3939 # error "_AIX not defined"
3940 #endif
3941     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
3942     ;;
3943
3944   cygwin)
3945     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
3946     ;;
3947
3948   darwin)
3949     dnl BSD4_3 and BSD4_4 are already defined in sys/param.h.
3950     AC_DEFINE(BSD4_2, [])
3951     AC_DEFINE(BSD_SYSTEM, [])
3952     dnl More specific than the above two.  We cannot use __APPLE__ as this
3953     dnl may not be defined on non-OSX Darwin, and we cannot define DARWIN
3954     dnl here because Panther and lower CoreFoundation.h uses DARWIN to
3955     dnl distinguish OS X from pure Darwin.
3956     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
3957     ;;
3958
3959   freebsd)
3960     AC_DEFINE(BSD4_2, [])
3961     dnl Hack to avoid calling AC_PREPROC_IFELSE multiple times.
3962     dnl Would not be needed with autoconf >= 2.67, where the
3963     dnl preprocessed output is accessible in "conftest.i".
3964     AC_DEFINE(BSD_SYSTEM_AHB, 1, [Define if AH_BOTTOM should change BSD_SYSTEM.])
3965     ;;
3966
3967   gnu | netbsd | openbsd )
3968     AC_DEFINE(BSD4_2, [])
3969     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3970 #ifndef BSD_SYSTEM
3971 # error "BSD_SYSTEM not defined"
3972 #endif
3973     ]], [[]])], [], AC_DEFINE(BSD_SYSTEM, 43) )
3974     ;;
3975
3976   gnu-linux | gnu-kfreebsd )
3977     AC_DEFINE(USG, [])
3978     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
3979     ;;
3980
3981   hpux*)
3982     AC_DEFINE(USG, [])
3983     AC_DEFINE(USG5, [])
3984     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
3985     ;;
3986
3987   irix6-5)
3988     AC_DEFINE(USG, [])
3989     AC_DEFINE(USG5, [])
3990     AC_DEFINE(USG5_4, [])
3991     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
3992     ;;
3993
3994   sol2*)
3995     AC_DEFINE(USG, [])
3996     AC_DEFINE(USG5, [])
3997     AC_DEFINE(USG5_4, [])
3998     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
3999     ;;
4000
4001   unixware)
4002     AC_DEFINE(USG, [])
4003     AC_DEFINE(USG5, [])
4004     AC_DEFINE(USG5_4, [])
4005     ;;
4006 esac
4007
4008 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4009   [case $opsys in
4010      aix4-2)
4011        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4012        emacs_cv_usable_FIONREAD=no
4013        ;;
4014
4015      *)
4016        AC_COMPILE_IFELSE(
4017          [AC_LANG_PROGRAM([[#include <sys/types.h>
4018                             #include <sys/ioctl.h>
4019                             #ifdef USG5_4
4020                             # include <sys/filio.h>
4021                             #endif
4022                           ]],
4023                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4024          [emacs_cv_usable_FIONREAD=yes],
4025          [emacs_cv_usable_FIONREAD=no])
4026        ;;
4027    esac])
4028 if test $emacs_cv_usable_FIONREAD = yes; then
4029   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4030
4031   if test $emacs_broken_SIGIO = no; then
4032     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4033       [AC_COMPILE_IFELSE(
4034          [AC_LANG_PROGRAM([[#include <fcntl.h>
4035                             #include <signal.h>
4036                           ]],
4037                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4038          [emacs_cv_usable_SIGIO=yes],
4039          [emacs_cv_usable_SIGIO=no])],
4040       [emacs_cv_usable_SIGIO=yes],
4041       [emacs_cv_usable_SIGIO=no])
4042     if test $emacs_cv_usable_SIGIO = yes; then
4043       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4044     fi
4045   fi
4046 fi
4047
4048
4049 case $opsys in
4050   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
4051   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
4052   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
4053   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
4054   cygwin)
4055     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4056       G_SLICE environment variable to "always-malloc" at startup, if
4057       using GTK.])
4058     ;;
4059
4060   hpux11)
4061     dnl It works to open the pty's tty in the parent (Emacs), then
4062     dnl close and reopen it in the child.
4063     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4064       works to open a pty's tty in the parent process, then close and
4065       reopen it in the child.])
4066     ;;
4067
4068   irix6-5)
4069     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4070       use VSUSP instead of VSWTCH.])
4071     AC_DEFINE(SETPGRP_RELEASES_CTTY, 1, [Define if process.c:child_setup
4072       should not call setpgrp.])
4073     ;;
4074
4075   sol2-10)
4076     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4077       on Solaris.])
4078     ;;
4079 esac
4080
4081 # Set up the CFLAGS for real compilation, so we can substitute it.
4082 CFLAGS="$REAL_CFLAGS"
4083 CPPFLAGS="$REAL_CPPFLAGS"
4084
4085 ## Hack to detect a buggy GCC version.
4086 if test "x$GCC" = xyes \
4087    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4088    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4089    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4090    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4091 fi
4092
4093 version=$PACKAGE_VERSION
4094
4095 copyright="Copyright (C) 2013 Free Software Foundation, Inc."
4096 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4097   [Short copyright string for this version of Emacs.])
4098 AC_SUBST(copyright)
4099
4100 ### Specify what sort of things we'll be editing into Makefile and config.h.
4101 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4102 AC_SUBST(version)
4103 AC_SUBST(configuration)
4104 ## Unused?
4105 AC_SUBST(canonical)
4106 AC_SUBST(srcdir)
4107 AC_SUBST(prefix)
4108 AC_SUBST(exec_prefix)
4109 AC_SUBST(bindir)
4110 AC_SUBST(datadir)
4111 AC_SUBST(sharedstatedir)
4112 AC_SUBST(libexecdir)
4113 AC_SUBST(mandir)
4114 AC_SUBST(infodir)
4115 AC_SUBST(lispdir)
4116 AC_SUBST(leimdir)
4117 AC_SUBST(standardlisppath)
4118 AC_SUBST(locallisppath)
4119 AC_SUBST(lisppath)
4120 AC_SUBST(x_default_search_path)
4121 AC_SUBST(etcdir)
4122 AC_SUBST(archlibdir)
4123 AC_SUBST(docdir)
4124 AC_SUBST(bitmapdir)
4125 AC_SUBST(gamedir)
4126 AC_SUBST(gameuser)
4127 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4128 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4129 ## end of LIBX_BASE, but nothing ever set it.
4130 AC_SUBST(LD_SWITCH_X_SITE)
4131 AC_SUBST(C_SWITCH_X_SITE)
4132 AC_SUBST(GNUSTEP_CFLAGS)
4133 AC_SUBST(CFLAGS)
4134 ## Used in lwlib/Makefile.in.
4135 AC_SUBST(X_TOOLKIT_TYPE)
4136 AC_SUBST(ns_appdir)
4137 AC_SUBST(ns_appbindir)
4138 AC_SUBST(ns_appresdir)
4139 AC_SUBST(ns_appsrc)
4140 AC_SUBST(GNU_OBJC_CFLAGS)
4141 AC_SUBST(OTHER_FILES)
4142
4143 if test -n "${term_header}"; then
4144     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4145         [Define to the header for the built-in window system.])
4146 fi
4147
4148 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4149                    [Define to the canonical Emacs configuration name.])
4150 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
4151                    [Define to the options passed to configure.])
4152 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4153   define this to include extra configuration information.])
4154
4155 XMENU_OBJ=
4156 XOBJ=
4157 FONT_OBJ=
4158 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4159   AC_DEFINE(HAVE_X_WINDOWS, 1,
4160             [Define to 1 if you want to use the X window system.])
4161   XMENU_OBJ=xmenu.o
4162   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o xgselect.o"
4163   FONT_OBJ=xfont.o
4164   if test "$HAVE_XFT" = "yes"; then
4165     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4166   elif test "$HAVE_FREETYPE" = "yes"; then
4167     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4168   fi
4169   AC_SUBST(FONT_OBJ)
4170 fi
4171 AC_SUBST(XMENU_OBJ)
4172 AC_SUBST(XOBJ)
4173 AC_SUBST(FONT_OBJ)
4174
4175 WIDGET_OBJ=
4176 MOTIF_LIBW=
4177 if test "${USE_X_TOOLKIT}" != "none" ; then
4178   WIDGET_OBJ=widget.o
4179   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4180   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4181     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4182   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4183     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4184     MOTIF_LIBW=-lXm
4185     case "$opsys" in
4186       gnu-linux)
4187         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4188         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4189         ;;
4190
4191       unixware)
4192         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4193         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4194         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4195         ;;
4196
4197       aix4-2)
4198         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4199         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4200         ;;
4201     esac
4202     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4203   fi
4204 fi
4205 AC_SUBST(WIDGET_OBJ)
4206
4207 TOOLKIT_LIBW=
4208 case "$USE_X_TOOLKIT" in
4209   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4210   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4211   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4212 esac
4213 AC_SUBST(TOOLKIT_LIBW)
4214
4215 if test "$USE_X_TOOLKIT" = "none"; then
4216   LIBXT_OTHER="\$(LIBXSM)"
4217   OLDXMENU_TARGET="really-oldXMenu"
4218 else
4219   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4220   OLDXMENU_TARGET="really-lwlib"
4221 fi
4222 AC_SUBST(LIBXT_OTHER)
4223
4224 ## The X Menu stuff is present in the X10 distribution, but missing
4225 ## from X11.  If we have X10, just use the installed library;
4226 ## otherwise, use our own copy.
4227 if test "${HAVE_X11}" = "yes" ; then
4228   AC_DEFINE(HAVE_X11, 1,
4229             [Define to 1 if you want to use version 11 of X windows.
4230              Otherwise, Emacs expects to use version 10.])
4231
4232   if test "$USE_X_TOOLKIT" = "none"; then
4233     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4234   else
4235     OLDXMENU="\${lwlibdir}/liblw.a"
4236   fi
4237   LIBXMENU="\$(OLDXMENU)"
4238   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4239   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4240 else
4241   ## For a syntactically valid Makefile; not actually used for anything.
4242   ## See comments in src/Makefile.in.
4243   OLDXMENU=nothing
4244   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4245   if test "${HAVE_X_WINDOWS}" = "yes"; then
4246     LIBXMENU="-lXMenu"
4247   else
4248     LIBXMENU=
4249   fi
4250   LIBX_OTHER=
4251   OLDXMENU_DEPS=
4252 fi
4253
4254 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4255   OLDXMENU_TARGET=
4256   OLDXMENU=nothing
4257   LIBXMENU=
4258   OLDXMENU_DEPS=
4259 fi
4260
4261 AC_SUBST(OLDXMENU_TARGET)
4262 AC_SUBST(OLDXMENU)
4263 AC_SUBST(LIBXMENU)
4264 AC_SUBST(LIBX_OTHER)
4265 AC_SUBST(OLDXMENU_DEPS)
4266
4267 if test "${HAVE_MENUS}" = "yes" ; then
4268   AC_DEFINE(HAVE_MENUS, 1,
4269             [Define to 1 if you have mouse menus.
4270              (This is automatic if you use X, but the option to specify it remains.)
4271              It is also defined with other window systems that support xmenu.c.])
4272 fi
4273
4274 if test "${GNU_MALLOC}" = "yes" ; then
4275   AC_DEFINE(GNU_MALLOC, 1,
4276             [Define to 1 if you want to use the GNU memory allocator.])
4277 fi
4278
4279 RALLOC_OBJ=
4280 if test "${REL_ALLOC}" = "yes" ; then
4281   AC_DEFINE(REL_ALLOC, 1,
4282             [Define REL_ALLOC if you want to use the relocating allocator for
4283              buffer space.])
4284
4285   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4286 fi
4287 AC_SUBST(RALLOC_OBJ)
4288
4289 if test "$opsys" = "cygwin"; then
4290   CYGWIN_OBJ="sheap.o cygw32.o"
4291   ## Cygwin differs because of its unexec().
4292   PRE_ALLOC_OBJ=
4293   POST_ALLOC_OBJ=lastfile.o
4294 else
4295   CYGWIN_OBJ=
4296   PRE_ALLOC_OBJ=lastfile.o
4297   POST_ALLOC_OBJ=
4298 fi
4299 AC_SUBST(CYGWIN_OBJ)
4300 AC_SUBST(PRE_ALLOC_OBJ)
4301 AC_SUBST(POST_ALLOC_OBJ)
4302
4303 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4304 # it temporarily reverts them to their pre-pkg-config values,
4305 # because gnulib needs to work with both src (which uses the
4306 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4307 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4308 # and it therefore needs to run in an environment where LIBS does not
4309 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4310 # for some package unrelated to lib-src.
4311 SAVE_CFLAGS=$CFLAGS
4312 SAVE_LIBS=$LIBS
4313 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4314 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4315 gl_ASSERT_NO_GNULIB_POSIXCHECK
4316 gl_ASSERT_NO_GNULIB_TESTS
4317 gl_INIT
4318 CFLAGS=$SAVE_CFLAGS
4319 LIBS=$SAVE_LIBS
4320
4321 case "$opsys" in
4322   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4323
4324   darwin)
4325    ## The -headerpad option tells ld (see man page) to leave room at the
4326    ## end of the header for adding load commands.  Needed for dumping.
4327    ## 0x690 is the total size of 30 segment load commands (at 56
4328    ## each); under Cocoa 31 commands are required.
4329    if test "$HAVE_NS" = "yes"; then
4330      libs_nsgui="-framework AppKit"
4331      headerpad_extra=6C8
4332    else
4333      libs_nsgui=
4334      headerpad_extra=690
4335    fi
4336    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4337
4338    ## This is here because src/Makefile.in did some extra fiddling around
4339    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
4340    ##   #ifndef LD_SWITCH_SYSTEM
4341    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
4342    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
4343    ## not using gcc, darwin.
4344    ## Because this was done in src/Makefile.in, the resulting part of
4345    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
4346    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
4347    ## rather than LD_SWITCH_SYSTEM.
4348    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4349      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4350    ;;
4351
4352   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4353   ## find X at run-time.
4354   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4355   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4356   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4357   ## had different values in configure (in ac_link) and src/Makefile.in.
4358   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4359   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4360
4361   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4362 esac
4363
4364 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4365
4366
4367 LD_FIRSTFLAG=
4368 ORDINARY_LINK=
4369 case "$opsys" in
4370   ## gnu: GNU needs its own crt0.
4371   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
4372
4373   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
4374   ## library search parth, i.e. it won't search /usr/lib for libc and
4375   ## friends.  Using -nostartfiles instead avoids this problem, and
4376   ## will also work on earlier NetBSD releases.
4377   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
4378
4379   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
4380   ##   MkLinux/LinuxPPC needs this.
4381   ## s390x-* only supports opsys = gnu-linux so it can be added here.
4382   gnu-*)
4383     case "$canonical" in
4384       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
4385     esac
4386     ;;
4387 esac
4388
4389
4390 if test "x$ORDINARY_LINK" = "xyes"; then
4391
4392   LD_FIRSTFLAG=""
4393   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
4394
4395 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
4396 ## freebsd, gnu-* not on powerpc*|s390x*.
4397 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
4398
4399   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
4400   ## places that are difficult to figure out at make time.  Fortunately,
4401   ## these same versions allow you to pass arbitrary flags on to the
4402   ## linker, so there is no reason not to use it as a linker.
4403   ##
4404   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
4405   ## searching for libraries in its internal directories, so we have to
4406   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
4407   LD_FIRSTFLAG="-nostdlib"
4408 fi
4409
4410 ## FIXME? What setting of EDIT_LDFLAGS should this have?
4411 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
4412
4413 AC_SUBST(LD_FIRSTFLAG)
4414
4415
4416 ## FIXME? The logic here is not precisely the same as that above.
4417 ## There is no check here for a pre-defined LD_FIRSTFLAG.
4418 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
4419 LIB_GCC=
4420 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
4421
4422   case "$opsys" in
4423     freebsd|netbsd|openbsd) LIB_GCC= ;;
4424
4425     gnu-*)
4426       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
4427       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
4428       case $host_cpu in
4429       arm*)
4430         LIB_GCC="-lgcc_s"
4431         ;;
4432       *)
4433         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
4434         ## immediately undefine it again and redefine it to empty.
4435         ## Was the C_SWITCH_X_SITE part really necessary?
4436 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
4437         LIB_GCC=
4438         ;;
4439       esac
4440       ;;
4441
4442     ## Ask GCC where to find libgcc.a.
4443     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
4444   esac
4445 fi                              dnl if $GCC
4446 AC_SUBST(LIB_GCC)
4447
4448 ## Common for all window systems
4449 if test "$window_system" != "none"; then
4450   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4451   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
4452   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4453 fi
4454
4455 AC_SUBST(WINDOW_SYSTEM_OBJ)
4456
4457 AH_TOP([/* GNU Emacs site configuration template file.
4458
4459 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2013
4460   Free Software Foundation, Inc.
4461
4462 This file is part of GNU Emacs.
4463
4464 GNU Emacs is free software: you can redistribute it and/or modify
4465 it under the terms of the GNU General Public License as published by
4466 the Free Software Foundation, either version 3 of the License, or
4467 (at your option) any later version.
4468
4469 GNU Emacs is distributed in the hope that it will be useful,
4470 but WITHOUT ANY WARRANTY; without even the implied warranty of
4471 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4472 GNU General Public License for more details.
4473
4474 You should have received a copy of the GNU General Public License
4475 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4476
4477
4478 /* No code in Emacs #includes config.h twice, but some bits of code
4479    intended to work with other packages as well (like gmalloc.c)
4480    think they can include it as many times as they like.  */
4481 #ifndef EMACS_CONFIG_H
4482 #define EMACS_CONFIG_H
4483 ])dnl
4484
4485 AH_BOTTOM([#include <conf_post.h>
4486
4487 #endif /* EMACS_CONFIG_H */
4488
4489 /*
4490 Local Variables:
4491 mode: c
4492 End:
4493 */
4494 ])dnl
4495
4496 #### Report on what we decided to do.
4497 #### Report GTK as a toolkit, even if it doesn't use Xt.
4498 #### It makes printing result more understandable as using GTK sets
4499 #### toolkit_scroll_bars to yes by default.
4500 if test "${HAVE_GTK}" = "yes"; then
4501   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4502 fi
4503
4504 echo "
4505 Configured for \`${canonical}'.
4506
4507   Where should the build process find the source code?    ${srcdir}
4508   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4509   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4510   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4511   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4512   What window system should Emacs use?                    ${window_system}
4513   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4514
4515 if test -n "${x_includes}"; then
4516 echo "  Where do we find X Windows header files?                ${x_includes}"
4517 else
4518 echo "  Where do we find X Windows header files?                Standard dirs"
4519 fi
4520 if test -n "${x_libraries}"; then
4521 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4522 else
4523 echo "  Where do we find X Windows libraries?                   Standard dirs"
4524 fi
4525
4526 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4527 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4528 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4529 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4530 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4531 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4532 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4533 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4534
4535 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4536 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4537 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4538 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4539 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4540 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4541 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4542
4543 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4544 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4545 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4546 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4547
4548 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4549 echo
4550
4551 if test -n "${EMACSDATA}"; then
4552    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4553 fi
4554 if test -n "${EMACSDOC}"; then
4555    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4556 fi
4557
4558 echo
4559
4560 if test "$HAVE_NS" = "yes"; then
4561    echo
4562    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4563 The installed application will go to nextstep/Emacs.app and can be
4564 run or moved from there."
4565    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4566       echo "The application will be fully self-contained."
4567     else
4568       echo "The lisp resources for the application will be installed under ${prefix}.
4569 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4570 to run if these resources are not installed."
4571    fi
4572    echo
4573 fi
4574
4575 if test "${opsys}" = "cygwin"; then
4576   case `uname -r` in
4577     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4578            echo
4579            ;;
4580   esac
4581 fi
4582
4583 # Remove any trailing slashes in these variables.
4584 [test "${prefix}" != NONE &&
4585   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4586 test "${exec_prefix}" != NONE &&
4587   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4588
4589 if test "$HAVE_NS" = "yes"; then
4590   if test "$NS_IMPL_GNUSTEP" = yes; then
4591     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
4592       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
4593   else
4594     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
4595       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
4596   fi
4597 fi
4598
4599 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4600 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4601 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4602 dnl (else you get "no `Makefile.am' found for any configure output").
4603 dnl This will work, but you get a config.status that is not quite right
4604 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4605 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4606 dnl it seems better to just live with the duplication.
4607 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile"
4608
4609 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4610        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4611        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4612        leim/Makefile nextstep/Makefile])
4613
4614 dnl test/ is not present in release tarfiles.
4615 opt_makefile=test/automated/Makefile
4616
4617 if test -f $srcdir/${opt_makefile}.in; then
4618   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4619   dnl Again, it's best not to use a variable.  Though you can add
4620   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4621   AC_CONFIG_FILES([test/automated/Makefile])
4622 fi
4623
4624
4625 dnl admin/ may or may not be present.
4626 opt_makefile=admin/unidata/Makefile
4627
4628 if test -f $srcdir/${opt_makefile}.in; then
4629   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4630   AC_CONFIG_FILES([admin/unidata/Makefile])
4631 fi
4632
4633
4634 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4635
4636 AC_SUBST(SUBDIR_MAKEFILES_IN)
4637
4638 dnl Make the necessary directories, if they don't exist.
4639 AC_CONFIG_COMMANDS([mkdirs], [
4640 for dir in etc lisp ; do
4641   test -d ${dir} || mkdir ${dir}
4642 done
4643 ])
4644
4645 dnl You might wonder (I did) why epaths.h is generated by running make,
4646 dnl rather than just letting configure generate it from epaths.in.
4647 dnl One reason is that the various paths are not fully expanded (see above);
4648 dnl eg gamedir=${prefix}/var/games/emacs.
4649 dnl Secondly, the GNU Coding standards require that one should be able
4650 dnl to run `make prefix=/some/where/else' and override the values set
4651 dnl by configure.  This also explains the `move-if-change' test and
4652 dnl the use of force in the `epaths-force' rule in Makefile.in.
4653 AC_CONFIG_COMMANDS([epaths], [
4654 echo creating src/epaths.h
4655 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4656 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4657
4658 AC_CONFIG_COMMANDS([gdbinit], [
4659 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
4660   echo creating src/.gdbinit
4661   echo source $srcdir/src/.gdbinit > src/.gdbinit
4662 fi
4663 ])
4664
4665 AC_OUTPUT