code.delx.au - gnu-emacs/blob - test/automated/package-test.el

   1 ;;; package-test.el --- Tests for the Emacs package system
   2
   3 ;; Copyright (C) 2013-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel Hackney <dan@haxney.org>
   6 ;; Version: 1.0
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; You may want to run this from a separate Emacs instance from your
  26 ;; main one, because a bug in the code below could mess with your
  27 ;; installed packages.
  28
  29 ;; Run this in a clean Emacs session using:
  30 ;;
  31 ;;     $ emacs -Q --batch -L . -l package-test.el -l ert -f ert-run-tests-batch-and-exit
  32
  33 ;;; Code:
  34
  35 (require 'package)
  36 (require 'ert)
  37 (require 'cl-lib)
  38
  39 (setq package-menu-async nil)
  40
  41 (defvar package-test-user-dir nil
  42   "Directory to use for installing packages during testing.")
  43
  44 (defvar package-test-file-dir (file-name-directory (or load-file-name
  45                                                        buffer-file-name))
  46   "Directory of the actual \"package-test.el\" file.")
  47
  48 (defvar simple-single-desc
  49   (package-desc-create :name 'simple-single
  50                        :version '(1 3)
  51                        :summary "A single-file package with no dependencies"
  52                        :kind 'single
  53                        :extras '((:url . "http://doodles.au")))
  54   "Expected `package-desc' parsed from simple-single-1.3.el.")
  55
  56 (defvar simple-depend-desc
  57   (package-desc-create :name 'simple-depend
  58                        :version '(1 0)
  59                        :summary "A single-file package with a dependency."
  60                        :kind 'single
  61                        :reqs '((simple-single (1 3))))
  62   "Expected `package-desc' parsed from simple-depend-1.0.el.")
  63
  64 (defvar multi-file-desc
  65   (package-desc-create :name 'multi-file
  66                        :version '(0 2 3)
  67                        :summary "Example of a multi-file tar package"
  68                        :kind 'tar
  69                        :extras '((:url . "http://puddles.li")))
  70   "Expected `package-desc' from \"multi-file-0.2.3.tar\".")
  71
  72 (defvar new-pkg-desc
  73   (package-desc-create :name 'new-pkg
  74                        :version '(1 0)
  75                        :kind 'single)
  76   "Expected `package-desc' parsed from new-pkg-1.0.el.")
  77
  78 (defvar simple-depend-desc-1
  79   (package-desc-create :name 'simple-depend-1
  80                        :version '(1 0)
  81                        :summary "A single-file package with a dependency."
  82                        :kind 'single
  83                        :reqs '((simple-depend (1 0))
  84                                (multi-file (0 1))))
  85   "`package-desc' used for testing dependencies.")
  86
  87 (defvar simple-depend-desc-2
  88   (package-desc-create :name 'simple-depend-2
  89                        :version '(1 0)
  90                        :summary "A single-file package with a dependency."
  91                        :kind 'single
  92                        :reqs '((simple-depend-1 (1 0))
  93                                (multi-file (0 1))))
  94   "`package-desc' used for testing dependencies.")
  95
  96 (defvar package-test-data-dir (expand-file-name "data/package" package-test-file-dir)
  97   "Base directory of package test files.")
  98
  99 (defvar package-test-fake-contents-file
 100   (expand-file-name "archive-contents" package-test-data-dir)
 101   "Path to a static copy of \"archive-contents\".")
 102
 103 (cl-defmacro with-package-test ((&optional &key file
 104                                            basedir
 105                                            install
 106                                            location
 107                                            update-news
 108                                            upload-base)
 109                                 &rest body)
 110   "Set up temporary locations and variables for testing."
 111   (declare (indent 1))
 112   `(let* ((package-test-user-dir (make-temp-file "pkg-test-user-dir-" t))
 113           (process-environment (cons (format "HOME=%s" package-test-user-dir)
 114                                      process-environment))
 115           (package-user-dir package-test-user-dir)
 116           (package-archives `(("gnu" . ,(or ,location package-test-data-dir))))
 117           (default-directory package-test-file-dir)
 118           abbreviated-home-dir
 119           package--initialized
 120           package-alist
 121           ,@(if update-news
 122                 '(package-update-news-on-upload t)
 123               (list (cl-gensym)))
 124           ,@(if upload-base
 125                 '((package-test-archive-upload-base (make-temp-file "pkg-archive-base-" t))
 126                   (package-archive-upload-base package-test-archive-upload-base))
 127               (list (cl-gensym)))) ;; Dummy value so `let' doesn't try to bind nil
 128      (let ((buf (get-buffer "*Packages*")))
 129        (when (buffer-live-p buf)
 130          (kill-buffer buf)))
 131      (unwind-protect
 132          (progn
 133            ,(if basedir `(cd ,basedir))
 134            (unless (file-directory-p package-user-dir)
 135              (mkdir package-user-dir))
 136            (cl-letf (((symbol-function 'yes-or-no-p) (lambda (&rest r) t))
 137                      ((symbol-function 'y-or-n-p)    (lambda (&rest r) t)))
 138              ,@(when install
 139                  `((package-initialize)
 140                    (package-refresh-contents)
 141                    (mapc 'package-install ,install)))
 142              (with-temp-buffer
 143                ,(if file
 144                     `(insert-file-contents ,file))
 145                ,@body)))
 146
 147        (when (file-directory-p package-test-user-dir)
 148          (delete-directory package-test-user-dir t))
 149
 150        (when (and (boundp 'package-test-archive-upload-base)
 151                   (file-directory-p package-test-archive-upload-base))
 152          (delete-directory package-test-archive-upload-base t)))))
 153
 154 (defmacro with-fake-help-buffer (&rest body)
 155   "Execute BODY in a temp buffer which is treated as the \"*Help*\" buffer."
 156   `(with-temp-buffer
 157     (help-mode)
 158     ;; Trick `help-buffer' into using the temp buffer.
 159     (let ((help-xref-following t))
 160       ,@body)))
 161
 162 (defun package-test-strip-version (dir)
 163   (replace-regexp-in-string "-pkg\\.el\\'" "" (package--description-file dir)))
 164
 165 (defun package-test-suffix-matches (base suffix-list)
 166   "Return file names matching BASE concatenated with each item in SUFFIX-LIST"
 167   (cl-mapcan
 168    '(lambda (item) (file-expand-wildcards (concat base item)))
 169    suffix-list))
 170
 171 (defvar tar-parse-info)
 172 (declare-function tar-header-name "tar-mode" (cl-x) t) ; defstruct
 173
 174 (defun package-test-search-tar-file (filename)
 175   "Search the current buffer's `tar-parse-info' variable for FILENAME.
 176
 177 Must called from within a `tar-mode' buffer."
 178   (cl-dolist (header tar-parse-info)
 179     (let ((tar-name (tar-header-name header)))
 180       (when (string= tar-name filename)
 181         (cl-return t)))))
 182
 183 (defun package-test-desc-version-string (desc)
 184   "Return the package version as a string."
 185   (package-version-join (package-desc-version desc)))
 186
 187 (ert-deftest package-test-desc-from-buffer ()
 188   "Parse an elisp buffer to get a `package-desc' object."
 189   (with-package-test (:basedir "data/package" :file "simple-single-1.3.el")
 190     (should (equal (package-buffer-info) simple-single-desc)))
 191   (with-package-test (:basedir "data/package" :file "simple-depend-1.0.el")
 192     (should (equal (package-buffer-info) simple-depend-desc)))
 193   (with-package-test (:basedir "data/package"
 194                                :file "multi-file-0.2.3.tar")
 195     (tar-mode)
 196     (should (equal (package-tar-file-info) multi-file-desc))))
 197
 198 (ert-deftest package-test-install-single ()
 199   "Install a single file without using an archive."
 200   (with-package-test (:basedir "data/package" :file "simple-single-1.3.el")
 201     (should (package-install-from-buffer))
 202     (package-initialize)
 203     (should (package-installed-p 'simple-single))
 204     (let* ((simple-pkg-dir (file-name-as-directory
 205                             (expand-file-name
 206                              "simple-single-1.3"
 207                              package-test-user-dir)))
 208            (autoloads-file (expand-file-name "simple-single-autoloads.el"
 209                                              simple-pkg-dir)))
 210       (should (file-directory-p simple-pkg-dir))
 211       (with-temp-buffer
 212         (insert-file-contents (expand-file-name "simple-single-pkg.el"
 213                                                 simple-pkg-dir))
 214         (should (string= (buffer-string)
 215                          (concat ";;; -*- no-byte-compile: t -*-\n"
 216                                  "(define-package \"simple-single\" \"1.3\" "
 217                                  "\"A single-file package "
 218                                  "with no dependencies\" 'nil "
 219                                  ":url \"http://doodles.au\""
 220                                  ")\n"))))
 221       (should (file-exists-p autoloads-file))
 222       (should-not (get-file-buffer autoloads-file)))))
 223
 224 (ert-deftest package-test-install-dependency ()
 225   "Install a package which includes a dependency."
 226   (with-package-test ()
 227     (package-initialize)
 228     (package-refresh-contents)
 229     (package-install 'simple-depend)
 230     (should (package-installed-p 'simple-single))
 231     (should (package-installed-p 'simple-depend))))
 232
 233 (ert-deftest package-test-install-two-dependencies ()
 234   "Install a package which includes a dependency."
 235   (with-package-test ()
 236     (package-initialize)
 237     (package-refresh-contents)
 238     (package-install 'simple-two-depend)
 239     (should (package-installed-p 'simple-single))
 240     (should (package-installed-p 'simple-depend))
 241     (should (package-installed-p 'simple-two-depend))))
 242
 243 (ert-deftest package-test-refresh-contents ()
 244   "Parse an \"archive-contents\" file."
 245   (with-package-test ()
 246     (package-initialize)
 247     (package-refresh-contents)
 248     (should (eq 4 (length package-archive-contents)))))
 249
 250 (ert-deftest package-test-install-single-from-archive ()
 251   "Install a single package from a package archive."
 252   (with-package-test ()
 253     (package-initialize)
 254     (package-refresh-contents)
 255     (package-install 'simple-single)))
 256
 257 (ert-deftest package-test-install-prioritized ()
 258   "Install a lower version from a higher-prioritized archive."
 259   (with-package-test ()
 260     (let* ((newer-version (expand-file-name "data/package/newer-versions"
 261                                             package-test-file-dir))
 262            (package-archives `(("older" . ,package-test-data-dir)
 263                                ("newer" . ,newer-version)))
 264            (package-archive-priorities '(("older" . 100))))
 265
 266       (package-initialize)
 267       (package-refresh-contents)
 268       (package-install 'simple-single)
 269
 270       (let ((installed (cadr (assq 'simple-single package-alist))))
 271         (should (version-list-= '(1 3)
 272                                 (package-desc-version installed)))))))
 273
 274 (ert-deftest package-test-install-multifile ()
 275   "Check properties of the installed multi-file package."
 276   (with-package-test (:basedir "data/package" :install '(multi-file))
 277     (let ((autoload-file
 278            (expand-file-name "multi-file-autoloads.el"
 279                              (expand-file-name
 280                               "multi-file-0.2.3"
 281                               package-test-user-dir)))
 282           (installed-files '("dir" "multi-file.info" "multi-file-sub.elc"
 283                              "multi-file-autoloads.el" "multi-file.elc"))
 284           (autoload-forms '("^(defvar multi-file-custom-var"
 285                             "^(custom-autoload 'multi-file-custom-var"
 286                             "^(autoload 'multi-file-mode"))
 287           (pkg-dir (file-name-as-directory
 288                     (expand-file-name
 289                      "multi-file-0.2.3"
 290                      package-test-user-dir))))
 291       (package-refresh-contents)
 292       (should (package-installed-p 'multi-file))
 293       (with-temp-buffer
 294         (insert-file-contents-literally autoload-file)
 295         (dolist (fn installed-files)
 296           (should (file-exists-p (expand-file-name fn pkg-dir))))
 297         (dolist (re autoload-forms)
 298           (goto-char (point-min))
 299           (should (re-search-forward re nil t)))))))
 300
 301 (ert-deftest package-test-update-listing ()
 302   "Ensure installed package status is updated."
 303   (with-package-test ()
 304     (let ((buf (package-list-packages)))
 305       (search-forward-regexp "^ +simple-single")
 306       (package-menu-mark-install)
 307       (package-menu-execute)
 308       (should (package-installed-p 'simple-single))
 309       (switch-to-buffer "*Packages*")
 310       (goto-char (point-min))
 311       (should (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+installed" nil t))
 312       (goto-char (point-min))
 313       (should-not (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+\\(available\\|new\\)" nil t))
 314       (kill-buffer buf))))
 315
 316 (ert-deftest package-test-update-archives ()
 317   "Test updating package archives."
 318   (with-package-test ()
 319     (let ((buf (package-list-packages)))
 320       (package-menu-refresh)
 321       (search-forward-regexp "^ +simple-single")
 322       (package-menu-mark-install)
 323       (package-menu-execute)
 324       (should (package-installed-p 'simple-single))
 325       (let ((package-test-data-dir
 326              (expand-file-name "data/package/newer-versions" package-test-file-dir)))
 327         (setq package-archives `(("gnu" . ,package-test-data-dir)))
 328         (package-menu-refresh)
 329
 330         ;; New version should be available and old version should be installed
 331         (goto-char (point-min))
 332         (should (re-search-forward "^\\s-+simple-single\\s-+1.4\\s-+available" nil t))
 333         (should (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+installed" nil t))
 334
 335         (goto-char (point-min))
 336         (should (re-search-forward "^\\s-+new-pkg\\s-+1.0\\s-+\\(available\\|new\\)" nil t))
 337
 338         (package-menu-mark-upgrades)
 339         (package-menu-execute)
 340         (package-menu-refresh)
 341         (should (package-installed-p 'simple-single '(1 4)))))))
 342
 343 (ert-deftest package-test-update-archives-async ()
 344   "Test updating package archives asynchronously."
 345   (skip-unless (executable-find "python2"))
 346   ;; For some reason this test doesn't work reliably on hydra.nixos.org.
 347   (skip-unless (not (getenv "NIX_STORE")))
 348   (with-package-test (:basedir
 349                       package-test-data-dir
 350                       :location "http://0.0.0.0:8000/")
 351     (let* ((package-menu-async t)
 352            (process (start-process
 353                      "package-server" "package-server-buffer"
 354                      (executable-find "python2")
 355                      (expand-file-name "package-test-server.py"))))
 356       (unwind-protect
 357           (progn
 358             (list-packages)
 359             (should package--downloads-in-progress)
 360             (should mode-line-process)
 361             (should-not
 362              (with-timeout (10 'timeout)
 363                (while package--downloads-in-progress
 364                  (accept-process-output nil 1))
 365                nil))
 366             ;; If the server process died, there's some non-Emacs problem.
 367             ;; Eg maybe the port was already in use.
 368             (skip-unless (process-live-p process))
 369             (goto-char (point-min))
 370             (should
 371              (search-forward-regexp "^ +simple-single" nil t)))
 372         (if (process-live-p process) (kill-process process))))))
 373
 374 (ert-deftest package-test-describe-package ()
 375   "Test displaying help for a package."
 376
 377   (require 'finder-inf)
 378   ;; Built-in
 379   (with-fake-help-buffer
 380    (describe-package '5x5)
 381    (goto-char (point-min))
 382    (should (search-forward "5x5 is a built-in package." nil t))
 383    (should (search-forward "Status: Built-in." nil t))
 384    (should (search-forward "Summary: simple little puzzle game" nil t))
 385    (should (search-forward "The aim of 5x5" nil t)))
 386
 387   ;; Installed
 388   (with-package-test ()
 389     (package-initialize)
 390     (package-refresh-contents)
 391     (package-install 'simple-single)
 392     (with-fake-help-buffer
 393      (describe-package 'simple-single)
 394      (goto-char (point-min))
 395      (should (search-forward "simple-single is an installed package." nil t))
 396      (should (re-search-forward
 397               "Status: Installed in ['`‘]~/simple-single-1.3/['’] (unsigned)."
 398               nil t))
 399      (should (search-forward "Version: 1.3" nil t))
 400      (should (search-forward "Summary: A single-file package with no dependencies"
 401                              nil t))
 402      (should (search-forward "Homepage: http://doodles.au" nil t))
 403      (should (re-search-forward "Keywords: \\[?frobnicate\\]?" nil t))
 404      ;; No description, though. Because at this point we don't know
 405      ;; what archive the package originated from, and we don't have
 406      ;; its readme file saved.
 407      )))
 408
 409 (ert-deftest package-test-describe-non-installed-package ()
 410   "Test displaying of the readme for non-installed package."
 411
 412   (with-package-test ()
 413     (package-initialize)
 414     (package-refresh-contents)
 415     (with-fake-help-buffer
 416      (describe-package 'simple-single)
 417      (goto-char (point-min))
 418      (should (search-forward "Homepage: http://doodles.au" nil t))
 419      (should (search-forward "This package provides a minor mode to frobnicate"
 420                              nil t)))))
 421
 422 (ert-deftest package-test-describe-non-installed-multi-file-package ()
 423   "Test displaying of the readme for non-installed multi-file package."
 424
 425   (with-package-test ()
 426     (package-initialize)
 427     (package-refresh-contents)
 428     (with-fake-help-buffer
 429      (describe-package 'multi-file)
 430      (goto-char (point-min))
 431      (should (search-forward "Homepage: http://puddles.li" nil t))
 432      (should (search-forward "This is a bare-bones readme file for the multi-file"
 433                              nil t)))))
 434
 435 (ert-deftest package-test-signed ()
 436   "Test verifying package signature."
 437   (skip-unless (ignore-errors
 438                  (let ((homedir (make-temp-file "package-test" t)))
 439                    (unwind-protect
 440                        (let ((process-environment
 441                               (cons (format "HOME=%s" homedir)
 442                                     process-environment)))
 443                          (epg-check-configuration (epg-configuration))
 444                          t)
 445                      (delete-directory homedir t)))))
 446   (let* ((keyring (expand-file-name "key.pub" package-test-data-dir))
 447          (package-test-data-dir
 448            (expand-file-name "data/package/signed" package-test-file-dir)))
 449     (with-package-test ()
 450       (package-initialize)
 451       (package-import-keyring keyring)
 452       (package-refresh-contents)
 453       (should (package-install 'signed-good))
 454       (should-error (package-install 'signed-bad))
 455       ;; Check if the installed package status is updated.
 456       (let ((buf (package-list-packages)))
 457         (package-menu-refresh)
 458         (should (re-search-forward
 459                  "^\\s-+signed-good\\s-+\\(\\S-+\\)\\s-+\\(\\S-+\\)\\s-"
 460                  nil t))
 461         (should (string-equal (match-string-no-properties 1) "1.0"))
 462         (should (string-equal (match-string-no-properties 2) "installed")))
 463       ;; Check if the package description is updated.
 464       (with-fake-help-buffer
 465        (describe-package 'signed-good)
 466        (goto-char (point-min))
 467        (should (re-search-forward "signed-good is an? \\(\\S-+\\) package." nil t))
 468        (should (string-equal (match-string-no-properties 1) "installed"))
 469        (should (re-search-forward
 470                 "Status: Installed in ['`‘]~/signed-good-1.0/['’]."
 471                 nil t))))))
 472
 473
 474 \f
 475 ;;; Tests for package-x features.
 476
 477 (require 'package-x)
 478
 479 (defvar package-x-test--single-archive-entry-1-3
 480   (cons 'simple-single
 481         (package-make-ac-desc '(1 3) nil
 482                               "A single-file package with no dependencies"
 483                               'single
 484                               '((:url . "http://doodles.au"))))
 485   "Expected contents of the archive entry from the \"simple-single\" package.")
 486
 487 (defvar package-x-test--single-archive-entry-1-4
 488   (cons 'simple-single
 489         (package-make-ac-desc '(1 4) nil
 490                               "A single-file package with no dependencies"
 491                               'single
 492                               nil))
 493   "Expected contents of the archive entry from the updated \"simple-single\" package.")
 494
 495 (ert-deftest package-x-test-upload-buffer ()
 496   "Test creating an \"archive-contents\" file"
 497   (with-package-test (:basedir "data/package"
 498                                :file "simple-single-1.3.el"
 499                                :upload-base t)
 500     (package-upload-buffer)
 501     (should (file-exists-p (expand-file-name "archive-contents"
 502                                              package-archive-upload-base)))
 503     (should (file-exists-p (expand-file-name "simple-single-1.3.el"
 504                                              package-archive-upload-base)))
 505     (should (file-exists-p (expand-file-name "simple-single-readme.txt"
 506                                              package-archive-upload-base)))
 507
 508     (let (archive-contents)
 509       (with-temp-buffer
 510         (insert-file-contents
 511          (expand-file-name "archive-contents"
 512                            package-archive-upload-base))
 513         (setq archive-contents
 514               (package-read-from-string
 515                (buffer-substring (point-min) (point-max)))))
 516       (should (equal archive-contents
 517                      (list 1 package-x-test--single-archive-entry-1-3))))))
 518
 519 (ert-deftest package-x-test-upload-new-version ()
 520   "Test uploading a new version of a package"
 521   (with-package-test (:basedir "data/package"
 522                                :file "simple-single-1.3.el"
 523                                :upload-base t)
 524     (package-upload-buffer)
 525     (with-temp-buffer
 526       (insert-file-contents "newer-versions/simple-single-1.4.el")
 527       (package-upload-buffer))
 528
 529     (let (archive-contents)
 530       (with-temp-buffer
 531         (insert-file-contents
 532          (expand-file-name "archive-contents"
 533                            package-archive-upload-base))
 534         (setq archive-contents
 535               (package-read-from-string
 536                (buffer-substring (point-min) (point-max)))))
 537       (should (equal archive-contents
 538                      (list 1 package-x-test--single-archive-entry-1-4))))))
 539
 540 (ert-deftest package-test-get-deps ()
 541   "Test `package--get-deps' with complex structures."
 542   (let ((package-alist
 543          (mapcar (lambda (p) (list (package-desc-name p) p))
 544            (list simple-single-desc
 545                  simple-depend-desc
 546                  multi-file-desc
 547                  new-pkg-desc
 548                  simple-depend-desc-1
 549                  simple-depend-desc-2))))
 550     (should
 551      (equal (package--get-deps 'simple-depend)
 552             '(simple-single)))
 553     (should
 554      (equal (package--get-deps 'simple-depend 'indirect)
 555             nil))
 556     (should
 557      (equal (package--get-deps 'simple-depend 'direct)
 558             '(simple-single)))
 559     (should
 560      (equal (package--get-deps 'simple-depend-2)
 561             '(simple-depend-1 multi-file simple-depend simple-single)))
 562     (should
 563      (equal (package--get-deps 'simple-depend-2 'indirect)
 564             '(simple-depend multi-file simple-single)))
 565     (should
 566      (equal (package--get-deps 'simple-depend-2 'direct)
 567             '(simple-depend-1 multi-file)))))
 568
 569 (ert-deftest package-test-sort-by-dependence ()
 570   "Test `package--sort-by-dependence' with complex structures."
 571   (let ((package-alist
 572          (mapcar (lambda (p) (list (package-desc-name p) p))
 573            (list simple-single-desc
 574                  simple-depend-desc
 575                  multi-file-desc
 576                  new-pkg-desc
 577                  simple-depend-desc-1
 578                  simple-depend-desc-2)))
 579         (delete-list
 580          (list simple-single-desc
 581                simple-depend-desc
 582                multi-file-desc
 583                new-pkg-desc
 584                simple-depend-desc-1
 585                simple-depend-desc-2)))
 586     (should
 587      (equal (package--sort-by-dependence delete-list)
 588             (list simple-depend-desc-2 simple-depend-desc-1 new-pkg-desc
 589                   multi-file-desc simple-depend-desc simple-single-desc)))
 590     (should
 591      (equal (package--sort-by-dependence (reverse delete-list))
 592             (list new-pkg-desc simple-depend-desc-2 simple-depend-desc-1
 593                   multi-file-desc simple-depend-desc simple-single-desc)))))
 594
 595 (provide 'package-test)
 596
 597 ;;; package-test.el ends here