code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 3, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 dnl  Boston, MA 02110-1301, USA.
  25
  26 AC_PREREQ(2.61)dnl
  27 AC_INIT(emacs, 23.0.60)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 lispdir='${datadir}/emacs/${version}/lisp'
  36 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  37 '${datadir}/emacs/site-lisp'
  38 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  39 etcdir='${datadir}/emacs/${version}/etc'
  40 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  41 docdir='${datadir}/emacs/${version}/etc'
  42 gamedir='${localstatedir}/games/emacs'
  43
  44 gameuser=games
  45
  46 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  47 dnl Create a new --with option that defaults to being disabled.
  48 dnl NAME is the base name of the option.  The shell variable with_NAME
  49 dnl   will be set to either the user's value (if the option is
  50 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  51 dnl   option is not specified).  Note that the shell variable name is
  52 dnl   constructed as autoconf does, by replacing non-alphanumeric
  53 dnl   characters with "_".
  54 dnl HELP-STRING is the help text for the option.
  55 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  56   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  57     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  58 ])dnl
  59
  60 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  61 dnl Create a new --with option that defaults to being enabled.  NAME
  62 dnl   is the base name of the option.  The shell variable with_NAME
  63 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  64 dnl   'yes' (if the option is not specified).  Note that the shell
  65 dnl   variable name is constructed as autoconf does, by replacing
  66 dnl   non-alphanumeric characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  70    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  71 ])dnl
  72
  73 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  74 if test "$with_pop" = yes; then
  75    AC_DEFINE(MAIL_USE_POP)
  76 fi
  77 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  78
  79 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  80 if test "$with_kerberos" = yes; then
  81    AC_DEFINE(KERBEROS)
  82 fi
  83 AH_TEMPLATE(KERBEROS,
  84             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  85
  86 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  87 if test "${with_kerberos5}" = yes; then
  88   if test "${with_kerberos}" != yes; then
  89     with_kerberos=yes
  90     AC_DEFINE(KERBEROS)
  91   fi
  92   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  93 fi
  94
  95 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  96 if test "$with_hesiod" = yes; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 101
 102 OPTION_DEFAULT_ON([sync-input],[Process async input synchronously])
 103 if test "$with_sync_input" = yes; then
 104    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 105 fi
 106
 107 dnl FIXME currently it is not the last.
 108 dnl This should be the last --with option, because --with-x is
 109 dnl added later on when we find the path of X, and it's best to
 110 dnl keep them together visually.
 111 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 112  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 113 [         case "${withval}" in
 114             y | ye | yes )      val=gtk ;;
 115             n | no )            val=no  ;;
 116             l | lu | luc | luci | lucid )       val=lucid ;;
 117             a | at | ath | athe | athen | athena )      val=athena ;;
 118             m | mo | mot | moti | motif )       val=motif ;;
 119             g | gt | gtk  )     val=gtk ;;
 120             * )
 121 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 122 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 123 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 124             ;;
 125           esac
 126           with_x_toolkit=$val
 127 ])
 128
 129 dnl _ON results in a '--without' option in the --help output, so
 130 dnl the help text should refer to "don't compile", etc.
 131 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 132 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 133 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 134 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 135 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 136 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 137
 138 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 139 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 140 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 141 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 142
 143 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 144 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 145 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 146 OPTION_DEFAULT_OFF([carbon],[use Carbon GUI on Mac OS X.  This is unsupported!])
 147
 148 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 149 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 150
 151 ## For the times when you want to build Emacs but don't have
 152 ## a suitable makeinfo, and can live without the manuals.
 153 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 154 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 155
 156 dnl Can remove these in Emacs 24.
 157 AC_ARG_WITH([gtk],,
 158   AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 159 specify a toolkit.]),,)
 160
 161 AC_ARG_WITH([gcc],,
 162   AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 163   variable to specify a compiler.]),,)
 164
 165 AC_ARG_WITH([pkg-config-prog],dnl
 166 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 167                   [Path to pkg-config for finding GTK and librsvg])])
 168 if test "X${with_pkg_config_prog}" != X; then
 169    if test "${with_pkg_config_prog}" != yes; then
 170       PKG_CONFIG="${with_pkg_config_prog}"
 171    fi
 172 fi
 173
 174 AC_ARG_ENABLE(carbon-app,
 175 [AS_HELP_STRING([--enable-carbon-app@<:@=DIR@:>@],
 176                 [specify install directory for Emacs.app on Mac OS X
 177                  [DIR=/Application]])],
 178 [ carbon_appdir_x=${enableval}])
 179
 180 ## Enabled by default.
 181 AC_ARG_ENABLE(font-backend,
 182 [AS_HELP_STRING([--disable-font-backend],[don't compile font-backend support])],
 183       USE_FONT_BACKEND=$enableval,
 184       USE_FONT_BACKEND=yes)
 185
 186 AC_ARG_ENABLE(asserts,
 187 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 188       USE_XASSERTS=$enableval,
 189       USE_XASSERTS=no)
 190
 191 AC_ARG_ENABLE(maintainer-mode,
 192 [AS_HELP_STRING([--enable-maintainer-mode],
 193                 [enable make rules and dependencies not useful (and sometimes
 194                  confusing) to the casual installer])],
 195       USE_MAINTAINER_MODE=$enableval,
 196       USE_MAINTAINER_MODE=no)
 197 if test $USE_MAINTAINER_MODE = yes; then
 198   MAINT=
 199 else
 200   MAINT=#
 201 fi
 202 AC_SUBST(MAINT)
 203
 204 AC_ARG_ENABLE(locallisppath,
 205 [AS_HELP_STRING([--enable-locallisppath=PATH],
 206                 [directories Emacs should search for lisp files specific
 207                  to this site])],
 208 if test "${enableval}" = "no"; then
 209   locallisppath=
 210 elif test "${enableval}" != "yes"; then
 211   locallisppath=${enableval}
 212 fi)
 213
 214 #### Make srcdir absolute, if it isn't already.  It's important to
 215 #### avoid running the path through pwd unnecessarily, since pwd can
 216 #### give you automounter prefixes, which can go away.  We do all this
 217 #### so Emacs can find its files when run uninstalled.
 218 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 219 unset CDPATH
 220 case "${srcdir}" in
 221   /* ) ;;
 222   . )
 223     ## We may be able to use the $PWD environment variable to make this
 224     ## absolute.  But sometimes PWD is inaccurate.
 225     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 226     ## but that tested only for a well-formed and valid PWD,
 227     ## it did not object when PWD was well-formed and valid but just wrong.
 228     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 229     then
 230       srcdir="$PWD"
 231     else
 232       srcdir="`(cd ${srcdir}; pwd)`"
 233     fi
 234   ;;
 235   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 236 esac
 237
 238 #### Check if the source directory already has a configured system in it.
 239 if test `pwd` != `(cd ${srcdir} && pwd)` \
 240    && test -f "${srcdir}/src/config.h" ; then
 241   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 242    as a build directory right now; it has been configured in its own
 243    right.  To configure in another directory as well, you MUST
 244    use GNU make.  If you do not have GNU make, then you must
 245    now do `make distclean' in ${srcdir},
 246    and then run $0 again.]])
 247 fi
 248
 249 #### Given the configuration name, set machfile and opsysfile to the
 250 #### names of the m/*.h and s/*.h files we should use.
 251
 252 ### Canonicalize the configuration name.
 253
 254 AC_CANONICAL_HOST
 255 canonical=$host
 256 configuration=${host_alias-${build_alias-$host}}
 257
 258 dnl This used to use changequote, but, apart from `changequote is evil'
 259 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 260 dnl the great gob of text.  Thus it's not processed for possible expansion.
 261 dnl Just make sure the brackets remain balanced.
 262 dnl
 263 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 264 dnl indicated by comments.
 265 dnl quotation begins
 266 [
 267
 268 ### If you add support for a new configuration, add code to this
 269 ### switch statement to recognize your configuration name and select
 270 ### the appropriate operating system and machine description files.
 271
 272 ### You would hope that you could choose an m/*.h file pretty much
 273 ### based on the machine portion of the configuration name, and an s-
 274 ### file based on the operating system portion.  However, it turns out
 275 ### that each m/*.h file is pretty manufacturer-specific - for
 276 ### example hp9000s300.h is a 68000 machine;
 277 ### mips.h, pmax.h are all MIPS
 278 ### machines.  So we basically have to have a special case for each
 279 ### configuration name.
 280 ###
 281 ### As far as handling version numbers on operating systems is
 282 ### concerned, make sure things will fail in a fixable way.  If
 283 ### /etc/MACHINES doesn't say anything about version numbers, be
 284 ### prepared to handle anything reasonably.  If version numbers
 285 ### matter, be sure /etc/MACHINES says something about it.
 286 ###
 287 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 288 ### "System V Release 4"; he writes, "The old convention encouraged
 289 ### confusion between `system' and `release' levels'."
 290
 291 machine='' opsys='' unported=no
 292 case "${canonical}" in
 293
 294   ## FreeBSD ports
 295   *-*-freebsd* )
 296     opsys=freebsd
 297     case "${canonical}" in
 298       alpha*-*-freebsd*)        machine=alpha ;;
 299       arm*-*-freebsd*)          machine=arm ;;
 300       ia64-*-freebsd*)          machine=ia64 ;;
 301       sparc64-*-freebsd*)       machine=sparc ;;
 302       powerpc-*-freebsd*)       machine=macppc ;;
 303       i[3456]86-*-freebsd*)     machine=intel386 ;;
 304       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 305     esac
 306   ;;
 307
 308   ## FreeBSD kernel + glibc based userland
 309   *-*-kfreebsd*gnu* )
 310     opsys=gnu-kfreebsd
 311     case "${canonical}" in
 312       alpha*-*-kfreebsd*)       machine=alpha ;;
 313       ia64-*-kfreebsd*)         machine=ia64 ;;
 314       sparc64-*-kfreebsd*)      machine=sparc ;;
 315       powerpc-*-kfreebsd*)      machine=macppc ;;
 316       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 317       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 318     esac
 319   ;;
 320
 321   ## NetBSD ports
 322   *-*-netbsd* )
 323     opsys=netbsd
 324     if test -f /usr/lib/crti.o; then]
 325 dnl The close and open brackets here are because this section is quoted --
 326 dnl see the `changequote' comment above.
 327       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 328 [   fi
 329
 330     case "${canonical}" in
 331       alpha*-*-netbsd*) machine=alpha ;;
 332       i[3456]86-*-netbsd*) machine=intel386 ;;
 333       m68k-*-netbsd*)
 334                         # This is somewhat bogus.
 335                         machine=hp9000s300 ;;
 336       mips-*-netbsd*)   machine=pmax ;;
 337       mipsel-*-netbsd*) machine=pmax ;;
 338       mipseb-*-netbsd*) machine=pmax ;;
 339       powerpc-*-netbsd*) machine=macppc ;;
 340       sparc*-*-netbsd*) machine=sparc ;;
 341       vax-*-netbsd*)    machine=vax ;;
 342       arm-*-netbsd*)    machine=arm ;;
 343       x86_64-*-netbsd*) machine=amdx86-64 ;;
 344       hppa-*-netbsd*)   machine=hp800 ;;
 345     esac
 346   ;;
 347
 348   ## OpenBSD ports
 349   *-*-openbsd* )
 350     opsys=openbsd
 351     case "${canonical}" in
 352       alpha*-*-openbsd*)        machine=alpha ;;
 353       arm-*-openbsd*)          machine=arm ;;
 354       hppa-*-openbsd*)         machine=hp9000s300 ;;
 355       i386-*-openbsd*)         machine=intel386 ;;
 356       m68k-*-openbsd*)         machine=hp9000s300 ;;
 357       powerpc-*-openbsd*)      machine=macppc ;;
 358       sparc*-*-openbsd*)       machine=sparc ;;
 359       vax-*-openbsd*)          machine=vax ;;
 360       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 361     esac
 362   ;;
 363
 364   ## LynxOS ports
 365   *-*-lynxos* )
 366     opsys=lynxos
 367     case "${canonical}" in
 368       i[3456]86-*-lynxos*) machine=intel386 ;;
 369       powerpc-*-lynxos*) machine=powerpc ;;
 370     esac
 371   ;;
 372
 373   ## BSDI ports
 374   *-*-bsdi* )
 375     opsys=bsdi
 376     case "${canonical}" in
 377       i[345]86-*-bsdi*) machine=intel386 ;;
 378       sparc-*-bsdi*)  machine=sparc ;;
 379       powerpc-*-bsdi*)  machine=macppc ;;
 380     esac
 381     case "${canonical}" in
 382       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 383       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 384       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 385       *-*-bsdi3* )              opsys=bsdos3 ;;
 386       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 387     esac
 388   ;;
 389
 390   alpha*-*-linux-gnu* )
 391     machine=alpha opsys=gnu-linux
 392   ;;
 393
 394   arm*-*-linux-gnu* )
 395     machine=arm opsys=gnu-linux
 396   ;;
 397
 398   ## Apple Darwin / Mac OS X
 399   *-apple-darwin* )
 400     case "${canonical}" in
 401       i[3456]86-* )  machine=intel386 ;;
 402       powerpc-* )    machine=powermac ;;
 403       * )            unported=yes ;;
 404     esac
 405     opsys=darwin
 406     # Define CPP as follows to make autoconf work correctly.
 407     CPP="${CC-cc} -E -no-cpp-precomp"
 408     # Use fink packages if available.
 409     if test -d /sw/include && test -d /sw/lib; then
 410       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 411       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 412       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 413     fi
 414   ;;
 415
 416   ## Cubix QBx/386
 417   i[3456]86-cubix-sysv* )
 418     machine=intel386 opsys=usg5-3
 419   ;;
 420
 421   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 422     machine=pmax opsys=bsd4-2
 423   ;;
 424   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 425     machine=pmax opsys=bsd4-3
 426   ;;
 427   mips-dec-ultrix* )
 428     machine=pmax opsys=ultrix4-3
 429   ;;
 430   ## HP 9000 series 200 or 300
 431   m68*-hp-bsd* )
 432     machine=hp9000s300 opsys=bsd4-3
 433   ;;
 434   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 435   m68*-hp-hpux* )
 436     case "`uname -r`" in
 437       ## Someone's system reports A.B8.05 for this.
 438       ## I wonder what other possibilities there are.
 439       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 440       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 441       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 442       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 443       *) machine=hp9000s300 opsys=hpux ;;
 444     esac
 445   ;;
 446
 447   ## HP 9000 series 700 and 800, running HP/UX
 448   hppa*-hp-hpux7* )
 449     machine=hp800 opsys=hpux
 450   ;;
 451   hppa*-hp-hpux8* )
 452     machine=hp800 opsys=hpux8
 453   ;;
 454   hppa*-hp-hpux9shr* )
 455     machine=hp800 opsys=hpux9shr
 456   ;;
 457   hppa*-hp-hpux9* )
 458     machine=hp800 opsys=hpux9
 459   ;;
 460   hppa*-hp-hpux10.2* )
 461     machine=hp800 opsys=hpux10-20
 462   ;;
 463   hppa*-hp-hpux10* )
 464     machine=hp800 opsys=hpux10
 465   ;;
 466   hppa*-hp-hpux1[1-9]* )
 467     machine=hp800 opsys=hpux11
 468     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 469   ;;
 470
 471   hppa*-*-linux-gnu* )
 472     machine=hp800 opsys=gnu-linux
 473   ;;
 474
 475   ## HP 9000 series 700 and 800, running HP/UX
 476   hppa*-hp-hpux* )
 477     ## Cross-compilation?  Nah!
 478     case "`uname -r`" in
 479       ## Someone's system reports A.B8.05 for this.
 480       ## I wonder what other possibilities there are.
 481       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 482       *.08.* ) machine=hp800 opsys=hpux8 ;;
 483       *.09.* ) machine=hp800 opsys=hpux9 ;;
 484       *) machine=hp800 opsys=hpux10 ;;
 485     esac
 486   ;;
 487   hppa*-*-nextstep* )
 488     machine=hp800 opsys=nextstep
 489   ;;
 490
 491   ## IBM machines
 492   i370-ibm-aix*)
 493     machine=ibm370aix opsys=usg5-3
 494   ;;
 495   s390-*-linux-gnu* )
 496     machine=ibms390 opsys=gnu-linux
 497   ;;
 498   s390x-*-linux-gnu* )
 499     machine=ibms390x opsys=gnu-linux
 500   ;;
 501   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 502     machine=ibmrs6000 opsys=aix3-1
 503   ;;
 504   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 505     machine=ibmrs6000 opsys=aix3-2-5
 506   ;;
 507   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 508     machine=ibmrs6000 opsys=aix4-1
 509   ;;
 510   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 511     machine=ibmrs6000 opsys=aix4-2
 512   ;;
 513   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 514     machine=ibmrs6000 opsys=aix4-2
 515   ;;
 516   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 517     machine=ibmrs6000 opsys=aix4-2
 518   ;;
 519   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 520     machine=ibmrs6000 opsys=aix4-2
 521   ;;
 522   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 523     machine=ibmrs6000 opsys=aix4
 524   ;;
 525   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 526     machine=ibmrs6000 opsys=aix4-1
 527   ;;
 528   rs6000-ibm-aix* | powerpc-ibm-aix* )
 529     machine=ibmrs6000 opsys=aix3-2
 530   ;;
 531
 532   ## Prime EXL
 533   i[3456]86-prime-sysv* )
 534     machine=i386 opsys=usg5-3
 535   ;;
 536
 537   ## ncr machine running svr4.3.
 538   i[3456]86-ncr-sysv4.3 )
 539     machine=ncr386 opsys=usg5-4-3
 540   ;;
 541
 542   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 543   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 544   i[3456]86-ncr-sysv* )
 545     machine=ncr386 opsys=usg5-4-2
 546   ;;
 547
 548   ## Macintosh PowerPC
 549   powerpc*-*-linux-gnu* )
 550     machine=macppc opsys=gnu-linux
 551   ;;
 552
 553   ## Workstations sold by MIPS
 554   ## This is not necessarily all workstations using the MIPS processor -
 555   ## Irises are produced by SGI, and DECstations by DEC.
 556
 557   mips-mips-bsd* )
 558     machine=mips opsys=bsd4-3
 559   ;;
 560   mips-mips-* )
 561     machine=mips opsys=usg5-2-2
 562   ;;
 563
 564   ## NeXT
 565   m68*-next-* | m68k-*-nextstep* )
 566     machine=m68k opsys=nextstep
 567   ;;
 568
 569   ## NEC EWS4800
 570   mips-nec-sysv4*)
 571   machine=ews4800 opsys=ux4800
 572   ;;
 573
 574   ## Siemens Nixdorf
 575   mips-siemens-sysv* | mips-sni-sysv*)
 576     machine=mips-siemens opsys=usg5-4
 577     NON_GNU_CC=/usr/ccs/bin/cc
 578     NON_GNU_CPP=/usr/ccs/lib/cpp
 579   ;;
 580
 581   ## Silicon Graphics machines
 582   ## Iris 4D
 583   mips-sgi-irix6.5 )
 584     machine=iris4d opsys=irix6-5
 585     # Without defining _LANGUAGE_C, things get masked out in the headers
 586     # so that, for instance, grepping for `free' in stdlib.h fails and
 587     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 588     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 589     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 590   ;;
 591
 592   ## Suns
 593   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 594     machine=sparc opsys=gnu-linux
 595   ;;
 596
 597   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 598     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 599     | rs6000-*-solaris2*)
 600     case "${canonical}" in
 601       i[3456]86-*-* )     machine=intel386 ;;
 602       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 603       powerpcle* )      machine=powerpcle ;;
 604       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 605       sparc* )          machine=sparc ;;
 606       * )               unported=yes ;;
 607     esac
 608     case "${canonical}" in
 609       *-sunos5.3* | *-solaris2.3* )
 610                 opsys=sol2-3
 611                 NON_GNU_CPP=/usr/ccs/lib/cpp
 612                 ;;
 613       *-sunos5.4* | *-solaris2.4* )
 614                 opsys=sol2-4
 615                 NON_GNU_CPP=/usr/ccs/lib/cpp
 616                 RANLIB="ar -ts"
 617                 ;;
 618       *-sunos5.5* | *-solaris2.5* )
 619                 opsys=sol2-5
 620                 NON_GNU_CPP=/usr/ccs/lib/cpp
 621                 RANLIB="ar -ts"
 622                 ;;
 623       *-sunos5.6* | *-solaris2.6* )
 624                 opsys=sol2-6
 625                 NON_GNU_CPP=/usr/ccs/lib/cpp
 626                 RANLIB="ar -ts"
 627                 ;;
 628       *-sunos5* | *-solaris* )
 629                 opsys=sol2-6
 630                 emacs_check_sunpro_c=yes
 631                 NON_GNU_CPP=/usr/ccs/lib/cpp
 632                 ;;
 633       *                   ) opsys=bsd4-2   ;;
 634     esac
 635     ## Watch out for a compiler that we know will not work.
 636     case "${canonical}" in
 637      *-solaris* | *-sunos5* )
 638                 if [ "x$CC" = x/usr/ucb/cc ]; then
 639                   ## /usr/ucb/cc doesn't work;
 640                   ## we should find some other compiler that does work.
 641                   unset CC
 642                 fi
 643                 ;;
 644       *) ;;
 645     esac
 646   ;;
 647   sparc-*-nextstep* )
 648     machine=sparc opsys=nextstep
 649   ;;
 650
 651   ## Tandem Integrity S2
 652   mips-tandem-sysv* )
 653     machine=tandem-s2 opsys=usg5-3
 654   ;;
 655
 656   ## Vaxen.
 657   vax-dec-* )
 658     machine=vax
 659     case "${canonical}" in
 660       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 661       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 662       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 663       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 664       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 665       *-vms* )                                          opsys=vms ;;
 666       * )                                               unported=yes
 667     esac
 668   ;;
 669
 670   ## IA-64
 671   ia64*-*-linux* )
 672     machine=ia64 opsys=gnu-linux
 673   ;;
 674
 675   ## Intel 386 machines where we don't care about the manufacturer
 676   i[3456]86-*-* )
 677     machine=intel386
 678     case "${canonical}" in
 679       *-cygwin )                opsys=cygwin ;;
 680       *-darwin* )               opsys=darwin
 681                                 CPP="${CC-cc} -E -no-cpp-precomp"
 682                                 ;;
 683       *-linux-gnu* )            opsys=gnu-linux ;;
 684       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 685       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 686       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 687       *-386bsd* )               opsys=386bsd ;;
 688       *-nextstep* )             opsys=nextstep ;;
 689       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 690     esac
 691   ;;
 692
 693   ## m68k Linux-based GNU system
 694   m68k-*-linux-gnu* )
 695     machine=m68k opsys=gnu-linux
 696   ;;
 697
 698   ## Mips Linux-based GNU system
 699   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 700     machine=mips opsys=gnu-linux
 701   ;;
 702
 703   ## UXP/DS
 704   sparc-fujitsu-sysv4* )
 705     machine=sparc opsys=uxpds
 706     NON_GNU_CPP=/usr/ccs/lib/cpp
 707     RANLIB="ar -ts"
 708   ;;
 709
 710   ## AMD x86-64 Linux-based GNU system
 711   x86_64-*-linux-gnu* )
 712     machine=amdx86-64 opsys=gnu-linux
 713   ;;
 714
 715   ## Tensilica Xtensa Linux-based GNU system
 716   xtensa*-*-linux-gnu* )
 717     machine=xtensa opsys=gnu-linux
 718     ;;
 719
 720   * )
 721     unported=yes
 722   ;;
 723 esac
 724
 725 ### If the code above didn't choose an operating system, just choose
 726 ### an operating system based on the configuration name.  You really
 727 ### only want to use this when you have no idea what the right
 728 ### operating system is; if you know what operating systems a machine
 729 ### runs, it's cleaner to make it explicit in the case statement
 730 ### above.
 731 if test x"${opsys}" = x; then
 732   case "${canonical}" in
 733     *-gnu* )                            opsys=gnu ;;
 734     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 735     *-bsd4.2 )                          opsys=bsd4-2 ;;
 736     *-bsd4.3 )                          opsys=bsd4-3 ;;
 737     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 738     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 739     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 740     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 741     *-sysv4.2uw* )                      opsys=unixware ;;
 742     *-sysv5uw* )                        opsys=unixware ;;
 743     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 744     *-sysv4.1* | *-sysvr4.1* )
 745         NON_GNU_CPP=/usr/lib/cpp
 746         opsys=usg5-4 ;;
 747     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 748         if [ x$NON_GNU_CPP = x ]; then
 749           if [ -f /usr/ccs/lib/cpp ]; then
 750             NON_GNU_CPP=/usr/ccs/lib/cpp
 751           else
 752             NON_GNU_CPP=/lib/cpp
 753           fi
 754         fi
 755         opsys=usg5-4-2 ;;
 756     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 757     * )
 758       unported=yes
 759     ;;
 760   esac
 761 fi
 762
 763 ### Tests for sytems that we beleive are obsolete and should be desupported.
 764
 765 case "${machine}" in
 766      pmax | hp9000s300 | ibm370aix | ncr386 | ews4800 | mips-siemens | powerpcle | tandem-s2 )
 767           echo "The system that you are configuring on: ${canonical} is considered to be obsolete"
 768           echo "and it is planned to be desupported in the next version of Emacs"
 769           echo "Please email emacs-devel@gnu.org as soon as possible if this system is still in use."
 770           echo "The code is still functional, but you need to edit the 'configure' script and remove the"
 771           echo "exit 33 line.  After that you can run configure again and 'complete' the build."
 772           exit 33
 773           ;;
 774 esac
 775
 776 case "${opsys}" in
 777      bsd386 | bsdos2-1 |  bsdos2 | bsdos3 | bsdos4 | bsd4-1 | bsd4-2 | bsd4-3 | usg5-0 | usg5-2-2 | usg5-2 | usg5-3 | ultrix4-3 | 386bsd | hpux | hpux8 | hpux9 | hpux9shr | hpux10 | aix3-1 | aix3-2-5 | aix3-2 | aix4-1 | nextstep | ux4800 | uxpds | uxpv )
 778           echo "The system that you are configuring on: ${canonical} is considered to be obsolete"
 779           echo "and it is planned to be desupported in the next version of Emacs"
 780           echo "Please email emacs-devel@gnu.org as soon as possible if this system is still in use."
 781           echo "The code is still functional, but you need to edit the 'configure' script and remove the"
 782           echo "'exit 44' line.  After that you can run 'configure' again and complete the build."
 783           exit 44
 784           ;;
 785 esac
 786
 787 ]
 788 dnl quotation ends
 789
 790 if test $unported = yes; then
 791   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 792 Check `etc/MACHINES' for recognized configuration names.])
 793 fi
 794
 795 machfile="m/${machine}.h"
 796 opsysfile="s/${opsys}.h"
 797
 798
 799 #### Choose a compiler.
 800 test -n "$CC" && cc_specified=yes
 801
 802 # Save the value of CFLAGS that the user specified.
 803 SPECIFIED_CFLAGS="$CFLAGS"
 804
 805 dnl Sets GCC=yes if using gcc.
 806 AC_PROG_CC
 807
 808 # On Suns, sometimes $CPP names a directory.
 809 if test -n "$CPP" && test -d "$CPP"; then
 810   CPP=
 811 fi
 812
 813 ## If not using gcc, and on Solaris, and no CPP specified, see if
 814 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 815 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 816  test x"$CPP" = x; then
 817   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 818   AC_CACHE_VAL(emacs_cv_sunpro_c,
 819   [AC_TRY_LINK([],
 820 [#ifndef __SUNPRO_C
 821 fail;
 822 #endif
 823 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 824   AC_MSG_RESULT($emacs_cv_sunpro_c)
 825
 826   if test x"$emacs_cv_sunpro_c" = xyes; then
 827     NON_GNU_CPP="$CC -E -Xs"
 828   fi
 829 fi
 830
 831 #### Some systems specify a CPP to use unless we are using GCC.
 832 #### Now that we know whether we are using GCC, we can decide whether
 833 #### to use that one.
 834 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 835 then
 836   CPP="$NON_GNU_CPP"
 837 fi
 838
 839 #### Some systems specify a CC to use unless we are using GCC.
 840 #### Now that we know whether we are using GCC, we can decide whether
 841 #### to use that one.
 842 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 843   test x$cc_specified != xyes
 844 then
 845   CC="$NON_GNU_CC"
 846 fi
 847
 848 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 849 then
 850   CC="$CC $GCC_TEST_OPTIONS"
 851 fi
 852
 853 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 854 then
 855   CC="$CC $NON_GCC_TEST_OPTIONS"
 856 fi
 857
 858 dnl checks for Unix variants
 859 AC_USE_SYSTEM_EXTENSIONS
 860
 861 ### Use -Wno-pointer-sign if the compiler supports it
 862 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 863 SAVE_CFLAGS="$CFLAGS"
 864 CFLAGS="$CFLAGS -Wno-pointer-sign"
 865 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 866 if test $has_option = yes; then
 867    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 868 fi
 869 AC_MSG_RESULT($has_option)
 870 CFLAGS="$SAVE_CFLAGS"
 871 unset has_option
 872 unset SAVE_CFLAGS
 873
 874 #### Some other nice autoconf tests.
 875
 876 dnl checks for programs
 877 AC_PROG_LN_S
 878 AC_PROG_CPP
 879 AC_PROG_INSTALL
 880 if test "x$RANLIB" = x; then
 881   AC_PROG_RANLIB
 882 fi
 883 AC_PATH_PROG(INSTALL_INFO, install-info)
 884 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 885 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 886 dnl Don't use GZIP, which is used by gzip for additional parameters.
 887 AC_PATH_PROG(GZIP_PROG, gzip)
 888
 889
 890 ## Need makeinfo >= 4.6 (?) to build the manuals.
 891 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 892 dnl By this stage, configure has already checked for egrep and set EGREP,
 893 dnl or exited with an error if no egrep was found.
 894 if test "$MAKEINFO" != "no" && \
 895   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 896    MAKEINFO=no
 897 fi
 898
 899 if test "$MAKEINFO" = "no" && test "x${with_makeinfo}" != "xno"; then
 900
 901    if test -e $srcdir/info/emacs; then
 902       gotinfo="seems"
 903    else
 904       gotinfo="does NOT seem"
 905    fi
 906
 907   AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6.
 908 You will not be able to build the Emacs manuals.
 909 In Emacs releases, they are prebuilt, so this might not be a problem.
 910 Your source tree $gotinfo to have manuals in the `info' directory.
 911 Either install a suitable version of makeinfo, or re-run configure
 912 with the `--without-makeinfo' option.] )
 913
 914 fi
 915
 916 dnl Add our options to ac_link now, after it is set up.
 917
 918 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 919 then
 920   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 921 fi
 922
 923 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 924 then
 925   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 926 fi
 927
 928 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 929 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 930 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 931 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 932 dnl if not built to support GNU ld.
 933
 934 late_LDFLAGS=$LDFLAGS
 935 if test "$GCC" = yes; then
 936   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 937 else
 938   LDFLAGS="$LDFLAGS -znocombreloc"
 939 fi
 940
 941 AC_MSG_CHECKING([for -znocombreloc])
 942 AC_LINK_IFELSE([main(){return 0;}],
 943   [AC_MSG_RESULT(yes)],
 944   LDFLAGS=$late_LDFLAGS
 945   [AC_MSG_RESULT(no)])
 946
 947 #### Extract some information from the operating system and machine files.
 948
 949 AC_CHECKING([the machine- and system-dependent files to find out
 950  - which libraries the lib-src programs will want, and
 951  - whether the GNU malloc routines are usable])
 952
 953 ### First figure out CFLAGS (which we use for running the compiler here)
 954 ### and REAL_CFLAGS (which we use for real compilation).
 955 ### The two are the same except on a few systems, where they are made
 956 ### different to work around various lossages.  For example,
 957 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 958 ### as implying static linking.
 959
 960 ### If the CFLAGS env var is specified, we use that value
 961 ### instead of the default.
 962
 963 ### It's not important that this name contain the PID; you can't run
 964 ### two configures in the same directory and have anything work
 965 ### anyway.
 966 tempcname="conftest.c"
 967
 968 echo '
 969 #include "'${srcdir}'/src/'${opsysfile}'"
 970 #include "'${srcdir}'/src/'${machfile}'"
 971 #ifndef LIBS_MACHINE
 972 #define LIBS_MACHINE
 973 #endif
 974 #ifndef LIBS_SYSTEM
 975 #define LIBS_SYSTEM
 976 #endif
 977 #ifndef C_SWITCH_SYSTEM
 978 #define C_SWITCH_SYSTEM
 979 #endif
 980 #ifndef C_SWITCH_MACHINE
 981 #define C_SWITCH_MACHINE
 982 #endif
 983 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 984 configure___ c_switch_system=C_SWITCH_SYSTEM
 985 configure___ c_switch_machine=C_SWITCH_MACHINE
 986
 987 #ifndef LIB_X11_LIB
 988 #define LIB_X11_LIB -lX11
 989 #endif
 990
 991 #ifndef LIBX11_SYSTEM
 992 #define LIBX11_SYSTEM
 993 #endif
 994 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 995
 996 #ifdef UNEXEC
 997 configure___ unexec=UNEXEC
 998 #else
 999 configure___ unexec=unexec.o
1000 #endif
1001
1002 #ifdef SYSTEM_MALLOC
1003 configure___ system_malloc=yes
1004 #else
1005 configure___ system_malloc=no
1006 #endif
1007
1008 #ifdef USE_MMAP_FOR_BUFFERS
1009 configure___ use_mmap_for_buffers=yes
1010 #else
1011 configure___ use_mmap_for_buffers=no
1012 #endif
1013
1014 #ifndef C_DEBUG_SWITCH
1015 #define C_DEBUG_SWITCH -g
1016 #endif
1017
1018 #ifndef C_OPTIMIZE_SWITCH
1019 #ifdef __GNUC__
1020 #define C_OPTIMIZE_SWITCH -O2
1021 #else
1022 #define C_OPTIMIZE_SWITCH -O
1023 #endif
1024 #endif
1025
1026 #ifndef C_WARNINGS_SWITCH
1027 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1028 #endif
1029
1030 #ifndef LD_SWITCH_MACHINE
1031 #define LD_SWITCH_MACHINE
1032 #endif
1033
1034 #ifndef LD_SWITCH_SYSTEM
1035 #define LD_SWITCH_SYSTEM
1036 #endif
1037
1038 #ifndef LD_SWITCH_X_SITE_AUX
1039 #define LD_SWITCH_X_SITE_AUX
1040 #endif
1041
1042 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1043 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1044
1045 #ifdef THIS_IS_CONFIGURE
1046
1047 /* Get the CFLAGS for tests in configure.  */
1048 #ifdef __GNUC__
1049 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1050 #else
1051 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1052 #endif
1053
1054 #else /* not THIS_IS_CONFIGURE */
1055
1056 /* Get the CFLAGS for real compilation.  */
1057 #ifdef __GNUC__
1058 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1059 #else
1060 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1061 #endif
1062
1063 #endif /* not THIS_IS_CONFIGURE */
1064 ' > ${tempcname}
1065
1066 # The value of CPP is a quoted variable reference, so we need to do this
1067 # to get its actual value...
1068 CPP=`eval "echo $CPP"`
1069 [eval `${CPP} -Isrc ${tempcname} \
1070        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1071 if test "x$SPECIFIED_CFLAGS" = x; then
1072   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1073          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1074 else
1075   REAL_CFLAGS="$CFLAGS"
1076 fi]
1077 rm ${tempcname}
1078
1079 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1080
1081 ### Make sure subsequent tests use flags consistent with the build flags.
1082
1083 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1084   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1085 else
1086   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1087 fi
1088
1089 dnl For AC_FUNC_GETLOADAVG, at least:
1090 AC_CONFIG_LIBOBJ_DIR(src)
1091
1092 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1093 AC_SYS_LARGEFILE
1094
1095
1096 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1097 ### be located in either /usr/lib64 or /usr/lib.
1098 case "${canonical}" in
1099   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1100     if test -d /usr/lib64; then
1101       AC_DEFINE(HAVE_LIB64_DIR, 1,
1102         [Define to 1 if the directory /usr/lib64 exists.])
1103 fi
1104 esac
1105
1106 dnl This function defintion taken from Gnome 2.0
1107 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1108 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1109 dnl also defines GSTUFF_PKG_ERRORS on error
1110 AC_DEFUN([PKG_CHECK_MODULES], [
1111   succeeded=no
1112
1113   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1114
1115   if test "$PKG_CONFIG" = "no" ; then
1116      ifelse([$4], , [AC_MSG_ERROR([
1117       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1118   else
1119      PKG_CONFIG_MIN_VERSION=0.9.0
1120      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1121         AC_MSG_CHECKING(for $2)
1122
1123         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1124             AC_MSG_RESULT(yes)
1125             succeeded=yes
1126
1127             AC_MSG_CHECKING($1_CFLAGS)
1128             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1129             AC_MSG_RESULT($$1_CFLAGS)
1130
1131             AC_MSG_CHECKING($1_LIBS)
1132             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1133             AC_MSG_RESULT($$1_LIBS)
1134         else
1135             AC_MSG_RESULT(no)
1136             $1_CFLAGS=""
1137             $1_LIBS=""
1138             ## If we have a custom action on failure, don't print errors, but
1139             ## do set a variable so people can do so.
1140             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1141             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1142         fi
1143
1144         AC_SUBST($1_CFLAGS)
1145         AC_SUBST($1_LIBS)
1146      else
1147         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1148         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1149      fi
1150   fi
1151
1152   if test $succeeded = yes; then
1153      ifelse([$3], , :, [$3])
1154   else
1155      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1156   fi
1157 ])
1158
1159
1160 if test "${with_sound}" != "no"; then
1161   # Sound support for GNU/Linux and the free BSDs.
1162   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1163   # Emulation library used on NetBSD.
1164   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1165   AC_SUBST(LIBSOUND)
1166
1167   ALSA_REQUIRED=1.0.0
1168   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1169   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1170   if test $HAVE_ALSA = yes; then
1171     SAVE_CFLAGS="$CFLAGS"
1172     SAVE_LDFLAGS="$LDFLAGS"
1173     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1174     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1175     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1176                     emacs_alsa_normal=yes,
1177                     emacs_alsa_normal=no)
1178     if test "$emacs_alsa_normal" != yes; then
1179       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1180                      [snd_lib_error_set_handler (0);],
1181                      emacs_alsa_subdir=yes,
1182                      emacs_alsa_subdir=no)
1183       if test "$emacs_alsa_subdir" != yes; then
1184         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1185       fi
1186       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1187     fi
1188
1189     CFLAGS="$SAVE_CFLAGS"
1190     LDFLAGS="$SAVE_LDFLAGS"
1191     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1192     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1193     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1194   fi
1195   AC_SUBST(CFLAGS_SOUND)
1196 fi
1197
1198 dnl checks for header files
1199 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1200   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1201   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1202   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1203   sys/utsname.h pwd.h)
1204
1205 AC_MSG_CHECKING(if personality LINUX32 can be set)
1206 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1207                emacs_cv_personality_linux32=yes,
1208                emacs_cv_personality_linux32=no)
1209 AC_MSG_RESULT($emacs_cv_personality_linux32)
1210
1211 if test $emacs_cv_personality_linux32 = yes; then
1212   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1213             [Define to 1 if personality LINUX32 can be set.])
1214 fi
1215
1216 dnl On Solaris 8 there's a compilation warning for term.h because
1217 dnl it doesn't define `bool'.
1218 AC_CHECK_HEADERS(term.h, , , -)
1219 AC_HEADER_STDC
1220 AC_HEADER_TIME
1221 AC_CHECK_DECLS([sys_siglist])
1222 if test $ac_cv_have_decl_sys_siglist != yes; then
1223   # For Tru64, at least:
1224   AC_CHECK_DECLS([__sys_siglist])
1225   if test $ac_cv_have_decl___sys_siglist = yes; then
1226     AC_DEFINE(sys_siglist, __sys_siglist,
1227               [Define to any substitute for sys_siglist.])
1228   fi
1229 fi
1230 AC_HEADER_SYS_WAIT
1231
1232 dnl Some systems have utime.h but don't declare the struct anyplace.
1233 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1234 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1235 #include <sys/time.h>
1236 #include <time.h>
1237 #else
1238 #ifdef HAVE_SYS_TIME_H
1239 #include <sys/time.h>
1240 #else
1241 #include <time.h>
1242 #endif
1243 #endif
1244 #ifdef HAVE_UTIME_H
1245 #include <utime.h>
1246 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1247   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1248 if test $emacs_cv_struct_utimbuf = yes; then
1249   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1250 fi
1251
1252 dnl checks for typedefs
1253 AC_TYPE_SIGNAL
1254
1255 dnl Check for speed_t typedef.
1256 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1257   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1258     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1259 if test $emacs_cv_speed_t = yes; then
1260   AC_DEFINE(HAVE_SPEED_T, 1,
1261            [Define to 1 if `speed_t' is declared by <termios.h>.])
1262 fi
1263
1264 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1265 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1266 #include <sys/time.h>
1267 #include <time.h>
1268 #else
1269 #ifdef HAVE_SYS_TIME_H
1270 #include <sys/time.h>
1271 #else
1272 #include <time.h>
1273 #endif
1274 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1275   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1276 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1277 if test $emacs_cv_struct_timeval = yes; then
1278   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1279 fi
1280
1281 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1282 AC_TRY_COMPILE([#include <math.h>],
1283 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1284   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1285 HAVE_EXCEPTION=$emacs_cv_struct_exception
1286 if test $emacs_cv_struct_exception != yes; then
1287   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1288 fi
1289
1290 AC_CHECK_HEADERS(sys/socket.h)
1291 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1292 #if HAVE_SYS_SOCKET_H
1293 #include <sys/socket.h>
1294 #endif])
1295
1296 dnl checks for structure members
1297 AC_STRUCT_TM
1298 AC_STRUCT_TIMEZONE
1299 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1300                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1301                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1302                 [#include <time.h>])
1303 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1304                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1305                   struct ifreq.ifr_addr], , ,
1306                  [AC_INCLUDES_DEFAULT
1307 #if HAVE_SYS_SOCKET_H
1308 #include <sys/socket.h>
1309 #endif
1310 #if HAVE_NET_IF_H
1311 #include <net/if.h>
1312 #endif])
1313
1314 dnl checks for compiler characteristics
1315
1316 dnl Testing __STDC__ to determine prototype support isn't good enough.
1317 dnl DEC C, for instance, doesn't define it with default options, and
1318 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1319 dnl and void *.
1320 AC_C_PROTOTYPES
1321 AC_C_VOLATILE
1322 AC_C_CONST
1323 dnl This isn't useful because we can't turn on use of `inline' unless
1324 dnl the compiler groks `extern inline'.
1325 dnl AC_C_INLINE
1326 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1327   [AC_TRY_COMPILE(, [void * foo;],
1328                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1329 if test $emacs_cv_void_star = yes; then
1330   AC_DEFINE(POINTER_TYPE, void)
1331 else
1332   AC_DEFINE(POINTER_TYPE, char)
1333 fi
1334 AH_TEMPLATE(POINTER_TYPE,
1335             [Define as `void' if your compiler accepts `void *'; otherwise
1336              define as `char'.])dnl
1337
1338
1339
1340 dnl This could be used for targets which can have both byte sexes.
1341 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1342 dnl AC_C_BIGENDIAN
1343
1344 dnl check for Make feature
1345 AC_PROG_MAKE_SET
1346
1347 dnl checks for operating system services
1348 AC_SYS_LONG_FILE_NAMES
1349
1350 #### Choose a window system.
1351
1352 AC_PATH_X
1353 if test "$no_x" = yes; then
1354   window_system=none
1355 else
1356   window_system=x11
1357 fi
1358
1359 ## Workaround for bug in autoconf <= 2.62.
1360 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1361 ## No need to do anything special for these standard directories.
1362 ## This is an experiment, take it out if it causes problems.
1363 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1364
1365    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1366
1367 fi
1368
1369 if test "${x_libraries}" != NONE; then
1370   if test -n "${x_libraries}"; then
1371     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1372     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1373   fi
1374   x_default_search_path=""
1375   x_search_path=${x_libraries}
1376   if test -z "${x_search_path}"; then
1377     x_search_path=/usr/lib
1378   fi
1379   for x_library in `echo ${x_search_path}: | \
1380                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1381     x_search_path="\
1382 ${x_library}/X11/%L/%T/%N%C%S:\
1383 ${x_library}/X11/%l/%T/%N%C%S:\
1384 ${x_library}/X11/%T/%N%C%S:\
1385 ${x_library}/X11/%L/%T/%N%S:\
1386 ${x_library}/X11/%l/%T/%N%S:\
1387 ${x_library}/X11/%T/%N%S"
1388     if test x"${x_default_search_path}" = x; then
1389       x_default_search_path=${x_search_path}
1390     else
1391       x_default_search_path="${x_search_path}:${x_default_search_path}"
1392     fi
1393   done
1394 fi
1395 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1396   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1397 fi
1398
1399 if test x"${x_includes}" = x; then
1400   bitmapdir=/usr/include/X11/bitmaps
1401 else
1402   # accumulate include directories that have X11 bitmap subdirectories
1403   bmd_acc="dummyval"
1404   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1405     if test -d "${bmd}/X11/bitmaps"; then
1406       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1407     fi
1408     if test -d "${bmd}/bitmaps"; then
1409       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1410     fi
1411   done
1412   if test ${bmd_acc} != "dummyval"; then
1413     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1414   fi
1415 fi
1416
1417 HAVE_CARBON=no
1418 if test "${with_carbon}" != no; then
1419   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1420 fi
1421 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1422   if test "${with_carbon+set}" != set \
1423      && test "${carbon_appdir_x+set}" != set; then
1424     for var in with_x with_x_toolkit with_xim \
1425                with_xpm with_jpeg with_tiff with_gif with_png; do
1426       if eval test \"\${$var+set}\" = set; then
1427         HAVE_CARBON=no
1428         break
1429       fi
1430     done
1431   fi
1432 fi
1433 if test "${HAVE_CARBON}" = yes; then
1434   window_system=mac
1435 fi
1436
1437 case "${window_system}" in
1438   x11 )
1439     HAVE_X_WINDOWS=yes
1440     HAVE_X11=yes
1441     case "${with_x_toolkit}" in
1442       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1443       motif ) USE_X_TOOLKIT=MOTIF ;;
1444       gtk ) with_gtk=yes
1445 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1446 dnl USE_X_TOOLKIT is set.
1447             USE_X_TOOLKIT=none ;;
1448       no ) USE_X_TOOLKIT=none ;;
1449 dnl If user did not say whether to use a toolkit, make this decision later:
1450 dnl use the toolkit if we have gtk, or X11R5 or newer.
1451       * ) USE_X_TOOLKIT=maybe ;;
1452     esac
1453   ;;
1454   mac | none )
1455     HAVE_X_WINDOWS=no
1456     HAVE_X11=no
1457     USE_X_TOOLKIT=none
1458   ;;
1459 esac
1460
1461 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1462    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1463    if test "$HAVE_XSERVER" = true ||
1464       test -n "$DISPLAY" ||
1465       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1466         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1467 were found.  You should install the relevant development files for X
1468 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1469 sure you have development files for image handling, i.e.
1470 tiff, gif, jpeg, png and xpm.
1471 If you are sure you want Emacs compiled without X window support, pass
1472   --without-x
1473 to configure.])
1474    fi
1475 fi
1476
1477 ### If we're using X11, we should use the X menu package.
1478 HAVE_MENUS=no
1479 case ${HAVE_X11} in
1480   yes ) HAVE_MENUS=yes ;;
1481 esac
1482
1483 ### Compute the unexec source name from the object name.
1484 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1485
1486 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1487 # Assume not, until told otherwise.
1488 GNU_MALLOC=yes
1489 doug_lea_malloc=yes
1490 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1491 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1492 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1493                emacs_cv_var___after_morecore_hook,
1494 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1495   emacs_cv_var___after_morecore_hook=yes,
1496   emacs_cv_var___after_morecore_hook=no)])
1497 if test $emacs_cv_var___after_morecore_hook = no; then
1498   doug_lea_malloc=no
1499 fi
1500 if test "${system_malloc}" = "yes"; then
1501   GNU_MALLOC=no
1502   GNU_MALLOC_reason="
1503     (The GNU allocators don't work with this system configuration.)"
1504 fi
1505 if test "$doug_lea_malloc" = "yes" ; then
1506   if test "$GNU_MALLOC" = yes ; then
1507     GNU_MALLOC_reason="
1508       (Using Doug Lea's new malloc from the GNU C Library.)"
1509   fi
1510   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1511             [Define to 1 if you are using the GNU C Library.])
1512 fi
1513
1514 if test x"${REL_ALLOC}" = x; then
1515   REL_ALLOC=${GNU_MALLOC}
1516 fi
1517
1518 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1519 dnl the system configuration file (s/*.h) to turn the use of mmap
1520 dnl in the relocating allocator on.
1521
1522 AC_FUNC_MMAP
1523 if test $use_mmap_for_buffers = yes; then
1524   REL_ALLOC=no
1525 fi
1526
1527 LIBS="$libsrc_libs $LIBS"
1528
1529 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1530 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1531 AC_CHECK_LIB(dnet, dnet_ntoa)
1532 dnl This causes -lresolv to get used in subsequent tests,
1533 dnl which causes failures on some systems such as HPUX 9.
1534 dnl AC_CHECK_LIB(resolv, gethostbyname)
1535
1536 dnl FIXME replace main with a function we actually want from this library.
1537 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1538
1539 AC_CHECK_LIB(pthreads, cma_open)
1540
1541 dnl Check for need for bigtoc support on IBM AIX
1542
1543 case ${host_os} in
1544 aix*)
1545   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1546     case $GCC in
1547     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1548     *) gdb_cv_bigtoc=-bbigtoc ;;
1549     esac
1550
1551     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1552     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1553   ])
1554   ;;
1555 esac
1556
1557 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1558 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1559 # REAL_CPPFLAGS later on.
1560
1561 REAL_CPPFLAGS="$CPPFLAGS"
1562
1563 if test "${HAVE_X11}" = "yes"; then
1564   DEFS="$C_SWITCH_X_SITE $DEFS"
1565   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1566   LIBS="$LIBX $LIBS"
1567   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1568   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1569
1570   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1571   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1572   # but it's more convenient here to set LD_RUN_PATH
1573   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1574   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1575     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1576     export LD_RUN_PATH
1577   fi
1578
1579   if test "${opsys}" = "gnu-linux"; then
1580     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1581     AC_TRY_LINK([],
1582      [XOpenDisplay ("foo");],
1583      [xlinux_first_failure=no],
1584      [xlinux_first_failure=yes])
1585     if test "${xlinux_first_failure}" = "yes"; then
1586       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1587       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1588       OLD_CPPFLAGS="$CPPFLAGS"
1589       OLD_LIBS="$LIBS"
1590       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1591       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1592       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1593       LIBS="$LIBS -b i486-linuxaout"
1594       AC_TRY_LINK([],
1595        [XOpenDisplay ("foo");],
1596        [xlinux_second_failure=no],
1597        [xlinux_second_failure=yes])
1598       if test "${xlinux_second_failure}" = "yes"; then
1599         # If we get the same failure with -b, there is no use adding -b.
1600         # So take it out.  This plays safe.
1601         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1602         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1603         CPPFLAGS="$OLD_CPPFLAGS"
1604         LIBS="$OLD_LIBS"
1605         AC_MSG_RESULT(no)
1606       else
1607         AC_MSG_RESULT(yes)
1608       fi
1609     else
1610       AC_MSG_RESULT(no)
1611     fi
1612   fi
1613
1614   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1615   # header files included from there.
1616   AC_MSG_CHECKING(for Xkb)
1617   AC_TRY_LINK([#include <X11/Xlib.h>
1618 #include <X11/XKBlib.h>],
1619         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1620         emacs_xkb=yes, emacs_xkb=no)
1621   AC_MSG_RESULT($emacs_xkb)
1622   if test $emacs_xkb = yes; then
1623     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1624   fi
1625
1626   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1627 XScreenNumberOfScreen XSetWMProtocols)
1628 fi
1629
1630 if test "${window_system}" = "x11"; then
1631   AC_MSG_CHECKING(X11 version 6)
1632   AC_CACHE_VAL(emacs_cv_x11_version_6,
1633   [AC_TRY_LINK([#include <X11/Xlib.h>],
1634 [#if XlibSpecificationRelease < 6
1635 fail;
1636 #endif
1637 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1638   if test $emacs_cv_x11_version_6 = yes; then
1639     AC_MSG_RESULT(6 or newer)
1640     AC_DEFINE(HAVE_X11R6, 1,
1641               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1642   else
1643     AC_MSG_RESULT(before 6)
1644   fi
1645 fi
1646
1647
1648 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1649 HAVE_RSVG=no
1650 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
1651   if test "${with_rsvg}" != "no"; then
1652     RSVG_REQUIRED=2.0.0
1653     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1654
1655     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1656     AC_SUBST(RSVG_CFLAGS)
1657     AC_SUBST(RSVG_LIBS)
1658
1659     if test ".${RSVG_CFLAGS}" != "."; then
1660       HAVE_RSVG=yes
1661       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1662       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1663       LIBS="$RSVG_LIBS $LIBS"
1664     fi
1665   fi
1666 fi
1667
1668
1669 HAVE_GTK=no
1670 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1671   GLIB_REQUIRED=2.6
1672   GTK_REQUIRED=2.6
1673   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1674
1675   dnl Checks for libraries.
1676   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1677   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1678      AC_MSG_ERROR($GTK_PKG_ERRORS)
1679   fi
1680 fi
1681
1682
1683 if test x"$pkg_check_gtk" = xyes; then
1684
1685   AC_SUBST(GTK_CFLAGS)
1686   AC_SUBST(GTK_LIBS)
1687   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1688   CFLAGS="$CFLAGS $GTK_CFLAGS"
1689   LIBS="$GTK_LIBS $LIBS"
1690   dnl Try to compile a simple GTK program.
1691   GTK_COMPILES=no
1692   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1693   if test "${GTK_COMPILES}" != "yes"; then
1694     if test "$USE_X_TOOLKIT" != "maybe"; then
1695       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1696     fi
1697   else
1698     HAVE_GTK=yes
1699     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1700     USE_X_TOOLKIT=none
1701     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1702       :
1703     else
1704       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1705        closing open displays.  This is no problem if you just use
1706        one display, but if you use more than one and close one of them
1707        Emacs may crash.]])
1708       sleep 3
1709     fi
1710   fi
1711
1712 fi
1713
1714
1715 if test "${HAVE_GTK}" = "yes"; then
1716
1717   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1718   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1719   if test "$with_toolkit_scroll_bars" != no; then
1720     with_toolkit_scroll_bars=yes
1721   fi
1722
1723   dnl  Check if we can use multiple displays with this GTK version.
1724   dnl  If gdk_display_open exists, assume all others are there also.
1725   HAVE_GTK_MULTIDISPLAY=no
1726   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1727   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1728     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1729               [Define to 1 if GTK can handle more than one display.])
1730   fi
1731
1732   dnl  Check if we have the old file selection dialog.
1733   dnl  If gdk_display_open exists, assume all others are there also.
1734   HAVE_GTK_FILE_SELECTION=no
1735   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1736
1737   dnl  Check if we have the new file chooser dialog
1738   dnl  If gdk_display_open exists, assume all others are there also.
1739   HAVE_GTK_FILE_CHOOSER=no
1740   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1741
1742   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1743      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1744     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1745               [Define to 1 if GTK has both file selection and chooser dialog.])
1746   fi
1747
1748   dnl Check if pthreads are available.  Emacs only needs this when using
1749   dnl gtk_file_chooser under Gnome.
1750   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1751     HAVE_GTK_AND_PTHREAD=no
1752     AC_CHECK_HEADERS(pthread.h)
1753     if test "$ac_cv_header_pthread_h"; then
1754       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1755     fi
1756     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1757       case "${canonical}" in
1758         *-hpux*) ;;
1759         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1760       esac
1761       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1762                [Define to 1 if you have GTK and pthread (-lpthread).])
1763     fi
1764   fi
1765 fi
1766
1767 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1768 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1769 dnl also not configured.
1770 HAVE_DBUS=no
1771 if test "${with_dbus}" = "yes"; then
1772    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1773    if test "$HAVE_DBUS" = yes; then
1774       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1775    fi
1776 fi
1777
1778 dnl Do not put whitespace before the #include statements below.
1779 dnl Older compilers (eg sunos4 cc) choke on it.
1780 HAVE_XAW3D=no
1781 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1782   if test "$with_xaw3d" != no; then
1783     AC_MSG_CHECKING(for xaw3d)
1784     AC_CACHE_VAL(emacs_cv_xaw3d,
1785     [AC_TRY_LINK([
1786 #include <X11/Intrinsic.h>
1787 #include <X11/Xaw3d/Simple.h>],
1788       [],
1789       emacs_cv_xaw3d=yes,
1790       emacs_cv_xaw3d=no)])
1791   else
1792     emacs_cv_xaw3d=no
1793   fi
1794   if test $emacs_cv_xaw3d = yes; then
1795     AC_MSG_RESULT([yes; using Lucid toolkit])
1796     USE_X_TOOLKIT=LUCID
1797     HAVE_XAW3D=yes
1798     AC_DEFINE(HAVE_XAW3D, 1,
1799               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1800   else
1801     AC_MSG_RESULT(no)
1802     AC_MSG_CHECKING(for libXaw)
1803     AC_CACHE_VAL(emacs_cv_xaw,
1804     [AC_TRY_LINK([
1805 #include <X11/Intrinsic.h>
1806 #include <X11/Xaw/Simple.h>],
1807       [],
1808       emacs_cv_xaw=yes,
1809       emacs_cv_xaw=no)])
1810     if test $emacs_cv_xaw = yes; then
1811       AC_MSG_RESULT([yes; using Lucid toolkit])
1812       USE_X_TOOLKIT=LUCID
1813     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1814       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1815     else
1816       AC_MSG_RESULT([no; do not use toolkit by default])
1817       USE_X_TOOLKIT=none
1818     fi
1819   fi
1820 fi
1821
1822 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1823
1824 if test "${USE_X_TOOLKIT}" != "none"; then
1825   AC_MSG_CHECKING(X11 toolkit version)
1826   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1827   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1828 [#if XtSpecificationRelease < 6
1829 fail;
1830 #endif
1831 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1832   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1833   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1834     AC_MSG_RESULT(6 or newer)
1835     AC_DEFINE(HAVE_X11XTR6, 1,
1836               [Define to 1 if you have the X11R6 or newer version of Xt.])
1837   else
1838     AC_MSG_RESULT(before 6)
1839   fi
1840
1841 dnl If using toolkit, check whether libXmu.a exists.
1842 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1843   OLDLIBS="$LIBS"
1844   if test x$HAVE_X11XTR6 = xyes; then
1845     LIBS="-lXt -lSM -lICE $LIBS"
1846   else
1847     LIBS="-lXt $LIBS"
1848   fi
1849   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1850   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1851 fi
1852
1853 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1854 if test "${HAVE_X11}" = "yes"; then
1855   if test "${USE_X_TOOLKIT}" != "none"; then
1856     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1857   fi
1858 fi
1859
1860 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1861   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1862   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1863     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1864 int x = 5;
1865 #else
1866 Motif version prior to 2.1.
1867 #endif],
1868     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1869   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1870   if test $emacs_cv_motif_version_2_1 = yes; then
1871     HAVE_LIBXP=no
1872     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1873               [Define to 1 if you have Motif 2.1 or newer.])
1874     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1875     if test ${HAVE_LIBXP} = yes; then
1876       AC_DEFINE(HAVE_LIBXP, 1,
1877                 [Define to 1 if you have the Xp library (-lXp).])
1878     fi
1879   else
1880     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1881     # We put this in CFLAGS temporarily to precede other -I options
1882     # that might be in CFLAGS temporarily.
1883     # We put this in CPPFLAGS where it precedes the other -I options.
1884     OLD_CPPFLAGS=$CPPFLAGS
1885     OLD_CFLAGS=$CFLAGS
1886     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1887     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1888     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1889       [int x = 5;],
1890       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1891     if test $emacs_cv_lesstif = yes; then
1892       # Make sure this -I option remains in CPPFLAGS after it is set
1893       # back to REAL_CPPFLAGS.
1894       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1895       # have those other -I options anyway.  Ultimately, having this
1896       # directory ultimately in CPPFLAGS will be enough.
1897       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1898       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1899     else
1900       CFLAGS=$OLD_CFLAGS
1901       CPPFLAGS=$OLD_CPPFLAGS
1902     fi
1903   fi
1904 fi
1905
1906 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1907 dnl using Motif or Xaw3d is available, and unless
1908 dnl --with-toolkit-scroll-bars=no was specified.
1909
1910 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1911             [Define to 1 if we should use toolkit scroll bars.])dnl
1912 USE_TOOLKIT_SCROLL_BARS=no
1913 if test "${with_toolkit_scroll_bars}" != "no"; then
1914   if test "${USE_X_TOOLKIT}" != "none"; then
1915     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1916       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1917       HAVE_XAW3D=no
1918       USE_TOOLKIT_SCROLL_BARS=yes
1919     elif test "${HAVE_XAW3D}" = "yes"; then
1920       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1921       USE_TOOLKIT_SCROLL_BARS=yes
1922     fi
1923   elif test "${HAVE_GTK}" = "yes"; then
1924     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1925     USE_TOOLKIT_SCROLL_BARS=yes
1926   elif test "${HAVE_CARBON}" = "yes"; then
1927     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1928     USE_TOOLKIT_SCROLL_BARS=yes
1929   fi
1930 fi
1931
1932 dnl See if XIM is available.
1933 AC_TRY_COMPILE([
1934           #include <X11/Xlib.h>
1935           #include <X11/Xresource.h>],
1936          [XIMProc  callback;],
1937          [HAVE_XIM=yes
1938          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1939          HAVE_XIM=no)
1940
1941 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1942
1943 if test "${with_xim}" != "no"; then
1944   AC_DEFINE(USE_XIM, 1,
1945             [Define to 1 if we should use XIM, if it is available.])
1946 fi
1947
1948
1949 if test "${HAVE_XIM}" != "no"; then
1950   late_CFLAGS=$CFLAGS
1951   if test "$GCC" = yes; then
1952     CFLAGS="$CFLAGS --pedantic-errors"
1953   fi
1954   AC_TRY_COMPILE([
1955 #include <X11/Xlib.h>
1956 #include <X11/Xresource.h>],
1957 [Display *display;
1958 XrmDatabase db;
1959 char *res_name;
1960 char *res_class;
1961 XIMProc  callback;
1962 XPointer *client_data;
1963 #ifndef __GNUC__
1964 /* If we're not using GCC, it's probably not XFree86, and this is
1965    probably right, but we can't use something like --pedantic-errors.  */
1966 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1967                                            char*, XIMProc, XPointer*);
1968 #endif
1969 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1970    client_data);],
1971     [emacs_cv_arg6_star=yes])
1972   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1973          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1974 either XPointer or XPointer*.])dnl
1975   if test "$emacs_cv_arg6_star" = yes; then
1976     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1977   else
1978     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1979   fi
1980   CFLAGS=$late_CFLAGS
1981 fi
1982
1983 ### Start of font-backend section.
1984 if test "${HAVE_X11}" != "yes"; then
1985   USE_FONT_BACKEND=no
1986 fi
1987
1988 if test "${USE_FONT_BACKEND}" = "yes"; then
1989   AC_DEFINE(USE_FONT_BACKEND, 1, [Define to 1 if we should use font-backend.])
1990
1991   ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1992   HAVE_XFT=maybe
1993   if test "x${with_freetype}" = "xno"; then
1994     with_xft="no";
1995   fi
1996   if test "x${with_xft}" != "xno"; then
1997
1998     PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1999     if test "$HAVE_XFT" != no; then
2000       OLD_CPPFLAGS="$CPPFLAGS"
2001       OLD_CFLAGS="$CFLAGS"
2002       OLD_LIBS="$LIBS"
2003       CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2004       CFLAGS="$CFLAGS $XFT_CFLAGS"
2005       LIBS="$XFT_LIBS $LIBS"
2006       AC_CHECK_HEADER(X11/Xft/Xft.h,
2007         AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2008
2009       if test "${HAVE_XFT}" = "yes"; then
2010         AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2011         AC_SUBST(XFT_LIBS)
2012         C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2013       else
2014         CPPFLAGS="$OLD_CPPFLAGS"
2015         CFLAGS="$OLD_CFLAGS"
2016         LIBS="$OLD_LIBS"
2017       fi                        # "${HAVE_XFT}" = "yes"
2018     fi                          # "$HAVE_XFT" != no
2019   fi                            # "x${with_xft}" != "xno"
2020
2021   dnl For the "Does Emacs use" message at the end.
2022   if test "$HAVE_XFT" != "yes"; then
2023      HAVE_XFT=no
2024   fi
2025
2026
2027   HAVE_FREETYPE=no
2028   ### Use -lfreetype if available, unless `--with-freetype=no'.
2029   if test "${HAVE_XFT}" = "yes"; then
2030     dnl As we use Xft, we anyway use freetype.
2031     dnl In this case, there's no need of additional CFLAGS and LIBS.
2032     HAVE_FREETYPE=yes
2033   elif test "x${with_freetype}" != "xno"; then
2034
2035     PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
2036     if test "${HAVE_FREETYPE}" = "yes"; then
2037       PKG_CHECK_MODULES(FONTCONFIG, fontconfig, HAVE_FC=yes, HAVE_FC=no)
2038       if test "${HAVE_FC}" = "no"; then
2039         dnl Without fontconfig, we can't use freetype at the moment.
2040         HAVE_FREETYPE=no
2041       fi
2042     fi
2043   fi
2044
2045   HAVE_LIBOTF=no
2046   if test "${HAVE_FREETYPE}" = "yes"; then
2047     AC_DEFINE(HAVE_FREETYPE, 1,
2048               [Define to 1 if using the freetype and fontconfig libraries.])
2049     if test "${with_libotf}" != "no"; then
2050       PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2051                         HAVE_LIBOTF=no)
2052       if test "$HAVE_LIBOTF" = "yes"; then
2053         AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2054       fi
2055     fi
2056 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2057 dnl Does the new font backend require it, or can it work without it?
2058   fi
2059
2060   HAVE_M17N_FLT=no
2061   if test "${with_m17n_flt}" != "no"; then
2062     PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2063     if test "$HAVE_M17N_FLT" = "yes"; then
2064       AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2065     fi
2066   fi
2067
2068   AC_SUBST(FREETYPE_CFLAGS)
2069   AC_SUBST(FREETYPE_LIBS)
2070   AC_SUBST(FONTCONFIG_CFLAGS)
2071   AC_SUBST(FONTCONFIG_LIBS)
2072   AC_SUBST(LIBOTF_CFLAGS)
2073   AC_SUBST(LIBOTF_LIBS)
2074   AC_SUBST(M17N_FLT_CFLAGS)
2075   AC_SUBST(M17N_FLT_LIBS)
2076
2077 fi                              # "${USE_FONT_BACKEND}" = "yes"
2078 ### End of font-backend section.
2079
2080 ### Use -lXpm if available, unless `--with-xpm=no'.
2081 HAVE_XPM=no
2082 if test "${HAVE_X11}" = "yes"; then
2083   if test "${with_xpm}" != "no"; then
2084     AC_CHECK_HEADER(X11/xpm.h,
2085       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2086     if test "${HAVE_XPM}" = "yes"; then
2087       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2088       AC_EGREP_CPP(no_return_alloc_pixels,
2089       [#include "X11/xpm.h"
2090 #ifndef XpmReturnAllocPixels
2091 no_return_alloc_pixels
2092 #endif
2093       ], HAVE_XPM=no, HAVE_XPM=yes)
2094
2095       if test "${HAVE_XPM}" = "yes"; then
2096         AC_MSG_RESULT(yes)
2097       else
2098         AC_MSG_RESULT(no)
2099       fi
2100     fi
2101   fi
2102
2103   if test "${HAVE_XPM}" = "yes"; then
2104     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2105   fi
2106 fi
2107
2108 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2109 HAVE_JPEG=no
2110 if test "${HAVE_X11}" = "yes"; then
2111   if test "${with_jpeg}" != "no"; then
2112     dnl Checking for jpeglib.h can lose because of a redefinition of
2113     dnl  HAVE_STDLIB_H.
2114     AC_CHECK_HEADER(jerror.h,
2115       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2116   fi
2117
2118   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2119   if test "${HAVE_JPEG}" = "yes"; then
2120     AC_DEFINE(HAVE_JPEG)
2121     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2122         [#include <jpeglib.h>
2123          version=JPEG_LIB_VERSION
2124 ],
2125         [AC_DEFINE(HAVE_JPEG)],
2126         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2127         HAVE_JPEG=no])
2128   fi
2129 fi
2130
2131 ### Use -lpng if available, unless `--with-png=no'.
2132 HAVE_PNG=no
2133 if test "${HAVE_X11}" = "yes"; then
2134   if test "${with_png}" != "no"; then
2135     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2136     # in /usr/include/libpng.
2137     AC_CHECK_HEADERS(png.h libpng/png.h)
2138     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2139       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2140     fi
2141   fi
2142
2143   if test "${HAVE_PNG}" = "yes"; then
2144     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2145   fi
2146 fi
2147
2148 ### Use -ltiff if available, unless `--with-tiff=no'.
2149 HAVE_TIFF=no
2150 if test "${HAVE_X11}" = "yes"; then
2151   if test "${with_tiff}" != "no"; then
2152     AC_CHECK_HEADER(tiffio.h,
2153       [tifflibs="-lz -lm"
2154       # At least one tiff package requires the jpeg library.
2155       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2156       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2157   fi
2158
2159   if test "${HAVE_TIFF}" = "yes"; then
2160     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2161   fi
2162 fi
2163
2164 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2165 HAVE_GIF=no
2166 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2167   AC_CHECK_HEADER(gif_lib.h,
2168 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2169 # Earlier versions can crash Emacs.
2170     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2171
2172   if test "$HAVE_GIF" = yes; then
2173       ac_gif_lib_name="-lgif"
2174   fi
2175
2176 # If gif_lib.h but no libgif, try libungif.
2177   if test x"$try_libungif" = xyes; then
2178     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2179
2180     if test "$HAVE_GIF" = yes; then
2181       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2182       ac_gif_lib_name="-lungif"
2183     fi
2184   fi
2185
2186   if test "${HAVE_GIF}" = "yes"; then
2187     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2188   fi
2189 fi
2190
2191 dnl Check for required libraries.
2192 if test "${HAVE_X11}" = "yes"; then
2193   MISSING=""
2194   WITH_NO=""
2195   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2196     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2197   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2198     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2199   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2200     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2201   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2202     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2203   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2204     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2205
2206   if test "X${MISSING}" != X; then
2207     AC_MSG_ERROR([The following required libraries were not found:
2208     $MISSING
2209 Maybe some development libraries/packages are missing?
2210 If you don't want to link with them give
2211     $WITH_NO
2212 as options to configure])
2213   fi
2214 fi
2215
2216 ### Use -lgpm if available, unless `--with-gpm=no'.
2217 HAVE_GPM=no
2218 if test "${with_gpm}" != "no"; then
2219   AC_CHECK_HEADER(gpm.h,
2220     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2221 fi
2222
2223 if test "${HAVE_GPM}" = "yes"; then
2224   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2225 fi
2226
2227 dnl Check for malloc/malloc.h on darwin
2228 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2229
2230 ### Use Mac OS X Carbon API to implement GUI.
2231 if test "${HAVE_CARBON}" = "yes"; then
2232   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2233   AC_CHECK_HEADERS(AvailabilityMacros.h)
2234   ## Specify the install directory
2235   carbon_appdir=
2236   if test "${carbon_appdir_x}" != ""; then
2237     case ${carbon_appdir_x} in
2238       y | ye | yes)  carbon_appdir=/Applications ;;
2239       * ) carbon_appdir=${carbon_appdir_x} ;;
2240     esac
2241   fi
2242   # We also have mouse menus.
2243   HAVE_MENUS=yes
2244 fi
2245
2246 ### Use session management (-lSM -lICE) if available
2247 HAVE_X_SM=no
2248 if test "${HAVE_X11}" = "yes"; then
2249   AC_CHECK_HEADER(X11/SM/SMlib.h,
2250     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2251
2252   if test "${HAVE_X_SM}" = "yes"; then
2253     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2254     case "$LIBS" in
2255       *-lSM*) ;;
2256       *)      LIBS="-lSM -lICE $LIBS" ;;
2257     esac
2258   fi
2259 fi
2260
2261 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2262 AC_CACHE_CHECK(whether netdb declares h_errno,
2263                emacs_cv_netdb_declares_h_errno,
2264 [AC_TRY_LINK([#include <netdb.h>],
2265   [return h_errno;],
2266   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2267 if test $emacs_cv_netdb_declares_h_errno = yes; then
2268   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2269 fi
2270
2271 AC_FUNC_ALLOCA
2272
2273 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2274 dnl FIXME is there an autoconf test that does the right thing, without
2275 dnl needing to call A_M_E afterwards?
2276 if test x"$ac_cv_func_alloca_works" != xyes; then
2277    AC_MSG_ERROR( [a system implementation of alloca is required] )
2278 fi
2279
2280 # fmod, logb, and frexp are found in -lm on most systems.
2281 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2282 AC_CHECK_LIB(m, sqrt)
2283
2284 # Check for mail-locking functions in a "mail" library.  Probably this should
2285 # have the same check as for liblockfile below.
2286 AC_CHECK_LIB(mail, maillock)
2287 dnl Debian, at least:
2288 AC_CHECK_LIB(lockfile, maillock)
2289 # If we have the shared liblockfile, assume we must use it for mail
2290 # locking (e.g. Debian).  If we couldn't link against liblockfile
2291 # (no liblockfile.a installed), ensure that we don't need to.
2292 if test "$ac_cv_lib_lockfile_maillock" = no; then
2293   dnl This works for files generally, not just executables.
2294   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2295   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2296                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2297   if test $ac_cv_prog_liblockfile = yes; then
2298     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2299 This probably means that movemail could lose mail.
2300 There may be a `development' package to install containing liblockfile.])
2301   else :
2302   fi
2303 fi
2304 AC_CHECK_FUNCS(touchlock)
2305 AC_CHECK_HEADERS(maillock.h)
2306
2307 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2308 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2309 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2310 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2311 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2312 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2313 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2314 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2315 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2316
2317 AC_CHECK_HEADERS(sys/un.h)
2318
2319 AC_FUNC_MKTIME
2320 if test "$ac_cv_func_working_mktime" = no; then
2321   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2322 fi
2323
2324 AC_FUNC_GETLOADAVG
2325
2326 AC_FUNC_FSEEKO
2327
2328 # Configure getopt.
2329 m4_include([m4/getopt.m4])
2330 gl_GETOPT_IFELSE([
2331   gl_GETOPT_SUBSTITUTE_HEADER
2332   gl_PREREQ_GETOPT
2333   GETOPTOBJS='getopt.o getopt1.o'
2334 ])
2335 AC_SUBST(GETOPTOBJS)
2336
2337 AC_FUNC_GETPGRP
2338
2339 AC_FUNC_STRFTIME
2340
2341 # UNIX98 PTYs.
2342 AC_CHECK_FUNCS(grantpt)
2343
2344 # PTY-related GNU extensions.
2345 AC_CHECK_FUNCS(getpt)
2346
2347 # Check this now, so that we will NOT find the above functions in ncurses.
2348 # That is because we have not set up to link ncurses in lib-src.
2349 # It's better to believe a function is not available
2350 # than to expect to find it in ncurses.
2351 AC_CHECK_LIB(ncurses, tparm)
2352
2353 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2354
2355 resolv=no
2356 AC_TRY_LINK([#include <netinet/in.h>
2357 #include <arpa/nameser.h>
2358 #include <resolv.h>],
2359     [return res_init();],
2360     have_res_init=yes, have_res_init=no)
2361 if test "$have_res_init" = no; then
2362   OLIBS="$LIBS"
2363   LIBS="$LIBS -lresolv"
2364   AC_MSG_CHECKING(for res_init with -lresolv)
2365   AC_TRY_LINK([#include <netinet/in.h>
2366 #include <arpa/nameser.h>
2367 #include <resolv.h>],
2368     [return res_init();],
2369     have_res_init=yes, have_res_init=no)
2370   AC_MSG_RESULT($have_res_init)
2371   if test "$have_res_init" = yes ; then
2372     resolv=yes
2373   fi
2374   LIBS="$OLIBS"
2375 fi
2376
2377 if test "$have_res_init" = yes; then
2378   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2379 fi
2380
2381 # Do we need the Hesiod library to provide the support routines?
2382 if test "$with_hesiod" = yes ; then
2383   # Don't set $LIBS here -- see comments above.
2384   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2385      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2386                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2387   if test "$resolv" = yes ; then
2388     RESOLVLIB=-lresolv
2389   else
2390     RESOLVLIB=
2391   fi
2392   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2393         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2394                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2395         :, $RESOLVLIB)])
2396 fi
2397
2398 # Do we need libresolv (due to res_init or Hesiod)?
2399 if test "$resolv" = yes ; then
2400   AC_DEFINE(HAVE_LIBRESOLV, 1,
2401             [Define to 1 if you have the resolv library (-lresolv).])
2402 fi
2403
2404 # These tell us which Kerberos-related libraries to use.
2405 if test "${with_kerberos+set}" = set; then
2406   AC_CHECK_LIB(com_err, com_err)
2407   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2408   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2409   AC_CHECK_LIB(krb5, krb5_init_context)
2410   if test "${with_kerberos5+set}" != set; then
2411     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2412                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2413     AC_CHECK_LIB(krb4, krb_get_cred,,
2414                  [AC_CHECK_LIB(krb, krb_get_cred)])
2415   fi
2416
2417   if test "${with_kerberos5+set}" = set; then
2418     AC_CHECK_HEADERS(krb5.h)
2419   else
2420     AC_CHECK_HEADERS(des.h,,
2421                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2422                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2423     AC_CHECK_HEADERS(krb.h,,
2424                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2425                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2426   fi
2427   AC_CHECK_HEADERS(com_err.h)
2428 fi
2429
2430 # Solaris requires -lintl if you want strerror (which calls dgettext)
2431 # to return localized messages.
2432 AC_CHECK_LIB(intl, dgettext)
2433
2434 AC_MSG_CHECKING(whether localtime caches TZ)
2435 AC_CACHE_VAL(emacs_cv_localtime_cache,
2436 [if test x$ac_cv_func_tzset = xyes; then
2437 AC_TRY_RUN([#include <time.h>
2438 extern char **environ;
2439 unset_TZ ()
2440 {
2441   char **from, **to;
2442   for (to = from = environ; (*to = *from); from++)
2443     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2444       to++;
2445 }
2446 char TZ_GMT0[] = "TZ=GMT0";
2447 char TZ_PST8[] = "TZ=PST8";
2448 main()
2449 {
2450   time_t now = time ((time_t *) 0);
2451   int hour_GMT0, hour_unset;
2452   if (putenv (TZ_GMT0) != 0)
2453     exit (1);
2454   hour_GMT0 = localtime (&now)->tm_hour;
2455   unset_TZ ();
2456   hour_unset = localtime (&now)->tm_hour;
2457   if (putenv (TZ_PST8) != 0)
2458     exit (1);
2459   if (localtime (&now)->tm_hour == hour_GMT0)
2460     exit (1);
2461   unset_TZ ();
2462   if (localtime (&now)->tm_hour != hour_unset)
2463     exit (1);
2464   exit (0);
2465 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2466 [# If we have tzset, assume the worst when cross-compiling.
2467 emacs_cv_localtime_cache=yes])
2468 else
2469         # If we lack tzset, report that localtime does not cache TZ,
2470         # since we can't invalidate the cache if we don't have tzset.
2471         emacs_cv_localtime_cache=no
2472 fi])dnl
2473 AC_MSG_RESULT($emacs_cv_localtime_cache)
2474 if test $emacs_cv_localtime_cache = yes; then
2475   AC_DEFINE(LOCALTIME_CACHE, 1,
2476             [Define to 1 if localtime caches TZ.])
2477 fi
2478
2479 if test "x$HAVE_TIMEVAL" = xyes; then
2480   AC_CHECK_FUNCS(gettimeofday)
2481   if test $ac_cv_func_gettimeofday = yes; then
2482     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2483                    emacs_cv_gettimeofday_two_arguments,
2484     [AC_TRY_COMPILE([
2485 #ifdef TIME_WITH_SYS_TIME
2486 #include <sys/time.h>
2487 #include <time.h>
2488 #else
2489 #ifdef HAVE_SYS_TIME_H
2490 #include <sys/time.h>
2491 #else
2492 #include <time.h>
2493 #endif
2494 #endif],
2495       [struct timeval time;
2496        gettimeofday (&time, 0);],
2497       emacs_cv_gettimeofday_two_arguments=yes,
2498       emacs_cv_gettimeofday_two_arguments=no)])
2499     if test $emacs_cv_gettimeofday_two_arguments = no; then
2500       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2501                 [Define to 1 if gettimeofday accepts only one argument.])
2502     fi
2503   fi
2504 fi
2505
2506 ok_so_far=yes
2507 AC_CHECK_FUNC(socket, , ok_so_far=no)
2508 if test $ok_so_far = yes; then
2509   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2510 fi
2511 if test $ok_so_far = yes; then
2512   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2513 fi
2514 if test $ok_so_far = yes; then
2515 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2516   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2517             [Define to 1 if you have inet sockets.])
2518 fi
2519
2520 AC_CHECK_HEADERS(sys/ioctl.h)
2521
2522 if test -f /usr/lpp/X11/bin/smt.exp; then
2523   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2524             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2525 fi
2526
2527 AC_MSG_CHECKING(whether system supports dynamic ptys)
2528 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2529   AC_MSG_RESULT(yes)
2530   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2531 else
2532   AC_MSG_RESULT(no)
2533 fi
2534
2535 AC_FUNC_FORK
2536
2537 dnl Adapted from Haible's version.
2538 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2539   [AC_TRY_LINK([#include <langinfo.h>],
2540     [char* cs = nl_langinfo(CODESET);],
2541     emacs_cv_langinfo_codeset=yes,
2542     emacs_cv_langinfo_codeset=no)
2543   ])
2544 if test $emacs_cv_langinfo_codeset = yes; then
2545   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2546     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2547 fi
2548
2549 AC_CHECK_TYPES(size_t)
2550
2551 AC_TYPE_MBSTATE_T
2552
2553 dnl Restrict could probably be used effectively other than in regex.c.
2554 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2555   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2556                   emacs_cv_c_restrict=yes,
2557                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2558                                   emacs_cv_c_restrict=__restrict,
2559                                   emacs_cv_c_restrict=no)])])
2560 case "$emacs_cv_c_restrict" in
2561   yes) emacs_restrict=restrict;;
2562   no) emacs_restrict="";;
2563   *) emacs_restrict="$emacs_cv_c_restrict";;
2564 esac
2565 if test "$emacs_restrict" != __restrict; then
2566   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2567     [Define to compiler's equivalent of C99 restrict keyword.
2568      Don't define if equivalent is `__restrict'.])
2569 fi
2570
2571 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2572   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2573                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2574 if test "$emacs_cv_c_restrict_arr" = yes; then
2575   AC_DEFINE(__restrict_arr, __restrict,
2576     [Define to compiler's equivalent of C99 restrict keyword in array
2577      declarations.  Define as empty for no equivalent.])
2578 fi
2579
2580 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2581 dnl how the tty code is related to POSIX and/or other versions of termios.
2582 dnl The following looks like a useful start.
2583 dnl
2584 dnl AC_SYS_POSIX_TERMIOS
2585 dnl if test $ac_cv_sys_posix_termios = yes; then
2586 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2587 dnl                                and macros for terminal control.])
2588 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2589 dnl fi
2590
2591 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2592
2593 # Set up the CFLAGS for real compilation, so we can substitute it.
2594 CFLAGS="$REAL_CFLAGS"
2595 CPPFLAGS="$REAL_CPPFLAGS"
2596
2597 #### Find out which version of Emacs this is.
2598 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2599          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2600 if test x"${version}" = x; then
2601   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2602 fi
2603
2604 ### Specify what sort of things we'll be editing into Makefile and config.h.
2605 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2606 AC_SUBST(version)
2607 AC_SUBST(configuration)
2608 AC_SUBST(canonical)
2609 AC_SUBST(srcdir)
2610 AC_SUBST(prefix)
2611 AC_SUBST(exec_prefix)
2612 AC_SUBST(bindir)
2613 AC_SUBST(datadir)
2614 AC_SUBST(sharedstatedir)
2615 AC_SUBST(libexecdir)
2616 AC_SUBST(mandir)
2617 AC_SUBST(infodir)
2618 AC_SUBST(lispdir)
2619 AC_SUBST(locallisppath)
2620 AC_SUBST(lisppath)
2621 AC_SUBST(x_default_search_path)
2622 AC_SUBST(etcdir)
2623 AC_SUBST(archlibdir)
2624 AC_SUBST(docdir)
2625 AC_SUBST(bitmapdir)
2626 AC_SUBST(gamedir)
2627 AC_SUBST(gameuser)
2628 AC_SUBST(c_switch_system)
2629 AC_SUBST(c_switch_machine)
2630 AC_SUBST(LD_SWITCH_X_SITE)
2631 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2632 AC_SUBST(C_SWITCH_X_SITE)
2633 AC_SUBST(CFLAGS)
2634 AC_SUBST(X_TOOLKIT_TYPE)
2635 AC_SUBST(machfile)
2636 AC_SUBST(opsysfile)
2637 AC_SUBST(GETLOADAVG_LIBS)
2638 AC_SUBST(carbon_appdir)
2639
2640 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2641                    [Define to the canonical Emacs configuration name.])
2642 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2643                    [Define to the options passed to configure.])
2644 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2645                    [Define to the used machine dependent file.])
2646 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2647                    [Define to the used os dependent file.])
2648 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2649 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2650  may need to deal with X Windows.  For instance, if you've defined
2651  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2652  your loader can find on its own, you might want to add "-L/..." or
2653  something similar.])
2654 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2655                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2656                     in case it's needed (for Solaris, for example).])
2657 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2658 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2659  may need to deal with X Windows.  For instance, if you've defined
2660  HAVE_X_WINDOWS above and your X include files aren't in a place
2661  that your compiler can find on its own, you might want to add
2662  "-I/..." or something similar.])
2663 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2664                    [Define to the unexec source file name.])
2665
2666 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2667   AC_DEFINE(HAVE_X_WINDOWS, 1,
2668             [Define to 1 if you want to use the X window system.])
2669 fi
2670 if test "${USE_X_TOOLKIT}" != "none" ; then
2671   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2672   if test "${USE_X_TOOLKIT}" == "LUCID"; then
2673     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2674   elif test "${USE_X_TOOLKIT}" == "MOTIF"; then
2675     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2676   fi
2677 fi
2678 if test "${HAVE_X11}" = "yes" ; then
2679   AC_DEFINE(HAVE_X11, 1,
2680             [Define to 1 if you want to use version 11 of X windows.
2681              Otherwise, Emacs expects to use version 10.])
2682 fi
2683 if test "${HAVE_MENUS}" = "yes" ; then
2684   AC_DEFINE(HAVE_MENUS, 1,
2685             [Define to 1 if you have mouse menus.
2686              (This is automatic if you use X, but the option to specify it remains.)
2687              It is also defined with other window systems that support xmenu.c.])
2688 fi
2689 if test "${GNU_MALLOC}" = "yes" ; then
2690   AC_DEFINE(GNU_MALLOC, 1,
2691             [Define to 1 if you want to use the GNU memory allocator.])
2692 fi
2693 if test "${REL_ALLOC}" = "yes" ; then
2694   AC_DEFINE(REL_ALLOC, 1,
2695             [Define REL_ALLOC if you want to use the relocating allocator for
2696              buffer space.])
2697 fi
2698
2699
2700 AH_TOP([/* GNU Emacs site configuration template file.
2701    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2702      2006, 2007, 2008  Free Software Foundation, Inc.
2703
2704 This file is part of GNU Emacs.
2705
2706 GNU Emacs is free software; you can redistribute it and/or modify
2707 it under the terms of the GNU General Public License as published by
2708 the Free Software Foundation; either version 3, or (at your option)
2709 any later version.
2710
2711 GNU Emacs is distributed in the hope that it will be useful,
2712 but WITHOUT ANY WARRANTY; without even the implied warranty of
2713 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2714 GNU General Public License for more details.
2715
2716 You should have received a copy of the GNU General Public License
2717 along with GNU Emacs; see the file COPYING.  If not, write to the
2718 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
2719 Boston, MA 02110-1301, USA.  */
2720
2721
2722 /* No code in Emacs #includes config.h twice, but some bits of code
2723    intended to work with other packages as well (like gmalloc.c)
2724    think they can include it as many times as they like.  */
2725 #ifndef EMACS_CONFIG_H
2726 #define EMACS_CONFIG_H
2727 ])dnl
2728
2729 AH_BOTTOM([
2730 /* If we're using any sort of window system, define some consequences.  */
2731 #ifdef HAVE_X_WINDOWS
2732 #define HAVE_WINDOW_SYSTEM
2733 #define MULTI_KBOARD
2734 #define HAVE_MOUSE
2735 #endif
2736
2737 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
2738    on unconditionally. */
2739 #ifndef MULTI_KBOARD
2740 #define MULTI_KBOARD
2741 #endif
2742
2743 /* If we're using the Carbon API on Mac OS X, define a few more
2744    variables as well.  */
2745 #ifdef HAVE_CARBON
2746 #define HAVE_WINDOW_SYSTEM
2747 #define HAVE_MOUSE
2748 #endif
2749
2750 /* Define USER_FULL_NAME to return a string
2751    that is the user's full name.
2752    It can assume that the variable `pw'
2753    points to the password file entry for this user.
2754
2755    At some sites, the pw_gecos field contains
2756    the user's full name.  If neither this nor any other
2757    field contains the right thing, use pw_name,
2758    giving the user's login name, since that is better than nothing.  */
2759 #define USER_FULL_NAME pw->pw_gecos
2760
2761 /* Define AMPERSAND_FULL_NAME if you use the convention
2762    that & in the full name stands for the login id.  */
2763 /* Turned on June 1996 supposing nobody will mind it.  */
2764 #define AMPERSAND_FULL_NAME
2765
2766 /* We have blockinput.h.  */
2767 #define DO_BLOCK_INPUT
2768
2769 /* Define HAVE_SOUND if we have sound support.  We know it works
2770    and compiles only on the specified platforms.   For others,
2771    it probably doesn't make sense to try.  */
2772
2773 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2774 #ifdef HAVE_MACHINE_SOUNDCARD_H
2775 #define HAVE_SOUND 1
2776 #endif
2777 #ifdef HAVE_SYS_SOUNDCARD_H
2778 #define HAVE_SOUND 1
2779 #endif
2780 #ifdef HAVE_SOUNDCARD_H
2781 #define HAVE_SOUND 1
2782 #endif
2783 #ifdef HAVE_ALSA
2784 #define HAVE_SOUND 1
2785 #endif
2786 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2787
2788 /* If using GNU, then support inline function declarations. */
2789 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2790    generally, because even if non-gcc compilers accept `inline', they
2791    may reject `extern inline'.  */
2792 #if defined (__GNUC__) && defined (OPTIMIZE)
2793 #define INLINE __inline__
2794 #else
2795 #define INLINE
2796 #endif
2797
2798 /* Include the os and machine dependent files.  */
2799 #include config_opsysfile
2800 #include config_machfile
2801
2802 /* If no remapping takes place, static variables cannot be dumped as
2803    pure, so don't worry about the `static' keyword. */
2804 #ifdef NO_REMAP
2805 #undef static
2806 #endif
2807
2808 /* Define `subprocesses' should be defined if you want to
2809    have code for asynchronous subprocesses
2810    (as used in M-x compile and M-x shell).
2811    These do not work for some USG systems yet;
2812    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2813
2814 #ifndef VMS
2815 #ifndef USG
2816 /* #define subprocesses */
2817 #endif
2818 #endif
2819
2820 /* SIGTYPE is the macro we actually use.  */
2821 #ifndef SIGTYPE
2822 #define SIGTYPE RETSIGTYPE
2823 #endif
2824
2825 #ifdef emacs /* Don't do this for lib-src.  */
2826 /* Tell regex.c to use a type compatible with Emacs.  */
2827 #define RE_TRANSLATE_TYPE Lisp_Object
2828 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2829 #ifdef make_number
2830 /* If make_number is a macro, use it.  */
2831 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2832 #else
2833 /* If make_number is a function, avoid it.  */
2834 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2835 #endif
2836 #endif
2837
2838 /* Avoid link-time collision with system mktime if we will use our own.  */
2839 #if ! HAVE_MKTIME || BROKEN_MKTIME
2840 #define mktime emacs_mktime
2841 #endif
2842
2843 #define my_strftime nstrftime   /* for strftime.c */
2844
2845 /* The rest of the code currently tests the CPP symbol BSTRING.
2846    Override any claims made by the system-description files.
2847    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2848 #undef BSTRING
2849 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2850 #define BSTRING
2851 #endif
2852
2853 /* Some of the files of Emacs which are intended for use with other
2854    programs assume that if you have a config.h file, you must declare
2855    the type of getenv.
2856
2857    This declaration shouldn't appear when alloca.s or Makefile.in
2858    includes config.h.  */
2859 #ifndef NOT_C_CODE
2860 extern char *getenv ();
2861 #endif
2862
2863 /* These default definitions are good for almost all machines.
2864    The exceptions override them in m/MACHINE.h.  */
2865
2866 #ifndef BITS_PER_CHAR
2867 #define BITS_PER_CHAR 8
2868 #endif
2869
2870 #ifndef BITS_PER_SHORT
2871 #define BITS_PER_SHORT 16
2872 #endif
2873
2874 /* Note that lisp.h uses this in a preprocessor conditional, so it
2875    would not work to use sizeof.  That being so, we do all of them
2876    without sizeof, for uniformity's sake.  */
2877 #ifndef BITS_PER_INT
2878 #define BITS_PER_INT 32
2879 #endif
2880
2881 #ifndef BITS_PER_LONG
2882 #ifdef _LP64
2883 #define BITS_PER_LONG 64
2884 #else
2885 #define BITS_PER_LONG 32
2886 #endif
2887 #endif
2888
2889 /* Define if the compiler supports function prototypes.  It may do so
2890    but not define __STDC__ (e.g. DEC C by default) or may define it as
2891    zero.  */
2892 #undef PROTOTYPES
2893 /* For mktime.c:  */
2894 #ifndef __P
2895 # if defined PROTOTYPES
2896 #  define __P(args) args
2897 # else
2898 #  define __P(args) ()
2899 # endif  /* GCC.  */
2900 #endif /* __P */
2901
2902 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2903 #ifndef NOT_C_CODE
2904 #ifdef HAVE_STRING_H
2905 #include "string.h"
2906 #endif
2907 #ifdef HAVE_STRINGS_H
2908 #include "strings.h"  /* May be needed for bcopy & al. */
2909 #endif
2910 #ifdef HAVE_STDLIB_H
2911 #include <stdlib.h>
2912 #endif
2913 #ifndef __GNUC__
2914 # ifdef HAVE_ALLOCA_H
2915 #  include <alloca.h>
2916 # else /* AIX files deal with #pragma.  */
2917 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2918 char *alloca ();
2919 #  endif
2920 # endif /* HAVE_ALLOCA_H */
2921 #endif /* __GNUC__ */
2922 #ifndef HAVE_SIZE_T
2923 typedef unsigned size_t;
2924 #endif
2925 #endif /* NOT_C_CODE */
2926
2927 /* Define HAVE_X_I18N if we have usable i18n support.  */
2928
2929 #ifdef HAVE_X11R6
2930 #define HAVE_X_I18N
2931 #elif !defined X11R5_INHIBIT_I18N
2932 #define HAVE_X_I18N
2933 #endif
2934
2935 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2936
2937 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2938 #define HAVE_X11R6_XIM
2939 #endif
2940
2941 /* Should we enable expensive run-time checking of data types?  */
2942 #undef ENABLE_CHECKING
2943
2944 #if defined __GNUC__ && (__GNUC__ > 2 \
2945                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2946 #define NO_RETURN       __attribute__ ((__noreturn__))
2947 #else
2948 #define NO_RETURN       /* nothing */
2949 #endif
2950
2951 /* These won't be used automatically yet.  We also need to know, at least,
2952    that the stack is continuous.  */
2953 #ifdef __GNUC__
2954 #  ifndef GC_SETJMP_WORKS
2955   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2956      see NON_SAVING_SETJMP in the target descriptions.  */
2957   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2958      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2959      Fixme: Deal with SVR3.  */
2960 #    define GC_SETJMP_WORKS 1
2961 #  endif
2962 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2963 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2964 #  endif
2965 #endif
2966
2967 #ifndef HAVE_BCOPY
2968 #define bcopy(a,b,s) memcpy (b,a,s)
2969 #endif
2970 #ifndef HAVE_BZERO
2971 #define bzero(a,s) memset (a,0,s)
2972 #endif
2973 #ifndef HAVE_BCMP
2974 #define BCMP memcmp
2975 #endif
2976
2977 #endif /* EMACS_CONFIG_H */
2978
2979 /*
2980 Local Variables:
2981 mode: c
2982 End:
2983 */
2984 ])dnl
2985
2986 #### Report on what we decided to do.
2987 #### Report GTK as a toolkit, even if it doesn't use Xt.
2988 #### It makes printing result more understandable as using GTK sets
2989 #### toolkit_scroll_bars to yes by default.
2990 if test "${HAVE_GTK}" = "yes"; then
2991   USE_X_TOOLKIT=GTK
2992 fi
2993
2994 echo "
2995 Configured for \`${canonical}'.
2996
2997   Where should the build process find the source code?    ${srcdir}
2998   What operating system and machine description files should Emacs use?
2999         \`${opsysfile}' and \`${machfile}'
3000   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3001   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3002   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3003   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3004   What window system should Emacs use?                    ${window_system}
3005   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3006
3007 if test -n "${x_includes}"; then
3008 echo "  Where do we find X Windows header files?                ${x_includes}"
3009 else
3010 echo "  Where do we find X Windows header files?                Standard dirs"
3011 fi
3012 if test -n "${x_libraries}"; then
3013 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3014 else
3015 echo "  Where do we find X Windows libraries?                   Standard dirs"
3016 fi
3017
3018 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3019 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3020 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3021 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3022 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
3023 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3024 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3025 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3026 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3027 echo "  Does Emacs use a font backend?                          ${USE_FONT_BACKEND}"
3028
3029 if test "${USE_FONT_BACKEND}" = "yes"; then
3030   echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3031   echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3032   echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3033   echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3034 fi
3035 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
3036 echo
3037
3038 if test $USE_XASSERTS = yes; then
3039    echo "  Compiling with asserts turned on."
3040    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3041 fi
3042
3043 echo
3044
3045 if test "$USE_X_TOOLKIT" = GTK; then
3046   case "$canonical" in
3047   *cygwin*)
3048     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
3049   will probably get a crash on startup.  If this happens, please use another
3050   toolkit for Emacs.  See etc/PROBLEMS for more information."
3051   ;;
3052   esac
3053 fi
3054
3055
3056 if test "$HAVE_CARBON" = "yes"; then
3057    echo
3058    echo "Warning: The Mac Carbon port is currently unsupported and has
3059 known problems.  It is not recommended for use by non-developers.
3060 Read the emacs-devel archives for more information."
3061    echo
3062 fi
3063
3064 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3065   echo "D-Bus integration has been tested for GNU/Linux only."
3066   echo
3067 fi
3068
3069
3070 # Remove any trailing slashes in these variables.
3071 [test "${prefix}" != NONE &&
3072   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3073 test "${exec_prefix}" != NONE &&
3074   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3075
3076 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3077 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3078 ## from Makefile.c can correctly provide the arg `-traditional' to the
3079 ## C preprocessor.
3080
3081 AC_EGREP_CPP(yes..yes,
3082         [yes..yes],
3083         CPP_NEED_TRADITIONAL=no,
3084         CPP_NEED_TRADITIONAL=yes)
3085
3086 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3087         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3088         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3089         lwlib/Makefile lisp/Makefile leim/Makefile, [
3090
3091 ### Make the necessary directories, if they don't exist.
3092 for dir in etc lisp ; do
3093   test -d ${dir} || mkdir ${dir}
3094 done
3095
3096 # Build src/Makefile from ${srcdir}/src/Makefile.c
3097 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3098 # This must be done after src/config.h is built, since we rely on that file.
3099
3100 # Now get this: Some word that is part of the ${srcdir} directory name
3101 # or the ${configuration} value might, just might, happen to be an
3102 # identifier like `sun4' or `i386' or something, and be predefined by
3103 # the C preprocessor to some helpful value like 1, or maybe the empty
3104 # string.  Needless to say consequent macro substitutions are less
3105 # than conducive to the makefile finding the correct directory.
3106 [undefs="`echo $top_srcdir $configuration $canonical |
3107 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3108     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3109 `"]
3110
3111 echo creating src/epaths.h
3112 ${MAKE-make} epaths-force
3113
3114 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3115 # `..' to `. .'  unless invoked with -traditional
3116
3117 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3118   CPPFLAGS="$CPPFLAGS -traditional"
3119 fi
3120
3121 echo creating lib-src/Makefile
3122 ( cd lib-src
3123   rm -f junk.c junk1.c junk2.c
3124   sed -e '/start of cpp stuff/q' \
3125       < Makefile.c > junk1.c
3126   sed -e '1,/start of cpp stuff/d'\
3127       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3128       < Makefile.c > junk.c
3129   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3130       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3131   cat junk1.c junk2.c > Makefile.new
3132   rm -f junk.c junk1.c junk2.c
3133   chmod 444 Makefile.new
3134   mv -f Makefile.new Makefile
3135 )
3136
3137 echo creating src/Makefile
3138 ( cd src
3139   rm -f junk.c junk1.c junk2.c
3140   sed -e '/start of cpp stuff/q' \
3141       < Makefile.c > junk1.c
3142   sed -e '1,/start of cpp stuff/d'\
3143       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3144       < Makefile.c > junk.c
3145   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3146       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3147   cat junk1.c junk2.c > Makefile.new
3148   rm -f junk.c junk1.c junk2.c
3149   chmod 444 Makefile.new
3150   mv -f Makefile.new Makefile
3151 )
3152
3153 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3154   echo creating src/.gdbinit
3155   echo source $srcdir/src/.gdbinit > src/.gdbinit
3156 fi
3157
3158 # This is how we know whether to re-run configure in certain cases.
3159 touch src/config.stamp
3160
3161 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3162
3163 m4_if(dnl       Do not change this comment
3164    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3165 )dnl