code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_ON([libsystemd],[don't compile with libsystemd support])
 334 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 335 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 336 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 337
 338 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 339 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 340 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 341
 342 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 343 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 344 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 345 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 346 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 347 On by default on Mac OS X.])],[],[with_ns=maybe])
 348 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 349
 350 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 351 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 352 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 353 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 354 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 355 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 356 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 357 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 358
 359 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 360  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 361  [ case "${withval}" in
 362     y | ye | yes )      val=yes ;;
 363     n | no )            val=no  ;;
 364     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 365     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 366     g | gf | gfi | gfil | gfile )       val=gfile ;;
 367     w | w3 | w32 )      val=w32 ;;
 368     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 369 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 370 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 371 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 372     ;;
 373    esac
 374    with_file_notification=$val
 375  ],
 376  [with_file_notification=$with_features])
 377
 378 OPTION_DEFAULT_OFF([xwidgets],
 379   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 380
 381 ## For the times when you want to build Emacs but don't have
 382 ## a suitable makeinfo, and can live without the manuals.
 383 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 384 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 385
 386 ## This might be a 'configure' arg.
 387 AC_SUBST([ACLOCAL_PATH])
 388
 389 ## Makefile.in needs the cache file name.
 390 AC_SUBST(cache_file)
 391
 392 ## This is an option because I do not know if all info/man support
 393 ## compressed files, nor how to test if they do so.
 394 OPTION_DEFAULT_ON([compress-install],
 395   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 396 make GZIP_PROG= install])
 397
 398 AC_ARG_WITH(gameuser,dnl
 399 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 400                 [user for shared game score files.
 401                 An argument prefixed by ':' specifies a group instead.])])
 402 gameuser=
 403 gamegroup=
 404 # We don't test if we can actually chown/chgrp here, because configure
 405 # may run without root privileges.  lib-src/Makefile.in will handle
 406 # any errors due to missing user/group gracefully.
 407 case ${with_gameuser} in
 408   no) ;;
 409   "" | yes) gamegroup=games ;;
 410   :*) gamegroup=${with_gameuser#:} ;;
 411   *) gameuser=${with_gameuser} ;;
 412 esac
 413
 414 AC_ARG_WITH([gnustep-conf],dnl
 415 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 416    [name of GNUstep configuration file to use on systems where the command
 417     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 418     /etc/GNUstep/GNUstep.conf])])
 419 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 420   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 421 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 422      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 423
 424 AC_ARG_ENABLE(ns-self-contained,
 425 [AS_HELP_STRING([--disable-ns-self-contained],
 426                 [disable self contained build under NeXTstep])],
 427    EN_NS_SELF_CONTAINED=$enableval,
 428    EN_NS_SELF_CONTAINED=yes)
 429
 430 locallisppathset=no
 431 AC_ARG_ENABLE(locallisppath,
 432 [AS_HELP_STRING([--enable-locallisppath=PATH],
 433                 [directories Emacs should search for lisp files specific
 434                  to this site])],
 435 if test "${enableval}" = "no"; then
 436   locallisppath=
 437 elif test "${enableval}" != "yes"; then
 438   locallisppath=${enableval} locallisppathset=yes
 439 fi)
 440
 441 AC_ARG_ENABLE(checking,
 442 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 443                 [enable expensive run-time checks.  With LIST,
 444                  enable only specific categories of checks.
 445                  Categories are: all,yes,no.
 446                  Flags are: stringbytes, stringoverrun, stringfreelist,
 447                  xmallocoverrun, conslist, glyphs])],
 448 [ac_checking_flags="${enableval}"],[])
 449 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 450 for check in $ac_checking_flags
 451 do
 452         case $check in
 453         # these set all the flags to specific states
 454         yes)            ac_enable_checking=1 ;;
 455         no)             ac_enable_checking= ;
 456                         ac_gc_check_stringbytes= ;
 457                         ac_gc_check_string_overrun= ;
 458                         ac_gc_check_string_free_list= ;
 459                         ac_xmalloc_overrun= ;
 460                         ac_gc_check_cons_list= ;
 461                         ac_glyphs_debug= ;;
 462         all)            ac_enable_checking=1 ;
 463                         ac_gc_check_stringbytes=1 ;
 464                         ac_gc_check_string_overrun=1 ;
 465                         ac_gc_check_string_free_list=1 ;
 466                         ac_xmalloc_overrun=1 ;
 467                         ac_gc_check_cons_list=1 ;
 468                         ac_glyphs_debug=1 ;;
 469         # these enable particular checks
 470         stringbytes)    ac_gc_check_stringbytes=1 ;;
 471         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 472         stringfreelist) ac_gc_check_string_free_list=1 ;;
 473         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 474         conslist)       ac_gc_check_cons_list=1 ;;
 475         glyphs)         ac_glyphs_debug=1 ;;
 476         *)      AC_MSG_ERROR(unknown check category $check) ;;
 477         esac
 478 done
 479 IFS="$ac_save_IFS"
 480
 481 if test x$ac_enable_checking != x ; then
 482   AC_DEFINE(ENABLE_CHECKING, 1,
 483 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 484 fi
 485 if test x$ac_gc_check_stringbytes != x ; then
 486   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 487 [Define this temporarily to hunt a bug.  If defined, the size of
 488    strings is redundantly recorded in sdata structures so that it can
 489    be compared to the sizes recorded in Lisp strings.])
 490 fi
 491 if test x$ac_gc_check_string_overrun != x ; then
 492   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 493 [Define this to check for short string overrun.])
 494 fi
 495 if test x$ac_gc_check_string_free_list != x ; then
 496   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 497 [Define this to check the string free list.])
 498 fi
 499 if test x$ac_xmalloc_overrun != x ; then
 500   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 501 [Define this to check for malloc buffer overrun.])
 502 fi
 503 if test x$ac_gc_check_cons_list != x ; then
 504   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 505 [Define this to check for errors in cons list.])
 506 fi
 507 if test x$ac_glyphs_debug != x ; then
 508   AC_DEFINE(GLYPH_DEBUG, 1,
 509 [Define this to enable glyphs debugging code.])
 510 fi
 511
 512 AC_ARG_ENABLE(check-lisp-object-type,
 513 [AS_HELP_STRING([--enable-check-lisp-object-type],
 514                 [enable compile time checks for the Lisp_Object data type.
 515                 This is useful for development for catching certain types of bugs.])],
 516 if test "${enableval}" != "no"; then
 517    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 518    [Define this to enable compile time checks for the Lisp_Object data type.])
 519 fi)
 520
 521
 522 dnl The name of this option is unfortunate.  It predates, and has no
 523 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 524 dnl Actually, it stops it working.
 525 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 526 AC_ARG_ENABLE(profiling,
 527 [AS_HELP_STRING([--enable-profiling],
 528                 [build emacs with low-level, gprof profiling support.
 529                 Mainly useful for debugging Emacs itself.  May not work on
 530                 all platforms.  Stops profiler.el working.])],
 531 [ac_enable_profiling="${enableval}"],[])
 532 if test x$ac_enable_profiling != x ; then
 533    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 534 else
 535    PROFILING_CFLAGS=
 536 fi
 537 AC_SUBST(PROFILING_CFLAGS)
 538
 539 AC_ARG_ENABLE(autodepend,
 540 [AS_HELP_STRING([--enable-autodepend],
 541                 [automatically generate dependencies to .h-files.
 542                  Requires gcc, enabled if found.])],
 543 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 544
 545 AC_ARG_ENABLE(gtk-deprecation-warnings,
 546 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 547                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 548 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 549
 550 BUILD_DETAILS=
 551 AC_ARG_ENABLE([build-details],
 552   [AS_HELP_STRING([--disable-build-details],
 553                   [Make the build more deterministic by omitting host
 554                    names, time stamps, etc. from the output.])],
 555   [test "$enableval" = no && BUILD_DETAILS=--no-build-details])
 556 AC_SUBST([BUILD_DETAILS])
 557
 558 dnl This used to use changequote, but, apart from 'changequote is evil'
 559 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 560 dnl the great gob of text.  Thus it's not processed for possible expansion.
 561 dnl Just make sure the brackets remain balanced.
 562 dnl
 563 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 564 dnl indicated by comments.
 565 dnl quotation begins
 566 [
 567
 568 ### If you add support for a new configuration, add code to this
 569 ### switch statement to recognize your configuration name and select
 570 ### the appropriate opsys.
 571
 572 ### As far as handling version numbers on operating systems is
 573 ### concerned, make sure things will fail in a fixable way.  If
 574 ### /etc/MACHINES doesn't say anything about version numbers, be
 575 ### prepared to handle anything reasonably.  If version numbers
 576 ### matter, be sure /etc/MACHINES says something about it.
 577
 578 opsys='' unported=no
 579 case "${canonical}" in
 580
 581   ## GNU/Linux and similar ports
 582   *-*-linux* )
 583     opsys=gnu-linux
 584   ;;
 585
 586   ## FreeBSD ports
 587   *-*-freebsd* )
 588     opsys=freebsd
 589   ;;
 590
 591   ## DragonFly ports
 592   *-*-dragonfly* )
 593     opsys=dragonfly
 594   ;;
 595
 596   ## FreeBSD kernel + glibc based userland
 597   *-*-kfreebsd*gnu* )
 598     opsys=gnu-kfreebsd
 599   ;;
 600
 601   ## NetBSD ports
 602   *-*-netbsd* )
 603     opsys=netbsd
 604   ;;
 605
 606   ## OpenBSD ports
 607   *-*-openbsd* | *-*-mirbsd* )
 608     opsys=openbsd
 609   ;;
 610
 611   ## Apple Darwin / Mac OS X
 612   *-apple-darwin* )
 613     case "${canonical}" in
 614       *-apple-darwin[0-9].*) unported=yes ;;
 615       i[3456]86-* | x86_64-* )  ;;
 616       * )            unported=yes ;;
 617     esac
 618     opsys=darwin
 619     ## FIXME: Find a way to use Fink if available (Bug#11507).
 620   ;;
 621
 622   ## Chromium Native Client
 623   *-nacl )
 624     opsys=nacl
 625   ;;
 626
 627   ## Cygwin ports
 628   *-*-cygwin )
 629     opsys=cygwin
 630   ;;
 631
 632   ## HP 9000 series 700 and 800, running HP/UX
 633   hppa*-hp-hpux10.2* )
 634     opsys=hpux10-20
 635   ;;
 636   hppa*-hp-hpux1[1-9]* )
 637     opsys=hpux11
 638     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 639   ;;
 640
 641   ## IBM machines
 642   rs6000-ibm-aix4.[23]* )
 643     opsys=aix4-2
 644   ;;
 645   powerpc-ibm-aix4.[23]*  )
 646     opsys=aix4-2
 647   ;;
 648   rs6000-ibm-aix[56]* )
 649     opsys=aix4-2
 650   ;;
 651   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 652     opsys=aix4-2
 653   ;;
 654
 655   ## Suns
 656   *-sun-solaris* \
 657     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 658     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 659     case "${canonical}" in
 660       i[3456]86-*-* )   ;;
 661       amd64-*-*|x86_64-*-*) ;;
 662       sparc* )          ;;
 663       * )               unported=yes ;;
 664     esac
 665     case "${canonical}" in
 666       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 667                 opsys=sol2-10
 668                 emacs_check_sunpro_c=yes
 669                 ;;
 670       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 671       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 672       *-sunos5.6* | *-solaris2.6* )
 673                 opsys=sol2-6
 674                 RANLIB="ar -ts"
 675                 ;;
 676       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 677       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 678                 opsys=sol2-6
 679                 emacs_check_sunpro_c=yes
 680                 ;;
 681     esac
 682     ## Watch out for a compiler that we know will not work.
 683     case "${canonical}" in
 684      *-solaris* | *-sunos5* )
 685                 if [ "x$CC" = x/usr/ucb/cc ]; then
 686                   ## /usr/ucb/cc doesn't work;
 687                   ## we should find some other compiler that does work.
 688                   unset CC
 689                 fi
 690                 ;;
 691       *) ;;
 692     esac
 693   ;;
 694
 695   ## Intel 386 machines where we don't care about the manufacturer.
 696   i[3456]86-*-* )
 697     case "${canonical}" in
 698       *-darwin* )               opsys=darwin ;;
 699       *-mingw* )
 700                 opsys=mingw32
 701                 # MinGW overrides and adds some system headers in nt/inc.
 702                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 703                 ;;
 704       *-sysv4.2uw* )            opsys=unixware ;;
 705       *-sysv5uw* )              opsys=unixware ;;
 706       *-sysv5OpenUNIX* )        opsys=unixware ;;
 707       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 708     esac
 709   ;;
 710
 711   # MinGW64
 712   x86_64-*-* )
 713     case "${canonical}" in
 714       *-mingw* )
 715                 opsys=mingw32
 716                 # MinGW overrides and adds some system headers in nt/inc.
 717                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 718                 ;;
 719       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 720     esac
 721   ;;
 722
 723   * )
 724     unported=yes
 725   ;;
 726 esac
 727
 728 ### If the code above didn't choose an operating system, just choose
 729 ### an operating system based on the configuration name.  You really
 730 ### only want to use this when you have no idea what the right
 731 ### operating system is; if you know what operating systems a machine
 732 ### runs, it's cleaner to make it explicit in the case statement
 733 ### above.
 734 if test x"${opsys}" = x; then
 735   case "${canonical}" in
 736     *-gnu* )                            opsys=gnu ;;
 737     * )
 738       unported=yes
 739     ;;
 740   esac
 741 fi
 742
 743 ]
 744 dnl quotation ends
 745
 746 if test $unported = yes; then
 747   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 748 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 749 Check 'etc/MACHINES' for recognized configuration names.])
 750 fi
 751
 752 #### Choose a compiler.
 753
 754 dnl Don't bother to test for C89.
 755 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 756
 757 dnl Sets GCC=yes if using gcc.
 758 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 759 if test -n "$XCRUN"; then
 760   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 761   test -n "$AR" && export AR
 762 fi
 763
 764 dnl Emacs needs C99 or later.
 765 gl_PROG_CC_C99
 766
 767 AM_PROG_CC_C_O
 768
 769 if test x$GCC = xyes; then
 770   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 771 fi
 772
 773 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 774 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 775 dnl that clash with MinGW.
 776 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 777
 778 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 779 AC_DEFUN([gl_CRYPTO_CHECK])
 780 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 781 # as we don't use them.
 782 AC_DEFUN([gl_FCNTL_O_FLAGS])
 783 # Avoid gnulib's test for pthread_sigmask.
 784 funcs=
 785 for func in $ac_func_list; do
 786   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 787 done
 788 ac_func_list=$funcs
 789 # Use the system putenv even if it lacks GNU features, as we don't need them,
 790 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 791 AC_CHECK_FUNCS_ONCE([putenv])
 792 AC_DEFUN([gl_FUNC_PUTENV],
 793   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 794
 795 # Initialize gnulib right after choosing the compiler.
 796 dnl Amongst other things, this sets AR and ARFLAGS.
 797 gl_EARLY
 798
 799 if test "$ac_test_CFLAGS" != set; then
 800   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 801   # if -g3 works and the user does not specify CFLAGS.
 802   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 803   case $CFLAGS in
 804     '-g')
 805       emacs_g3_CFLAGS='-g3';;
 806     '-g -O2')
 807       emacs_g3_CFLAGS='-g3 -O2';;
 808     *)
 809       emacs_g3_CFLAGS='';;
 810   esac
 811   if test -n "$emacs_g3_CFLAGS"; then
 812     emacs_save_CFLAGS=$CFLAGS
 813     CFLAGS=$emacs_g3_CFLAGS
 814     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 815       [emacs_cv_prog_cc_g3],
 816       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 817          [emacs_cv_prog_cc_g3=yes],
 818          [emacs_cv_prog_cc_g3=no])])
 819     if test $emacs_cv_prog_cc_g3 != yes; then
 820       CFLAGS=$emacs_save_CFLAGS
 821     fi
 822     if test $opsys = mingw32; then
 823       CFLAGS="$CFLAGS -gdwarf-2"
 824     fi
 825   fi
 826
 827   case $CFLAGS in
 828     *-O*) ;;
 829     *)
 830       # No optimization flag was inferred for this non-GCC compiler.
 831       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 832       emacs_save_CFLAGS=$CFLAGS
 833       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 834       CFLAGS=${CFLAGS}-O
 835       AC_CACHE_CHECK([whether $CC accepts -O],
 836         [emacs_cv_prog_cc_o],
 837         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 838            [emacs_cv_prog_cc_o=yes],
 839            [emacs_cv_prog_cc_o=no])])
 840       if test $emacs_cv_prog_cc_o != yes; then
 841         CFLAGS=$emacs_save_CFLAGS
 842       fi ;;
 843   esac
 844 fi
 845
 846 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 847 # ---------------------------------------------------------------------------
 848 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 849 # Otherwise, run RUN-IF-NOT-FOUND.
 850 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 851   [AC_PREPROC_IFELSE(
 852     [AC_LANG_PROGRAM(
 853       [[
 854 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 855 /* ok */
 856 #else
 857 # error "your version of gcc is older than $1.$2"
 858 #endif
 859       ]]),
 860     ], [$3], [$4])
 861   ]
 862 )
 863
 864 AC_ARG_ENABLE([gcc-warnings],
 865   [AS_HELP_STRING([--enable-gcc-warnings@<:@=TYPE@:>@],
 866                   [control generation of GCC warnings.  The TYPE 'yes'
 867                    means to fail if any warnings are issued; 'warn-only'
 868                    means issue warnings without failing (default for
 869                    developer builds); 'no' means disable warnings
 870                    (default for non-developer builds).])],
 871   [case $enableval in
 872      yes|no|warn-only) ;;
 873      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 874    esac
 875    gl_gcc_warnings=$enableval],
 876   [# By default, use 'warn-only' if it looks like the invoker of 'configure'
 877    # is a developer as opposed to a builder.  This is most likely true
 878    # if GCC is recent enough and there is a .git directory or file;
 879    # however, if there is also a .tarball-version file it is probably
 880    # just a release imported into Git for patch management.
 881    gl_gcc_warnings=no
 882    if test -e "$srcdir"/.git && test ! -f "$srcdir"/.tarball-version; then
 883      gl_GCC_VERSION_IFELSE([5], [3], [gl_gcc_warnings=warn-only])]
 884    fi
 885 )
 886
 887 # clang is unduly picky about some things.
 888 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 889   [AC_COMPILE_IFELSE(
 890      [AC_LANG_PROGRAM([[
 891           #ifndef __clang__
 892             error "not clang";
 893           #endif
 894         ]])],
 895      [emacs_cv_clang=yes],
 896      [emacs_cv_clang=no])])
 897
 898 # When compiling with GCC, prefer -isystem to -I when including system
 899 # include files, to avoid generating useless diagnostics for the files.
 900 AS_IF([test $gl_gcc_warnings = no],
 901  [
 902   isystem='-I'
 903   AS_IF([test "$emacs_cv_clang" = yes],
 904    [
 905      # Turn off some warnings if supported.
 906      gl_WARN_ADD([-Wno-switch])
 907      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 908      gl_WARN_ADD([-Wno-pointer-sign])
 909      gl_WARN_ADD([-Wno-string-plus-int])
 910      gl_WARN_ADD([-Wno-unknown-attributes])
 911    ])
 912  ],[
 913   isystem='-isystem '
 914
 915   # This, $nw, is the list of warnings we disable.
 916   nw=
 917
 918   case $with_x_toolkit in
 919     lucid | athena | motif)
 920        # Old toolkits mishandle 'const'.
 921        nw="$nw -Wwrite-strings"
 922        ;;
 923   esac
 924   AS_IF([test $gl_gcc_warnings = yes],
 925     [gl_WARN_ADD([-Werror], [WERROR_CFLAGS])])
 926   AC_SUBST([WERROR_CFLAGS])
 927
 928   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 929   nw="$nw -Woverlength-strings"     # Not a problem these days
 930   nw="$nw -Wformat-nonliteral"      # we do this a lot
 931   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 932   nw="$nw -Wswitch-default"         # Too many warnings for now
 933   nw="$nw -Winline"                 # OK to ignore 'inline'
 934   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 935                                     # signed overflow has undefined behavior
 936   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 937   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 938   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 939
 940   # Emacs doesn't care about shadowing; see
 941   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 942   nw="$nw -Wshadow"
 943
 944   # Emacs's use of alloca inhibits protecting the stack.
 945   nw="$nw -Wstack-protector"
 946
 947   # Emacs's use of partly-const functions such as Fgnutls_available_p
 948   # make this option problematic.
 949   nw="$nw -Wsuggest-attribute=const"
 950
 951   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 952   # option problematic.
 953   nw="$nw -Wsuggest-attribute=pure"
 954
 955   # This part is merely for shortening the command line,
 956   # since -Wall implies -Wswitch.
 957   nw="$nw -Wswitch"
 958
 959   # This part is merely for shortening the command line,
 960   # since -Wno-FOO needs to be added below regardless.
 961   nw="$nw -Wmissing-field-initializers"
 962   nw="$nw -Wtype-limits"
 963   nw="$nw -Wunused-parameter"
 964
 965   if test $emacs_cv_clang = yes; then
 966     nw="$nw -Wcast-align"
 967   fi
 968
 969   gl_MANYWARN_ALL_GCC([ws])
 970   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 971   for w in $ws; do
 972     gl_WARN_ADD([$w])
 973   done
 974   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 975   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 976   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 977   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 978   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 979   gl_WARN_ADD([-Wno-format-nonliteral])
 980
 981   # More things that clang is unduly picky about.
 982   if test $emacs_cv_clang = yes; then
 983     gl_WARN_ADD([-Wno-format-extra-args])
 984     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 985     gl_WARN_ADD([-Wno-unused-command-line-argument])
 986     gl_WARN_ADD([-Wno-unused-value])
 987   fi
 988
 989   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 990   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 991   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 992   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 993       without upsetting glibc 2.15+. */
 994    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 995         && defined __OPTIMIZE__ && __OPTIMIZE__)
 996    # define _FORTIFY_SOURCE 2
 997    #endif
 998   ])
 999
1000   # We use a slightly smaller set of warning options for lib/.
1001   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
1002   nw=
1003   nw="$nw -Wunused-macros"
1004
1005   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1006   AC_SUBST([GNULIB_WARN_CFLAGS])
1007  ])
1008
1009 edit_cflags="
1010   s,///*,/,g
1011   s/^/ /
1012   s/ -I/ $isystem/g
1013   s/^ //
1014 "
1015
1016 AC_ARG_ENABLE(link-time-optimization,
1017 [AS_HELP_STRING([--enable-link-time-optimization],
1018                 [build emacs with link-time optimization.
1019                  This requires GCC 4.5.0 or later, or clang.
1020                  (Note that clang support is experimental - see INSTALL.)
1021                  It also makes Emacs harder to debug, and when we tried it
1022                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1023                  recommended for typical use.])],
1024 if test "${enableval}" != "no"; then
1025    ac_lto_supported=no
1026    if test $emacs_cv_clang = yes; then
1027       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1028       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1029       if test -x "$GOLD_PLUGIN"; then
1030          LTO="-flto"
1031       fi
1032    elif test x$GCC = xyes; then
1033       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1034       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1035       if test x$CPUS != x; then
1036          LTO="-flto=$CPUS"
1037       else
1038          LTO="-flto"
1039       fi
1040    else
1041       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1042    fi
1043    if test -z "$LTO"; then
1044       ac_lto_supported=no
1045    else
1046       old_CFLAGS=$CFLAGS
1047       CFLAGS="$CFLAGS $LTO"
1048       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1049          [ac_lto_supported=yes], [ac_lto_supported=no])
1050          CFLAGS="$old_CFLAGS"
1051    fi
1052    AC_MSG_RESULT([$ac_lto_supported])
1053    if test "$ac_lto_supported" = "yes"; then
1054       CFLAGS="$CFLAGS $LTO"
1055       if test x$emacs_cv_clang = xyes; then
1056          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1057          # WARNING: 'ar --plugin ...' doesn't work without
1058          # command, so plugin name is appended to ARFLAGS.
1059          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1060          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1061       else
1062         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1063         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1064         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1065         dnl dump core on Fedora 20, so play it safe for now.
1066         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1067           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1068       fi
1069    fi
1070 fi)
1071
1072 dnl Prefer silent make output.  For verbose output, use
1073 dnl 'configure --disable-silent-rules' or 'make V=1' .
1074 AM_SILENT_RULES([yes])
1075 dnl Port to Automake 1.11.
1076 dnl This section can be removed once we assume Automake 1.14 or later.
1077 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1078 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1079 AC_SUBST([AM_V])
1080 AM_SUBST_NOTMAKE([AM_V])
1081 AC_SUBST([AM_DEFAULT_V])
1082 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1083 AC_SUBST([AM_DEFAULT_VERBOSITY])
1084
1085 dnl Some other nice autoconf tests.
1086 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1087 dnl AC_PROG_INSTALL
1088 dnl AC_PROG_MKDIR_P
1089 dnl if test "x$RANLIB" = x; then
1090 dnl   AC_PROG_RANLIB
1091 dnl fi
1092
1093
1094 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1095 dnl can be made to directories.  This is not relevant for our usage, and
1096 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1097 dnl hosted on AFS, both examples where simple links work, but links to
1098 dnl directories fail.  We use a cut-down version instead.
1099 dnl AC_PROG_LN_S
1100
1101 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1102 rm -f conf$$ conf$$.file
1103
1104 LN_S_FILEONLY='cp -p'
1105
1106 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1107 dnl random program in the current directory.
1108 if (echo >conf$$.file) 2>/dev/null; then
1109   if ln -s conf$$.file conf$$ 2>/dev/null; then
1110     if test "$opsys" = "mingw32"; then
1111       LN_S_FILEONLY='/bin/ln -s'
1112     else
1113       LN_S_FILEONLY='ln -s'
1114     fi
1115   elif ln conf$$.file conf$$ 2>/dev/null; then
1116     if test "$opsys" = "mingw32"; then
1117       LN_S_FILEONLY=/bin/ln
1118     else
1119       LN_S_FILEONLY=ln
1120     fi
1121   fi
1122 fi
1123
1124 rm -f conf$$ conf$$.file
1125
1126 if test "$LN_S_FILEONLY" = "ln -s"; then
1127    AC_MSG_RESULT([yes])
1128 else
1129    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1130 fi
1131
1132 AC_SUBST(LN_S_FILEONLY)
1133
1134
1135 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1136 dnl doesn't support links to directories, as in "ln file dir".  But that
1137 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1138 dnl executables at "make install" time.
1139 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1140 dnl for more details.
1141 if test "$opsys" = "mingw32"; then
1142   LN_S="/bin/ln"
1143 fi
1144
1145 dnl On some Debian versions, "install-info" prints irritating messages
1146 dnl "This is not dpkg install-info anymore, but GNU install-info"
1147 dnl if called via an absolute file name.
1148 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1149 dnl Sadly some people may have an old ginstall-info installed on
1150 dnl non-Debian systems, so we can't use this.
1151 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1152 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1153
1154 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1155   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1156 dnl Don't use GZIP, which is used by gzip for additional parameters.
1157 AC_PATH_PROG(GZIP_PROG, gzip)
1158
1159 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1160    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1161
1162 if test $opsys = gnu-linux; then
1163   AC_PATH_PROG(PAXCTL, paxctl,,
1164     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1165   if test "X$PAXCTL" != X; then
1166     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1167     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1168       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1169       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1170   fi
1171
1172   if test "${SETFATTR+set}" != set; then
1173     AC_CACHE_CHECK([for setfattr],
1174       [emacs_cv_prog_setfattr],
1175       [touch conftest.tmp
1176        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1177          emacs_cv_prog_setfattr=yes
1178        else
1179          emacs_cv_prog_setfattr=no
1180        fi])
1181     if test "$emacs_cv_prog_setfattr" = yes; then
1182       SETFATTR=setfattr
1183     else
1184       SETFATTR=
1185     fi
1186     rm -f conftest.tmp
1187     AC_SUBST([SETFATTR])
1188   fi
1189 fi
1190
1191 ## Need makeinfo >= 4.7 (?) to build the manuals.
1192 if test "$MAKEINFO" != "no"; then
1193   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1194     MAKEINFO=makeinfo
1195   fi
1196   case `($MAKEINFO --version) 2>/dev/null` in
1197     *' (GNU texinfo) '4.[[7-9]]* | \
1198     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1199     *' (GNU texinfo) '[[5-9]]* | \
1200     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1201     *) MAKEINFO=no;;
1202   esac
1203 fi
1204
1205 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1206 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1207 ## therefore in the category of "special tools" not normally required, which
1208 ## configure does not have to check for (eg autoconf itself).
1209 ## In a repository checkout on the other hand, the manuals are not included.
1210 ## So makeinfo is a requirement to build from the repository, and configure
1211 ## should test for it as it does for any other build requirement.
1212 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1213 ## with pre-built manuals, from a repository checkout.
1214 HAVE_MAKEINFO=yes
1215
1216 if test "$MAKEINFO" = "no"; then
1217   MAKEINFO=makeinfo
1218   if test "x${with_makeinfo}" = "xno"; then
1219     HAVE_MAKEINFO=no
1220   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1221     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1222 source tree does not seem to have pre-built manuals in the 'info' directory.
1223 Either install a suitable version of makeinfo, or re-run configure
1224 with the '--without-makeinfo' option to build without the manuals.] )
1225   fi
1226 fi
1227 AC_SUBST(HAVE_MAKEINFO)
1228
1229 if test $opsys = mingw32; then
1230    DOCMISC_W32=efaq-w32
1231 else
1232    DOCMISC_W32=
1233 fi
1234 AC_SUBST(DOCMISC_W32)
1235
1236 dnl Add our options to ac_link now, after it is set up.
1237
1238 if test x$GCC = xyes; then
1239   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1240     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1241 else
1242   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1243     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1244 fi
1245
1246 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1247 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1248 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1249 dnl if not built to support GNU ld.
1250
1251 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1252 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1253 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1254 dnl   Eg "make LDFLAGS=... all" could run into problems,
1255 dnl   http://bugs.debian.org/684788
1256 dnl * unnecessary, since temacs is the only thing that actually needs it.
1257 dnl   Indeed this is where it was originally, prior to:
1258 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1259 late_LDFLAGS="$LDFLAGS"
1260 if test x$GCC = xyes; then
1261   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1262 else
1263   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1264 fi
1265
1266 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1267
1268 AC_MSG_CHECKING([for -znocombreloc])
1269 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1270   [AC_MSG_RESULT(yes)],
1271   LDFLAGS_NOCOMBRELOC=
1272   [AC_MSG_RESULT(no)])
1273
1274 LDFLAGS="$late_LDFLAGS"
1275
1276 AC_CACHE_CHECK([whether addresses are sanitized],
1277   [emacs_cv_sanitize_address],
1278   [AC_COMPILE_IFELSE(
1279      [AC_LANG_PROGRAM(
1280         [[#ifndef __has_feature
1281           #define __has_feature(f) 0
1282           #endif
1283           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1284           #else
1285            error "Addresses are not sanitized.";
1286           #endif
1287         ]])],
1288      [emacs_cv_sanitize_address=yes],
1289      [emacs_cv_sanitize_address=no])])
1290
1291 dnl The function dump-emacs will not be defined and temacs will do
1292 dnl (load "loadup") automatically unless told otherwise.
1293 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1294 case "$opsys" in
1295   nacl) CANNOT_DUMP=yes ;;
1296 esac
1297
1298 if test "$CANNOT_DUMP" = "yes"; then
1299   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1300 elif test "$emacs_cv_sanitize_address" = yes; then
1301   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1302 fi
1303
1304 AC_SUBST(CANNOT_DUMP)
1305
1306
1307 UNEXEC_OBJ=unexelf.o
1308 case "$opsys" in
1309   # MSDOS uses unexcoff.o
1310   aix4-2)
1311    UNEXEC_OBJ=unexaix.o
1312    ;;
1313   cygwin)
1314    UNEXEC_OBJ=unexcw.o
1315    ;;
1316   darwin)
1317    UNEXEC_OBJ=unexmacosx.o
1318    ;;
1319   hpux10-20 | hpux11)
1320    UNEXEC_OBJ=unexhp9k800.o
1321    ;;
1322   mingw32)
1323    UNEXEC_OBJ=unexw32.o
1324    ;;
1325   sol2-10)
1326    # Use the Solaris dldump() function, called from unexsol.c, to dump
1327    # emacs, instead of the generic ELF dump code found in unexelf.c.
1328    # The resulting binary has a complete symbol table, and is better
1329    # for debugging and other observability tools (debuggers, pstack, etc).
1330    #
1331    # If you encounter a problem using dldump(), please consider sending
1332    # a message to the OpenSolaris tools-linking mailing list:
1333    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1334    #
1335    # It is likely that dldump() works with older Solaris too, but this has
1336    # not been tested, so for now this change is for Solaris 10 or newer.
1337    UNEXEC_OBJ=unexsol.o
1338    ;;
1339 esac
1340
1341 LD_SWITCH_SYSTEM=
1342 case "$opsys" in
1343   freebsd|dragonfly)
1344    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1345    ## The system compiler, GCC, has apparently been modified to not
1346    ## look there, contrary to what a stock GCC would do.
1347 ### It's not our place to do this.  See bug#10313#17.
1348 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1349       :
1350    ;;
1351
1352   gnu-linux)
1353    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1354    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1355    ;;
1356
1357   netbsd)
1358 ### It's not our place to do this.  See bug#10313#17.
1359 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1360       :
1361    ;;
1362
1363   openbsd)
1364    ## Han Boetes <han@boetes.org> says this is necessary,
1365    ## otherwise Emacs dumps core on elf systems.
1366    LD_SWITCH_SYSTEM="-Z"
1367    ;;
1368 esac
1369 AC_SUBST(LD_SWITCH_SYSTEM)
1370
1371 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1372
1373 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1374 ## which has not been defined yet.  When this was handled with cpp,
1375 ## it was expanded to null when configure sourced the s/*.h file.
1376 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1377 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1378 ## (or somesuch), but because it is supposed to go at the _front_
1379 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1380 ## Compare with the gnu-linux case below, which added to the end
1381 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1382 ## LD_SWITCH_SYSTEM_TEMACS.
1383 case "$opsys" in
1384   netbsd|openbsd)
1385    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1386 esac
1387
1388
1389 C_SWITCH_MACHINE=
1390 case $canonical in
1391  alpha*)
1392   AC_CHECK_DECL([__ELF__])
1393   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1394     ## With ELF, make sure that all common symbols get allocated to in the
1395     ## data section.  Otherwise, the dump of temacs may miss variables in
1396     ## the shared library that have been initialized.  For example, with
1397     ## GNU libc, __malloc_initialized would normally be resolved to the
1398     ## shared library's .bss section, which is fatal.
1399     if test "x$GCC" = "xyes"; then
1400       C_SWITCH_MACHINE="-fno-common"
1401     else
1402       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1403     fi
1404   else
1405       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1406       dnl albeit under the mistaken assumption that said file
1407       dnl was no longer used.
1408       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1409   fi
1410   ;;
1411 esac
1412 AC_SUBST(C_SWITCH_MACHINE)
1413
1414 AC_SUBST(UNEXEC_OBJ)
1415
1416 C_SWITCH_SYSTEM=
1417 ## Some programs in src produce warnings saying certain subprograms
1418 ## are too complex and need a MAXMEM value greater than 2000 for
1419 ## additional optimization.  --nils@exp-math.uni-essen.de
1420 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1421   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1422 if test "$opsys" = "mingw32"; then
1423   case "$canonical" in
1424     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1425     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1426   esac
1427 fi
1428 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1429 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1430 AC_SUBST(C_SWITCH_SYSTEM)
1431
1432
1433 LIBS_SYSTEM=
1434 case "$opsys" in
1435   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1436   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1437
1438   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1439
1440   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1441
1442   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1443
1444   ## Motif needs -lgen.
1445   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1446 esac
1447
1448 AC_SUBST(LIBS_SYSTEM)
1449
1450 ### Make sure subsequent tests use flags consistent with the build flags.
1451
1452 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1453   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1454 else
1455   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1456 fi
1457
1458 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1459 AC_DEFUN([AC_TYPE_SIZE_T])
1460 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1461 AC_DEFUN([AC_TYPE_UID_T])
1462
1463 # sqrt and other floating-point functions such as fmod and frexp
1464 # are found in -lm on many systems.
1465 OLD_LIBS=$LIBS
1466 AC_SEARCH_LIBS([sqrt], [m])
1467 if test "X$LIBS" = "X$OLD_LIBS"; then
1468   LIB_MATH=
1469 else
1470   LIB_MATH=$ac_cv_search_sqrt
1471 fi
1472 LIBS=$OLD_LIBS
1473
1474 dnl Current possibilities handled by sed (aix4-2 -> aix,
1475 dnl gnu-linux -> gnu/linux, etc.):
1476 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux.
1477 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1478 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1479
1480 case $opsys in
1481   cygwin )
1482     LIB_MATH=
1483     ;;
1484   darwin )
1485     ## Adding -lm confuses the dynamic linker, so omit it.
1486     LIB_MATH=
1487     ;;
1488   freebsd | dragonfly )
1489     SYSTEM_TYPE=berkeley-unix
1490     ;;
1491   gnu-linux | gnu-kfreebsd )
1492     ;;
1493   hpux10-20 | hpux11 )
1494     ;;
1495   mingw32 )
1496     LIB_MATH=
1497     SYSTEM_TYPE=windows-nt
1498     ;;
1499   dnl NB this may be adjusted below.
1500   netbsd | openbsd )
1501     SYSTEM_TYPE=berkeley-unix
1502     ;;
1503
1504   sol2* | unixware )
1505     SYSTEM_TYPE=usg-unix-v
1506     ;;
1507
1508 esac
1509
1510 AC_SUBST(LIB_MATH)
1511 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1512   [The type of system you are compiling for; sets 'system-type'.])
1513
1514
1515 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1516 pre_PKG_CONFIG_LIBS=$LIBS
1517
1518 PKG_PROG_PKG_CONFIG(0.9.0)
1519
1520 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1521 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1522 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1523 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1524 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1525 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1526 dnl actions.
1527 AC_DEFUN([EMACS_CHECK_MODULES],
1528   [PKG_CHECK_MODULES([$1], [$2],
1529      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1530       m4_default([$3], [HAVE_$1=yes])],
1531      [m4_default([$4], [HAVE_$1=no])])])
1532
1533 HAVE_SOUND=no
1534 if test "${with_sound}" != "no"; then
1535   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1536   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1537     have_sound_header=yes, [], [
1538     #ifdef __MINGW32__
1539     #define WIN32_LEAN_AND_MEAN
1540     #include <windows.h>
1541     #endif
1542     ])
1543   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1544     AC_MSG_ERROR([OSS sound support requested but not found.])
1545
1546   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1547     # Emulation library used on NetBSD.
1548     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1549     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1550       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1551     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1552     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1553   fi
1554   AC_SUBST(LIBSOUND)
1555
1556   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1557     ALSA_REQUIRED=1.0.0
1558     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1559     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1560     if test $HAVE_ALSA = yes; then
1561       SAVE_CFLAGS="$CFLAGS"
1562       SAVE_LIBS="$LIBS"
1563       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1564       LIBS="$ALSA_LIBS $LIBS"
1565       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1566                       emacs_alsa_normal=yes,
1567                     emacs_alsa_normal=no)
1568       if test "$emacs_alsa_normal" != yes; then
1569         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1570                        [[snd_lib_error_set_handler (0);]])],
1571                        emacs_alsa_subdir=yes,
1572                      emacs_alsa_subdir=no)
1573         if test "$emacs_alsa_subdir" != yes; then
1574           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1575         fi
1576         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1577       fi
1578
1579       CFLAGS="$SAVE_CFLAGS"
1580       LIBS="$SAVE_LIBS"
1581       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1582       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1583       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1584     elif test "${with_sound}" = "alsa"; then
1585       AC_MSG_ERROR([ALSA sound support requested but not found.])
1586     fi
1587   fi                            dnl with_sound = alsa|yes
1588
1589   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1590   dnl compiles only on the specified platforms.  For others, it
1591   dnl probably doesn't make sense to try.
1592   dnl FIXME So surely we should bypass this whole section if not using
1593   dnl one of these platforms?
1594   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1595      case "$opsys" in
1596        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1597        dnl Adjust the --with-sound help text if you change this.
1598        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1599          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1600          HAVE_SOUND=yes
1601          ;;
1602      esac
1603   fi
1604
1605   AC_SUBST(CFLAGS_SOUND)
1606 fi
1607
1608 dnl checks for header files
1609 AC_CHECK_HEADERS_ONCE(
1610   malloc.h
1611   sys/systeminfo.h
1612   sys/sysinfo.h
1613   coff.h pty.h
1614   sys/resource.h
1615   sys/utsname.h pwd.h utmp.h util.h)
1616
1617 AC_MSG_CHECKING(if personality LINUX32 can be set)
1618 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1619                emacs_cv_personality_linux32=yes,
1620                emacs_cv_personality_linux32=no)
1621 AC_MSG_RESULT($emacs_cv_personality_linux32)
1622
1623 if test $emacs_cv_personality_linux32 = yes; then
1624   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1625             [Define to 1 if personality LINUX32 can be set.])
1626 fi
1627
1628 # Note that Solaris has sys/sysinfo.h which defines struct
1629 # sysinfo as well.  To make sure that we're using GNU/Linux
1630 # sysinfo, we explicitly set one of its fields.
1631 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1632   AC_MSG_CHECKING([if Linux sysinfo may be used])
1633   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1634                                      [[struct sysinfo si;
1635                                        si.totalram = 0;
1636                                        sysinfo (&si)]])],
1637     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1638   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1639   if test $emacs_cv_linux_sysinfo = yes; then
1640     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1641     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1642                                        [[struct sysinfo si; return si.mem_unit]])],
1643       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1644                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1645   fi
1646 fi
1647
1648 dnl On Solaris 8 there's a compilation warning for term.h because
1649 dnl it doesn't define 'bool'.
1650 AC_CHECK_HEADERS(term.h, , , -)
1651 AC_HEADER_TIME
1652 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1653                                       ]])
1654 if test $ac_cv_have_decl_sys_siglist != yes; then
1655   # For Tru64, at least:
1656   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1657                                           ]])
1658 fi
1659 AC_HEADER_SYS_WAIT
1660
1661 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1662 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1663 #if HAVE_SYS_SOCKET_H
1664 #include <sys/socket.h>
1665 #endif])
1666 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1667 #if HAVE_SYS_SOCKET_H
1668 #include <sys/socket.h>
1669 #endif])
1670 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1671 #if HAVE_SYS_SOCKET_H
1672 #include <sys/socket.h>
1673 #endif])
1674
1675 dnl checks for structure members
1676 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1677                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1678                   struct ifreq.ifr_addr,
1679                   struct ifreq.ifr_addr.sa_len], , ,
1680                  [AC_INCLUDES_DEFAULT
1681 #if HAVE_SYS_SOCKET_H
1682 #include <sys/socket.h>
1683 #endif
1684 #if HAVE_NET_IF_H
1685 #include <net/if.h>
1686 #endif])
1687
1688 dnl Check for endianness.
1689 dnl AC_C_BIGENDIAN is done by gnulib.
1690
1691 dnl check for Make feature
1692
1693 AUTO_DEPEND=no
1694 dnl check if we have GCC and autodepend is on.
1695 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1696    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1697    SAVE_CFLAGS="$CFLAGS"
1698    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1699    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1700    CFLAGS="$SAVE_CFLAGS"
1701    test -f deps.d || ac_enable_autodepend=no
1702    rm -rf deps.d
1703    AC_MSG_RESULT([$ac_enable_autodepend])
1704    if test $ac_enable_autodepend = yes; then
1705       AUTO_DEPEND=yes
1706    fi
1707 fi
1708 AC_SUBST(AUTO_DEPEND)
1709
1710 dnl checks for operating system services
1711 AC_SYS_LONG_FILE_NAMES
1712
1713 #### Choose a window system.
1714
1715 ## We leave window_system equal to none if
1716 ## we end up building without one.  Any new window system should
1717 ## set window_system to an appropriate value and add objects to
1718 ## window-system-specific substs.
1719
1720 window_system=none
1721 AC_PATH_X
1722 if test "$no_x" != yes; then
1723   window_system=x11
1724 fi
1725
1726 LD_SWITCH_X_SITE_RPATH=
1727 if test "${x_libraries}" != NONE; then
1728   if test -n "${x_libraries}"; then
1729     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1730     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1731       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1732     `
1733   fi
1734   x_default_search_path=""
1735   x_search_path=${x_libraries}
1736   if test -z "${x_search_path}"; then
1737     x_search_path=/usr/lib
1738   fi
1739   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1740                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1741     x_search_path="\
1742 ${x_library}/X11/%L/%T/%N%C%S:\
1743 ${x_library}/X11/%l/%T/%N%C%S:\
1744 ${x_library}/X11/%T/%N%C%S:\
1745 ${x_library}/X11/%L/%T/%N%S:\
1746 ${x_library}/X11/%l/%T/%N%S:\
1747 ${x_library}/X11/%T/%N%S"
1748     if test x"${x_default_search_path}" = x; then
1749       x_default_search_path=${x_search_path}
1750     else
1751       x_default_search_path="${x_search_path}:${x_default_search_path}"
1752     fi
1753   done
1754 fi
1755 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1756
1757 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1758   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1759 fi
1760
1761 if test x"${x_includes}" = x; then
1762   bitmapdir=/usr/include/X11/bitmaps
1763 else
1764   # accumulate include directories that have X11 bitmap subdirectories
1765   bmd_acc=
1766   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1767     if test -d "${bmd}/X11/bitmaps"; then
1768       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1769     fi
1770     if test -d "${bmd}/bitmaps"; then
1771       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1772     fi
1773   done
1774   bitmapdir=${bmd_acc#:}
1775 fi
1776
1777 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1778 HAVE_NS=no
1779 NS_GNUSTEP_CONFIG=no
1780 NS_IMPL_COCOA=no
1781 NS_IMPL_GNUSTEP=no
1782 tmp_CPPFLAGS="$CPPFLAGS"
1783 tmp_CFLAGS="$CFLAGS"
1784 CPPFLAGS="$CPPFLAGS -x objective-c"
1785 CFLAGS="$CFLAGS -x objective-c"
1786 GNU_OBJC_CFLAGS=
1787 LIBS_GNUSTEP=
1788 if test "${with_ns}" != no; then
1789   if test "${opsys}" = darwin; then
1790      NS_IMPL_COCOA=yes
1791      ns_appdir=`pwd`/nextstep/Emacs.app
1792      ns_appbindir=${ns_appdir}/Contents/MacOS
1793      ns_appresdir=${ns_appdir}/Contents/Resources
1794      ns_appsrc=Cocoa/Emacs.base
1795      ns_fontfile=macfont.o
1796   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1797      NS_IMPL_GNUSTEP=yes
1798      NS_GNUSTEP_CONFIG=yes
1799      GNU_OBJC_CFLAGS=$flags
1800      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1801   elif test -f $GNUSTEP_CONFIG_FILE; then
1802      NS_IMPL_GNUSTEP=yes
1803      dnl FIXME sourcing this several times in subshells seems inefficient.
1804      GNUSTEP_SYSTEM_HEADERS=$(
1805        . $GNUSTEP_CONFIG_FILE
1806        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1807      )
1808      GNUSTEP_SYSTEM_LIBRARIES=$(
1809        . $GNUSTEP_CONFIG_FILE
1810        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1811      )
1812      dnl I seemed to need these as well with GNUstep-startup 0.25.
1813      GNUSTEP_LOCAL_HEADERS=$(
1814        . $GNUSTEP_CONFIG_FILE
1815        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1816      )
1817      GNUSTEP_LOCAL_LIBRARIES=$(
1818        . $GNUSTEP_CONFIG_FILE
1819        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1820      )
1821      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1822        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1823      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1824        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1825      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1826      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1827      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1828      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1829      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1830      dnl If they had chosen to either define it or not, we could have
1831      dnl just used AC_CHECK_DECL here.
1832      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1833        emacs_cv_objc_exceptions,
1834 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1835 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1836 1;
1837 #else
1838 fail;
1839 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1840      if test $emacs_cv_objc_exceptions = yes; then
1841        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1842        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1843          [Define if GNUstep uses ObjC exceptions.])
1844        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1845      fi
1846   fi
1847   if test $NS_IMPL_GNUSTEP = yes; then
1848      ns_appdir=`pwd`/nextstep/Emacs.app
1849      ns_appbindir=${ns_appdir}
1850      ns_appresdir=${ns_appdir}/Resources
1851      ns_appsrc=GNUstep/Emacs.base
1852      ns_fontfile=nsfont.o
1853   fi
1854
1855   dnl This is only used while we test the NS headers, it gets reset below.
1856   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1857   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1858
1859   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1860                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1861 are required for a Nextstep build are missing or cannot be compiled.
1862 Either fix this, or re-configure with the option '--without-ns'.])])
1863
1864   macfont_file=""
1865   if test "${NS_IMPL_COCOA}" = "yes"; then
1866     AC_MSG_CHECKING([for OSX 10.6 or newer])
1867     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1868                                      [
1869 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1870 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1871  ; /* OK */
1872 #else
1873  error "OSX 10.6 or newer required";
1874 #endif
1875 #endif
1876                     ])],
1877                     ns_osx_have_106=yes,
1878                     ns_osx_have_106=no)
1879     AC_MSG_RESULT([$ns_osx_have_106])
1880
1881     if test $ns_osx_have_106 = no; then
1882        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1883     fi
1884   fi
1885 fi
1886
1887 AC_SUBST(LIBS_GNUSTEP)
1888
1889 INSTALL_ARCH_INDEP_EXTRA=install-etc
1890 ns_self_contained=no
1891 NS_OBJ=
1892 NS_OBJC_OBJ=
1893 if test "${HAVE_NS}" = yes; then
1894   if test "$with_toolkit_scroll_bars" = "no"; then
1895     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1896   fi
1897
1898   window_system=nextstep
1899   # set up packaging dirs
1900   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1901      ns_self_contained=yes
1902      prefix=${ns_appresdir}
1903      exec_prefix=${ns_appbindir}
1904      dnl This one isn't really used, only archlibdir is.
1905      libexecdir="\${ns_appbindir}/libexec"
1906      archlibdir="\${ns_appbindir}/libexec"
1907      etcdocdir="\${ns_appresdir}/etc"
1908      etcdir="\${ns_appresdir}/etc"
1909      dnl FIXME maybe set datarootdir instead.
1910      dnl That would also get applications, icons, man.
1911      infodir="\${ns_appresdir}/info"
1912      mandir="\${ns_appresdir}/man"
1913      lispdir="\${ns_appresdir}/lisp"
1914      test "$locallisppathset" = no && locallisppath=""
1915      INSTALL_ARCH_INDEP_EXTRA=
1916   fi
1917
1918   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1919 fi
1920 CFLAGS="$tmp_CFLAGS"
1921 CPPFLAGS="$tmp_CPPFLAGS"
1922 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1923 AC_SUBST(ns_self_contained)
1924 AC_SUBST(NS_OBJ)
1925 AC_SUBST(NS_OBJC_OBJ)
1926
1927 HAVE_W32=no
1928 W32_OBJ=
1929 W32_LIBS=
1930 EMACSRES=
1931 CLIENTRES=
1932 CLIENTW=
1933 W32_RES_LINK=
1934 EMACS_MANIFEST=
1935 UPDATE_MANIFEST=
1936 if test "${with_w32}" != no; then
1937   case "${opsys}" in
1938     cygwin)
1939       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1940              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1941                    cannot be found.])])
1942     ;;
1943     mingw32)
1944     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1945     ;;
1946     *)
1947       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1948     ;;
1949   esac
1950 fi
1951
1952 if test "${opsys}" = "mingw32"; then
1953   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1954   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1955      #include <windows.h>
1956      #include <usp10.h>]],
1957    [[PIMAGE_NT_HEADERS pHeader;
1958      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1959    [emacs_cv_w32api=yes
1960     HAVE_W32=yes],
1961    emacs_cv_w32api=no)
1962   AC_MSG_RESULT($emacs_cv_w32api)
1963   if test "${emacs_cv_w32api}" = "no"; then
1964     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1965   fi
1966 fi
1967
1968 FIRSTFILE_OBJ=
1969 NTDIR=
1970 LIBS_ECLIENT=
1971 LIB_WSOCK32=
1972 NTLIB=
1973 CM_OBJ="cm.o"
1974 XARGS_LIMIT=
1975 if test "${HAVE_W32}" = "yes"; then
1976   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1977   if test "$with_toolkit_scroll_bars" = "no"; then
1978     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1979   fi
1980   AC_CHECK_TOOL(WINDRES, [windres],
1981                 [AC_MSG_ERROR([No resource compiler found.])])
1982   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1983   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1984   EMACSRES="emacs.res"
1985   case "$canonical" in
1986     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1987     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1988   esac
1989   dnl Construct something of the form "24,4,0,0" with 4 components.
1990   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1991
1992   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1993   AC_SUBST(comma_version)
1994   AC_SUBST(comma_space_version)
1995   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1996   if test "${opsys}" = "cygwin"; then
1997     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1998     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1999     # Tell the linker that emacs.res is an object (which we compile from
2000     # the rc file), not a linker script.
2001     W32_RES_LINK="-Wl,emacs.res"
2002   else
2003     UPDATE_MANIFEST=update-game-score.exe.manifest
2004     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
2005     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
2006     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
2007     W32_RES_LINK="\$(EMACSRES)"
2008     CLIENTRES="emacsclient.res"
2009     CLIENTW="emacsclientw\$(EXEEXT)"
2010     FIRSTFILE_OBJ=firstfile.o
2011     NTDIR=nt
2012     CM_OBJ=
2013     LIBS_ECLIENT="-lcomctl32"
2014     LIB_WSOCK32="-lwsock32"
2015     NTLIB="ntlib.$ac_objext"
2016     XARGS_LIMIT="-s 10000"
2017   fi
2018 fi
2019 AC_SUBST(W32_OBJ)
2020 AC_SUBST(W32_LIBS)
2021 AC_SUBST(EMACSRES)
2022 AC_SUBST(EMACS_MANIFEST)
2023 AC_SUBST(UPDATE_MANIFEST)
2024 AC_SUBST(CLIENTRES)
2025 AC_SUBST(CLIENTW)
2026 AC_SUBST(W32_RES_LINK)
2027 AC_SUBST(FIRSTFILE_OBJ)
2028 AC_SUBST(NTDIR)
2029 AC_SUBST(CM_OBJ)
2030 AC_SUBST(LIBS_ECLIENT)
2031 AC_SUBST(LIB_WSOCK32)
2032 AC_SUBST(NTLIB)
2033 AC_SUBST(XARGS_LIMIT)
2034
2035 if test "${HAVE_W32}" = "yes"; then
2036   window_system=w32
2037   with_xft=no
2038 fi
2039
2040 ## $window_system is now set to the window system we will
2041 ## ultimately use.
2042
2043 term_header=
2044 HAVE_X_WINDOWS=no
2045 HAVE_X11=no
2046 USE_X_TOOLKIT=none
2047
2048 case "${window_system}" in
2049   x11 )
2050     HAVE_X_WINDOWS=yes
2051     HAVE_X11=yes
2052     term_header=xterm.h
2053     case "${with_x_toolkit}" in
2054       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2055       motif ) USE_X_TOOLKIT=MOTIF ;;
2056       gtk ) with_gtk=yes
2057             term_header=gtkutil.h
2058 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2059 dnl USE_X_TOOLKIT is set.
2060             USE_X_TOOLKIT=none ;;
2061       gtk2 ) with_gtk2=yes
2062              term_header=gtkutil.h
2063              USE_X_TOOLKIT=none ;;
2064       gtk3 ) with_gtk3=yes
2065              term_header=gtkutil.h
2066              USE_X_TOOLKIT=none ;;
2067       no ) USE_X_TOOLKIT=none ;;
2068 dnl If user did not say whether to use a toolkit, make this decision later:
2069 dnl use the toolkit if we have gtk, or X11R5 or newer.
2070       * ) USE_X_TOOLKIT=maybe ;;
2071     esac
2072   ;;
2073   nextstep )
2074     term_header=nsterm.h
2075   ;;
2076   w32 )
2077     term_header=w32term.h
2078   ;;
2079 esac
2080
2081 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2082    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2083    if test "$HAVE_XSERVER" = true ||
2084       test -n "$DISPLAY" ||
2085       {
2086         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2087         test "$emacs_libX11" != '/usr/lib/libX11.*'
2088       }
2089    then
2090         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2091 were found.  You should install the relevant development files for X
2092 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2093 sure you have development files for image handling, i.e.
2094 tiff, gif, jpeg, png and xpm.
2095 If you are sure you want Emacs compiled without X window support, pass
2096   --without-x
2097 to configure.])
2098    fi
2099 fi
2100
2101 # Does the opsystem file prohibit the use of the GNU malloc?
2102 # Assume not, until told otherwise.
2103 GNU_MALLOC=yes
2104
2105 AC_CACHE_CHECK(
2106   [whether malloc is Doug Lea style],
2107   [emacs_cv_var_doug_lea_malloc],
2108   [emacs_cv_var_doug_lea_malloc=no
2109    dnl Hooks do not work with address sanitization.
2110    if test "$emacs_cv_sanitize_address" != yes; then
2111      AC_LINK_IFELSE(
2112        [AC_LANG_PROGRAM(
2113           [[#include <malloc.h>
2114             static void hook (void) {}]],
2115           [[malloc_set_state (malloc_get_state ());
2116             __after_morecore_hook = hook;
2117             __malloc_initialize_hook = hook;]])],
2118        [emacs_cv_var_doug_lea_malloc=yes])
2119    fi])
2120 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2121
2122 system_malloc=$emacs_cv_sanitize_address
2123
2124 hybrid_malloc=
2125
2126 case "$opsys" in
2127   ## darwin ld insists on the use of malloc routines in the System framework.
2128   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2129   cygwin) hybrid_malloc=yes;;
2130 esac
2131
2132 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2133    && test "${UNEXEC_OBJ}" = unexelf.o; then
2134   hybrid_malloc=yes
2135 fi
2136
2137 GMALLOC_OBJ=
2138 HYBRID_MALLOC=
2139 if test "${system_malloc}" = "yes"; then
2140   AC_DEFINE([SYSTEM_MALLOC], 1,
2141     [Define to 1 to use the system memory allocator, even if it is not
2142      Doug Lea style.])
2143   GNU_MALLOC=no
2144   GNU_MALLOC_reason="
2145     (The GNU allocators don't work with this system configuration.)"
2146   VMLIMIT_OBJ=
2147 elif test "$hybrid_malloc" = yes; then
2148   AC_DEFINE(HYBRID_MALLOC, 1,
2149     [Define to use gmalloc before dumping and the system malloc after.])
2150   HYBRID_MALLOC=1
2151   GNU_MALLOC=
2152   GNU_MALLOC_reason="only before dumping"
2153   GMALLOC_OBJ=gmalloc.o
2154   VMLIMIT_OBJ=
2155 else
2156   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2157   VMLIMIT_OBJ=vm-limit.o
2158
2159   AC_CHECK_HEADERS([sys/vlimit.h])
2160   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2161     [AC_LINK_IFELSE(
2162        [AC_LANG_PROGRAM(
2163          [[extern char data_start[]; char ch;]],
2164          [[return data_start < &ch;]])],
2165        [emacs_cv_data_start=yes],
2166        [emacs_cv_data_start=no])])
2167   if test $emacs_cv_data_start = yes; then
2168     AC_DEFINE([HAVE_DATA_START], 1,
2169       [Define to 1 if data_start is the address of the start
2170        of the main data segment.])
2171   fi
2172 fi
2173 AC_SUBST([HYBRID_MALLOC])
2174 AM_CONDITIONAL([HYBRID_MALLOC_LIB], [test -n "$HYBRID_MALLOC"])
2175 AC_SUBST(GMALLOC_OBJ)
2176 AC_SUBST(VMLIMIT_OBJ)
2177
2178 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2179   if test "$GNU_MALLOC" = yes ; then
2180     GNU_MALLOC_reason="
2181       (Using Doug Lea's new malloc from the GNU C Library.)"
2182   fi
2183   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2184     [Define to 1 if the system memory allocator is Doug Lea style,
2185      with malloc hooks and malloc_set_state.])
2186
2187   ## Use mmap directly for allocating larger buffers.
2188   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2189   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2190   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2191   case "$opsys" in
2192     mingw32|gnu*) REL_ALLOC=no ;;
2193   esac
2194 fi
2195
2196 if test x"${REL_ALLOC}" = x; then
2197   REL_ALLOC=${GNU_MALLOC}
2198 fi
2199
2200 use_mmap_for_buffers=no
2201 case "$opsys" in
2202   cygwin|mingw32) use_mmap_for_buffers=yes ;;
2203 esac
2204
2205 AC_FUNC_MMAP
2206 if test $use_mmap_for_buffers = yes; then
2207   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2208   REL_ALLOC=no
2209 fi
2210
2211 LIBS="$LIBS_SYSTEM $LIBS"
2212
2213 dnl FIXME replace main with a function we actually want from this library.
2214 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2215
2216 dnl Check for the POSIX thread library.
2217 LIB_PTHREAD=
2218 AC_CHECK_HEADERS_ONCE(pthread.h)
2219 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2220   AC_CACHE_CHECK([for pthread library],
2221     [emacs_cv_pthread_lib],
2222     [emacs_cv_pthread_lib=no
2223      OLD_LIBS=$LIBS
2224      for emacs_pthread_lib in 'none needed' -lpthread; do
2225        case $emacs_pthread_lib in
2226          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2227        esac
2228        AC_LINK_IFELSE(
2229          [AC_LANG_PROGRAM(
2230             [[#include <pthread.h>
2231               #include <signal.h>
2232               sigset_t old_mask, new_mask;
2233               void noop (void) {}]],
2234             [[pthread_t th = pthread_self ();
2235               int status = 0;
2236               status += pthread_create (&th, 0, 0, 0);
2237               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2238               status += pthread_kill (th, 0);
2239               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2240                      || defined DOUG_LEA_MALLOC)
2241               /* Test for pthread_atfork only if gmalloc uses it,
2242                  as older-style hosts like MirBSD 10 lack it.  */
2243               status += pthread_atfork (noop, noop, noop);
2244               #endif
2245               return status;]])],
2246          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2247        LIBS=$OLD_LIBS
2248        if test "$emacs_cv_pthread_lib" != no; then
2249          break
2250        fi
2251      done])
2252   if test "$emacs_cv_pthread_lib" != no; then
2253     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2254     case $emacs_cv_pthread_lib in
2255       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2256     esac
2257     ac_cv_func_pthread_sigmask=yes
2258     # Some systems optimize for single-threaded programs by default, and
2259     # need special flags to disable these optimizations. For example, the
2260     # definition of 'errno' in <errno.h>.
2261     case $opsys in
2262       hpux* | sol*)
2263         AC_DEFINE([_REENTRANT], 1,
2264           [Define to 1 if your system requires this in multithreaded code.]);;
2265       aix4-2)
2266         AC_DEFINE([_THREAD_SAFE], 1,
2267           [Define to 1 if your system requires this in multithreaded code.]);;
2268     esac
2269   fi
2270 fi
2271 AC_SUBST([LIB_PTHREAD])
2272
2273 dnl Check for need for bigtoc support on IBM AIX
2274
2275 case ${host_os} in
2276 aix*)
2277   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2278     case $GCC in
2279     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2280     *) gdb_cv_bigtoc=-bbigtoc ;;
2281     esac
2282
2283     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2284     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2285   ])
2286   ;;
2287 esac
2288
2289 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2290 # is for the tests that follow.  We set them back later on.
2291
2292 REAL_CFLAGS="$CFLAGS"
2293 REAL_CPPFLAGS="$CPPFLAGS"
2294 REAL_LIBS="$LIBS"
2295
2296 if test "${HAVE_X11}" = "yes"; then
2297   DEFS="$C_SWITCH_X_SITE $DEFS"
2298   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2299   LIBS="-lX11 $LIBS"
2300   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2301   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2302
2303   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2304   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2305   # but it's more convenient here to set LD_RUN_PATH since this
2306   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2307   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2308     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2309     export LD_RUN_PATH
2310   fi
2311
2312   if test "${opsys}" = "gnu-linux"; then
2313     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2314     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2315      [[XOpenDisplay ("foo");]])],
2316      [xgnu_linux_first_failure=no],
2317      [xgnu_linux_first_failure=yes])
2318     if test "${xgnu_linux_first_failure}" = "yes"; then
2319       OLD_CPPFLAGS="$CPPFLAGS"
2320       OLD_LIBS="$LIBS"
2321       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2322       LIBS="$LIBS -b i486-linuxaout"
2323       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2324        [[XOpenDisplay ("foo");]])],
2325        [xgnu_linux_second_failure=no],
2326        [xgnu_linux_second_failure=yes])
2327       if test "${xgnu_linux_second_failure}" = "yes"; then
2328         # If we get the same failure with -b, there is no use adding -b.
2329         # So leave it out.  This plays safe.
2330         AC_MSG_RESULT(no)
2331       else
2332         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2333         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2334         AC_MSG_RESULT(yes)
2335       fi
2336       CPPFLAGS=$OLD_CPPFLAGS
2337       LIBS=$OLD_LIBS
2338     else
2339       AC_MSG_RESULT(no)
2340     fi
2341   fi
2342
2343   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2344   # header files included from there.
2345   AC_MSG_CHECKING(for Xkb)
2346   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2347 #include <X11/XKBlib.h>]],
2348         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2349         emacs_xkb=yes, emacs_xkb=no)
2350   AC_MSG_RESULT($emacs_xkb)
2351   if test $emacs_xkb = yes; then
2352     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2353   fi
2354
2355   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2356 XScreenNumberOfScreen)
2357 fi
2358
2359 if test "${window_system}" = "x11"; then
2360   AC_MSG_CHECKING(X11 version 6)
2361   AC_CACHE_VAL(emacs_cv_x11_version_6,
2362   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2363 [[#if XlibSpecificationRelease < 6
2364 fail;
2365 #endif
2366 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2367   if test $emacs_cv_x11_version_6 = yes; then
2368     AC_MSG_RESULT(6 or newer)
2369     AC_DEFINE(HAVE_X11R6, 1,
2370               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2371     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2372     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2373     ## XIM support.
2374     case "$opsys" in
2375       sol2-*) : ;;
2376       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2377            [Define if you have usable X11R6-style XIM support.])
2378          ;;
2379     esac
2380   else
2381     AC_MSG_RESULT(before 6)
2382   fi
2383 fi
2384
2385
2386 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2387 HAVE_RSVG=no
2388 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2389   if test "${with_rsvg}" != "no"; then
2390     RSVG_REQUIRED=2.11.0
2391     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2392
2393     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2394     AC_SUBST(RSVG_CFLAGS)
2395     AC_SUBST(RSVG_LIBS)
2396
2397     if test $HAVE_RSVG = yes; then
2398       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2399       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2400       # Windows loads librsvg dynamically
2401       if test "${opsys}" = "mingw32"; then
2402         RSVG_LIBS=
2403       fi
2404     fi
2405   fi
2406 fi
2407
2408 HAVE_IMAGEMAGICK=no
2409 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2410   if test "${with_imagemagick}" != "no"; then
2411     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2412     ## 6.8.2 makes Emacs crash; see Bug#13867.
2413     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2414     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2415     AC_SUBST(IMAGEMAGICK_CFLAGS)
2416     AC_SUBST(IMAGEMAGICK_LIBS)
2417
2418     if test $HAVE_IMAGEMAGICK = yes; then
2419       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2420       OLD_CFLAGS=$CFLAGS
2421       OLD_LIBS=$LIBS
2422       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2423       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2424       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers MagickAutoOrientImage)
2425       CFLAGS=$OLD_CFLAGS
2426       LIBS=$OLD_LIBS
2427     fi
2428   fi
2429 fi
2430
2431 AC_CHECK_LIB(anl, getaddrinfo_a, HAVE_GETADDRINFO_A=yes)
2432 if test "${HAVE_GETADDRINFO_A}" = "yes"; then
2433   AC_DEFINE(HAVE_GETADDRINFO_A, 1,
2434 [Define to 1 if you have getaddrinfo_a for asynchronous DNS resolution.])
2435   GETADDRINFO_A_LIBS="-lanl"
2436   AC_SUBST(GETADDRINFO_A_LIBS)
2437 fi
2438
2439 HAVE_GTK=no
2440 GTK_OBJ=
2441 gtk_term_header=$term_header
2442 check_gtk2=no
2443 gtk3_pkg_errors=
2444 if test "${opsys}" != "mingw32"; then
2445   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2446     GLIB_REQUIRED=2.28
2447     GTK_REQUIRED=3.0
2448     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2449
2450     dnl Checks for libraries.
2451     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2452       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2453     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2454        AC_MSG_ERROR($GTK_PKG_ERRORS)
2455     fi
2456     if test "$pkg_check_gtk" = "yes"; then
2457        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2458        GTK_OBJ=emacsgtkfixed.o
2459        gtk_term_header=gtkutil.h
2460        USE_GTK_TOOLKIT="GTK3"
2461        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2462          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2463            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2464          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2465            [Define to 1 to disable Glib deprecation warnings.])
2466        fi
2467     else
2468        check_gtk2=yes
2469        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2470     fi
2471   fi
2472
2473   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2474     GLIB_REQUIRED=2.10
2475     GTK_REQUIRED=2.10
2476     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2477
2478     dnl Checks for libraries.
2479     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2480       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2481     if test "$pkg_check_gtk" = "no" &&
2482        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2483     then
2484       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2485     fi
2486     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2487   fi
2488 fi
2489
2490 OLD_CFLAGS=$CFLAGS
2491 OLD_LIBS=$LIBS
2492
2493 if test x"$pkg_check_gtk" = xyes; then
2494
2495   AC_SUBST(GTK_LIBS)
2496   CFLAGS="$CFLAGS $GTK_CFLAGS"
2497   LIBS="$GTK_LIBS $LIBS"
2498   dnl Try to compile a simple GTK program.
2499   AC_MSG_CHECKING([whether GTK compiles])
2500   GTK_COMPILES=no
2501   AC_LINK_IFELSE(
2502     [AC_LANG_PROGRAM(
2503        [[/* Check the Gtk and Glib APIs.  */
2504          #include <gtk/gtk.h>
2505          #include <glib-object.h>
2506          static void
2507          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2508          {}
2509        ]],
2510        [[
2511          GtkSettings *gs = 0;
2512          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2513             strict C prohibits this.  Use gtk_main_iteration to test that the
2514             libraries are there.  */
2515          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2516                                     0, 0, 0, G_CALLBACK (callback), 0))
2517            gtk_main_iteration ();
2518        ]])],
2519     [GTK_COMPILES=yes])
2520   AC_MSG_RESULT([$GTK_COMPILES])
2521   if test "${GTK_COMPILES}" != "yes"; then
2522     GTK_OBJ=
2523     if test "$USE_X_TOOLKIT" != "maybe"; then
2524       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2525     fi
2526   else
2527     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2528     HAVE_GTK=yes
2529     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2530     GTK_OBJ="gtkutil.o $GTK_OBJ"
2531     term_header=$gtk_term_header
2532     USE_X_TOOLKIT=none
2533     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2534        closing open displays.  This is no problem if you just use
2535        one display, but if you use more than one and close one of them
2536        Emacs may crash.
2537        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2538     sleep 3
2539   fi
2540
2541 fi
2542 AC_SUBST(GTK_OBJ)
2543
2544
2545 if test "${HAVE_GTK}" = "yes"; then
2546
2547   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2548   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2549   if test "$with_toolkit_scroll_bars" != no; then
2550     with_toolkit_scroll_bars=yes
2551   fi
2552
2553   dnl  Check if we have the old file selection dialog declared and
2554   dnl  in the link library.  In 2.x it may be in the library,
2555   dnl  but not declared if deprecated featured has been selected out.
2556   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2557   HAVE_GTK_FILE_SELECTION=no
2558   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2559                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2560 #include <gtk/gtk.h>])
2561   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2562     AC_CHECK_FUNCS(gtk_file_selection_new)
2563   fi
2564
2565   dnl Same as above for gtk_handle_box.
2566   HAVE_GTK_HANDLE_BOX=no
2567   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2568                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2569 #include <gtk/gtk.h>])
2570   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2571     AC_CHECK_FUNCS(gtk_handle_box_new)
2572   fi
2573
2574   dnl Same as above for gtk_tearoff_menu_item.
2575   HAVE_GTK_TEAROFF_MENU_ITEM=no
2576   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2577                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2578 #include <gtk/gtk.h>])
2579   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2580     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2581   fi
2582
2583   dnl Check for functions introduced in 2.14 and later.
2584   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2585                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2586                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2587                  gtk_orientable_set_orientation \
2588                  gtk_window_set_has_resize_grip)
2589
2590  term_header=gtkutil.h
2591 fi
2592
2593
2594 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2595 HAVE_XWIDGETS=no
2596 XWIDGETS_OBJ=
2597 if test "$with_xwidgets" != "no"; then
2598   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2599     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2600
2601   WEBKIT_REQUIRED=1.4.0
2602   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2603   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2604   HAVE_XWIDGETS=$HAVE_WEBKIT
2605   test $HAVE_XWIDGETS = yes ||
2606     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2607
2608   XWIDGETS_OBJ=xwidget.o
2609   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2610 fi
2611 AC_SUBST(XWIDGETS_OBJ)
2612
2613 CFLAGS=$OLD_CFLAGS
2614 LIBS=$OLD_LIBS
2615
2616 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2617 dnl other platforms.
2618 HAVE_DBUS=no
2619 DBUS_OBJ=
2620 if test "${with_dbus}" = "yes"; then
2621    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2622    if test "$HAVE_DBUS" = yes; then
2623      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2624      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2625      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2626      dnl D-Bus 1.5.12.
2627      OLD_LIBS=$LIBS
2628      LIBS="$LIBS $DBUS_LIBS"
2629      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2630                     dbus_type_is_valid \
2631                     dbus_validate_bus_name \
2632                     dbus_validate_path \
2633                     dbus_validate_interface \
2634                     dbus_validate_member)
2635      LIBS=$OLD_LIBS
2636      DBUS_OBJ=dbusbind.o
2637    fi
2638 fi
2639 AC_SUBST(DBUS_CFLAGS)
2640 AC_SUBST(DBUS_LIBS)
2641 AC_SUBST(DBUS_OBJ)
2642
2643 dnl GSettings has been tested under GNU/Linux only.
2644 HAVE_GSETTINGS=no
2645 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2646    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2647    if test "$HAVE_GSETTINGS" = "yes"; then
2648       old_CFLAGS=$CFLAGS
2649       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2650       old_LIBS=$LIBS
2651       LIBS="$LIBS $GSETTINGS_LIBS"
2652       AC_MSG_CHECKING([whether GSettings is in gio])
2653       AC_LINK_IFELSE(
2654          [AC_LANG_PROGRAM(
2655              [[/* Check that gsettings really is present.  */
2656              #include <glib-object.h>
2657              #include <gio/gio.h>
2658              ]],
2659              [[
2660                GSettings *settings;
2661                GVariant *val = g_settings_get_value (settings, "");
2662              ]])],
2663          [], HAVE_GSETTINGS=no)
2664       AC_MSG_RESULT([$HAVE_GSETTINGS])
2665
2666       if test "$HAVE_GSETTINGS" = "yes"; then
2667         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2668         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2669         SETTINGS_LIBS="$GSETTINGS_LIBS"
2670       fi
2671       CFLAGS=$old_CFLAGS
2672       LIBS=$old_LIBS
2673    fi
2674 fi
2675
2676 dnl GConf has been tested under GNU/Linux only.
2677 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2678 HAVE_GCONF=no
2679 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2680    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2681    if test "$HAVE_GCONF" = yes; then
2682       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2683       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2684       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2685       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2686    fi
2687 fi
2688
2689 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2690     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2691     if test "$HAVE_GOBJECT" = "yes"; then
2692        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2693        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2694     fi
2695     SAVE_CFLAGS="$CFLAGS"
2696     SAVE_LIBS="$LIBS"
2697     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2698     LIBS="$SETTINGS_LIBS $LIBS"
2699     CFLAGS="$SAVE_CFLAGS"
2700     LIBS="$SAVE_LIBS"
2701 fi
2702 AC_SUBST(SETTINGS_CFLAGS)
2703 AC_SUBST(SETTINGS_LIBS)
2704
2705
2706 dnl SELinux is available for GNU/Linux only.
2707 HAVE_LIBSELINUX=no
2708 LIBSELINUX_LIBS=
2709 if test "${with_selinux}" = "yes"; then
2710    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2711    if test "$HAVE_LIBSELINUX" = yes; then
2712       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2713       LIBSELINUX_LIBS=-lselinux
2714    fi
2715 fi
2716 AC_SUBST(LIBSELINUX_LIBS)
2717
2718 HAVE_GNUTLS=no
2719 if test "${with_gnutls}" = "yes" ; then
2720   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2721     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2722   if test "${HAVE_GNUTLS}" = "yes"; then
2723     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2724     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2725       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2726   fi
2727
2728   # Windows loads GnuTLS dynamically
2729   if test "${opsys}" = "mingw32"; then
2730     LIBGNUTLS_LIBS=
2731   fi
2732 fi
2733
2734 AC_SUBST(LIBGNUTLS_LIBS)
2735 AC_SUBST(LIBGNUTLS_CFLAGS)
2736
2737 HAVE_LIBSYSTEMD=no
2738 if test "${with_libsystemd}" = "yes" ; then
2739   dnl This code has been tested with libsystemd 222 and later.
2740   dnl FIXME: Find the earliest version number for which Emacs should work,
2741   dnl and change '222' to that number.
2742   EMACS_CHECK_MODULES([LIBSYSTEMD], [libsystemd >= 222],
2743     [HAVE_LIBSYSTEMD=yes], [HAVE_LIBSYSTEMD=no])
2744   if test "${HAVE_LIBSYSTEMD}" = "yes"; then
2745     AC_DEFINE(HAVE_LIBSYSTEMD, 1, [Define if using libsystemd.])
2746   fi
2747 fi
2748
2749 AC_SUBST(LIBSYSTEMD_LIBS)
2750 AC_SUBST(LIBSYSTEMD_CFLAGS)
2751
2752 NOTIFY_OBJ=
2753 NOTIFY_SUMMARY=no
2754
2755 dnl MS Windows native file monitor is available for mingw32 only.
2756 case $with_file_notification,$opsys in
2757   w32,cygwin)
2758     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2759     this is only supported on MS-Windows native and MinGW32 builds.
2760     Consider using gfile instead.])
2761     ;;
2762   w32,* | yes,mingw32)
2763     AC_CHECK_HEADER(windows.h)
2764     if test "$ac_cv_header_windows_h" = yes ; then
2765        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2766        NOTIFY_OBJ=w32notify.o
2767        NOTIFY_SUMMARY="yes (w32)"
2768     fi ;;
2769 esac
2770
2771 dnl inotify is available only on GNU/Linux.
2772 case $with_file_notification,$NOTIFY_OBJ in
2773   inotify, | yes,)
2774     AC_CHECK_HEADER(sys/inotify.h)
2775     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2776         AC_CHECK_FUNC(inotify_init1)
2777         if test "$ac_cv_func_inotify_init1" = yes; then
2778           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2779           NOTIFY_OBJ=inotify.o
2780           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2781        fi
2782     fi ;;
2783 esac
2784
2785 dnl kqueue is available on BSD-like systems.
2786 case $with_file_notification,$NOTIFY_OBJ in
2787   kqueue,* | yes,)
2788     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2789     if test "$HAVE_KQUEUE" = "yes"; then
2790        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2791        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2792        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2793        NOTIFY_LIBS=$KQUEUE_LIBS
2794        NOTIFY_OBJ=kqueue.o
2795        NOTIFY_SUMMARY="yes -lkqueue"
2796     else
2797        AC_SEARCH_LIBS(kqueue, [])
2798        if test "$ac_cv_search_kqueue" != no; then
2799          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2800          NOTIFY_OBJ=kqueue.o
2801          NOTIFY_SUMMARY="yes (kqueue)"
2802        fi
2803     fi ;;
2804 esac
2805
2806 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2807 dnl has been added in glib 2.24.  It has been tested under
2808 dnl GNU/Linux only.
2809 case $with_file_notification,$NOTIFY_OBJ in
2810   gfile,* | yes,)
2811     if test "${HAVE_NS}" = yes; then
2812        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2813 Consider kqueue instead.])
2814     else
2815        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2816        if test "$HAVE_GFILENOTIFY" = "yes"; then
2817           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2818           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2819           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2820           NOTIFY_OBJ=gfilenotify.o
2821           NOTIFY_SUMMARY="yes -lgio (gfile)"
2822        fi
2823     fi ;;
2824 esac
2825
2826 case $with_file_notification,$NOTIFY_OBJ in
2827   yes,* | no,* | *,?*) ;;
2828   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2829 esac
2830
2831 if test -n "$NOTIFY_OBJ"; then
2832    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2833 fi
2834 AC_SUBST(NOTIFY_CFLAGS)
2835 AC_SUBST(NOTIFY_LIBS)
2836 AC_SUBST(NOTIFY_OBJ)
2837
2838 dnl Do not put whitespace before the #include statements below.
2839 dnl Older compilers (eg sunos4 cc) choke on it.
2840 HAVE_XAW3D=no
2841 LUCID_LIBW=
2842 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2843   if test "$with_xaw3d" != no; then
2844     AC_CACHE_VAL(emacs_cv_xaw3d,
2845     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2846 #include <X11/Intrinsic.h>
2847 #include <X11/Xaw3d/Simple.h>]],
2848       [[]])],
2849       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2850                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2851       emacs_cv_xaw3d=no)])
2852   else
2853     emacs_cv_xaw3d=no
2854   fi
2855   if test $emacs_cv_xaw3d = yes; then
2856     AC_MSG_CHECKING(for xaw3d)
2857     AC_MSG_RESULT([yes; using Lucid toolkit])
2858     USE_X_TOOLKIT=LUCID
2859     HAVE_XAW3D=yes
2860     LUCID_LIBW=-lXaw3d
2861     AC_DEFINE(HAVE_XAW3D, 1,
2862               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2863   else
2864     AC_MSG_CHECKING(for xaw3d)
2865     AC_MSG_RESULT(no)
2866     AC_MSG_CHECKING(for libXaw)
2867     AC_CACHE_VAL(emacs_cv_xaw,
2868     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2869 #include <X11/Intrinsic.h>
2870 #include <X11/Xaw/Simple.h>]],
2871       [[]])],
2872       emacs_cv_xaw=yes,
2873       emacs_cv_xaw=no)])
2874     if test $emacs_cv_xaw = yes; then
2875       AC_MSG_RESULT([yes; using Lucid toolkit])
2876       USE_X_TOOLKIT=LUCID
2877       LUCID_LIBW=-lXaw
2878     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2879       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2880     else
2881       AC_MSG_ERROR([No X toolkit could be found.
2882 If you are sure you want Emacs compiled without an X toolkit, pass
2883   --with-x-toolkit=no
2884 to configure.  Otherwise, install the development libraries for the toolkit
2885 that you want to use (e.g. Gtk+) and re-run configure.])
2886     fi
2887   fi
2888 fi
2889
2890 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2891
2892 LIBXTR6=
2893 LIBXMU=
2894 if test "${USE_X_TOOLKIT}" != "none"; then
2895   AC_MSG_CHECKING(X11 toolkit version)
2896   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2897   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2898 [[#if XtSpecificationRelease < 6
2899 fail;
2900 #endif
2901 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2902   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2903   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2904     AC_MSG_RESULT(6 or newer)
2905     AC_DEFINE(HAVE_X11XTR6, 1,
2906               [Define to 1 if you have the X11R6 or newer version of Xt.])
2907     LIBXTR6="-lSM -lICE"
2908     case "$opsys" in
2909       ## Use libw.a along with X11R6 Xt.
2910       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2911     esac
2912   else
2913     AC_MSG_RESULT(before 6)
2914   fi
2915
2916 dnl If using toolkit, check whether libXmu.a exists.
2917 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2918   OLDLIBS="$LIBS"
2919   if test x$HAVE_X11XTR6 = xyes; then
2920     OTHERLIBS='-lXt -lSM -lICE'
2921   else
2922     OTHERLIBS='-lXt'
2923   fi
2924   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2925   if test "X$LIBS" != "X$OLDLIBS"; then
2926     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2927   fi
2928   LIBS=$OLDLIBS
2929   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2930 fi
2931 AC_SUBST(LIBXTR6)
2932 AC_SUBST(LIBXMU)
2933
2934 LIBXP=
2935 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2936   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2937   if test -d /usr/include/openmotif; then
2938     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2939     emacs_cv_openmotif=yes
2940     case "$canonical" in
2941       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2942       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2943       ;;
2944       *)
2945       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2946     esac
2947   else
2948     emacs_cv_openmotif=no
2949   fi
2950   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2951   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2952     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2953 int x = 5;
2954 #else
2955 Motif version prior to 2.1.
2956 #endif]])],
2957     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2958   if test $emacs_cv_motif_version_2_1 = yes; then
2959     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2960     if test x$emacs_cv_openmotif = xyes; then
2961       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2962     fi
2963   else
2964     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2965     # We put this in CFLAGS temporarily to precede other -I options
2966     # that might be in CFLAGS temporarily.
2967     # We put this in CPPFLAGS where it precedes the other -I options.
2968     OLD_CPPFLAGS=$CPPFLAGS
2969     OLD_CFLAGS=$CFLAGS
2970     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2971     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2972     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2973       [[int x = 5;]])],
2974       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2975     if test $emacs_cv_lesstif = yes; then
2976       # Make sure this -I option remains in CPPFLAGS after it is set
2977       # back to REAL_CPPFLAGS.
2978       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2979       # have those other -I options anyway.  Ultimately, having this
2980       # directory ultimately in CPPFLAGS will be enough.
2981       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2982       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2983     else
2984       CFLAGS=$OLD_CFLAGS
2985       CPPFLAGS=$OLD_CPPFLAGS
2986     fi
2987   fi
2988   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2989     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2990 fi
2991
2992 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2993 dnl using Motif or Xaw3d is available, and unless
2994 dnl --with-toolkit-scroll-bars=no was specified.
2995
2996 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2997             [Define to 1 if we should use toolkit scroll bars.])dnl
2998 USE_TOOLKIT_SCROLL_BARS=no
2999 if test "${with_toolkit_scroll_bars}" != "no"; then
3000   if test "${USE_X_TOOLKIT}" != "none"; then
3001     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
3002       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3003       HAVE_XAW3D=no
3004       USE_TOOLKIT_SCROLL_BARS=yes
3005     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
3006       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3007       USE_TOOLKIT_SCROLL_BARS=yes
3008     fi
3009   elif test "${HAVE_GTK}" = "yes"; then
3010     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3011     USE_TOOLKIT_SCROLL_BARS=yes
3012   elif test "${HAVE_NS}" = "yes"; then
3013     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3014     USE_TOOLKIT_SCROLL_BARS=yes
3015   elif test "${HAVE_W32}" = "yes"; then
3016     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3017     USE_TOOLKIT_SCROLL_BARS=yes
3018   fi
3019 fi
3020
3021 dnl See if XIM is available.
3022 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3023           #include <X11/Xlib.h>
3024           #include <X11/Xresource.h>]],
3025          [[XIMProc  callback;]])],
3026          [HAVE_XIM=yes
3027          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
3028          HAVE_XIM=no)
3029
3030 dnl '--with-xim' now controls only the initial value of use_xim at run time.
3031
3032 if test "${with_xim}" != "no"; then
3033   AC_DEFINE(USE_XIM, 1,
3034             [Define to 1 if we should use XIM, if it is available.])
3035 fi
3036
3037
3038 if test "${HAVE_XIM}" != "no"; then
3039   late_CFLAGS=$CFLAGS
3040   if test "$GCC" = yes; then
3041     CFLAGS="$CFLAGS --pedantic-errors"
3042   fi
3043   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3044 #include <X11/Xlib.h>
3045 #include <X11/Xresource.h>]],
3046 [[Display *display;
3047 XrmDatabase db;
3048 char *res_name;
3049 char *res_class;
3050 XIMProc  callback;
3051 XPointer *client_data;
3052 #ifndef __GNUC__
3053 /* If we're not using GCC, it's probably not XFree86, and this is
3054    probably right, but we can't use something like --pedantic-errors.  */
3055 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3056                                            char*, XIMProc, XPointer*);
3057 #endif
3058 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3059    client_data);]])],
3060     [emacs_cv_arg6_star=yes])
3061   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3062          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3063 either XPointer or XPointer*.])dnl
3064   if test "$emacs_cv_arg6_star" = yes; then
3065     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3066   else
3067     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3068   fi
3069   CFLAGS=$late_CFLAGS
3070 fi
3071
3072 ### Start of font-backend (under any platform) section.
3073 # (nothing here yet -- this is a placeholder)
3074 ### End of font-backend (under any platform) section.
3075
3076 ### Start of font-backend (under X11) section.
3077 if test "${HAVE_X11}" = "yes"; then
3078     ## Use -lXft if available, unless '--with-xft=no'.
3079     HAVE_XFT=maybe
3080     if test "x${with_x}" = "xno"; then
3081       with_xft="no";
3082     fi
3083
3084     if test "$with_xft" != no; then
3085       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3086       with_xft=$HAVE_FONTCONFIG
3087     fi
3088
3089     if test "x${with_xft}" != "xno"; then
3090
3091       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3092       ## Because xftfont.c uses XRenderQueryExtension, we also
3093       ## need to link to -lXrender.
3094       HAVE_XRENDER=no
3095       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3096       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3097         OLD_CPPFLAGS="$CPPFLAGS"
3098         OLD_CFLAGS="$CFLAGS"
3099         OLD_LIBS="$LIBS"
3100         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3101         CFLAGS="$CFLAGS $XFT_CFLAGS"
3102         XFT_LIBS="-lXrender $XFT_LIBS"
3103         LIBS="$XFT_LIBS $LIBS"
3104         AC_CHECK_HEADER(X11/Xft/Xft.h,
3105           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3106           [[#include <X11/X.h>]])
3107
3108         if test "${HAVE_XFT}" = "yes"; then
3109           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3110             AC_SUBST(XFT_LIBS)
3111           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3112         fi                        # "${HAVE_XFT}" = "yes"
3113         CPPFLAGS=$OLD_CPPFLAGS
3114         CFLAGS=$OLD_CFLAGS
3115         LIBS=$OLD_LIBS
3116       fi                          # "$HAVE_XFT" != no
3117     fi                            # "x${with_xft}" != "xno"
3118
3119     ## We used to allow building with FreeType and without Xft.
3120     ## However, the ftx font backend driver is not in good shape.
3121     if test "$HAVE_XFT" != "yes"; then
3122        dnl For the "Does Emacs use" message at the end.
3123        HAVE_XFT=no
3124        HAVE_FREETYPE=no
3125     else
3126        dnl Strict linkers fail with
3127        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3128        dnl if -lfreetype is not specified.
3129        dnl The following is needed to set FREETYPE_LIBS.
3130        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3131
3132        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3133     fi
3134
3135     HAVE_LIBOTF=no
3136     if test "${HAVE_FREETYPE}" = "yes"; then
3137       AC_DEFINE(HAVE_FREETYPE, 1,
3138                 [Define to 1 if using the freetype and fontconfig libraries.])
3139       if test "${with_libotf}" != "no"; then
3140         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3141         if test "$HAVE_LIBOTF" = "yes"; then
3142           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3143           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3144                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3145                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3146           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3147             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3148                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3149           fi
3150         fi
3151       fi
3152     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3153     dnl Does the new font backend require it, or can it work without it?
3154     fi
3155
3156     HAVE_M17N_FLT=no
3157     if test "${HAVE_LIBOTF}" = yes; then
3158       if test "${with_m17n_flt}" != "no"; then
3159         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3160         if test "$HAVE_M17N_FLT" = "yes"; then
3161           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3162         fi
3163       fi
3164     fi
3165 else
3166     HAVE_XFT=no
3167     HAVE_FREETYPE=no
3168     HAVE_LIBOTF=no
3169     HAVE_M17N_FLT=no
3170 fi
3171
3172 ### End of font-backend (under X11) section.
3173
3174 AC_SUBST(FREETYPE_CFLAGS)
3175 AC_SUBST(FREETYPE_LIBS)
3176 AC_SUBST(FONTCONFIG_CFLAGS)
3177 AC_SUBST(FONTCONFIG_LIBS)
3178 AC_SUBST(LIBOTF_CFLAGS)
3179 AC_SUBST(LIBOTF_LIBS)
3180 AC_SUBST(M17N_FLT_CFLAGS)
3181 AC_SUBST(M17N_FLT_LIBS)
3182
3183 HAVE_CAIRO=no
3184 if test "${HAVE_X11}" = "yes"; then
3185   if test "${with_cairo}" != "no"; then
3186     CAIRO_REQUIRED=1.12.0
3187     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3188     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3189     if test $HAVE_CAIRO = yes; then
3190       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3191     else
3192       AC_MSG_ERROR([cairo requested but not found.])
3193     fi
3194
3195     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3196     LIBS="$LIBS $CAIRO_LIBS"
3197     AC_SUBST(CAIRO_CFLAGS)
3198     AC_SUBST(CAIRO_LIBS)
3199   fi
3200 fi
3201
3202 if test "${HAVE_X11}" = "yes"; then
3203   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3204     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3205   if test "${HAVE_XCB}" = "yes"; then
3206     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3207     if test "${HAVE_X11_XCB}" = "yes"; then
3208       AC_DEFINE(USE_XCB, 1,
3209 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3210    X11/XCB programming.])
3211       XCB_LIBS="-lX11-xcb -lxcb"
3212       AC_SUBST(XCB_LIBS)
3213     fi
3214   fi
3215 fi
3216
3217 ### Use -lXpm if available, unless '--with-xpm=no'.
3218 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3219 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3220 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3221 ### LDFLAGS) accordingly.
3222 HAVE_XPM=no
3223 LIBXPM=
3224 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3225   if test "${with_xpm}" != "no"; then
3226     SAVE_CPPFLAGS="$CPPFLAGS"
3227     SAVE_LDFLAGS="$LDFLAGS"
3228     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3229     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3230     AC_CHECK_HEADER(X11/xpm.h,
3231       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3232     if test "${HAVE_XPM}" = "yes"; then
3233       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3234       AC_EGREP_CPP(no_return_alloc_pixels,
3235       [#include "X11/xpm.h"
3236 #ifndef XpmReturnAllocPixels
3237 no_return_alloc_pixels
3238 #endif
3239       ], HAVE_XPM=no, HAVE_XPM=yes)
3240
3241       if test "${HAVE_XPM}" = "yes"; then
3242         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3243         AC_MSG_RESULT(yes)
3244       else
3245         AC_MSG_RESULT(no)
3246         CPPFLAGS="$SAVE_CPPFLAGS"
3247         LDFLAGS="$SAVE_LDFLAGS"
3248       fi
3249     fi
3250   fi
3251
3252   if test "${HAVE_XPM}" = "yes"; then
3253     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3254     LIBXPM=-lXpm
3255   fi
3256 fi
3257
3258 if test "${HAVE_X11}" = "yes"; then
3259   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3260   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3261
3262   if test "${with_xpm}" != "no"; then
3263     AC_CHECK_HEADER(X11/xpm.h,
3264       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3265     if test "${HAVE_XPM}" = "yes"; then
3266       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3267       AC_EGREP_CPP(no_return_alloc_pixels,
3268       [#include "X11/xpm.h"
3269 #ifndef XpmReturnAllocPixels
3270 no_return_alloc_pixels
3271 #endif
3272       ], HAVE_XPM=no, HAVE_XPM=yes)
3273
3274       if test "${HAVE_XPM}" = "yes"; then
3275         AC_MSG_RESULT(yes)
3276       else
3277         AC_MSG_RESULT(no)
3278       fi
3279     fi
3280   fi
3281
3282   if test "${HAVE_XPM}" = "yes"; then
3283     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3284     LIBXPM=-lXpm
3285   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3286     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3287     LIBXPM=-lXpm
3288   fi
3289 fi
3290
3291 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3292 ### slightly different requirements wrt image libraries (it doesn't
3293 ### use -lXpm because it loads the xpm shared library dynamically at
3294 ### run time).
3295 if test "${opsys}" = "mingw32"; then
3296   if test "${with_xpm}" != "no"; then
3297     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3298 #define FOR_MSW 1])
3299   fi
3300
3301   if test "${HAVE_XPM}" = "yes"; then
3302     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3303   fi
3304 fi
3305
3306 AC_SUBST(LIBXPM)
3307
3308 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3309 HAVE_JPEG=no
3310 LIBJPEG=
3311 if test "${with_jpeg}" != "no"; then
3312   AC_CACHE_CHECK([for jpeglib 6b or later],
3313     [emacs_cv_jpeglib],
3314     [OLD_LIBS=$LIBS
3315      for emacs_cv_jpeglib in yes -ljpeg no; do
3316        case $emacs_cv_jpeglib in
3317          yes) ;;
3318          no) break;;
3319          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3320        esac
3321        AC_LINK_IFELSE(
3322          [AC_LANG_PROGRAM(
3323             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3324               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3325               #include <jpeglib.h>
3326               #include <jerror.h>
3327               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3328               struct jpeg_decompress_struct cinfo;
3329             ]],
3330             [[
3331               jpeg_create_decompress (&cinfo);
3332               WARNMS (&cinfo, JWRN_JPEG_EOF);
3333               jpeg_destroy_decompress (&cinfo);
3334             ]])],
3335          [emacs_link_ok=yes],
3336          [emacs_link_ok=no])
3337        LIBS=$OLD_LIBS
3338        test $emacs_link_ok = yes && break
3339      done])
3340   if test "$emacs_cv_jpeglib" != no; then
3341     HAVE_JPEG=yes
3342     AC_DEFINE([HAVE_JPEG], 1,
3343       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3344     ### mingw32 doesn't use -ljpeg, since it loads the library
3345     ### dynamically when needed, and doesn't want a run-time
3346     ### dependency on the jpeglib DLL.
3347     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3348     && LIBJPEG=$emacs_cv_jpeglib
3349   fi
3350 fi
3351 AC_SUBST(LIBJPEG)
3352
3353 HAVE_ZLIB=no
3354 LIBZ=
3355 if test "${with_zlib}" != "no"; then
3356   OLIBS=$LIBS
3357   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3358   LIBS=$OLIBS
3359   case $ac_cv_search_inflateEnd in
3360     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3361   esac
3362 fi
3363 if test "${HAVE_ZLIB}" = "yes"; then
3364   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3365   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3366   if test "${opsys}" = "mingw32"; then
3367      LIBZ=
3368   fi
3369 fi
3370 AC_SUBST(LIBZ)
3371
3372 ### Dynamic modules support
3373 LIBMODULES=
3374 HAVE_MODULES=no
3375 MODULES_OBJ=
3376 MODULES_SUFFIX=
3377 if test "${with_modules}" != "no"; then
3378   case $opsys in
3379     gnu|gnu-linux)
3380       LIBMODULES="-ldl"
3381       MODULES_SUFFIX=".so"
3382       HAVE_MODULES=yes
3383       ;;
3384     cygwin|mingw32)
3385       MODULES_SUFFIX=".dll"
3386       HAVE_MODULES=yes
3387       ;;
3388     darwin)
3389       MODULES_SUFFIX=".so"
3390       HAVE_MODULES=yes
3391       ;;
3392     *)
3393       # BSD systems have dlopen in libc.
3394       AC_CHECK_FUNC([dlopen],
3395         [MODULES_SUFFIX=".so"
3396          HAVE_MODULES=yes])
3397       ;;
3398   esac
3399
3400   if test "${HAVE_MODULES}" = no; then
3401     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3402   else
3403     SAVE_LIBS=$LIBS
3404     LIBS="$LIBS $LIBMODULES"
3405     AC_CHECK_FUNCS([dladdr dlfunc])
3406     LIBS=$SAVE_LIBS
3407   fi
3408 fi
3409
3410 if test "${HAVE_MODULES}" = yes; then
3411    MODULES_OBJ="dynlib.o emacs-module.o"
3412    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3413    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3414      [System extension for dynamic libraries])
3415 fi
3416 AC_SUBST(MODULES_OBJ)
3417 AC_SUBST(LIBMODULES)
3418
3419 ### Use -lpng if available, unless '--with-png=no'.
3420 HAVE_PNG=no
3421 LIBPNG=
3422 PNG_CFLAGS=
3423 if test "${NS_IMPL_COCOA}" = yes; then
3424   : # Nothing to do
3425 elif test "${with_png}" != no; then
3426   # mingw32 loads the library dynamically.
3427   if test "$opsys" = mingw32; then
3428     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3429   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3430     AC_MSG_CHECKING([for png])
3431     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3432     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3433       # libpng-config does not work; configure by hand.
3434       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3435       # in /usr/include/libpng.
3436       if test -r /usr/include/libpng/png.h &&
3437          test ! -r /usr/include/png.h; then
3438         png_cflags=-I/usr/include/libpng
3439       else
3440         png_cflags=
3441       fi
3442       png_libs='-lpng'
3443     }
3444     SAVE_CFLAGS=$CFLAGS
3445     SAVE_LIBS=$LIBS
3446     CFLAGS="$CFLAGS $png_cflags"
3447     LIBS="$png_libs -lz -lm $LIBS"
3448     AC_LINK_IFELSE(
3449       [AC_LANG_PROGRAM([[#include <png.h>]],
3450          [[return !png_get_channels (0, 0);]])],
3451       [HAVE_PNG=yes
3452        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3453        LIBPNG=$png_libs
3454        # $LIBPNG requires explicit -lz in some cases.
3455        # We don't know what those cases are, exactly, so play it safe and
3456        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3457        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3458          LIBPNG="$LIBPNG -lz"
3459        fi])
3460     CFLAGS=$SAVE_CFLAGS
3461     LIBS=$SAVE_LIBS
3462     AC_MSG_RESULT([$HAVE_PNG])
3463   fi
3464 fi
3465 if test $HAVE_PNG = yes; then
3466   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3467
3468   SAVE_CFLAGS=$CFLAGS
3469   CFLAGS="$CFLAGS $PNG_CFLAGS"
3470   AC_CHECK_DECL([png_longjmp],
3471     [],
3472     [AC_DEFINE([PNG_DEPSTRUCT], [],
3473        [Define to empty to suppress deprecation warnings when building
3474         with --enable-gcc-warnings and with libpng versions before 1.5,
3475         which lack png_longjmp.])],
3476     [[#include <png.h>
3477     ]])
3478   CFLAGS=$SAVE_CFLAGS
3479 fi
3480 AC_SUBST(LIBPNG)
3481 AC_SUBST(PNG_CFLAGS)
3482
3483 ### Use -ltiff if available, unless '--with-tiff=no'.
3484 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3485 HAVE_TIFF=no
3486 LIBTIFF=
3487 if test "${opsys}" = "mingw32"; then
3488   if test "${with_tiff}" != "no"; then
3489     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3490   fi
3491   if test "${HAVE_TIFF}" = "yes"; then
3492     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3493   fi
3494 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3495   if test "${with_tiff}" != "no"; then
3496     AC_CHECK_HEADER(tiffio.h,
3497       [tifflibs="-lz -lm"
3498       # At least one tiff package requires the jpeg library.
3499       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3500       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3501   fi
3502
3503   if test "${HAVE_TIFF}" = "yes"; then
3504     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3505     dnl FIXME -lz -lm, as per libpng?
3506     LIBTIFF=-ltiff
3507   fi
3508 fi
3509 AC_SUBST(LIBTIFF)
3510
3511 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3512 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3513 HAVE_GIF=no
3514 LIBGIF=
3515 if test "${opsys}" = "mingw32"; then
3516   if test "${with_gif}" != "no"; then
3517     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3518   fi
3519   if test "${HAVE_GIF}" = "yes"; then
3520     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3521   fi
3522 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3523         || test "${HAVE_W32}" = "yes"; then
3524   AC_CHECK_HEADER(gif_lib.h,
3525 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3526 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3527     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3528         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3529
3530   if test "$HAVE_GIF" = yes; then
3531     LIBGIF=-lgif
3532   elif test "$HAVE_GIF" = maybe; then
3533 # If gif_lib.h but no libgif, try libungif.
3534     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3535     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3536   fi
3537
3538   if test "${HAVE_GIF}" = "yes"; then
3539     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3540   fi
3541 fi
3542 AC_SUBST(LIBGIF)
3543
3544 dnl Check for required libraries.
3545 if test "${HAVE_X11}" = "yes"; then
3546   MISSING=""
3547   WITH_NO=""
3548   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3549     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3550   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3551     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3552   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3553     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3554   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3555     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3556   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3557     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3558
3559   if test "X${MISSING}" != X; then
3560     AC_MSG_ERROR([The following required libraries were not found:
3561     $MISSING
3562 Maybe some development libraries/packages are missing?
3563 If you don't want to link with them give
3564     $WITH_NO
3565 as options to configure])
3566   fi
3567 fi
3568
3569 ### Use -lgpm if available, unless '--with-gpm=no'.
3570 HAVE_GPM=no
3571 LIBGPM=
3572 if test "${with_gpm}" != "no"; then
3573   AC_CHECK_HEADER(gpm.h,
3574     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3575
3576   if test "${HAVE_GPM}" = "yes"; then
3577     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3578     LIBGPM=-lgpm
3579   fi
3580 fi
3581 AC_SUBST(LIBGPM)
3582
3583 dnl Check for malloc/malloc.h on darwin
3584 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3585
3586 GNUSTEP_CFLAGS=
3587 ### Use NeXTstep API to implement GUI.
3588 if test "${HAVE_NS}" = "yes"; then
3589   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3590   if test "${NS_IMPL_COCOA}" = "yes"; then
3591     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3592   fi
3593   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3594     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3595     if test $NS_GNUSTEP_CONFIG != yes; then
3596       # See also .m.o rule in src/Makefile.in.  */
3597       # FIXME: are all these flags really needed?  Document here why.  */
3598       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3599       ## Extra CFLAGS applied to src/*.m files.
3600       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3601     fi
3602   fi
3603   OTHER_FILES=ns-app
3604 fi
3605
3606 ### Use session management (-lSM -lICE) if available
3607 HAVE_X_SM=no
3608 LIBXSM=
3609 if test "${HAVE_X11}" = "yes"; then
3610   AC_CHECK_HEADER(X11/SM/SMlib.h,
3611     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3612
3613   if test "${HAVE_X_SM}" = "yes"; then
3614     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3615     LIBXSM="-lSM -lICE"
3616   fi
3617 fi
3618 AC_SUBST(LIBXSM)
3619
3620 ### Use XRandr (-lXrandr) if available
3621 HAVE_XRANDR=no
3622 if test "${HAVE_X11}" = "yes"; then
3623   XRANDR_REQUIRED=1.2.2
3624   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3625   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3626   if test $HAVE_XRANDR = no; then
3627     # Test old way in case pkg-config doesn't have it (older machines).
3628     # Include Xrender.h by hand to work around bug in older Xrandr.h
3629     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3630     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3631       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3632       [], [AC_INCLUDES_DEFAULT
3633 #include <X11/extensions/Xrender.h>])
3634     if test $HAVE_XRANDR = yes; then
3635       XRANDR_LIBS=-lXrandr
3636     fi
3637   fi
3638   if test $HAVE_XRANDR = yes; then
3639     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3640   fi
3641 fi
3642 AC_SUBST(XRANDR_CFLAGS)
3643 AC_SUBST(XRANDR_LIBS)
3644
3645 ### Use Xinerama (-lXinerama) if available
3646 HAVE_XINERAMA=no
3647 if test "${HAVE_X11}" = "yes"; then
3648   XINERAMA_REQUIRED=1.0.2
3649   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3650   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3651   if test $HAVE_XINERAMA = no; then
3652     # Test old way in case pkg-config doesn't have it (older machines).
3653     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3654       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3655     if test $HAVE_XINERAMA = yes; then
3656       XINERAMA_LIBS=-lXinerama
3657     fi
3658   fi
3659   if test $HAVE_XINERAMA = yes; then
3660     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3661   fi
3662 fi
3663 AC_SUBST(XINERAMA_CFLAGS)
3664 AC_SUBST(XINERAMA_LIBS)
3665
3666 ### Use Xfixes (-lXfixes) if available
3667 HAVE_XFIXES=no
3668 if test "${HAVE_X11}" = "yes"; then
3669   XFIXES_REQUIRED=4.0.0
3670   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3671   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3672   if test $HAVE_XFIXES = no; then
3673     # Test old way in case pkg-config doesn't have it (older machines).
3674     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3675       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3676     if test $HAVE_XFIXES = yes; then
3677       XFIXES_LIBS=-lXfixes
3678     fi
3679   fi
3680   if test $HAVE_XFIXES = yes; then
3681     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3682   fi
3683 fi
3684 AC_SUBST(XFIXES_CFLAGS)
3685 AC_SUBST(XFIXES_LIBS)
3686
3687 ### Use libxml (-lxml2) if available
3688 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3689 HAVE_LIBXML2=no
3690 if test "${with_xml2}" != "no"; then
3691   ### I'm not sure what the version number should be, so I just guessed.
3692   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3693   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3694   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3695     SAVE_CPPFLAGS="$CPPFLAGS"
3696     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3697       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3698       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3699       case $xcsdkdir in
3700         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3701         xcsdkdir="" ;;
3702       esac
3703     fi
3704     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3705     AC_CHECK_HEADER(libxml/HTMLparser.h,
3706       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3707                      [#include <libxml/HTMLparser.h>])])
3708     CPPFLAGS="$SAVE_CPPFLAGS"
3709     if test "${HAVE_LIBXML2}" = "yes"; then
3710       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3711       LIBXML2_LIBS="-lxml2"
3712     fi
3713   fi
3714   if test "${HAVE_LIBXML2}" = "yes"; then
3715     if test "${opsys}" != "mingw32"; then
3716       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3717         [$LIBXML2_LIBS])
3718     else
3719       LIBXML2_LIBS=""
3720     fi
3721     if test "${HAVE_LIBXML2}" = "yes"; then
3722       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3723     else
3724       LIBXML2_LIBS=""
3725       LIBXML2_CFLAGS=""
3726     fi
3727   fi
3728 fi
3729 AC_SUBST(LIBXML2_LIBS)
3730 AC_SUBST(LIBXML2_CFLAGS)
3731
3732 # Check for mail-locking functions in a "mail" library.  Probably this should
3733 # have the same check as for liblockfile below.
3734 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3735 if test $have_mail = yes; then
3736   LIBS_MAIL=-lmail
3737   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3738
3739   OLD_LIBS=$LIBS
3740   LIBS="$LIBS_MAIL $LIBS"
3741   AC_CHECK_FUNCS(touchlock)
3742   LIBS=$OLD_LIBS
3743 else
3744   LIBS_MAIL=
3745 fi
3746 dnl Debian, at least:
3747 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3748 if test $have_lockfile = yes; then
3749    LIBS_MAIL=-llockfile
3750    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3751 else
3752 # If we have the shared liblockfile, assume we must use it for mail
3753 # locking (e.g. Debian).  If we couldn't link against liblockfile
3754 # (no liblockfile.a installed), ensure that we don't need to.
3755   dnl This works for files generally, not just executables.
3756   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3757   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3758                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3759   if test $ac_cv_prog_liblockfile = yes; then
3760     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3761 This probably means that movemail could lose mail.
3762 There may be a 'development' package to install containing liblockfile.])
3763   fi
3764 fi
3765 AC_CHECK_HEADERS_ONCE(maillock.h)
3766 AC_SUBST(LIBS_MAIL)
3767
3768 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3769 ## interlock access to the mail spool.  The alternative is a lock file named
3770 ## /usr/spool/mail/$USER.lock.
3771 mail_lock=no
3772 case "$opsys" in
3773   aix4-2) mail_lock="lockf" ;;
3774
3775   gnu|freebsd|dragonfly|netbsd|openbsd|darwin) mail_lock="flock" ;;
3776
3777   ## On GNU/Linux systems, both methods are used by various mail programs.
3778   ## I assume most people are using newer mailers that have heard of flock.
3779   ## Change this if you need to.
3780   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3781   ## configure gets the right answers, and that means *NOT* using flock.
3782   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3783   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3784   ## Debian maintainer hasn't provided a clean fix for Emacs.
3785   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3786   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3787   ## correct logic.  -- fx
3788   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3789   ## liblockfile is a Free Software replacement for libmail, used on
3790   ## Debian systems and elsewhere. -rfr.
3791   gnu-*)
3792     mail_lock="flock"
3793     if test $have_mail = yes || test $have_lockfile = yes; then
3794       test $ac_cv_header_maillock_h = yes && mail_lock=no
3795     fi
3796     ;;
3797
3798   mingw32)
3799     mail_lock="none-needed" ;;
3800 esac
3801
3802 BLESSMAIL_TARGET=
3803 case "$mail_lock" in
3804   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3805
3806   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3807
3808   none-needed) ;;
3809
3810   *) BLESSMAIL_TARGET="need-blessmail" ;;
3811 esac
3812 AC_SUBST(BLESSMAIL_TARGET)
3813
3814 OLD_LIBS=$LIBS
3815 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3816 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3817 getrusage get_current_dir_name \
3818 lrand48 random rint \
3819 select getpagesize setlocale newlocale \
3820 getrlimit setrlimit shutdown \
3821 pthread_sigmask strsignal setitimer \
3822 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3823 gai_strerror sync \
3824 getpwent endpwent getgrent endgrent \
3825 cfmakeraw cfsetspeed copysign __executable_start log2)
3826 LIBS=$OLD_LIBS
3827
3828 dnl No need to check for posix_memalign if aligned_alloc works.
3829 AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3830 AC_CHECK_DECLS([aligned_alloc], [], [], [[#include <stdlib.h>]])
3831
3832 dnl Cannot use AC_CHECK_FUNCS
3833 AC_CACHE_CHECK([for __builtin_unwind_init],
3834                emacs_cv_func___builtin_unwind_init,
3835 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3836                 emacs_cv_func___builtin_unwind_init=yes,
3837                 emacs_cv_func___builtin_unwind_init=no)])
3838 if test $emacs_cv_func___builtin_unwind_init = yes; then
3839   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3840             [Define to 1 if you have the '__builtin_unwind_init' function.])
3841 fi
3842
3843 AC_CHECK_HEADERS_ONCE(sys/un.h)
3844
3845 AC_FUNC_FSEEKO
3846
3847 # UNIX98 PTYs.
3848 AC_CHECK_FUNCS(grantpt)
3849
3850 # PTY-related GNU extensions.
3851 AC_CHECK_FUNCS(getpt posix_openpt)
3852
3853 # Check this now, so that we will NOT find the above functions in ncurses.
3854 # That is because we have not set up to link ncurses in lib-src.
3855 # It's better to believe a function is not available
3856 # than to expect to find it in ncurses.
3857 # Also we need tputs and friends to be able to build at all.
3858 AC_MSG_CHECKING([for library containing tputs])
3859 # Run a test program that contains a call to tputs, a call that is
3860 # never executed.  This tests whether a pre-'main' dynamic linker
3861 # works with the library.  It's too much trouble to actually call
3862 # tputs in the test program, due to portability hassles.  When
3863 # cross-compiling, assume the test program will run if it links.
3864 AC_DEFUN([tputs_link_source], [
3865   AC_LANG_SOURCE(
3866      [[extern void tputs (const char *, int, int (*)(int));
3867        int main (int argc, char **argv)
3868        {
3869           if (argc == 10000)
3870             tputs (argv[0], 0, 0);
3871           return 0;
3872        }]])
3873 ])
3874 if test "${opsys}" = "mingw32"; then
3875   msg='none required'
3876 else
3877   # Maybe curses should be tried earlier?
3878   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3879   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3880     OLIBS=$LIBS
3881     if test -z "$tputs_library"; then
3882       LIBS_TERMCAP=
3883       msg='none required'
3884     else
3885       LIBS_TERMCAP=-l$tputs_library
3886       msg=$LIBS_TERMCAP
3887       LIBS="$LIBS_TERMCAP $LIBS"
3888     fi
3889     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3890       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3891     LIBS=$OLIBS
3892     if test "X$msg" != Xno; then
3893       break
3894     fi
3895   done
3896 fi
3897 AC_MSG_RESULT([$msg])
3898 if test "X$msg" = Xno; then
3899   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3900 The following libraries were tried (in order):
3901   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3902 Please try installing whichever of these libraries is most appropriate
3903 for your system, together with its header files.
3904 For example, a libncurses-dev(el) or similar package.])
3905 fi
3906
3907 ## Use termcap instead of terminfo?
3908 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3909 TERMINFO=yes
3910 ## FIXME?  In the cases below where we unconditionally set
3911 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3912 ## if that was found above to have tputs.
3913 ## Should we use the gnu* logic everywhere?
3914 case "$opsys" in
3915   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3916   ##  The ncurses library has been moved out of the System framework in
3917   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3918   ##  option to use it.
3919   darwin) LIBS_TERMCAP="-lncurses" ;;
3920
3921   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3922
3923   freebsd)
3924     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3925     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3926     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3927 [[#if __FreeBSD_version < 400000
3928 fail;
3929 #endif
3930 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3931
3932     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3933
3934     if test $emacs_cv_freebsd_terminfo = yes; then
3935       LIBS_TERMCAP="-lncurses"
3936     else
3937       TERMINFO=no
3938       LIBS_TERMCAP="-ltermcap"
3939     fi
3940     ;;
3941
3942   mingw32)
3943     TERMINFO=no
3944     LIBS_TERMCAP=
3945     ;;
3946
3947   netbsd)
3948     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3949       TERMINFO=no
3950       LIBS_TERMCAP="-ltermcap"
3951     fi
3952     ;;
3953
3954   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3955
3956   ## hpux: Make sure we get select from libc rather than from libcurses
3957   ##  because libcurses on HPUX 10.10 has a broken version of select.
3958   ##  We used to use -lc -lcurses, but this may be cleaner.
3959   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3960   # set that way, now it uses the default).  Isn't this a contradiction?
3961   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3962
3963 esac
3964
3965 TERMCAP_OBJ=tparam.o
3966 if test $TERMINFO = yes; then
3967   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3968   TERMCAP_OBJ=terminfo.o
3969 fi
3970 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3971   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3972 fi
3973 AC_SUBST(LIBS_TERMCAP)
3974 AC_SUBST(TERMCAP_OBJ)
3975
3976 # GNU/Linux-specific timer functions.
3977 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3978   [AC_COMPILE_IFELSE(
3979      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3980                       ]],
3981                       [[timerfd_create (CLOCK_REALTIME,
3982                                         TFD_CLOEXEC | TFD_NONBLOCK);
3983                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3984      [emacs_cv_have_timerfd=yes],
3985      [emacs_cv_have_timerfd=no])])
3986 if test "$emacs_cv_have_timerfd" = yes; then
3987   AC_DEFINE([HAVE_TIMERFD], 1,
3988     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3989 fi
3990
3991 # Alternate stack for signal handlers.
3992 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3993                [emacs_cv_alternate_stack],
3994   [AC_COMPILE_IFELSE(
3995      [AC_LANG_PROGRAM([[#include <signal.h>
3996                       ]],
3997                       [[stack_t ss;
3998                         struct sigaction sa;
3999                         ss.ss_sp = malloc (SIGSTKSZ);
4000                         ss.ss_size = SIGSTKSZ;
4001                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
4002                         sigaltstack (&ss, 0);
4003                         sigaction (SIGSEGV, &sa, 0);]])],
4004      [emacs_cv_alternate_stack=yes],
4005      [emacs_cv_alternate_stack=no])])
4006
4007 # Do we need the Hesiod library to provide the support routines?
4008 dnl FIXME?  Should we be skipping this on Darwin too?
4009 LIBHESIOD=
4010 LIBRESOLV=
4011 if test "$with_hesiod" != no ; then
4012   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4013   resolv=no
4014   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4015      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4016                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4017   if test "$resolv" = yes ; then
4018     RESOLVLIB=-lresolv
4019   else
4020     RESOLVLIB=
4021   fi
4022   hesiod=no
4023   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4024         hesiod=yes, :, $RESOLVLIB)])
4025
4026   if test x"$hesiod" = xyes; then
4027     LIBHESIOD=-lhesiod
4028     LIBRESOLV=$RESOLVLIB
4029   fi
4030 fi
4031 AC_SUBST(LIBHESIOD)
4032 AC_SUBST(LIBRESOLV)
4033
4034 # These tell us which Kerberos-related libraries to use.
4035 COM_ERRLIB=
4036 CRYPTOLIB=
4037 KRB5LIB=
4038 DESLIB=
4039 KRB4LIB=
4040
4041 if test "${with_kerberos}" != no; then
4042   OLD_LIBS=$LIBS
4043   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4044   if test $have_com_err = yes; then
4045     COM_ERRLIB=-lcom_err
4046     LIBS="$COM_ERRLIB $LIBS"
4047   fi
4048   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4049   if test $have_crypto = yes; then
4050     CRYPTOLIB=-lcrypto
4051     LIBS="$CRYPTOLIB $LIBS"
4052   fi
4053   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4054   if test $have_k5crypto = yes; then
4055     CRYPTOLIB=-lk5crypto
4056     LIBS="$CRYPTOLIB $LIBS"
4057   fi
4058   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4059   if test $have_krb5=yes; then
4060     KRB5LIB=-lkrb5
4061     LIBS="$KRB5LIB $LIBS"
4062   fi
4063   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4064   if test "${with_kerberos5}" = no; then
4065     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4066     if test $have_des425 = yes; then
4067       DESLIB=-ldes425
4068       LIBS="$DESLIB $LIBS"
4069     else
4070       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4071       if test $have_des = yes; then
4072         DESLIB=-ldes
4073         LIBS="$DESLIB $LIBS"
4074       fi
4075     fi
4076     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4077     if test $have_krb4 = yes; then
4078       KRB4LIB=-lkrb4
4079       LIBS="$KRB4LIB $LIBS"
4080     else
4081       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4082       if test $have_krb = yes; then
4083         KRB4LIB=-lkrb
4084         LIBS="$KRB4LIB $LIBS"
4085       fi
4086     fi
4087   fi
4088
4089   if test "${with_kerberos5}" != no; then
4090     AC_CHECK_HEADERS(krb5.h,
4091       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4092                         [#include <krb5.h>])])
4093   else
4094     AC_CHECK_HEADERS(krb.h,,
4095                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4096                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4097   fi
4098   AC_CHECK_HEADERS(com_err.h)
4099   LIBS=$OLD_LIBS
4100 fi
4101
4102 AC_SUBST(COM_ERRLIB)
4103 AC_SUBST(CRYPTOLIB)
4104 AC_SUBST(KRB5LIB)
4105 AC_SUBST(DESLIB)
4106 AC_SUBST(KRB4LIB)
4107
4108 AC_CHECK_HEADERS(valgrind/valgrind.h)
4109
4110 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4111
4112 AC_CHECK_FUNCS_ONCE(tzset)
4113
4114 ok_so_far=yes
4115 AC_CHECK_FUNC(socket, , ok_so_far=no)
4116 if test $ok_so_far = yes; then
4117   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4118 fi
4119 if test $ok_so_far = yes; then
4120   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4121 fi
4122 if test $ok_so_far = yes; then
4123 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4124   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4125             [Define to 1 if you have inet sockets.])
4126 fi
4127
4128 AC_FUNC_FORK
4129
4130 AC_CHECK_FUNCS(snprintf)
4131
4132 dnl Check for glib.  This differs from other library checks in that
4133 dnl Emacs need not link to glib unless some other library is already
4134 dnl linking to glib.  Although glib provides no facilities that Emacs
4135 dnl needs for its own purposes, when glib is present Emacs needs to
4136 dnl use primitives like g_main_context_query to avoid clashing with
4137 dnl glib at a low level.
4138 dnl
4139 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4140 XGSELOBJ=
4141 OLDCFLAGS="$CFLAGS"
4142 OLDLIBS="$LIBS"
4143 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4144 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4145 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4146 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4147 AC_MSG_CHECKING([whether GLib is linked in])
4148 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4149         [[#include <glib.h>
4150         ]],
4151         [[g_print ("Hello world");]])],
4152      [links_glib=yes],
4153      [links_glib=no])
4154 AC_MSG_RESULT([$links_glib])
4155 if test "${links_glib}" = "yes"; then
4156   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4157   if test "$HAVE_NS" = no;then
4158     XGSELOBJ=xgselect.o
4159   fi
4160 fi
4161 CFLAGS="$OLDCFLAGS"
4162 LIBS="$OLDLIBS"
4163 AC_SUBST(XGSELOBJ)
4164
4165 dnl Adapted from Haible's version.
4166 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4167   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4168     [[char* cs = nl_langinfo(CODESET);]])],
4169     emacs_cv_langinfo_codeset=yes,
4170     emacs_cv_langinfo_codeset=no)
4171   ])
4172 if test $emacs_cv_langinfo_codeset = yes; then
4173   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4174     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4175 fi
4176
4177 AC_TYPE_MBSTATE_T
4178
4179 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4180 dnl how the tty code is related to POSIX and/or other versions of termios.
4181 dnl The following looks like a useful start.
4182 dnl
4183 dnl AC_SYS_POSIX_TERMIOS
4184 dnl if test $ac_cv_sys_posix_termios = yes; then
4185 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4186 dnl                                and macros for terminal control.])
4187 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4188 dnl fi
4189
4190 dnl Turned on June 1996 supposing nobody will mind it.
4191 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4192 if test "${opsys}" != "mingw32"; then
4193    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4194      in the full name stands for the login id.])
4195 fi
4196
4197 dnl Everybody supports this, except MS.
4198 dnl Seems like the kind of thing we should be testing for, though.
4199 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4200 if test "${opsys}" != "mingw32"; then
4201   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4202 fi
4203
4204 dnl Everybody supports this, except MS-DOS.
4205 dnl Seems like the kind of thing we should be testing for, though.
4206 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4207 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4208   4.2-compatible sockets.])
4209
4210 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4211
4212 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4213   a null file, or a data sink.])
4214 if test "${opsys}" = "mingw32"; then
4215   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4216 else
4217   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4218 fi
4219
4220 if test "${opsys}" = "mingw32"; then
4221   SEPCHAR=';'
4222 else
4223   SEPCHAR=':'
4224 fi
4225 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4226 dnl This is for MinGW, and is used in test/Makefile.in.
4227 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4228 dnl decides that a command-line argument to be passed to a MinGW program
4229 dnl is a PATH-style list of directories.  But that heuristics plays it
4230 dnl safe, and only does the replacement when it is _absolutely_ sure it
4231 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4232 dnl which breaks in-tree builds.  So we do this manually instead.
4233 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4234 dnl be computed as ':' in MSYS Bash.
4235 AC_SUBST(SEPCHAR)
4236
4237 dnl Everybody supports this, except MS-DOS.
4238 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4239
4240 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4241
4242
4243 AC_DEFINE(DIRECTORY_SEP, ['/'],
4244   [Character that separates directories in a file name.])
4245
4246 if test "${opsys}" = "mingw32"; then
4247   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4248     [Returns true if character is a device separator.])
4249
4250   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4251     [Returns true if character is a directory separator.])
4252
4253   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4254     [Returns true if character is any form of separator.])
4255 else
4256   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4257     [Returns true if character is a device separator.])
4258
4259   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4260     [Returns true if character is a directory separator.])
4261
4262   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4263     [Returns true if character is any form of separator.])
4264 fi
4265
4266 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4267
4268 case $opsys in
4269   aix4-2)
4270     dnl Unfortunately without libXmu we cannot support EditRes.
4271     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4272       AC_DEFINE(NO_EDITRES, 1)
4273     fi
4274     ;;
4275
4276   hpux*)
4277     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4278     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4279     AC_DEFINE(NO_EDITRES, 1)
4280     ;;
4281 esac
4282
4283
4284 case $opsys in
4285   sol2* | unixware )
4286     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4287     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4288     dnl need the constant to dimension an array.  So wire in the appropriate
4289     dnl value here.
4290     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4291     ;;
4292 esac
4293
4294 emacs_broken_SIGIO=no
4295
4296 case $opsys in
4297   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4298   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4299   hpux* | nacl | openbsd | sol2* | unixware )
4300     emacs_broken_SIGIO=yes
4301     ;;
4302
4303   aix4-2)
4304     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4305     dnl the way this system works, libc functions that return malloced
4306     dnl memory use the libc malloc implementation. Calling xfree or
4307     dnl xrealloc on the results of such functions results in a crash.
4308     dnl
4309     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4310     dnl but that does not currently work on this system.
4311     dnl
4312     dnl It is possible to completely override the malloc implementation on
4313     dnl AIX, but that involves putting the malloc functions in a shared
4314     dnl library and setting the MALLOCTYPE environment variable to point to
4315     dnl that shared library.
4316     dnl
4317     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4318     dnl to avoid a crash just use the Emacs implementation for that function.
4319     dnl
4320     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4321     dnl of this file, so that we do not check for get_current_dir_name
4322     dnl on AIX.  But that might be fragile if something else ends
4323     dnl up testing for get_current_dir_name as a dependency.
4324     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4325       get_current_dir_name should not be used.])
4326     ;;
4327
4328   freebsd)
4329     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4330     dnl writes/reads on a PTY, read(2) returns bogus data:
4331     dnl
4332     dnl write(2)  1022 bytes
4333     dnl write(2)   954 bytes, get EAGAIN
4334     dnl read(2)   1024 bytes in process_read_output
4335     dnl read(2)     11 bytes in process_read_output
4336     dnl
4337     dnl That is, read(2) returns more bytes than have ever been written
4338     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4339     dnl successfully after processing (for example with CRs added if the
4340     dnl terminal is set up that way which it is here).  The same bytes will
4341     dnl be seen again in a later read(2), without the CRs.
4342     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4343       work around an issue when reading from a PTY.])
4344     ;;
4345 esac
4346
4347 case $opsys in
4348   gnu-* | sol2-10 )
4349     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4350     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4351   ;;
4352 esac
4353
4354 case $opsys in
4355   darwin | dragonfly | freebsd | netbsd | openbsd )
4356     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4357       close a pty to make it a controlling terminal (it is already a
4358       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4359   ;;
4360 esac
4361
4362 dnl FIXME Surely we can test for this rather than hard-code it.
4363 case $opsys in
4364   netbsd | openbsd) sound_device="/dev/audio" ;;
4365   *) sound_device="/dev/dsp" ;;
4366 esac
4367
4368 dnl Used in sound.c
4369 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4370   [Name of the default sound device.])
4371
4372
4373 dnl Emacs can read input using SIGIO and buffering characters itself,
4374 dnl or using CBREAK mode and making C-g cause SIGINT.
4375 dnl The choice is controlled by the variable interrupt_input.
4376 dnl
4377 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4378 dnl
4379 dnl Emacs uses the presence of the USABLE_SIGIO macro
4380 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4381 dnl INTERRUPT_INPUT to decide whether to use it by default.
4382 dnl
4383 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4384 dnl CBREAK mode has two disadvantages
4385 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4386 dnl I hear that in system V this problem does not exist.
4387 dnl 2) Control-G causes output to be discarded.
4388 dnl I do not know whether this can be fixed in system V.
4389 dnl
4390 dnl Another method of doing input is planned but not implemented.
4391 dnl It would have Emacs fork off a separate process
4392 dnl to read the input and send it to the true Emacs process
4393 dnl through a pipe.
4394 case $opsys in
4395   darwin | gnu-linux | gnu-kfreebsd )
4396     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4397   ;;
4398 esac
4399
4400
4401 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4402 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4403 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4404 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4405 dnl taking float or double parameters.
4406 case $opsys in
4407   cygwin|gnu|gnu-linux|gnu-kfreebsd|freebsd|netbsd|openbsd)
4408     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4409       file defines 'NeedWidePrototypes' as 'NO'.])
4410   ;;
4411 esac
4412
4413
4414 dnl Used in process.c, this must be a loop, even if it only runs once.
4415 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4416 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4417 dnl trying suffixes 0-16.
4418 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4419   first PTY, if PTYs are supported.])
4420 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4421 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4422   end of a PTY, if non-standard.])
4423 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4424   end of a PTY, if non-standard.])
4425
4426 case $opsys in
4427   aix4-2 )
4428     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4429     dnl You allocate a pty by opening /dev/ptc to get the master side.
4430     dnl To get the name of the slave side, you just ttyname() the master side.
4431     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4432     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4433     ;;
4434
4435   cygwin )
4436     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4437     dnl multi-line AC_DEFINEs are hard. :(
4438     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4439     AC_DEFINE(PTY_NAME_SPRINTF, [])
4440     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4441     ;;
4442
4443   gnu | openbsd )
4444     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4445     ;;
4446
4447   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4448     dnl if HAVE_GRANTPT
4449     if test "x$ac_cv_func_grantpt" = xyes; then
4450       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4451       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4452       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4453       dnl to prevent sigchld_handler from intercepting the child's death.
4454       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4455       dnl if HAVE_POSIX_OPENPT
4456       if test "x$ac_cv_func_posix_openpt" = xyes; then
4457         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4458         AC_DEFINE(PTY_NAME_SPRINTF, [])
4459       dnl if HAVE_GETPT
4460       elif test "x$ac_cv_func_getpt" = xyes; then
4461         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4462         AC_DEFINE(PTY_NAME_SPRINTF, [])
4463       else
4464         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4465       fi
4466     else
4467       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4468     fi
4469     ;;
4470
4471   hpux*)
4472     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4473     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4474     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4475     ;;
4476
4477   sol2* )
4478     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4479     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4480     dnl from intercepting that death.  If any child but grantpt's should die
4481     dnl within, it should be caught after sigrelse(2).
4482     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4483     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4484     ;;
4485
4486   unixware )
4487     dnl Comments are as per sol2*.
4488     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4489     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4490     ;;
4491 esac
4492
4493
4494 case $opsys in
4495   sol2* | unixware )
4496     dnl This change means that we don't loop through allocate_pty too
4497     dnl many times in the (rare) event of a failure.
4498     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4499     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4500     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4501     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4502     ;;
4503 esac
4504
4505
4506 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4507 "typing" a signal character on the pty.])
4508
4509 case $opsys in
4510   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4511   aix4-2 | cygwin | gnu | dragonfly | freebsd | netbsd | openbsd | darwin )
4512     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4513     ;;
4514
4515   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4516   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4517   gnu-linux | gnu-kfreebsd )
4518
4519     AC_MSG_CHECKING([for signals via characters])
4520     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4521 #include <linux/version.h>
4522 #if LINUX_VERSION_CODE < 0x20400
4523 # error "Linux version too old"
4524 #endif
4525       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4526
4527     AC_MSG_RESULT([$emacs_signals_via_chars])
4528     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4529     ;;
4530 esac
4531
4532
4533 AH_TEMPLATE(TAB3, [Undocumented.])
4534
4535 case $opsys in
4536   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4537
4538   gnu | dragonfly | freebsd | netbsd | openbsd )
4539     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4540     AC_DEFINE(TAB3, OXTABS)
4541     ;;
4542
4543   gnu-linux | gnu-kfreebsd )
4544     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4545 #ifndef __ia64__
4546 # error "not ia64"
4547 #endif
4548       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4549         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4550         [Mark a secondary stack, like the register stack on the ia64.]), [])
4551     ;;
4552
4553   hpux*)
4554     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4555       run_time_remap; for HPUX.])
4556     ;;
4557 esac
4558
4559
4560 dnl This won't be used automatically yet.  We also need to know, at least,
4561 dnl that the stack is continuous.
4562 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4563   registers relevant for conservative garbage collection in the jmp_buf.])
4564
4565
4566 case $opsys in
4567   dnl Not all the architectures are tested, but there are Debian packages
4568   dnl for SCM and/or Guile on them, so the technique must work.  See also
4569   dnl comments in alloc.c concerning setjmp and gcc.
4570   dnl Fixme: it's probably safe to just use the GCC conditional below.
4571   gnu-linux | gnu-kfreebsd )
4572     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4573 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4574   || defined __alpha__ || defined __mips__ || defined __s390__ \
4575   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4576   || defined __ia64__ || defined __sh__
4577 /* ok */
4578 #else
4579 # error "setjmp not known to work on this arch"
4580 #endif
4581     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4582     ;;
4583 esac
4584
4585
4586 if test x$GCC = xyes; then
4587    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4588    AC_DEFINE(GC_SETJMP_WORKS, 1)
4589 else
4590   case $opsys in
4591     aix* | dragonfly | freebsd | netbsd | openbsd | sol2* )
4592       AC_DEFINE(GC_SETJMP_WORKS, 1)
4593       ;;
4594   esac
4595 fi                              dnl GCC?
4596
4597 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4598 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4599   [AC_LINK_IFELSE(
4600      [AC_LANG_PROGRAM(
4601        [[#include <setjmp.h>
4602          #ifdef __MINGW32__
4603          # define _longjmp longjmp
4604          #endif
4605        ]],
4606        [[jmp_buf j;
4607          if (! _setjmp (j))
4608            _longjmp (j, 1);]])],
4609      [emacs_cv_func__setjmp=yes],
4610      [emacs_cv_func__setjmp=no])])
4611 if test $emacs_cv_func__setjmp = yes; then
4612   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4613 fi
4614
4615 # We need to preserve signal mask to handle C stack overflows.
4616 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4617   [AC_LINK_IFELSE(
4618      [AC_LANG_PROGRAM(
4619        [[#include <setjmp.h>
4620        ]],
4621        [[sigjmp_buf j;
4622          if (! sigsetjmp (j, 1))
4623            siglongjmp (j, 1);]])],
4624      [emacs_cv_func_sigsetjmp=yes],
4625      [emacs_cv_func_sigsetjmp=no])])
4626 if test $emacs_cv_func_sigsetjmp = yes; then
4627   AC_DEFINE([HAVE_SIGSETJMP], 1,
4628     [Define to 1 if sigsetjmp and siglongjmp work.])
4629 fi
4630
4631 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4632   yes,yes,* | *,*,mingw32)
4633     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4634       [Define to 1 if C stack overflow can be handled in some cases.]);;
4635 esac
4636
4637 case $opsys in
4638   sol2* | unixware )
4639     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4640     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4641     dnl and this is all we need.
4642     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4643     ;;
4644 esac
4645
4646
4647 case $opsys in
4648   hpux* | sol2* )
4649     dnl Used in xfaces.c.
4650     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4651       some systems, where it requires time.h.])
4652     ;;
4653 esac
4654
4655
4656 dnl Define symbols to identify the version of Unix this is.
4657 dnl Define all the symbols that apply correctly.
4658 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4659 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4660 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4661 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4662
4663 case $opsys in
4664   aix4-2)
4665     AC_DEFINE(USG, [])
4666     dnl This symbol should be defined on AIX Version 3  ???????
4667     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4668 #ifndef _AIX
4669 # error "_AIX not defined"
4670 #endif
4671     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4672     ;;
4673
4674   cygwin)
4675     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4676     ;;
4677
4678   darwin)
4679     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4680     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4681     dnl distinguish OS X from pure Darwin.
4682     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4683     ;;
4684
4685   gnu-linux | gnu-kfreebsd )
4686     AC_DEFINE(USG, [])
4687     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4688     ;;
4689
4690   hpux*)
4691     AC_DEFINE(USG, [])
4692     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4693     ;;
4694
4695   mingw32)
4696     AC_DEFINE(DOS_NT, [])
4697     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4698     if test "x$ac_enable_checking" != "x" ; then
4699       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4700     fi
4701     ;;
4702
4703   sol2*)
4704     AC_DEFINE(USG, [])
4705     AC_DEFINE(USG5_4, [])
4706     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4707     ;;
4708
4709   unixware)
4710     AC_DEFINE(USG, [])
4711     AC_DEFINE(USG5_4, [])
4712     ;;
4713 esac
4714
4715 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4716   [case $opsys in
4717      aix4-2 | nacl)
4718        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4719        emacs_cv_usable_FIONREAD=no
4720        ;;
4721
4722      mingw32)
4723        emacs_cv_usable_FIONREAD=yes
4724        ;;
4725
4726      *)
4727        AC_COMPILE_IFELSE(
4728          [AC_LANG_PROGRAM([[#include <sys/types.h>
4729                             #include <sys/ioctl.h>
4730                             #ifdef USG5_4
4731                             # include <sys/filio.h>
4732                             #endif
4733                           ]],
4734                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4735          [emacs_cv_usable_FIONREAD=yes],
4736          [emacs_cv_usable_FIONREAD=no])
4737        ;;
4738    esac])
4739 if test $emacs_cv_usable_FIONREAD = yes; then
4740   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4741
4742   if test $emacs_broken_SIGIO = no; then
4743     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4744       [AC_COMPILE_IFELSE(
4745          [AC_LANG_PROGRAM([[#include <fcntl.h>
4746                             #include <signal.h>
4747                           ]],
4748                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4749          [emacs_cv_usable_SIGIO=yes],
4750          [emacs_cv_usable_SIGIO=no])],
4751       [emacs_cv_usable_SIGIO=yes],
4752       [emacs_cv_usable_SIGIO=no])
4753     if test $emacs_cv_usable_SIGIO = yes; then
4754       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4755     fi
4756   fi
4757 fi
4758
4759 case $opsys in
4760   hpux11)
4761     dnl It works to open the pty's tty in the parent (Emacs), then
4762     dnl close and reopen it in the child.
4763     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4764       works to open a pty's tty in the parent process, then close and
4765       reopen it in the child.])
4766     ;;
4767
4768   sol2-10)
4769     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4770       on Solaris.])
4771     ;;
4772 esac
4773
4774 # Set up the CFLAGS for real compilation, so we can substitute it.
4775 CFLAGS="$REAL_CFLAGS"
4776 CPPFLAGS="$REAL_CPPFLAGS"
4777 LIBS="$REAL_LIBS"
4778
4779 ## Hack to detect a buggy GCC version.
4780 if test "$GCC" = yes && \
4781    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4782   case $CFLAGS in
4783     *-fno-optimize-sibling-calls*) ;;
4784     *-O@<:@23@:>@*)
4785       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4786   esac
4787 fi
4788
4789 version=$PACKAGE_VERSION
4790
4791 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4792 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4793   [Short copyright string for this version of Emacs.])
4794 AC_SUBST(copyright)
4795
4796 ### Specify what sort of things we'll be editing into Makefile and config.h.
4797 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4798 AC_SUBST(version)
4799 AC_SUBST(configuration)
4800 ## Unused?
4801 AC_SUBST(canonical)
4802 AC_SUBST(srcdir)
4803 AC_SUBST(prefix)
4804 AC_SUBST(exec_prefix)
4805 AC_SUBST(bindir)
4806 AC_SUBST(datadir)
4807 AC_SUBST(sharedstatedir)
4808 AC_SUBST(libexecdir)
4809 AC_SUBST(mandir)
4810 AC_SUBST(infodir)
4811 AC_SUBST(lispdir)
4812 AC_SUBST(standardlisppath)
4813 AC_SUBST(locallisppath)
4814 AC_SUBST(lisppath)
4815 AC_SUBST(x_default_search_path)
4816 AC_SUBST(etcdir)
4817 AC_SUBST(archlibdir)
4818 AC_SUBST(etcdocdir)
4819 AC_SUBST(bitmapdir)
4820 AC_SUBST(gamedir)
4821 AC_SUBST(gameuser)
4822 AC_SUBST(gamegroup)
4823 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4824 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4825 ## end of LIBX_BASE, but nothing ever set it.
4826 AC_SUBST(LD_SWITCH_X_SITE)
4827 AC_SUBST(C_SWITCH_X_SITE)
4828 AC_SUBST(GNUSTEP_CFLAGS)
4829 AC_SUBST(CFLAGS)
4830 ## Used in lwlib/Makefile.in.
4831 AC_SUBST(X_TOOLKIT_TYPE)
4832 AC_SUBST(ns_appdir)
4833 AC_SUBST(ns_appbindir)
4834 AC_SUBST(ns_appresdir)
4835 AC_SUBST(ns_appsrc)
4836 AC_SUBST(GNU_OBJC_CFLAGS)
4837 AC_SUBST(OTHER_FILES)
4838
4839 if test -n "${term_header}"; then
4840     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4841         [Define to the header for the built-in window system.])
4842 fi
4843
4844 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4845                    [Define to the canonical Emacs configuration name.])
4846 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4847                    [Define to the options passed to configure.])
4848 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4849   define this to include extra configuration information.])
4850
4851 case $opsys in
4852   mingw32)
4853     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4854     ;;
4855 esac
4856
4857 XMENU_OBJ=
4858 XOBJ=
4859 FONT_OBJ=
4860 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4861   AC_DEFINE(HAVE_X_WINDOWS, 1,
4862             [Define to 1 if you want to use the X window system.])
4863   XMENU_OBJ=xmenu.o
4864   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4865   FONT_OBJ=xfont.o
4866   if test "$HAVE_CAIRO" = "yes"; then
4867     FONT_OBJ="ftfont.o ftcrfont.o"
4868   elif test "$HAVE_XFT" = "yes"; then
4869     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4870   elif test "$HAVE_FREETYPE" = "yes"; then
4871     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4872   fi
4873   AC_SUBST(FONT_OBJ)
4874 fi
4875 AC_SUBST(XMENU_OBJ)
4876 AC_SUBST(XOBJ)
4877 AC_SUBST(FONT_OBJ)
4878
4879 WIDGET_OBJ=
4880 MOTIF_LIBW=
4881 if test "${USE_X_TOOLKIT}" != "none" ; then
4882   WIDGET_OBJ=widget.o
4883   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4884   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4885     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4886   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4887     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4888     MOTIF_LIBW=-lXm
4889     case "$opsys" in
4890       gnu-linux)
4891         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4892         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4893         ;;
4894
4895       unixware)
4896         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4897         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4898         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4899         ;;
4900
4901       aix4-2)
4902         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4903         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4904         ;;
4905     esac
4906     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4907   fi
4908 fi
4909 AC_SUBST(WIDGET_OBJ)
4910
4911 TOOLKIT_LIBW=
4912 case "$USE_X_TOOLKIT" in
4913   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4914   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4915   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4916 esac
4917 if test "$HAVE_XWIDGETS" = "yes"; then
4918   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4919 fi
4920 AC_SUBST(TOOLKIT_LIBW)
4921
4922 if test "${opsys}" != "mingw32"; then
4923   if test "$USE_X_TOOLKIT" = "none"; then
4924     LIBXT_OTHER="\$(LIBXSM)"
4925   else
4926     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4927   fi
4928 fi
4929 AC_SUBST(LIBXT_OTHER)
4930
4931 if test "${HAVE_X11}" = "yes" ; then
4932   AC_DEFINE(HAVE_X11, 1,
4933             [Define to 1 if you want to use version 11 of X windows.])
4934   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4935 else
4936   LIBX_OTHER=
4937 fi
4938 AC_SUBST(LIBX_OTHER)
4939
4940 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4941   LIBXMENU=
4942 elif test "$USE_X_TOOLKIT" = none; then
4943   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4944 else
4945   LIBXMENU='$(lwlibdir)/liblw.a'
4946 fi
4947 AC_SUBST(LIBXMENU)
4948
4949 AC_CACHE_CHECK([for struct alignment],
4950   [emacs_cv_struct_alignment],
4951   [AC_COMPILE_IFELSE(
4952      [AC_LANG_PROGRAM([[#include <stddef.h>
4953                         struct __attribute__ ((aligned (8))) s { char c; };
4954                         struct t { char c; struct s s; };
4955                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4956                       ]])],
4957      [emacs_cv_struct_alignment=yes],
4958      [emacs_cv_struct_alignment=no])])
4959 if test "$emacs_cv_struct_alignment" = yes; then
4960   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4961     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4962      structure to an N-byte boundary.])
4963 fi
4964
4965 if test "${GNU_MALLOC}" = "yes" ; then
4966   AC_DEFINE(GNU_MALLOC, 1,
4967             [Define to 1 if you want to use the GNU memory allocator.])
4968 fi
4969
4970 RALLOC_OBJ=
4971 if test "${REL_ALLOC}" = "yes" ; then
4972   AC_DEFINE(REL_ALLOC, 1,
4973             [Define REL_ALLOC if you want to use the relocating allocator for
4974              buffer space.])
4975
4976   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4977 fi
4978 AC_SUBST(RALLOC_OBJ)
4979
4980 if test "$opsys" = "cygwin"; then
4981   CYGWIN_OBJ="cygw32.o"
4982   ## Cygwin differs because of its unexec().
4983   PRE_ALLOC_OBJ=
4984   POST_ALLOC_OBJ=lastfile.o
4985 elif test "$opsys" = "mingw32"; then
4986   CYGWIN_OBJ=
4987   PRE_ALLOC_OBJ=
4988   POST_ALLOC_OBJ=lastfile.o
4989 else
4990   CYGWIN_OBJ=
4991   PRE_ALLOC_OBJ=lastfile.o
4992   POST_ALLOC_OBJ=
4993 fi
4994 AC_SUBST(CYGWIN_OBJ)
4995 AC_SUBST(PRE_ALLOC_OBJ)
4996 AC_SUBST(POST_ALLOC_OBJ)
4997
4998 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4999 dnl verbatim defined above.  The tricky name is apropos, as this hack
5000 dnl makes Fortify go sour!
5001 AH_VERBATIM([FORTIFY_SOUR],
5002 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5003    The workaround disables some useful run-time checking, so it
5004    should be conditional to the platforms with the performance bug.
5005    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5006 #if defined __APPLE__ && defined __GNUC__
5007 # ifndef _DONT_USE_CTYPE_INLINE_
5008 #  define _DONT_USE_CTYPE_INLINE_
5009 # endif
5010 # ifndef _FORTIFY_SOURCE
5011 #  define _FORTIFY_SOURCE 0
5012 # endif
5013 #endif
5014 ])
5015
5016 # If user asks to omit features, disable optional features that gnulib
5017 # might otherwise enable.
5018 if test "$with_features" = no && test "$enable_acl" != yes; then
5019   enable_acl=no
5020 fi
5021
5022 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5023 # it temporarily reverts them to their pre-pkg-config values,
5024 # because gnulib needs to work with both src (which uses the
5025 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5026 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5027 # and it therefore needs to run in an environment where LIBS does not
5028 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5029 # for some package unrelated to lib-src.
5030 SAVE_CFLAGS=$CFLAGS
5031 SAVE_LIBS=$LIBS
5032 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5033 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5034 gl_ASSERT_NO_GNULIB_POSIXCHECK
5035 gl_ASSERT_NO_GNULIB_TESTS
5036 gl_INIT
5037 CFLAGS=$SAVE_CFLAGS
5038 LIBS=$SAVE_LIBS
5039
5040 if test "${opsys}" = "mingw32"; then
5041   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5042   # Remove unneeded switches from the value of CC that goes to Makefiles
5043   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5044 fi
5045
5046 case "$opsys" in
5047   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5048
5049   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5050
5051   darwin)
5052    ## The -headerpad option tells ld (see man page) to leave room at the
5053    ## end of the header for adding load commands.  Needed for dumping.
5054    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5055    ## architecture (where they are 78 bytes each). The actual number of
5056    ## load commands added is not consistent but normally ranges from
5057    ## about 14 to about 34. Setting it high gets us plenty of slop and
5058    ## only costs about 1.5K of wasted binary space.
5059    headerpad_extra=1000
5060    if test "$HAVE_NS" = "yes"; then
5061      libs_nsgui="-framework AppKit"
5062      if test "$NS_IMPL_COCOA" = "yes"; then
5063         libs_nsgui="$libs_nsgui -framework IOKit"
5064      fi
5065    else
5066      libs_nsgui=
5067    fi
5068    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5069
5070    ## This is here because src/Makefile.in did some extra fiddling around
5071    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5072    ## LD_SWITCH_SYSTEM_TEMACS instead,
5073    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5074      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5075    ;;
5076
5077   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5078   ## find X at run-time.
5079   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5080   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5081   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5082   ## had different values in configure (in ac_link) and src/Makefile.in.
5083   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5084   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5085
5086   mingw32)
5087    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5088    case "$canonical" in
5089      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5090      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5091    esac
5092    ;;
5093
5094   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5095 esac
5096
5097 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5098 # with "hardened" GCC configurations for some reason (Bug#18784).
5099 # We don't know why -nopie works, but not segfaulting is better than
5100 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5101 # clang keeps warning that it does not understand -nopie, and pre-4.6
5102 # GCC has a similar problem (Bug#20338).
5103 AC_CACHE_CHECK([whether $CC accepts -nopie],
5104   [emacs_cv_prog_cc_nopie],
5105   [emacs_save_c_werror_flag=$ac_c_werror_flag
5106    emacs_save_LDFLAGS=$LDFLAGS
5107    ac_c_werror_flag=yes
5108    LDFLAGS="$LDFLAGS -nopie"
5109    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5110      [emacs_cv_prog_cc_nopie=yes],
5111      [emacs_cv_prog_cc_nopie=no])
5112    ac_c_werror_flag=$emacs_save_c_werror_flag
5113    LDFLAGS=$emacs_save_LDFLAGS])
5114 if test "$emacs_cv_prog_cc_nopie" = yes; then
5115   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5116 fi
5117
5118 if test x$ac_enable_profiling != x ; then
5119   case $opsys in
5120     *freebsd | gnu-linux) ;;
5121     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5122   esac
5123 fi
5124
5125 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5126
5127 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5128
5129 ## Common for all window systems
5130 if test "$window_system" != "none"; then
5131   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5132   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5133   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5134 fi
5135
5136 AC_SUBST(WINDOW_SYSTEM_OBJ)
5137
5138 AH_TOP([/* GNU Emacs site configuration template file.
5139
5140 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5141   Free Software Foundation, Inc.
5142
5143 This file is part of GNU Emacs.
5144
5145 GNU Emacs is free software: you can redistribute it and/or modify
5146 it under the terms of the GNU General Public License as published by
5147 the Free Software Foundation, either version 3 of the License, or (at
5148 your option) any later version.
5149
5150 GNU Emacs is distributed in the hope that it will be useful,
5151 but WITHOUT ANY WARRANTY; without even the implied warranty of
5152 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5153 GNU General Public License for more details.
5154
5155 You should have received a copy of the GNU General Public License
5156 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5157
5158
5159 /* No code in Emacs #includes config.h twice, but some bits of code
5160    intended to work with other packages as well (like gmalloc.c)
5161    think they can include it as many times as they like.  */
5162 #ifndef EMACS_CONFIG_H
5163 #define EMACS_CONFIG_H
5164 ])dnl
5165
5166 AH_BOTTOM([#include <conf_post.h>
5167
5168 #endif /* EMACS_CONFIG_H */
5169
5170 /*
5171 Local Variables:
5172 mode: c
5173 End:
5174 */
5175 ])dnl
5176
5177 #### Report on what we decided to do.
5178 #### Report GTK as a toolkit, even if it doesn't use Xt.
5179 #### It makes printing result more understandable as using GTK sets
5180 #### toolkit_scroll_bars to yes by default.
5181 if test "${HAVE_GTK}" = "yes"; then
5182   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5183 fi
5184
5185 if test $USE_ACL -ne 0; then
5186   ACL_SUMMARY="yes $LIB_ACL"
5187 else
5188   ACL_SUMMARY=no
5189 fi
5190
5191 emacs_standard_dirs='Standard dirs'
5192 AS_ECHO(["
5193 Configured for '${canonical}'.
5194
5195   Where should the build process find the source code?    ${srcdir}
5196   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5197   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5198   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5199   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5200   What window system should Emacs use?                    ${window_system}
5201   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5202   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5203   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5204
5205 optsep=
5206 emacs_config_features=
5207 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5208   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5209   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5210   XWIDGETS LIBSYSTEMD; do
5211
5212     case $opt in
5213       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5214       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5215       *) eval val=\${HAVE_$opt} ;;
5216     esac
5217     case x$val in
5218       xno|xnone|x) continue ;;
5219     esac
5220     case $opt in
5221       X_TOOLKIT)
5222         case $val in
5223           GTK*|LUCID|MOTIF) opt=$val ;;
5224           *) continue ;;
5225         esac
5226       ;;
5227     esac
5228     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5229     optsep=' '
5230 done
5231 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5232   [Summary of some of the main features enabled by configure.])
5233
5234 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5235   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5236   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5237   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5238   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5239   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5240   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5241   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5242   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5243   Does Emacs support sound?                               ${HAVE_SOUND}
5244   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5245   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5246   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5247   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5248   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5249   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5250   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5251   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5252   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5253   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5254   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5255   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5256   Does Emacs use -lxft?                                   ${HAVE_XFT}
5257   Does Emacs use -lsystemd?                               ${HAVE_LIBSYSTEMD}
5258   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5259   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5260   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5261   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5262 "])
5263
5264 if test -n "${EMACSDATA}"; then
5265    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5266 fi
5267 if test -n "${EMACSDOC}"; then
5268    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5269 fi
5270
5271 echo
5272
5273 if test "$HAVE_NS" = "yes"; then
5274    echo
5275    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5276 The installed application will go to nextstep/Emacs.app and can be
5277 run or moved from there."])
5278    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5279       echo "The application will be fully self-contained."
5280     else
5281       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5282 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5283 to run if these resources are not installed."])
5284    fi
5285    echo
5286 fi
5287
5288 if test "${opsys}" = "cygwin"; then
5289   case `uname -r` in
5290     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5291            echo
5292            ;;
5293   esac
5294 fi
5295
5296 # Remove any trailing slashes in these variables.
5297 case $prefix in
5298   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5299 esac
5300 case $exec_prefix in
5301   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5302 esac
5303
5304 if test "$HAVE_NS" = "yes"; then
5305   if test "$NS_IMPL_GNUSTEP" = yes; then
5306     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5307       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5308     ns_check_file=Resources/Info-gnustep.plist
5309   else
5310     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5311       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5312     ns_check_file=Contents/Info.plist
5313   fi
5314   AC_SUBST(ns_check_file)
5315 fi
5316
5317 dnl config.status treats $srcdir specially, so I think this is ok...
5318 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5319
5320 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5321 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5322 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5323 dnl (else you get "no 'Makefile.am' found for any configure output").
5324 dnl This will work, but you get a config.status that is not quite right
5325 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5326 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5327 dnl it seems better to just live with the duplication.
5328 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5329
5330 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5331        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5332        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5333        leim/Makefile nextstep/Makefile nt/Makefile])
5334
5335 dnl test/ is not present in release tarfiles.
5336 opt_makefile=test/Makefile
5337
5338 if test -f "$srcdir/$opt_makefile.in"; then
5339   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5340   dnl Again, it's best not to use a variable.  Though you can add
5341   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5342   AC_CONFIG_FILES([test/Makefile])
5343 fi
5344
5345
5346 dnl The admin/ directory used to be excluded from tarfiles.
5347 if test -d $srcdir/admin; then
5348   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5349   AC_CONFIG_FILES([admin/charsets/Makefile])
5350   AC_CONFIG_FILES([admin/unidata/Makefile])
5351   AC_CONFIG_FILES([admin/grammars/Makefile])
5352 fi                              dnl -d admin
5353
5354
5355 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5356
5357 AC_SUBST(SUBDIR_MAKEFILES_IN)
5358
5359 dnl You might wonder (I did) why epaths.h is generated by running make,
5360 dnl rather than just letting configure generate it from epaths.in.
5361 dnl One reason is that the various paths are not fully expanded (see above);
5362 dnl eg gamedir=${prefix}/var/games/emacs.
5363 dnl Secondly, the GNU Coding standards require that one should be able
5364 dnl to run 'make prefix=/some/where/else' and override the values set
5365 dnl by configure.  This also explains the 'move-if-change' test and
5366 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5367 AC_CONFIG_COMMANDS([src/epaths.h], [
5368 if test "${opsys}" = "mingw32"; then
5369   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5370 else
5371   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5372 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5373 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5374
5375 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5376 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5377 dnl or a symlink?
5378 AC_CONFIG_COMMANDS([src/.gdbinit], [
5379 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5380   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5381 fi
5382 ])
5383
5384 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5385 dnl See comments for etc-refcards-emacsver.tex.
5386 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5387 dnl it is not quite the same.  But we are generating in $srcdir.
5388 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5389 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5390 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5391 ])
5392
5393 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5394 dnl then a directory etc/refcards is created in the build directory,
5395 dnl which is probably harmless, but confusing (in out-of-tree builds).
5396 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5397 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5398 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5399 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5400 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5401 ])
5402
5403 AC_OUTPUT
5404
5405 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])