code.delx.au - gnu-emacs/blob - lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 1986, 1992, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   4 ;;   2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file parses the command line and gets Emacs running.  Options
  29 ;; on the command line are handled in precedence order.  For priorities
  30 ;; see the structure standard_args in the emacs.c file.
  31
  32 ;;; Code:
  33
  34 (setq top-level '(normal-top-level))
  35
  36 (defvar command-line-processed nil
  37   "Non-nil once command line has been processed.")
  38
  39 (defvar window-system initial-window-system
  40   "Name of window system the selected frame is displaying through.
  41 The value is a symbol--for instance, `x' for X windows.
  42 The value is nil if the selected frame is on a text-only-terminal.")
  43
  44 (make-variable-frame-local 'window-system)
  45
  46 (defgroup initialization nil
  47   "Emacs start-up procedure."
  48   :group 'internal)
  49
  50 (defcustom inhibit-startup-message nil
  51   "*Non-nil inhibits the initial startup message.
  52 This is for use in your personal init file, once you are familiar
  53 with the contents of the startup message."
  54   :type 'boolean
  55   :group 'initialization)
  56
  57 (defvaralias 'inhibit-splash-screen 'inhibit-startup-message)
  58
  59 (defcustom inhibit-startup-echo-area-message nil
  60   "*Non-nil inhibits the initial startup echo area message.
  61 Setting this variable takes effect
  62 only if you do it with the customization buffer
  63 or if your `.emacs' file contains a line of this form:
  64  (setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\")
  65 If your `.emacs' file is byte-compiled, use the following form instead:
  66  (eval '(setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\"))
  67 Thus, someone else using a copy of your `.emacs' file will see
  68 the startup message unless he personally acts to inhibit it."
  69   :type '(choice (const :tag "Don't inhibit")
  70                  (string :tag "Enter your user name, to inhibit"))
  71   :group 'initialization)
  72
  73 (defcustom inhibit-default-init nil
  74   "*Non-nil inhibits loading the `default' library."
  75   :type 'boolean
  76   :group 'initialization)
  77
  78 (defcustom inhibit-startup-buffer-menu nil
  79   "*Non-nil inhibits display of buffer list when more than 2 files are loaded."
  80   :type 'boolean
  81   :group 'initialization)
  82
  83 (defvar command-switch-alist nil
  84   "Alist of command-line switches.
  85 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
  86 HANDLER-FUNCTION receives the switch string as its sole argument;
  87 the remaining command-line args are in the variable `command-line-args-left'.")
  88
  89 (defvar command-line-args-left nil
  90   "List of command-line args not yet processed.")
  91
  92 (defvar command-line-functions nil    ;; lrs 7/31/89
  93   "List of functions to process unrecognized command-line arguments.
  94 Each function should access the dynamically bound variables
  95 `argi' (the current argument) and `command-line-args-left' (the remaining
  96 arguments).  The function should return non-nil only if it recognizes and
  97 processes `argi'.  If it does so, it may consume successive arguments by
  98 altering `command-line-args-left' to remove them.")
  99
 100 (defvar command-line-default-directory nil
 101   "Default directory to use for command line arguments.
 102 This is normally copied from `default-directory' when Emacs starts.")
 103
 104 ;;; This is here, rather than in x-win.el, so that we can ignore these
 105 ;;; options when we are not using X.
 106 (defconst command-line-x-option-alist
 107   '(("-bw" 1 x-handle-numeric-switch border-width)
 108     ("-d" 1 x-handle-display)
 109     ("-display" 1 x-handle-display)
 110     ("-name" 1 x-handle-name-switch)
 111     ("-title" 1 x-handle-switch title)
 112     ("-T" 1 x-handle-switch title)
 113     ("-r" 0 x-handle-switch reverse t)
 114     ("-rv" 0 x-handle-switch reverse t)
 115     ("-reverse" 0 x-handle-switch reverse t)
 116     ("-reverse-video" 0 x-handle-switch reverse t)
 117     ("-fn" 1 x-handle-switch font)
 118     ("-font" 1 x-handle-switch font)
 119     ("-fs" 0 x-handle-initial-switch fullscreen fullboth)
 120     ("-fw" 0 x-handle-initial-switch fullscreen fullwidth)
 121     ("-fh" 0 x-handle-initial-switch fullscreen fullheight)
 122     ("-ib" 1 x-handle-numeric-switch internal-border-width)
 123     ("-g" 1 x-handle-geometry)
 124     ("-lsp" 1 x-handle-numeric-switch line-spacing)
 125     ("-geometry" 1 x-handle-geometry)
 126     ("-fg" 1 x-handle-switch foreground-color)
 127     ("-foreground" 1 x-handle-switch foreground-color)
 128     ("-bg" 1 x-handle-switch background-color)
 129     ("-background" 1 x-handle-switch background-color)
 130     ("-ms" 1 x-handle-switch mouse-color)
 131     ("-itype" 0 x-handle-switch icon-type t)
 132     ("-i" 0 x-handle-switch icon-type t)
 133     ("-iconic" 0 x-handle-iconic)
 134     ("-xrm" 1 x-handle-xrm-switch)
 135     ("-cr" 1 x-handle-switch cursor-color)
 136     ("-vb" 0 x-handle-switch vertical-scroll-bars t)
 137     ("-hb" 0 x-handle-switch horizontal-scroll-bars t)
 138     ("-bd" 1 x-handle-switch)
 139     ("--border-width" 1 x-handle-numeric-switch border-width)
 140     ("--display" 1 x-handle-display)
 141     ("--name" 1 x-handle-name-switch)
 142     ("--title" 1 x-handle-switch title)
 143     ("--reverse-video" 0 x-handle-switch reverse t)
 144     ("--font" 1 x-handle-switch font)
 145     ("--fullscreen" 0 x-handle-initial-switch fullscreen fullboth)
 146     ("--fullwidth" 0 x-handle-initial-switch fullscreen fullwidth)
 147     ("--fullheight" 0 x-handle-initial-switch fullscreen fullheight)
 148     ("--internal-border" 1 x-handle-numeric-switch internal-border-width)
 149     ("--geometry" 1 x-handle-geometry)
 150     ("--foreground-color" 1 x-handle-switch foreground-color)
 151     ("--background-color" 1 x-handle-switch background-color)
 152     ("--mouse-color" 1 x-handle-switch mouse-color)
 153     ("--icon-type" 0 x-handle-switch icon-type t)
 154     ("--iconic" 0 x-handle-iconic)
 155     ("--xrm" 1 x-handle-xrm-switch)
 156     ("--cursor-color" 1 x-handle-switch cursor-color)
 157     ("--vertical-scroll-bars" 0 x-handle-switch vertical-scroll-bars t)
 158     ("--line-spacing" 1 x-handle-numeric-switch line-spacing)
 159     ("--border-color" 1 x-handle-switch border-color)
 160     ("--smid" 1 x-handle-smid))
 161   "Alist of X Windows options.
 162 Each element has the form
 163   (NAME NUMARGS HANDLER FRAME-PARAM VALUE)
 164 where NAME is the option name string, NUMARGS is the number of arguments
 165 that the option accepts, HANDLER is a function to call to handle the option.
 166 FRAME-PARAM (optional) is the frame parameter this option specifies,
 167 and VALUE is the value which is given to that frame parameter
 168 \(most options use the argument for this, so VALUE is not present).")
 169
 170 (defvar before-init-hook nil
 171   "Normal hook run after handling urgent options but before loading init files.")
 172
 173 (defvar after-init-hook nil
 174   "Normal hook run after loading the init files, `~/.emacs' and `default.el'.
 175 There is no `condition-case' around the running of these functions;
 176 therefore, if you set `debug-on-error' non-nil in `.emacs',
 177 an error in one of these functions will invoke the debugger.")
 178
 179 (defvar emacs-startup-hook nil
 180   "Normal hook run after loading init files and handling the command line.")
 181
 182 (defvar term-setup-hook nil
 183   "Normal hook run after loading terminal-specific Lisp code.
 184 It also follows `emacs-startup-hook'.  This hook exists for users to set,
 185 so as to override the definitions made by the terminal-specific file.
 186 Emacs never sets this variable itself.")
 187
 188 (defvar inhibit-startup-hooks nil
 189   "Non-nil means don't run `term-setup-hook' and `emacs-startup-hook'.
 190 This is because we already did so.")
 191
 192 (defvar keyboard-type nil
 193   "The brand of keyboard you are using.
 194 This variable is used to define the proper function and keypad
 195 keys for use under X.  It is used in a fashion analogous to the
 196 environment variable TERM.")
 197
 198 (defvar window-setup-hook nil
 199   "Normal hook run to initialize window system display.
 200 Emacs runs this hook after processing the command line arguments and loading
 201 the user's init file.")
 202
 203 (defcustom initial-major-mode 'lisp-interaction-mode
 204   "Major mode command symbol to use for the initial *scratch* buffer."
 205   :type 'function
 206   :group 'initialization)
 207
 208 (defcustom init-file-user nil
 209   "Identity of user whose `.emacs' file is or was read.
 210 The value is nil if `-q' or `--no-init-file' was specified,
 211 meaning do not load any init file.
 212
 213 Otherwise, the value may be the null string, meaning use the init file
 214 for the user that originally logged in, or it may be a
 215 string containing a user's name meaning use that person's init file.
 216
 217 In either of the latter cases, `(concat \"~\" init-file-user \"/\")'
 218 evaluates to the name of the directory where the `.emacs' file was
 219 looked for.
 220
 221 Setting `init-file-user' does not prevent Emacs from loading
 222 `site-start.el'.  The only way to do that is to use `--no-site-file'."
 223   :type '(choice (const :tag "none" nil) string)
 224   :group 'initialization)
 225
 226 (defcustom site-run-file "site-start"
 227   "File containing site-wide run-time initializations.
 228 This file is loaded at run-time before `~/.emacs'.  It contains inits
 229 that need to be in place for the entire site, but which, due to their
 230 higher incidence of change, don't make sense to load into Emacs's
 231 dumped image.  Thus, the run-time load order is: 1. file described in
 232 this variable, if non-nil; 2. `~/.emacs'; 3. `default.el'.
 233
 234 Don't use the `site-start.el' file for things some users may not like.
 235 Put them in `default.el' instead, so that users can more easily
 236 override them.  Users can prevent loading `default.el' with the `-q'
 237 option or by setting `inhibit-default-init' in their own init files,
 238 but inhibiting `site-start.el' requires `--no-site-file', which
 239 is less convenient.
 240
 241 This variable is defined for customization so as to make
 242 it visible in the relevant context.  However, actually customizing it
 243 is not allowed, since it would not work anyway.  The only way to set
 244 this variable usefully is to set it while building and dumping Emacs."
 245   :type '(choice (const :tag "none" nil) string)
 246   :group 'initialization
 247   :initialize 'custom-initialize-default
 248   :set '(lambda (variable value)
 249           (error "Customizing `site-run-file' does not work")))
 250
 251 (defcustom mail-host-address nil
 252   "*Name of this machine, for purposes of naming users."
 253   :type '(choice (const nil) string)
 254   :group 'mail)
 255
 256 (defcustom user-mail-address (if command-line-processed
 257                                  (concat (user-login-name) "@"
 258                                          (or mail-host-address
 259                                              (system-name)))
 260                                ;; Empty string means "not set yet".
 261                                "")
 262   "*Full mailing address of this user.
 263 This is initialized based on `mail-host-address',
 264 after your init file is read, in case it sets `mail-host-address'."
 265   :type 'string
 266   :group 'mail)
 267
 268 (defcustom auto-save-list-file-prefix
 269   (cond ((eq system-type 'ms-dos)
 270          ;; MS-DOS cannot have initial dot, and allows only 8.3 names
 271          "~/_emacs.d/auto-save.list/_s")
 272         (t
 273          "~/.emacs.d/auto-save-list/.saves-"))
 274   "Prefix for generating `auto-save-list-file-name'.
 275 This is used after reading your `.emacs' file to initialize
 276 `auto-save-list-file-name', by appending Emacs's pid and the system name,
 277 if you have not already set `auto-save-list-file-name' yourself.
 278 Directories in the prefix will be created if necessary.
 279 Set this to nil if you want to prevent `auto-save-list-file-name'
 280 from being initialized."
 281   :type '(choice (const :tag "Don't record a session's auto save list" nil)
 282                  string)
 283   :group 'auto-save)
 284
 285 (defvar emacs-quick-startup nil)
 286
 287 (defvar emacs-basic-display nil)
 288
 289 (defvar init-file-debug nil)
 290
 291 (defvar init-file-had-error nil)
 292
 293 (defvar normal-top-level-add-subdirs-inode-list nil)
 294
 295 (defvar no-blinking-cursor nil)
 296
 297 (defvar default-frame-background-mode)
 298
 299 (defvar pure-space-overflow nil
 300   "Non-nil if building Emacs overflowed pure space.")
 301
 302 (defun normal-top-level-add-subdirs-to-load-path ()
 303   "Add all subdirectories of current directory to `load-path'.
 304 More precisely, this uses only the subdirectories whose names
 305 start with letters or digits; it excludes any subdirectory named `RCS'
 306 or `CVS', and any subdirectory that contains a file named `.nosearch'."
 307   (let (dirs
 308         attrs
 309         (pending (list default-directory)))
 310     ;; This loop does a breadth-first tree walk on DIR's subtree,
 311     ;; putting each subdir into DIRS as its contents are examined.
 312     (while pending
 313       (push (pop pending) dirs)
 314       (let* ((this-dir (car dirs))
 315              (contents (directory-files this-dir))
 316              (default-directory this-dir)
 317              (canonicalized (if (fboundp 'untranslated-canonical-name)
 318                                 (untranslated-canonical-name this-dir))))
 319         ;; The Windows version doesn't report meaningful inode
 320         ;; numbers, so use the canonicalized absolute file name of the
 321         ;; directory instead.
 322         (setq attrs (or canonicalized
 323                         (nthcdr 10 (file-attributes this-dir))))
 324         (unless (member attrs normal-top-level-add-subdirs-inode-list)
 325           (push attrs normal-top-level-add-subdirs-inode-list)
 326           (dolist (file contents)
 327             ;; The lower-case variants of RCS and CVS are for DOS/Windows.
 328             (unless (member file '("." ".." "RCS" "CVS" "rcs" "cvs"))
 329               (when (and (string-match "\\`[[:alnum:]]" file)
 330                          ;; Avoid doing a `stat' when it isn't necessary
 331                          ;; because that can cause trouble when an NFS server
 332                          ;; is down.
 333                          (not (string-match "\\.elc?\\'" file))
 334                          (file-directory-p file))
 335                 (let ((expanded (expand-file-name file)))
 336                   (unless (file-exists-p (expand-file-name ".nosearch"
 337                                                            expanded))
 338                     (setq pending (nconc pending (list expanded)))))))))))
 339     (normal-top-level-add-to-load-path (cdr (nreverse dirs)))))
 340
 341 ;; This function is called from a subdirs.el file.
 342 ;; It assumes that default-directory is the directory
 343 ;; in which the subdirs.el file exists,
 344 ;; and it adds to load-path the subdirs of that directory
 345 ;; as specified in DIRS.  Normally the elements of DIRS are relative.
 346 (defun normal-top-level-add-to-load-path (dirs)
 347   (let ((tail load-path)
 348         (thisdir (directory-file-name default-directory)))
 349     (while (and tail
 350                 ;;Don't go all the way to the nil terminator.
 351                 (cdr tail)
 352                 (not (equal thisdir (car tail)))
 353                 (not (and (memq system-type '(ms-dos windows-nt))
 354                           (equal (downcase thisdir) (downcase (car tail))))))
 355       (setq tail (cdr tail)))
 356     ;;Splice the new section in.
 357     (when tail
 358       (setcdr tail (append (mapcar 'expand-file-name dirs) (cdr tail))))))
 359
 360 (defun normal-top-level ()
 361   (if command-line-processed
 362       (message "Back to top level.")
 363     (setq command-line-processed t)
 364     ;; Give *Messages* the same default-directory as *scratch*,
 365     ;; just to keep things predictable.
 366     (let ((dir default-directory))
 367       (with-current-buffer "*Messages*"
 368         (setq default-directory dir)))
 369     ;; `user-full-name' is now known; reset its standard-value here.
 370     (put 'user-full-name 'standard-value
 371          (list (default-value 'user-full-name)))
 372     ;; For root, preserve owner and group when editing files.
 373     (if (equal (user-uid) 0)
 374         (setq backup-by-copying-when-mismatch t))
 375     ;; Look in each dir in load-path for a subdirs.el file.
 376     ;; If we find one, load it, which will add the appropriate subdirs
 377     ;; of that dir into load-path,
 378     ;; Look for a leim-list.el file too.  Loading it will register
 379     ;; available input methods.
 380     (let ((tail load-path) dir)
 381       (while tail
 382         (setq dir (car tail))
 383         (let ((default-directory dir))
 384           (load (expand-file-name "subdirs.el") t t t))
 385         (let ((default-directory dir))
 386           (load (expand-file-name "leim-list.el") t t t))
 387         ;; We don't use a dolist loop and we put this "setq-cdr" command at
 388         ;; the end, because the subdirs.el files may add elements to the end
 389         ;; of load-path and we want to take it into account.
 390         (setq tail (cdr tail))))
 391     (unless (eq system-type 'vax-vms)
 392       ;; If the PWD environment variable isn't accurate, delete it.
 393       (let ((pwd (getenv "PWD")))
 394         (and (stringp pwd)
 395              ;; Use FOO/., so that if FOO is a symlink, file-attributes
 396              ;; describes the directory linked to, not FOO itself.
 397              (or (equal (file-attributes
 398                          (concat (file-name-as-directory pwd) "."))
 399                         (file-attributes
 400                          (concat (file-name-as-directory default-directory)
 401                                  ".")))
 402                  (setq process-environment
 403                        (delete (concat "PWD=" pwd)
 404                                process-environment))))))
 405     (setq default-directory (abbreviate-file-name default-directory))
 406     (let ((menubar-bindings-done nil))
 407       (unwind-protect
 408           (command-line)
 409         ;; Do this again, in case .emacs defined more abbreviations.
 410         (setq default-directory (abbreviate-file-name default-directory))
 411         ;; Specify the file for recording all the auto save files of this session.
 412         ;; This is used by recover-session.
 413         (or auto-save-list-file-name
 414             (and auto-save-list-file-prefix
 415                  (setq auto-save-list-file-name
 416                        ;; Under MS-DOS our PID is almost always reused between
 417                        ;; Emacs invocations.  We need something more unique.
 418                        (cond ((eq system-type 'ms-dos)
 419                               ;; We are going to access the auto-save
 420                               ;; directory, so make sure it exists.
 421                               (make-directory
 422                                (file-name-directory auto-save-list-file-prefix)
 423                                t)
 424                               (concat
 425                                (make-temp-name
 426                                 (expand-file-name
 427                                  auto-save-list-file-prefix))
 428                                "~"))
 429                              (t
 430                               (expand-file-name
 431                                (format "%s%d-%s~"
 432                                        auto-save-list-file-prefix
 433                                        (emacs-pid)
 434                                        (system-name))))))))
 435         (unless inhibit-startup-hooks
 436           (run-hooks 'emacs-startup-hook)
 437           (and term-setup-hook
 438                (run-hooks 'term-setup-hook)))
 439
 440         ;; Don't do this if we failed to create the initial frame,
 441         ;; for instance due to a dense colormap.
 442         (when (or frame-initial-frame
 443                   ;; If frame-initial-frame has no meaning, do this anyway.
 444                   (not (and initial-window-system
 445                             (not noninteractive)
 446                             (not (eq initial-window-system 'pc)))))
 447           ;; Modify the initial frame based on what .emacs puts into
 448           ;; ...-frame-alist.
 449           (if (fboundp 'frame-notice-user-settings)
 450               (frame-notice-user-settings))
 451           ;; Set the faces for the initial background mode even if
 452           ;; frame-notice-user-settings didn't (such as on a tty).
 453           ;; frame-set-background-mode is idempotent, so it won't
 454           ;; cause any harm if it's already been done.
 455           (if (fboundp 'frame-set-background-mode)
 456               (frame-set-background-mode (selected-frame))))
 457
 458         ;; Now we know the user's default font, so add it to the menu.
 459         (if (fboundp 'font-menu-add-default)
 460             (font-menu-add-default))
 461         (and window-setup-hook
 462              (run-hooks 'window-setup-hook))
 463         (or menubar-bindings-done
 464             (if (display-popup-menus-p)
 465                 (precompute-menubar-bindings)))))))
 466
 467 ;; Precompute the keyboard equivalents in the menu bar items.
 468 (defun precompute-menubar-bindings ()
 469   (let ((submap (lookup-key global-map [menu-bar])))
 470     (while submap
 471       (and (consp (car submap))
 472            (symbolp (car (car submap)))
 473            (stringp (car-safe (cdr (car submap))))
 474            (keymapp (cdr (cdr (car submap))))
 475            (progn
 476              (x-popup-menu nil (cdr (cdr (car submap))))
 477              (if purify-flag
 478                  (garbage-collect))))
 479       (setq submap (cdr submap))))
 480     (setq define-key-rebound-commands t))
 481
 482 ;; Command-line options supported by tty's:
 483 (defconst tty-long-option-alist
 484   '(("--name"             . "-name")
 485     ("--title"            . "-T")
 486     ("--reverse-video"    . "-reverse")
 487     ("--foreground-color" . "-fg")
 488     ("--background-color" . "-bg")
 489     ("--color"            . "-color")))
 490
 491 (defconst tool-bar-images-pixel-height 24
 492   "Height in pixels of images in the tool bar.")
 493
 494 (defvar tool-bar-originally-present nil
 495   "Non-nil if tool-bars are present before user and site init files are read.")
 496
 497 (defvar handle-args-function-alist '((nil . tty-handle-args))
 498   "Functions for processing window-system dependent command-line arguments.
 499 Window system startup files should add their own function to this
 500 alist, which should parse the command line arguments.  Those
 501 pertaining to the window system should be processed and removed
 502 from the returned command line.")
 503
 504 (defvar window-system-initialization-alist '((nil . ignore))
 505   "Alist of window-system initialization functions.
 506 Window-system startup files should add their own initialization
 507 function to this list.  The function should take no arguments,
 508 and initialize the window system environment to prepare for
 509 opening the first frame (e.g. open a connection to an X server).")
 510
 511 ;; Handle the X-like command-line arguments "-fg", "-bg", "-name", etc.
 512 (defun tty-handle-args (args)
 513   (let (rest)
 514     (message "%s" args)
 515     (while (and args
 516                 (not (equal (car args) "--")))
 517       (let* ((argi (pop args))
 518              (orig-argi argi)
 519              argval completion)
 520         ;; Check for long options with attached arguments
 521         ;; and separate out the attached option argument into argval.
 522         (when (string-match "^\\(--[^=]*\\)=" argi)
 523           (setq argval (substring argi (match-end 0))
 524                 argi (match-string 1 argi)))
 525         (when (string-match "^--" argi)
 526           (setq completion (try-completion argi tty-long-option-alist))
 527           (if (eq completion t)
 528               ;; Exact match for long option.
 529               (setq argi (cdr (assoc argi tty-long-option-alist)))
 530             (if (stringp completion)
 531                 (let ((elt (assoc completion tty-long-option-alist)))
 532                   ;; Check for abbreviated long option.
 533                   (or elt
 534                       (error "Option `%s' is ambiguous" argi))
 535                   (setq argi (cdr elt)))
 536               ;; Check for a short option.
 537               (setq argval nil
 538                     argi orig-argi))))
 539         (cond ((member argi '("-fg" "-foreground"))
 540                (push (cons 'foreground-color (or argval (pop args)))
 541                      default-frame-alist))
 542               ((member argi '("-bg" "-background"))
 543                (push (cons 'background-color (or argval (pop args)))
 544                      default-frame-alist))
 545               ((member argi '("-T" "-name"))
 546                (unless argval (setq argval (pop args)))
 547                (push (cons 'title
 548                            (if (stringp argval)
 549                                argval
 550                              (let ((case-fold-search t)
 551                                    i)
 552                                (setq argval (invocation-name))
 553
 554                                ;; Change any . or * characters in name to
 555                                ;; hyphens, so as to emulate behavior on X.
 556                                (while
 557                                    (setq i (string-match "[.*]" argval))
 558                                  (aset argval i ?-))
 559                                argval)))
 560                      default-frame-alist))
 561               ((member argi '("-r" "-rv" "-reverse"))
 562                (push '(reverse . t)
 563                      default-frame-alist))
 564               ((equal argi "-color")
 565                (unless argval (setq argval 8)) ; default --color means 8 ANSI colors
 566                (push (cons 'tty-color-mode
 567                            (cond
 568                             ((numberp argval) argval)
 569                             ((string-match "-?[0-9]+" argval)
 570                              (string-to-number argval))
 571                             (t (intern argval))))
 572                      default-frame-alist))
 573               (t
 574                (push argi rest)))))
 575     (nreverse rest)))
 576
 577 (defun command-line ()
 578   (setq command-line-default-directory default-directory)
 579
 580   ;; Choose a reasonable location for temporary files.
 581   (custom-reevaluate-setting 'temporary-file-directory)
 582   (custom-reevaluate-setting 'small-temporary-file-directory)
 583   (custom-reevaluate-setting 'auto-save-file-name-transforms)
 584
 585   ;; See if we should import version-control from the environment variable.
 586   (let ((vc (getenv "VERSION_CONTROL")))
 587     (cond ((eq vc nil))                 ;don't do anything if not set
 588           ((member vc '("t" "numbered"))
 589            (setq version-control t))
 590           ((member vc '("nil" "existing"))
 591            (setq version-control nil))
 592           ((member vc '("never" "simple"))
 593            (setq version-control 'never))))
 594
 595   ;;! This has been commented out; I currently find the behavior when
 596   ;;! split-window-keep-point is nil disturbing, but if I can get used
 597   ;;! to it, then it would be better to eliminate the option.
 598   ;;! ;; Choose a good default value for split-window-keep-point.
 599   ;;! (setq split-window-keep-point (> baud-rate 2400))
 600
 601   ;; Set the default strings to display in mode line for
 602   ;; end-of-line formats that aren't native to this platform.
 603   (cond
 604    ((memq system-type '(ms-dos windows-nt emx))
 605     (setq eol-mnemonic-unix "(Unix)"
 606           eol-mnemonic-mac  "(Mac)"))
 607    ;; Both Mac and Unix EOLs are now "native" on Mac OS so keep the
 608    ;; abbreviated strings `/' and `:' set in coding.c for them.
 609    ((eq system-type 'macos)
 610     (setq eol-mnemonic-dos  "(DOS)"))
 611    (t                                   ; this is for Unix/GNU/Linux systems
 612     (setq eol-mnemonic-dos  "(DOS)"
 613           eol-mnemonic-mac  "(Mac)")))
 614
 615   ;; Make sure window system's init file was loaded in loadup.el if using a window system.
 616   (condition-case error
 617     (unless noninteractive
 618       (if (and initial-window-system
 619                (not (featurep
 620                      (intern (concat (symbol-name initial-window-system) "-win")))))
 621           (error "Unsupported window system `%s'" initial-window-system))
 622       ;; Process window-system specific command line parameters.
 623       (setq command-line-args
 624             (funcall (or (cdr (assq initial-window-system handle-args-function-alist))
 625                          (error "Unsupported window system `%s'" initial-window-system))
 626                      command-line-args))
 627       ;; Initialize the window system. (Open connection, etc.)
 628       (funcall (or (cdr (assq initial-window-system window-system-initialization-alist))
 629                    (error "Unsupported window system `%s'" initial-window-system))))
 630     ;; If there was an error, print the error message and exit.
 631     (error
 632      (princ
 633       (if (eq (car error) 'error)
 634           (apply 'concat (cdr error))
 635         (if (memq 'file-error (get (car error) 'error-conditions))
 636             (format "%s: %s"
 637                     (nth 1 error)
 638                     (mapconcat (lambda (obj) (prin1-to-string obj t))
 639                                (cdr (cdr error)) ", "))
 640           (format "%s: %s"
 641                   (get (car error) 'error-message)
 642                   (mapconcat (lambda (obj) (prin1-to-string obj t))
 643                              (cdr error) ", "))))
 644       'external-debugging-output)
 645      (terpri 'external-debugging-output)
 646      (setq initial-window-system nil)
 647      (kill-emacs)))
 648
 649   (set-locale-environment nil)
 650
 651   ;; Convert the arguments to Emacs internal representation.
 652   (let ((args (cdr command-line-args)))
 653     (while args
 654       (setcar args
 655               (decode-coding-string (car args) locale-coding-system t))
 656       (pop args)))
 657
 658   (let ((done nil)
 659         (args (cdr command-line-args)))
 660
 661     ;; Figure out which user's init file to load,
 662     ;; either from the environment or from the options.
 663     (setq init-file-user (if noninteractive nil (user-login-name)))
 664     ;; If user has not done su, use current $HOME to find .emacs.
 665     (and init-file-user
 666          (equal init-file-user (user-real-login-name))
 667          (setq init-file-user ""))
 668
 669     ;; Process the command-line args, and delete the arguments
 670     ;; processed.  This is consistent with the way main in emacs.c
 671     ;; does things.
 672     (while (and (not done) args)
 673       (let* ((longopts '(("--no-init-file") ("--no-site-file") ("--debug-init")
 674                          ("--user") ("--iconic") ("--icon-type") ("--quick")
 675                          ("--no-blinking-cursor") ("--basic-display")))
 676              (argi (pop args))
 677              (orig-argi argi)
 678              argval)
 679         ;; Handle --OPTION=VALUE format.
 680         (when (string-match "^\\(--[^=]*\\)=" argi)
 681           (setq argval (substring argi (match-end 0))
 682                 argi (match-string 1 argi)))
 683         (unless (equal argi "--")
 684           (let ((completion (try-completion argi longopts)))
 685             (if (eq completion t)
 686                 (setq argi (substring argi 1))
 687               (if (stringp completion)
 688                   (let ((elt (assoc completion longopts)))
 689                     (or elt
 690                         (error "Option `%s' is ambiguous" argi))
 691                     (setq argi (substring (car elt) 1)))
 692                 (setq argval nil
 693                       argi orig-argi)))))
 694         (cond
 695          ((member argi '("-Q" "-quick"))
 696           (setq init-file-user nil
 697                 site-run-file nil
 698                 emacs-quick-startup t))
 699          ((member argi '("-D" "-basic-display"))
 700           (setq no-blinking-cursor t
 701                 emacs-basic-display t)
 702           (push '(vertical-scroll-bars . nil) initial-frame-alist))
 703          ((member argi '("-q" "-no-init-file"))
 704           (setq init-file-user nil))
 705          ((member argi '("-u" "-user"))
 706           (setq init-file-user (or argval (pop args))
 707                 argval nil))
 708          ((equal argi "-no-site-file")
 709           (setq site-run-file nil))
 710          ((equal argi "-debug-init")
 711           (setq init-file-debug t))
 712          ((equal argi "-iconic")
 713           (push '(visibility . icon) initial-frame-alist))
 714          ((member argi '("-icon-type" "-i" "-itype"))
 715           (push '(icon-type . t) default-frame-alist))
 716          ((member argi '("-nbc" "-no-blinking-cursor"))
 717           (setq no-blinking-cursor t))
 718          ;; Push the popped arg back on the list of arguments.
 719          (t
 720           (push argi args)
 721           (setq done t)))
 722         ;; Was argval set but not used?
 723         (and argval
 724              (error "Option `%s' doesn't allow an argument" argi))))
 725
 726     ;; Re-attach the program name to the front of the arg list.
 727     (and command-line-args
 728          (setcdr command-line-args args)))
 729
 730   ;; Under X Window, this creates the X frame and deletes the terminal frame.
 731   (when (fboundp 'frame-initialize)
 732     (frame-initialize))
 733
 734   ;; Turn off blinking cursor if so specified in X resources.  This is here
 735   ;; only because all other settings of no-blinking-cursor are here.
 736   (unless (or noninteractive
 737               emacs-basic-display
 738               (and (memq window-system '(x w32 mac))
 739                    (not (member (x-get-resource "cursorBlink" "CursorBlink")
 740                                 '("off" "false")))))
 741     (setq no-blinking-cursor t))
 742
 743   ;; If frame was created with a menu bar, set menu-bar-mode on.
 744   (unless (or noninteractive
 745               emacs-basic-display
 746               (and (memq initial-window-system '(x w32))
 747                    (<= (frame-parameter nil 'menu-bar-lines) 0)))
 748     (menu-bar-mode 1))
 749
 750   ;; If frame was created with a tool bar, switch tool-bar-mode on.
 751   (unless (or noninteractive
 752               emacs-basic-display
 753               (not (display-graphic-p))
 754               (<= (frame-parameter nil 'tool-bar-lines) 0))
 755     (tool-bar-mode 1))
 756
 757   ;; Can't do this init in defcustom because the relevant variables
 758   ;; are not set.
 759   (custom-reevaluate-setting 'blink-cursor-mode)
 760   (custom-reevaluate-setting 'normal-erase-is-backspace)
 761   (custom-reevaluate-setting 'tooltip-mode)
 762
 763   ;; Register default TTY colors for the case the terminal hasn't a
 764   ;; terminal init file.
 765   ;; We do this regardles of whether the terminal supports colors
 766   ;; or not, since they can switch that support on or off in
 767   ;; mid-session by setting the tty-color-mode frame parameter.
 768   (tty-register-default-colors)
 769
 770   ;; Record whether the tool-bar is present before the user and site
 771   ;; init files are processed.  frame-notice-user-settings uses this
 772   ;; to determine if the tool-bar has been disabled by the init files,
 773   ;; and the frame needs to be resized.
 774   (when (fboundp 'frame-notice-user-settings)
 775     (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 776                               (assq 'tool-bar-lines default-frame-alist))))
 777       (setq tool-bar-originally-present
 778             (and tool-bar-lines
 779                  (cdr tool-bar-lines)
 780                  (not (eq 0 (cdr tool-bar-lines)))))))
 781
 782   (let ((old-scalable-fonts-allowed scalable-fonts-allowed)
 783         (old-font-list-limit font-list-limit)
 784         (old-face-ignored-fonts face-ignored-fonts))
 785
 786     (run-hooks 'before-init-hook)
 787
 788     ;; Run the site-start library if it exists.  The point of this file is
 789     ;; that it is run before .emacs.  There is no point in doing this after
 790     ;; .emacs; that is useless.
 791     (if site-run-file
 792         (load site-run-file t t))
 793
 794     ;; Sites should not disable this.  Only individuals should disable
 795     ;; the startup message.
 796     (setq inhibit-startup-message nil)
 797
 798     ;; Warn for invalid user name.
 799     (and init-file-user
 800          (not (file-directory-p (expand-file-name (concat "~" init-file-user))))
 801          (display-warning 'initialization
 802                           (format "User %s has no home directory"
 803                                   init-file-user)
 804                           :error))
 805
 806     ;; Load that user's init file, or the default one, or none.
 807     (let (debug-on-error-from-init-file
 808           debug-on-error-should-be-set
 809           (debug-on-error-initial
 810            (if (eq init-file-debug t) 'startup init-file-debug))
 811           (orig-enable-multibyte default-enable-multibyte-characters))
 812       (let ((debug-on-error debug-on-error-initial)
 813             ;; This function actually reads the init files.
 814             (inner
 815              (function
 816               (lambda ()
 817                 (if init-file-user
 818                     (let ((user-init-file-1
 819                            (cond
 820                             ((eq system-type 'ms-dos)
 821                              (concat "~" init-file-user "/_emacs"))
 822                             ((eq system-type 'windows-nt)
 823                              ;; Prefer .emacs on Windows.
 824                              (if (directory-files "~" nil "^\\.emacs\\(\\.elc?\\)?$")
 825                                  "~/.emacs"
 826                                ;; Also support _emacs for compatibility.
 827                                (if (directory-files "~" nil "^_emacs\\(\\.elc?\\)?$")
 828                                    "~/_emacs"
 829                                  ;; But default to .emacs if _emacs does not exist.
 830                                  "~/.emacs")))
 831                             ((eq system-type 'vax-vms)
 832                              "sys$login:.emacs")
 833                             (t
 834                              (concat "~" init-file-user "/.emacs")))))
 835                       ;; This tells `load' to store the file name found
 836                       ;; into user-init-file.
 837                       (setq user-init-file t)
 838                       (load user-init-file-1 t t)
 839
 840                       (when (eq user-init-file t)
 841                         ;; If we did not find ~/.emacs, try
 842                         ;; ~/.emacs.d/.emacs.
 843                         (let ((otherfile
 844                                (expand-file-name
 845                                 (file-name-nondirectory user-init-file-1)
 846                                 (file-name-as-directory
 847                                  (expand-file-name
 848                                   ".emacs.d"
 849                                   (file-name-directory user-init-file-1))))))
 850                           (load otherfile t t)
 851
 852                           ;; If we did not find the user's init file,
 853                           ;; set user-init-file conclusively.
 854                           ;; Don't let it be set from default.el.
 855                           (when (eq user-init-file t)
 856                             (setq user-init-file user-init-file-1))))
 857
 858                       ;; If we loaded a compiled file, set
 859                       ;; `user-init-file' to the source version if that
 860                       ;; exists.
 861                       (when (and user-init-file
 862                                  (equal (file-name-extension user-init-file)
 863                                         "elc"))
 864                         (let* ((source (file-name-sans-extension user-init-file))
 865                                (alt (concat source ".el")))
 866                           (setq source (cond ((file-exists-p alt) alt)
 867                                              ((file-exists-p source) source)
 868                                              (t nil)))
 869                           (when source
 870                             (when (file-newer-than-file-p source user-init-file)
 871                               (message "Warning: %s is newer than %s"
 872                                        source user-init-file)
 873                               (sit-for 1))
 874                             (setq user-init-file source))))
 875
 876                       (unless inhibit-default-init
 877                         (let ((inhibit-startup-message nil))
 878                           ;; Users are supposed to be told their rights.
 879                           ;; (Plus how to get help and how to undo.)
 880                           ;; Don't you dare turn this off for anyone
 881                           ;; except yourself.
 882                           (load "default" t t)))))))))
 883         (if init-file-debug
 884             ;; Do this without a condition-case if the user wants to debug.
 885             (funcall inner)
 886           (condition-case error
 887               (progn
 888                 (funcall inner)
 889                 (setq init-file-had-error nil))
 890             (error
 891              (let ((message-log-max nil))
 892                (save-excursion
 893                  (set-buffer (get-buffer-create "*Messages*"))
 894                  (insert "\n\n"
 895                          (format "An error has occurred while loading `%s':\n\n"
 896                                  user-init-file)
 897                          (format "%s%s%s"
 898                                  (get (car error) 'error-message)
 899                                  (if (cdr error) ": " "")
 900                                  (mapconcat (lambda (s) (prin1-to-string s t)) (cdr error) ", "))
 901                          "\n\n"
 902                          "To ensure normal operation, you should investigate and remove the\n"
 903                          "cause of the error in your initialization file.  Start Emacs with\n"
 904                          "the `--debug-init' option to view a complete error backtrace.\n\n"))
 905                (message "Error in init file: %s%s%s"
 906                         (get (car error) 'error-message)
 907                         (if (cdr error) ": " "")
 908                         (mapconcat 'prin1-to-string (cdr error) ", "))
 909                (let ((pop-up-windows nil))
 910                  (pop-to-buffer "*Messages*"))
 911                (setq init-file-had-error t)))))
 912
 913         ;; If the user has a file of abbrevs, read it.
 914         (if (file-exists-p abbrev-file-name)
 915             (quietly-read-abbrev-file abbrev-file-name))
 916
 917         ;; If the abbrevs came entirely from the init file or the
 918         ;; abbrevs file, they do not need saving.
 919         (setq abbrevs-changed nil)
 920
 921         ;; If we can tell that the init file altered debug-on-error,
 922         ;; arrange to preserve the value that it set up.
 923         (or (eq debug-on-error debug-on-error-initial)
 924             (setq debug-on-error-should-be-set t
 925                   debug-on-error-from-init-file debug-on-error)))
 926       (if debug-on-error-should-be-set
 927           (setq debug-on-error debug-on-error-from-init-file))
 928       (unless (or default-enable-multibyte-characters
 929                   (eq orig-enable-multibyte default-enable-multibyte-characters))
 930         ;; Init file changed to unibyte.  Reset existing multibyte
 931         ;; buffers (probably *scratch*, *Messages*, *Minibuff-0*).
 932         ;; Arguably this should only be done if they're free of
 933         ;; multibyte characters.
 934         (mapcar (lambda (buffer)
 935                   (with-current-buffer buffer
 936                     (if enable-multibyte-characters
 937                         (set-buffer-multibyte nil))))
 938                 (buffer-list))
 939         ;; Also re-set the language environment in case it was
 940         ;; originally done before unibyte was set and is sensitive to
 941         ;; unibyte (display table, terminal coding system &c).
 942         (set-language-environment current-language-environment)))
 943
 944     ;; Do this here in case the init file sets mail-host-address.
 945     (if (equal user-mail-address "")
 946         (setq user-mail-address (concat (user-login-name) "@"
 947                                         (or mail-host-address
 948                                             (system-name)))))
 949
 950     ;; If parameter have been changed in the init file which influence
 951     ;; face realization, clear the face cache so that new faces will
 952     ;; be realized.
 953     (unless (and (eq scalable-fonts-allowed old-scalable-fonts-allowed)
 954                  (eq font-list-limit old-font-list-limit)
 955                  (eq face-ignored-fonts old-face-ignored-fonts))
 956       (clear-face-cache)))
 957
 958   (run-hooks 'after-init-hook)
 959
 960   ;; Decode all default-directory.
 961   (if (and default-enable-multibyte-characters locale-coding-system)
 962       (save-excursion
 963         (dolist (elt (buffer-list))
 964           (set-buffer elt)
 965           (if default-directory
 966               (setq default-directory
 967                     (decode-coding-string default-directory
 968                                           locale-coding-system t))))
 969         (setq command-line-default-directory
 970               (decode-coding-string command-line-default-directory
 971                                     locale-coding-system t))))
 972
 973   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 974   (if (get-buffer "*scratch*")
 975       (with-current-buffer "*scratch*"
 976         (if (eq major-mode 'fundamental-mode)
 977             (funcall initial-major-mode))))
 978
 979   ;; Load library for our terminal type.
 980   ;; User init file can set term-file-prefix to nil to prevent this.
 981   (unless (or noninteractive
 982               initial-window-system
 983               (null term-file-prefix))
 984     (let ((term (getenv "TERM"))
 985           hyphend)
 986       (while (and term
 987                   (not (load (concat term-file-prefix term) t t)))
 988         ;; Strip off last hyphen and what follows, then try again
 989         (setq term
 990               (if (setq hyphend (string-match "[-_][^-_]+$" term))
 991                   (substring term 0 hyphend)
 992                 nil)))
 993       (when term
 994         ;; The terminal file has been loaded, now call the terminal
 995         ;; specific initialization function.
 996         (let ((term-init-func (intern (concat "terminal-init-" term))))
 997           (when (fboundp term-init-func)
 998             (funcall term-init-func))))))
 999
1000   ;; Update the out-of-memory error message based on user's key bindings
1001   ;; for save-some-buffers.
1002   (setq memory-signal-data
1003         (list 'error
1004               (substitute-command-keys "Memory exhausted--use \\[save-some-buffers] then exit and restart Emacs")))
1005
1006   ;; Process the remaining args.
1007   (command-line-1 (cdr command-line-args))
1008
1009   ;; If -batch, terminate after processing the command options.
1010   (if noninteractive (kill-emacs t))
1011
1012   ;; Run emacs-session-restore (session management) if started by
1013   ;; the session manager and we have a session manager connection.
1014   (if (and (boundp 'x-session-previous-id)
1015            (stringp x-session-previous-id))
1016       (with-no-warnings
1017         (emacs-session-restore x-session-previous-id))))
1018
1019 (defcustom initial-scratch-message (purecopy "\
1020 ;; This buffer is for notes you don't want to save, and for Lisp evaluation.
1021 ;; If you want to create a file, visit that file with C-x C-f,
1022 ;; then enter the text in that file's own buffer.
1023
1024 ")
1025   "Initial message displayed in *scratch* buffer at startup.
1026 If this is nil, no message will be displayed."
1027   :type '(choice (text :tag "Message")
1028                  (const :tag "none" nil))
1029   :group 'initialization)
1030
1031 \f
1032 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1033 ;;; Fancy splash screen
1034 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1035
1036 (defvar fancy-splash-text
1037   '((:face variable-pitch
1038            "You can do basic editing with the menu bar and scroll bar \
1039 using the mouse.\n\n"
1040            :face (variable-pitch :weight bold)
1041            "Important Help menu items:\n"
1042            :face variable-pitch
1043            (lambda ()
1044              (let* ((en "TUTORIAL")
1045                     (tut (or (get-language-info current-language-environment
1046                                                 'tutorial)
1047                              en))
1048                     (title (with-temp-buffer
1049                              (insert-file-contents
1050                               (expand-file-name tut data-directory)
1051                               nil 0 256)
1052                              (search-forward ".")
1053                              (buffer-substring (point-min) (1- (point))))))
1054                ;; If there is a specific tutorial for the current language
1055                ;; environment and it is not English, append its title.
1056                (concat
1057                 "Emacs Tutorial\tLearn how to use Emacs efficiently"
1058                 (if (string= en tut)
1059                     ""
1060                   (concat " (" title ")"))
1061                 "\n")))
1062            :face variable-pitch "\
1063 Emacs FAQ\tFrequently asked questions and answers
1064 Read the Emacs Manual\tView the Emacs manual using Info
1065 \(Non)Warranty\tGNU Emacs comes with "
1066            :face (variable-pitch :slant oblique)
1067            "ABSOLUTELY NO WARRANTY\n"
1068            :face variable-pitch
1069            "\
1070 Copying Conditions\tConditions for redistributing and changing Emacs
1071 Getting New Versions\tHow to obtain the latest version of Emacs
1072 More Manuals / Ordering Manuals       Buying printed manuals from the FSF\n")
1073   (:face variable-pitch
1074            "You can do basic editing with the menu bar and scroll bar \
1075 using the mouse.\n\n"
1076            :face (variable-pitch :weight bold)
1077            "Useful File menu items:\n"
1078            :face variable-pitch "\
1079 Exit Emacs\t(Or type Control-x followed by Control-c)
1080 Recover Crashed Session\tRecover files you were editing before a crash
1081
1082
1083
1084
1085 "
1086            ))
1087   "A list of texts to show in the middle part of splash screens.
1088 Each element in the list should be a list of strings or pairs
1089 `:face FACE', like `fancy-splash-insert' accepts them.")
1090
1091
1092 (defgroup fancy-splash-screen ()
1093   "Fancy splash screen when Emacs starts."
1094   :version "21.1"
1095   :group 'initialization)
1096
1097
1098 (defcustom fancy-splash-delay 7
1099   "*Delay in seconds between splash screens."
1100   :group 'fancy-splash-screen
1101   :type 'integer)
1102
1103
1104 (defcustom fancy-splash-max-time 30
1105   "*Show splash screens for at most this number of seconds.
1106 Values less than twice `fancy-splash-delay' are ignored."
1107   :group 'fancy-splash-screen
1108   :type 'integer)
1109
1110
1111 (defcustom fancy-splash-image nil
1112   "*The image to show in the splash screens, or nil for defaults."
1113   :group 'fancy-splash-screen
1114   :type '(choice (const :tag "Default" nil)
1115                  (file :tag "File")))
1116
1117
1118 ;; These are temporary storage areas for the splash screen display.
1119
1120 (defvar fancy-current-text nil)
1121 (defvar fancy-splash-help-echo nil)
1122 (defvar fancy-splash-stop-time nil)
1123 (defvar fancy-splash-outer-buffer nil)
1124
1125 (defun fancy-splash-insert (&rest args)
1126   "Insert text into the current buffer, with faces.
1127 Arguments from ARGS should be either strings, functions called
1128 with no args that return a string, or pairs `:face FACE',
1129 where FACE is a valid face specification, as it can be used with
1130 `put-text-property'."
1131   (let ((current-face nil))
1132     (while args
1133       (if (eq (car args) :face)
1134           (setq args (cdr args) current-face (car args))
1135         (insert (propertize (let ((it (car args)))
1136                               (if (functionp it)
1137                                   (funcall it)
1138                                 it))
1139                             'face current-face
1140                             'help-echo fancy-splash-help-echo)))
1141       (setq args (cdr args)))))
1142
1143
1144 (defun fancy-splash-head ()
1145   "Insert the head part of the splash screen into the current buffer."
1146   (let* ((image-file (cond ((stringp fancy-splash-image)
1147                             fancy-splash-image)
1148                            ((and (display-color-p)
1149                                  (image-type-available-p 'xpm))
1150                             (if (and (fboundp 'x-display-planes)
1151                                      (= (funcall 'x-display-planes) 8))
1152                                 "splash8.xpm"
1153                               "splash.xpm"))
1154                            (t "splash.pbm")))
1155          (img (create-image image-file))
1156          (image-width (and img (car (image-size img))))
1157          (window-width (window-width (selected-window))))
1158     (when img
1159       (when (> window-width image-width)
1160         ;; Center the image in the window.
1161         (insert (propertize " " 'display
1162                             `(space :align-to (+ center (-0.5 . ,img)))))
1163
1164         ;; Change the color of the XPM version of the splash image
1165         ;; so that it is visible with a dark frame background.
1166         (when (and (memq 'xpm img)
1167                    (eq (frame-parameter nil 'background-mode) 'dark))
1168           (setq img (append img '(:color-symbols (("#000000" . "gray30"))))))
1169
1170         ;; Insert the image with a help-echo and a keymap.
1171         (let ((map (make-sparse-keymap))
1172               (help-echo "mouse-2: browse http://www.gnu.org/"))
1173           (define-key map [mouse-2]
1174             (lambda ()
1175               (interactive)
1176               (browse-url "http://www.gnu.org/")
1177               (throw 'exit nil)))
1178           (define-key map [down-mouse-2] 'ignore)
1179           (define-key map [up-mouse-2] 'ignore)
1180           (insert-image img (propertize "xxx" 'help-echo help-echo
1181                                         'keymap map)))
1182         (insert "\n"))))
1183   (fancy-splash-insert
1184    :face '(variable-pitch :foreground "red")
1185    (if (eq system-type 'gnu/linux)
1186        "GNU Emacs is one component of the GNU/Linux operating system."
1187      "GNU Emacs is one component of the GNU operating system."))
1188   (insert "\n")
1189   (unless (equal (buffer-name fancy-splash-outer-buffer) "*scratch*")
1190     (fancy-splash-insert :face 'variable-pitch
1191                          (substitute-command-keys
1192                           "Type \\[recenter] to begin editing your file.\n"))))
1193
1194
1195 (defun fancy-splash-tail ()
1196   "Insert the tail part of the splash screen into the current buffer."
1197   (let ((fg (if (eq (frame-parameter nil 'background-mode) 'dark)
1198                 "cyan" "darkblue")))
1199     (fancy-splash-insert :face `(variable-pitch :foreground ,fg)
1200                          "\nThis is "
1201                          (emacs-version)
1202                          "\n"
1203                          :face '(variable-pitch :height 0.5)
1204                          "Copyright (C) 2005 Free Software Foundation, Inc.")
1205     (and auto-save-list-file-prefix
1206          ;; Don't signal an error if the
1207          ;; directory for auto-save-list files
1208          ;; does not yet exist.
1209          (file-directory-p (file-name-directory
1210                             auto-save-list-file-prefix))
1211          (directory-files
1212           (file-name-directory auto-save-list-file-prefix)
1213           nil
1214           (concat "\\`"
1215                   (regexp-quote (file-name-nondirectory
1216                                  auto-save-list-file-prefix)))
1217           t)
1218          (fancy-splash-insert :face '(variable-pitch :foreground "red")
1219                               "\n\nIf an Emacs session crashed recently, "
1220                               "type M-x recover-session RET\nto recover"
1221                               " the files you were editing."))))
1222
1223 (defun fancy-splash-screens-1 (buffer)
1224   "Timer function displaying a splash screen."
1225   (when (> (float-time) fancy-splash-stop-time)
1226     (throw 'stop-splashing nil))
1227   (unless fancy-current-text
1228     (setq fancy-current-text fancy-splash-text))
1229   (let ((text (car fancy-current-text)))
1230     (set-buffer buffer)
1231     (erase-buffer)
1232     (if pure-space-overflow
1233         (insert "Warning Warning  Pure space overflow   Warning Warning\n"))
1234     (fancy-splash-head)
1235     (apply #'fancy-splash-insert text)
1236     (fancy-splash-tail)
1237     (unless (current-message)
1238       (message fancy-splash-help-echo))
1239     (set-buffer-modified-p nil)
1240     (goto-char (point-min))
1241     (force-mode-line-update)
1242     (setq fancy-current-text (cdr fancy-current-text))))
1243
1244
1245 (defun fancy-splash-default-action ()
1246   "Stop displaying the splash screen buffer.
1247 This is an internal function used to turn off the splash screen after
1248 the user caused an input event by hitting a key or clicking with the
1249 mouse."
1250   (interactive)
1251   (push last-command-event unread-command-events)
1252   (throw 'exit nil))
1253
1254
1255 (defun fancy-splash-screens ()
1256   "Display fancy splash screens when Emacs starts."
1257   (setq fancy-splash-help-echo (startup-echo-area-message))
1258   (let ((old-hourglass display-hourglass)
1259         (fancy-splash-outer-buffer (current-buffer))
1260         splash-buffer
1261         (old-minor-mode-map-alist minor-mode-map-alist)
1262         (frame (fancy-splash-frame))
1263         timer)
1264     (save-selected-window
1265       (select-frame frame)
1266       (switch-to-buffer "GNU Emacs")
1267       (setq tab-width 20)
1268       (setq splash-buffer (current-buffer))
1269       (catch 'stop-splashing
1270         (unwind-protect
1271             (let ((map (make-sparse-keymap)))
1272               (use-local-map map)
1273               (define-key map [switch-frame] 'ignore)
1274               (define-key map [t] 'fancy-splash-default-action)
1275               (define-key map [mouse-movement] 'ignore)
1276               (define-key map [mode-line t] 'ignore)
1277               (setq cursor-type nil
1278                     display-hourglass nil
1279                     minor-mode-map-alist nil
1280                     buffer-undo-list t
1281                     mode-line-format (propertize "---- %b %-"
1282                                                  'face '(:weight bold))
1283                     fancy-splash-stop-time (+ (float-time)
1284                                               fancy-splash-max-time)
1285                     timer (run-with-timer 0 fancy-splash-delay
1286                                           #'fancy-splash-screens-1
1287                                           splash-buffer))
1288               (recursive-edit))
1289           (cancel-timer timer)
1290           (setq display-hourglass old-hourglass
1291                 minor-mode-map-alist old-minor-mode-map-alist)
1292           (kill-buffer splash-buffer))))))
1293
1294 (defun fancy-splash-frame ()
1295   "Return the frame to use for the fancy splash screen.
1296 Returning non-nil does not mean we should necessarily
1297 use the fancy splash screen, but if we do use it,
1298 we put it on this frame."
1299   (let (chosen-frame)
1300     (dolist (frame (append (frame-list) (list (selected-frame))))
1301       (if (and (frame-visible-p frame)
1302                (not (window-minibuffer-p (frame-selected-window frame))))
1303           (setq chosen-frame frame)))
1304     chosen-frame))
1305
1306 (defun use-fancy-splash-screens-p ()
1307   "Return t if fancy splash screens should be used."
1308   (when (and (display-graphic-p)
1309              (or (and (display-color-p)
1310                  (image-type-available-p 'xpm))
1311                  (image-type-available-p 'pbm)))
1312     (let ((frame (fancy-splash-frame)))
1313       (when frame
1314         (let* ((img (create-image (or fancy-splash-image
1315                                       (if (and (display-color-p)
1316                                                (image-type-available-p 'xpm))
1317                                           "splash.xpm" "splash.pbm"))))
1318                (image-height (and img (cdr (image-size img))))
1319                (window-height (1- (window-height (frame-selected-window frame)))))
1320           (> window-height (+ image-height 19)))))))
1321
1322
1323 (defun normal-splash-screen ()
1324   "Display splash screen when Emacs starts."
1325   (let ((prev-buffer (current-buffer)))
1326     (unwind-protect
1327         (with-current-buffer (get-buffer-create "GNU Emacs")
1328           (let ((tab-width 8)
1329                 (mode-line-format (propertize "---- %b %-"
1330                                               'face '(:weight bold))))
1331
1332             (if pure-space-overflow
1333                 (insert "Warning Warning  Pure space overflow   Warning Warning\n"))
1334
1335             ;; The convention for this piece of code is that
1336             ;; each piece of output starts with one or two newlines
1337             ;; and does not end with any newlines.
1338             (insert "Welcome to GNU Emacs")
1339             (insert
1340              (if (eq system-type 'gnu/linux)
1341                  ", one component of the GNU/Linux operating system.\n"
1342                ", a part of the GNU operating system.\n"))
1343
1344             (unless (equal (buffer-name prev-buffer) "*scratch*")
1345               (insert (substitute-command-keys
1346                        "\nType \\[recenter] to begin editing your file.\n")))
1347
1348             (if (display-mouse-p)
1349                 ;; The user can use the mouse to activate menus
1350                 ;; so give help in terms of menu items.
1351                 (progn
1352                   (insert "\
1353 You can do basic editing with the menu bar and scroll bar using the mouse.
1354
1355 Useful File menu items:
1356 Exit Emacs              (or type Control-x followed by Control-c)
1357 Recover Crashed Session Recover files you were editing before a crash
1358
1359 Important Help menu items:
1360 Emacs Tutorial          Learn how to use Emacs efficiently
1361 Emacs FAQ               Frequently asked questions and answers
1362 Read the Emacs Manual   View the Emacs manual using Info
1363 \(Non)Warranty          GNU Emacs comes with ABSOLUTELY NO WARRANTY
1364 Copying Conditions      Conditions for redistributing and changing Emacs
1365 Getting New Versions    How to obtain the latest version of Emacs
1366 More Manuals / Ordering Manuals    How to order printed manuals from the FSF
1367 ")
1368                   (insert "\n\n" (emacs-version)
1369                           "
1370 Copyright (C) 2005 Free Software Foundation, Inc."))
1371
1372               ;; No mouse menus, so give help using kbd commands.
1373
1374               ;; If keys have their default meanings,
1375               ;; use precomputed string to save lots of time.
1376               (if (and (eq (key-binding "\C-h") 'help-command)
1377                        (eq (key-binding "\C-xu") 'advertised-undo)
1378                        (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
1379                        (eq (key-binding "\C-ht") 'help-with-tutorial)
1380                        (eq (key-binding "\C-hi") 'info)
1381                        (eq (key-binding "\C-hr") 'info-emacs-manual)
1382                        (eq (key-binding "\C-h\C-n") 'view-emacs-news))
1383                   (insert "
1384 Get help           C-h  (Hold down CTRL and press h)
1385 Emacs manual       C-h r
1386 Emacs tutorial     C-h t           Undo changes     C-x u
1387 Buy manuals        C-h C-m         Exit Emacs       C-x C-c
1388 Browse manuals     C-h i")
1389
1390                 (insert (substitute-command-keys
1391                          (format "\n
1392 Get help           %s
1393 Emacs manual       \\[info-emacs-manual]
1394 Emacs tutorial     \\[help-with-tutorial]\tUndo changes\t\\[advertised-undo]
1395 Buy manuals        \\[view-order-manuals]\tExit Emacs\t\\[save-buffers-kill-emacs]
1396 Browse manuals     \\[info]"
1397                                  (let ((where (where-is-internal
1398                                                'help-command nil t)))
1399                                    (if where
1400                                        (key-description where)
1401                                      "M-x help"))))))
1402
1403               ;; Say how to use the menu bar with the keyboard.
1404               (if (and (eq (key-binding "\M-`") 'tmm-menubar)
1405                        (eq (key-binding [f10]) 'tmm-menubar))
1406                   (insert "
1407 Activate menubar   F10  or  ESC `  or   M-`")
1408                 (insert (substitute-command-keys "
1409 Activate menubar     \\[tmm-menubar]")))
1410
1411               ;; Many users seem to have problems with these.
1412               (insert "
1413 \(`C-' means use the CTRL key.  `M-' means use the Meta (or Alt) key.
1414 If you have no Meta key, you may instead type ESC followed by the character.)")
1415
1416               (insert "\n\n" (emacs-version)
1417                       "
1418 Copyright (C) 2005 Free Software Foundation, Inc.")
1419
1420               (if (and (eq (key-binding "\C-h\C-c") 'describe-copying)
1421                        (eq (key-binding "\C-h\C-d") 'describe-distribution)
1422                        (eq (key-binding "\C-h\C-w") 'describe-no-warranty))
1423                   (insert
1424                    "\n
1425 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
1426 Emacs is Free Software--Free as in Freedom--so you can redistribute copies
1427 of Emacs and modify it; type C-h C-c to see the conditions.
1428 Type C-h C-d for information on getting the latest version.")
1429                 (insert (substitute-command-keys
1430                          "\n
1431 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
1432 Emacs is Free Software--Free as in Freedom--so you can redistribute copies
1433 of Emacs and modify it; type \\[describe-copying] to see the conditions.
1434 Type \\[describe-distribution] for information on getting the latest version."))))
1435
1436             ;; The rest of the startup screen is the same on all
1437             ;; kinds of terminals.
1438
1439             ;; Give information on recovering, if there was a crash.
1440             (and auto-save-list-file-prefix
1441                  ;; Don't signal an error if the
1442                  ;; directory for auto-save-list files
1443                  ;; does not yet exist.
1444                  (file-directory-p (file-name-directory
1445                                     auto-save-list-file-prefix))
1446                  (directory-files
1447                   (file-name-directory auto-save-list-file-prefix)
1448                   nil
1449                   (concat "\\`"
1450                           (regexp-quote (file-name-nondirectory
1451                                          auto-save-list-file-prefix)))
1452                   t)
1453                  (insert "\n\nIf an Emacs session crashed recently, "
1454                          "type M-x recover-session RET\nto recover"
1455                          " the files you were editing."))
1456
1457             ;; Display the input that we set up in the buffer.
1458             (set-buffer-modified-p nil)
1459             (goto-char (point-min))
1460             (save-window-excursion
1461               (switch-to-buffer (current-buffer))
1462               (sit-for 120))))
1463       ;; Unwind ... ensure splash buffer is killed
1464       (kill-buffer "GNU Emacs"))))
1465
1466
1467 (defun startup-echo-area-message ()
1468   (if (eq (key-binding "\C-h\C-p") 'describe-project)
1469       "For information about the GNU Project and its goals, type C-h C-p."
1470     (substitute-command-keys
1471      "For information about the GNU Project and its goals, type \
1472 \\[describe-project].")))
1473
1474
1475 (defun display-startup-echo-area-message ()
1476   (let ((resize-mini-windows t))
1477     (message (startup-echo-area-message))))
1478
1479
1480 (defun display-splash-screen ()
1481   "Display splash screen according to display.
1482 Fancy splash screens are used on graphic displays,
1483 normal otherwise."
1484   (interactive)
1485   (if (use-fancy-splash-screens-p)
1486       (fancy-splash-screens)
1487     (normal-splash-screen)))
1488
1489
1490 (defun command-line-1 (command-line-args-left)
1491   (or noninteractive (input-pending-p) init-file-had-error
1492       ;; t if the init file says to inhibit the echo area startup message.
1493       (and inhibit-startup-echo-area-message
1494            user-init-file
1495            (or (and (get 'inhibit-startup-echo-area-message 'saved-value)
1496                     (equal inhibit-startup-echo-area-message
1497                            (if (equal init-file-user "")
1498                                (user-login-name)
1499                              init-file-user)))
1500                ;; Wasn't set with custom; see if .emacs has a setq.
1501                (let ((buffer (get-buffer-create " *temp*")))
1502                  (prog1
1503                      (condition-case nil
1504                          (save-excursion
1505                            (set-buffer buffer)
1506                            (insert-file-contents user-init-file)
1507                            (re-search-forward
1508                             (concat
1509                              "([ \t\n]*setq[ \t\n]+"
1510                              "inhibit-startup-echo-area-message[ \t\n]+"
1511                              (regexp-quote
1512                               (prin1-to-string
1513                                (if (equal init-file-user "")
1514                                    (user-login-name)
1515                                  init-file-user)))
1516                              "[ \t\n]*)")
1517                             nil t))
1518                        (error nil))
1519                    (kill-buffer buffer)))))
1520       ;; display-splash-screen at the end of command-line-1 calls
1521       ;; use-fancy-splash-screens-p. This can cause image.el to be
1522       ;; loaded, putting "Loading image... done" in the echo area.
1523       ;; This hides startup-echo-area-message. So
1524       ;; use-fancy-splash-screens-p is called here simply to get the
1525       ;; loading of image.el (if needed) out of the way before
1526       ;; display-startup-echo-area-message runs.
1527       (progn
1528         (use-fancy-splash-screens-p)
1529         (display-startup-echo-area-message)))
1530
1531   ;; Delay 2 seconds after an init file error message
1532   ;; was displayed, so user can read it.
1533   (when init-file-had-error
1534     (sit-for 2))
1535
1536   (when command-line-args-left
1537     ;; We have command args; process them.
1538     (let ((dir command-line-default-directory)
1539           (file-count 0)
1540           first-file-buffer
1541           tem
1542           ;; This approach loses for "-batch -L DIR --eval "(require foo)",
1543           ;; if foo is intended to be found in DIR.
1544           ;;
1545           ;; ;; The directories listed in --directory/-L options will *appear*
1546           ;; ;; at the front of `load-path' in the order they appear on the
1547           ;; ;; command-line.  We cannot do this by *placing* them at the front
1548           ;; ;; in the order they appear, so we need this variable to hold them,
1549           ;; ;; temporarily.
1550           ;; extra-load-path
1551           ;;
1552           ;; To DTRT we keep track of the splice point and modify `load-path'
1553           ;; straight away upon any --directory/-L option.
1554           splice
1555           just-files ;; t if this follows the magic -- option.
1556           ;; This includes our standard options' long versions
1557           ;; and long versions of what's on command-switch-alist.
1558           (longopts
1559            (append '(("--funcall") ("--load") ("--insert") ("--kill")
1560                      ("--directory") ("--eval") ("--execute") ("--no-splash")
1561                      ("--find-file") ("--visit") ("--file"))
1562                    (mapcar (lambda (elt)
1563                              (list (concat "-" (car elt))))
1564                            command-switch-alist)))
1565           (line 0)
1566           (column 0))
1567
1568       ;; Add the long X options to longopts.
1569       (dolist (tem command-line-x-option-alist)
1570         (if (string-match "^--" (car tem))
1571             (push (list (car tem)) longopts)))
1572
1573       ;; Loop, processing options.
1574       (while command-line-args-left
1575         (let* ((argi (car command-line-args-left))
1576                (orig-argi argi)
1577                argval completion)
1578           (setq command-line-args-left (cdr command-line-args-left))
1579
1580           ;; Do preliminary decoding of the option.
1581           (if just-files
1582               ;; After --, don't look for options; treat all args as files.
1583               (setq argi "")
1584             ;; Convert long options to ordinary options
1585             ;; and separate out an attached option argument into argval.
1586             (when (string-match "^\\(--[^=]*\\)=" argi)
1587               (setq argval (substring argi (match-end 0))
1588                     argi (match-string 1 argi)))
1589             (if (equal argi "--")
1590                 (setq completion nil)
1591               (setq completion (try-completion argi longopts)))
1592             (if (eq completion t)
1593                 (setq argi (substring argi 1))
1594               (if (stringp completion)
1595                   (let ((elt (assoc completion longopts)))
1596                     (or elt
1597                         (error "Option `%s' is ambiguous" argi))
1598                     (setq argi (substring (car elt) 1)))
1599                 (setq argval nil
1600                       argi orig-argi))))
1601
1602           ;; Execute the option.
1603           (cond ((setq tem (assoc argi command-switch-alist))
1604                  (if argval
1605                      (let ((command-line-args-left
1606                             (cons argval command-line-args-left)))
1607                        (funcall (cdr tem) argi))
1608                    (funcall (cdr tem) argi)))
1609
1610                 ((equal argi "-no-splash")
1611                  (setq inhibit-startup-message t))
1612
1613                 ((member argi '("-f"    ; what the manual claims
1614                                 "-funcall"
1615                                 "-e"))  ; what the source used to say
1616                  (setq tem (intern (or argval (pop command-line-args-left))))
1617                  (if (commandp tem)
1618                      (command-execute tem)
1619                    (funcall tem)))
1620
1621                 ((member argi '("-eval" "-execute"))
1622                  (eval (read (or argval (pop command-line-args-left)))))
1623
1624                 ((member argi '("-L" "-directory"))
1625                  (setq tem (expand-file-name
1626                             (command-line-normalize-file-name
1627                              (or argval (pop command-line-args-left)))))
1628                  (cond (splice (setcdr splice (cons tem (cdr splice)))
1629                                (setq splice (cdr splice)))
1630                        (t (setq load-path (cons tem load-path)
1631                                 splice load-path))))
1632
1633                 ((member argi '("-l" "-load"))
1634                  (let* ((file (command-line-normalize-file-name
1635                                (or argval (pop command-line-args-left))))
1636                         ;; Take file from default dir if it exists there;
1637                         ;; otherwise let `load' search for it.
1638                         (file-ex (expand-file-name file)))
1639                    (when (file-exists-p file-ex)
1640                      (setq file file-ex))
1641                    (load file nil t)))
1642
1643                 ;; This is used to handle -script.  It's not clear
1644                 ;; we need to document it.
1645                 ((member argi '("-scriptload"))
1646                  (let* ((file (command-line-normalize-file-name
1647                                (or argval (pop command-line-args-left))))
1648                         ;; Take file from default dir.
1649                         (file-ex (expand-file-name file)))
1650                    (load file-ex nil t t)))
1651
1652                 ((equal argi "-insert")
1653                  (setq tem (or argval (pop command-line-args-left)))
1654                  (or (stringp tem)
1655                      (error "File name omitted from `-insert' option"))
1656                  (insert-file-contents (command-line-normalize-file-name tem)))
1657
1658                 ((equal argi "-kill")
1659                  (kill-emacs t))
1660
1661                 ((string-match "^\\+[0-9]+\\'" argi)
1662                  (setq line (string-to-number argi)))
1663
1664                 ((string-match "^\\+\\([0-9]+\\):\\([0-9]+\\)\\'" argi)
1665                  (setq line (string-to-number (match-string 1 argi))
1666                        column (string-to-number (match-string 2 argi))))
1667
1668                 ((setq tem (assoc argi command-line-x-option-alist))
1669                  ;; Ignore X-windows options and their args if not using X.
1670                  (setq command-line-args-left
1671                        (nthcdr (nth 1 tem) command-line-args-left)))
1672
1673                 ((member argi '("-find-file" "-file" "-visit"))
1674                  ;; An explicit option to specify visiting a file.
1675                  (setq tem (or argval (pop command-line-args-left)))
1676                  (unless (stringp tem)
1677                    (error "File name omitted from `%s' option" argi))
1678                  (setq file-count (1+ file-count))
1679                  (let ((file (expand-file-name
1680                               (command-line-normalize-file-name tem) dir)))
1681                    (if (= file-count 1)
1682                        (setq first-file-buffer (find-file file))
1683                      (find-file-other-window file)))
1684                  (or (zerop line)
1685                      (goto-line line))
1686                  (setq line 0)
1687                  (unless (< column 1)
1688                    (move-to-column (1- column)))
1689                  (setq column 0))
1690
1691                 ((equal argi "--")
1692                  (setq just-files t))
1693                 (t
1694                  ;; We have almost exhausted our options. See if the
1695                  ;; user has made any other command-line options available
1696                  (let ((hooks command-line-functions) ;; lrs 7/31/89
1697                        (did-hook nil))
1698                    (while (and hooks
1699                                (not (setq did-hook (funcall (car hooks)))))
1700                      (setq hooks (cdr hooks)))
1701                    (if (not did-hook)
1702                        ;; Presume that the argument is a file name.
1703                        (progn
1704                          (if (string-match "\\`-" argi)
1705                              (error "Unknown option `%s'" argi))
1706                          (setq file-count (1+ file-count))
1707                          (let ((file
1708                                 (expand-file-name
1709                                  (command-line-normalize-file-name orig-argi)
1710                                  dir)))
1711                            (if (= file-count 1)
1712                                (setq first-file-buffer (find-file file))
1713                              (find-file-other-window file)))
1714                          (or (zerop line)
1715                              (goto-line line))
1716                          (setq line 0)
1717                          (unless (< column 1)
1718                            (move-to-column (1- column)))
1719                          (setq column 0))))))))
1720
1721       ;; If 3 or more files visited, and not all visible,
1722       ;; show user what they all are.  But leave the last one current.
1723       (and (> file-count 2)
1724            (not noninteractive)
1725            (not inhibit-startup-buffer-menu)
1726            (or (get-buffer-window first-file-buffer)
1727                (list-buffers)))))
1728
1729   ;; Maybe display a startup screen.
1730   (unless (or inhibit-startup-message
1731               noninteractive
1732               emacs-quick-startup)
1733     ;; Display a startup screen, after some preparations.
1734
1735     ;; If there are no switches to process, we might as well
1736     ;; run this hook now, and there may be some need to do it
1737     ;; before doing any output.
1738     (run-hooks 'emacs-startup-hook)
1739     (and term-setup-hook
1740          (run-hooks 'term-setup-hook))
1741     (setq inhibit-startup-hooks t)
1742
1743     ;; It's important to notice the user settings before we
1744     ;; display the startup message; otherwise, the settings
1745     ;; won't take effect until the user gives the first
1746     ;; keystroke, and that's distracting.
1747     (when (fboundp 'frame-notice-user-settings)
1748       (frame-notice-user-settings))
1749
1750     ;; If there are no switches to process, we might as well
1751     ;; run this hook now, and there may be some need to do it
1752     ;; before doing any output.
1753     (when window-setup-hook
1754       (run-hooks 'window-setup-hook)
1755       ;; Don't let the hook be run twice.
1756       (setq window-setup-hook nil))
1757
1758     ;; Do this now to avoid an annoying delay if the user
1759     ;; clicks the menu bar during the sit-for.
1760     (when (display-popup-menus-p)
1761       (precompute-menubar-bindings))
1762     (with-no-warnings
1763      (setq menubar-bindings-done t))
1764
1765     ;; If *scratch* is selected and it is empty, insert an
1766     ;; initial message saying not to create a file there.
1767     (when (and initial-scratch-message
1768                (equal (buffer-name) "*scratch*")
1769                (= 0 (buffer-size)))
1770       (insert initial-scratch-message)
1771       (set-buffer-modified-p nil))
1772
1773     ;; If user typed input during all that work,
1774     ;; abort the startup screen.  Otherwise, display it now.
1775     (unless (input-pending-p)
1776       (display-splash-screen))))
1777
1778
1779 (defun command-line-normalize-file-name (file)
1780   "Collapse multiple slashes to one, to handle non-Emacs file names."
1781   (save-match-data
1782     ;; Use arg 1 so that we don't collapse // at the start of the file name.
1783     ;; That is significant on some systems.
1784     ;; However, /// at the beginning is supposed to mean just /, not //.
1785     (if (string-match "^///+" file)
1786         (setq file (replace-match "/" t t file)))
1787     (while (string-match "//+" file 1)
1788       (setq file (replace-match "/" t t file)))
1789     file))
1790
1791 ;; arch-tag: 7e294698-244d-4758-984b-4047f887a5db
1792 ;;; startup.el ends here