code.delx.au - gnu-emacs/blob - lisp/talk.el

   1 ;;; talk.el --- allow several users to talk to each other through Emacs
   2
   3 ;; Copyright (C) 1995, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: comm, frames
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a multi-user talk package that runs in Emacs.
  28 ;; Use talk-connect to bring a new person into the conversation.
  29
  30 ;;; Code:
  31
  32 (defvar talk-display-alist nil
  33   "Alist of displays on which Emacs talk is now running.
  34 Each element has the form (DISPLAY FRAME BUFFER).")
  35
  36 ;;;###autoload
  37 (defun talk-connect (display)
  38   "Connect to display DISPLAY for the Emacs talk group."
  39   (interactive "sTalk to display: ")
  40   ;; Make sure we have an entry for the current display.
  41   (let ((mydisp (cdr (assq 'display (frame-parameters (selected-frame))))))
  42     (talk-add-display mydisp))
  43   ;; Make sure we have an entry for the specified display.
  44   (talk-add-display display)
  45   ;; Add the new buffers to all talk frames.
  46   (talk-update-buffers))
  47
  48 ;;;###autoload
  49 (defun talk ()
  50   "Connect to the Emacs talk group from the current X display or tty frame."
  51   (interactive)
  52   (let ((type (frame-live-p (selected-frame)))
  53         (display (frame-display (selected-frame))))
  54     (cond
  55      ((eq type t)
  56       (talk-add-display (selected-frame)))
  57      ((eq type 'x)
  58       (talk-add-display (frame-display (selected-frame))))
  59      (t
  60       (error "Unknown frame type"))))
  61   (talk-update-buffers))
  62
  63 (defun talk-add-display (frame)
  64   (let* ((display (if (frame-live-p frame)
  65                       (frame-display frame)
  66                     frame))
  67          (elt (assoc display talk-display-alist))
  68          (name (concat "*talk-" (display-name display) "*"))
  69          buffer)
  70     (unless (frame-live-p frame)
  71       (setq frame (make-frame-on-display display (list (cons 'name name)))))
  72     (if (and elt (frame-live-p (nth 1 elt)))
  73         (setq frame (nth 1 elt)))
  74     (if (not (and elt (buffer-name (get-buffer (setq buffer (nth 2 elt))))))
  75         (setq buffer (get-buffer-create name)))
  76     (add-to-list 'delete-frame-functions 'talk-handle-delete-frame)
  77     (setq talk-display-alist
  78           (cons (list display frame buffer) (delq elt talk-display-alist)))))
  79
  80 (defun talk-handle-delete-frame (frame)
  81   (dolist (d talk-display-alist)
  82     (when (eq (nth 1 d) frame)
  83       (setq talk-display-alist (delq d talk-display-alist))
  84       (talk-update-buffers))))
  85
  86 (defun talk-disconnect ()
  87   "Disconnect this display from the Emacs talk group."
  88   (interactive)
  89   (let* ((mydisp (cdr (assq 'display (frame-parameters (selected-frame)))))
  90          (elt (assoc mydisp talk-display-alist)))
  91     (delete-frame (nth 1 elt))
  92     (kill-buffer (nth 2 elt))
  93     (setq talk-display-alist (delq elt talk-display-alist))
  94     (talk-update-buffers)))
  95
  96 (defun talk-update-buffers ()
  97   "Update all the talk frames so that each shows all the talk buffers."
  98   (let ((tail talk-display-alist))
  99     (while tail
 100       (let ((frame (nth 1 (car tail)))
 101             (this-buffer (nth 2 (car tail)))
 102             (buffers
 103              (mapcar (function (lambda (elt) (nth 2 elt)))
 104                      talk-display-alist)))
 105         ;; Put this display's own talk buffer
 106         ;; at the front of the list.
 107         (setq buffers (cons this-buffer (delq this-buffer buffers)))
 108         (talk-split-up-frame frame buffers))
 109       (setq tail (cdr tail)))))
 110
 111 (defun talk-split-up-frame (frame buffers)
 112   "Split FRAME into equal-sized windows displaying the buffers in BUFFERS.
 113 Select the first of these windows, displaying the first of the buffers."
 114   (let ((lines-per-buffer (/ (frame-height frame) (length buffers)))
 115         (old-frame (selected-frame)))
 116     (unwind-protect
 117         (progn
 118           (select-frame frame)
 119           (select-window (frame-first-window frame))
 120           (delete-other-windows)
 121           (while (progn
 122                    (switch-to-buffer (car buffers))
 123                    (setq buffers (cdr buffers)))
 124             (split-window-vertically lines-per-buffer)
 125             (other-window 1))
 126           (select-window (frame-first-window frame)))
 127       (select-frame old-frame))))
 128
 129 (provide 'talk)
 130
 131 ;;; arch-tag: 7ab0ad88-1788-4886-a44c-ae685e6f8a1a
 132 ;;; talk.el ends here