code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 143 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 dnl _ON results in a '--without' option in the --help output, so
 150 dnl the help text should refer to "don't compile", etc.
 151 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 152 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 153 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 154 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 155 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 156 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 157 OPTION_DEFAULT_OFF([imagemagick],[compile with ImageMagick image support])
 158
 159 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 160 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 161 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 162
 163 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 164 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 165 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 166 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 167
 168 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 169 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 170 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 171 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH([gnustep-conf],dnl
 204 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 205 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 206   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 207 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 208      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 209
 210 AC_ARG_ENABLE(ns-self-contained,
 211 [AS_HELP_STRING([--disable-ns-self-contained],
 212                 [disable self contained build under NeXTstep])],
 213    EN_NS_SELF_CONTAINED=$enableval,
 214    EN_NS_SELF_CONTAINED=yes)
 215
 216 AC_ARG_ENABLE(asserts,
 217 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 218       USE_XASSERTS=$enableval,
 219       USE_XASSERTS=no)
 220
 221 AC_ARG_ENABLE(maintainer-mode,
 222 [AS_HELP_STRING([--enable-maintainer-mode],
 223                 [enable make rules and dependencies not useful (and sometimes
 224                  confusing) to the casual installer])],
 225       USE_MAINTAINER_MODE=$enableval,
 226       USE_MAINTAINER_MODE=no)
 227 if test $USE_MAINTAINER_MODE = yes; then
 228   MAINT=
 229 else
 230   MAINT=#
 231 fi
 232 AC_SUBST(MAINT)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;;
 264         all)            ac_enable_checking=1 ;
 265                         ac_gc_check_stringbytes=1 ;
 266                         ac_gc_check_string_overrun=1 ;
 267                         ac_gc_check_string_free_list=1 ;
 268                         ac_xmalloc_overrun=1 ;
 269                         ac_gc_check_cons_list=1 ;;
 270         # these enable particular checks
 271         stringbytes)    ac_gc_check_stringbytes=1 ;;
 272         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 273         stringfreelist) ac_gc_check_string_free_list=1 ;;
 274         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 275         conslist)       ac_gc_check_cons_list=1 ;;
 276         *)      AC_MSG_ERROR(unknown check category $check) ;;
 277         esac
 278 done
 279 IFS="$ac_save_IFS"
 280
 281 if test x$ac_enable_checking != x ; then
 282   AC_DEFINE(ENABLE_CHECKING, 1,
 283 [Enable expensive run-time checking of data types?])
 284 fi
 285 if test x$ac_gc_check_stringbytes != x ; then
 286   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 287 [Define this temporarily to hunt a bug.  If defined, the size of
 288    strings is redundantly recorded in sdata structures so that it can
 289    be compared to the sizes recorded in Lisp strings.])
 290 fi
 291 if test x$ac_gc_check_stringoverrun != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 293 [Define this to check for short string overrun.])
 294 fi
 295 if test x$ac_gc_check_string_free_list != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 297 [Define this to check the string free list.])
 298 fi
 299 if test x$ac_xmalloc_overrun != x ; then
 300   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 301 [Define this to check for malloc buffer overrun.])
 302 fi
 303 if test x$ac_gc_check_cons_list != x ; then
 304   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 305 [Define this to check for errors in cons list.])
 306 fi
 307
 308 AC_ARG_ENABLE(profiling,
 309 [AS_HELP_STRING([--enable-profiling],
 310                 [build emacs with profiling support.
 311                  This might not work on all platforms])],
 312 [ac_enable_profiling="${enableval}"],[])
 313 if test x$ac_enable_profiling != x ; then
 314    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 315    PROFILING_LDFLAGS="-pg"
 316 else
 317    PROFILING_CFLAGS=
 318    PROFILING_LDFLAGS=
 319 fi
 320
 321 AC_ARG_ENABLE(autodepend,
 322 [AS_HELP_STRING([--enable-autodepend],
 323                 [automatically generate dependencies to .h-files.
 324                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 325                  found])],
 326 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 327
 328 #### Make srcdir absolute, if it isn't already.  It's important to
 329 #### avoid running the path through pwd unnecessarily, since pwd can
 330 #### give you automounter prefixes, which can go away.  We do all this
 331 #### so Emacs can find its files when run uninstalled.
 332 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 333 unset CDPATH
 334 case "${srcdir}" in
 335   /* ) ;;
 336   . )
 337     ## We may be able to use the $PWD environment variable to make this
 338     ## absolute.  But sometimes PWD is inaccurate.
 339     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 340     ## but that tested only for a well-formed and valid PWD,
 341     ## it did not object when PWD was well-formed and valid but just wrong.
 342     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 343     then
 344       srcdir="$PWD"
 345     else
 346       srcdir="`(cd ${srcdir}; pwd)`"
 347     fi
 348   ;;
 349   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 350 esac
 351
 352 #### Check if the source directory already has a configured system in it.
 353 if test `pwd` != `(cd ${srcdir} && pwd)` \
 354    && test -f "${srcdir}/src/config.h" ; then
 355   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 356    as a build directory right now; it has been configured in its own
 357    right.  To configure in another directory as well, you MUST
 358    use GNU make.  If you do not have GNU make, then you must
 359    now do `make distclean' in ${srcdir},
 360    and then run $0 again.]])
 361 fi
 362
 363 #### Given the configuration name, set machfile and opsysfile to the
 364 #### names of the m/*.h and s/*.h files we should use.
 365
 366 ### Canonicalize the configuration name.
 367
 368 AC_CANONICAL_HOST
 369 canonical=$host
 370 configuration=${host_alias-${build_alias-$host}}
 371
 372 dnl This used to use changequote, but, apart from `changequote is evil'
 373 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 374 dnl the great gob of text.  Thus it's not processed for possible expansion.
 375 dnl Just make sure the brackets remain balanced.
 376 dnl
 377 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 378 dnl indicated by comments.
 379 dnl quotation begins
 380 [
 381
 382 ### If you add support for a new configuration, add code to this
 383 ### switch statement to recognize your configuration name and select
 384 ### the appropriate operating system and machine description files.
 385
 386 ### You would hope that you could choose an m/*.h file pretty much
 387 ### based on the machine portion of the configuration name, and an s/*.h
 388 ### file based on the operating system portion.  However, it turns out
 389 ### that each m/*.h file is pretty manufacturer-specific - for
 390 ### example mips.h is MIPS
 391 ### So we basically have to have a special case for each
 392 ### configuration name.
 393 ###
 394 ### As far as handling version numbers on operating systems is
 395 ### concerned, make sure things will fail in a fixable way.  If
 396 ### /etc/MACHINES doesn't say anything about version numbers, be
 397 ### prepared to handle anything reasonably.  If version numbers
 398 ### matter, be sure /etc/MACHINES says something about it.
 399
 400 machine='' opsys='' unported=no
 401 case "${canonical}" in
 402
 403   ## FreeBSD ports
 404   *-*-freebsd* )
 405     opsys=freebsd
 406     case "${canonical}" in
 407       alpha*)           machine=alpha ;;
 408       amd64-*|x86_64-*) machine=amdx86-64 ;;
 409       arm*)             machine=arm ;;
 410       ia64-*)           machine=ia64 ;;
 411       i[3456]86-*)      machine=intel386 ;;
 412       powerpc-*)        machine=macppc ;;
 413       sparc-*)          machine=sparc ;;
 414       sparc64-*)        machine=sparc ;;
 415     esac
 416   ;;
 417
 418   ## FreeBSD kernel + glibc based userland
 419   *-*-kfreebsd*gnu* )
 420     opsys=gnu-kfreebsd
 421     case "${canonical}" in
 422       alpha*)           machine=alpha ;;
 423       amd64-*|x86_64-*) machine=amdx86-64 ;;
 424       ia64-*)           machine=ia64 ;;
 425       i[3456]86-*)      machine=intel386 ;;
 426       powerpc-*)        machine=macppc ;;
 427       sparc-*)          machine=sparc ;;
 428       sparc64-*)        machine=sparc ;;
 429     esac
 430   ;;
 431
 432   ## NetBSD ports
 433   *-*-netbsd* )
 434     opsys=netbsd
 435     case "${canonical}" in
 436       alpha*)      machine=alpha ;;
 437       x86_64-*)    machine=amdx86-64 ;;
 438       arm-*)       machine=arm ;;
 439       hppa-*)      machine=hp800 ;;
 440       i[3456]86-*) machine=intel386 ;;
 441       m68k-*)      machine=m68k ;;
 442       powerpc-*)   machine=macppc ;;
 443       mips-*)      machine=mips ;;
 444       mipse[bl]-*) machine=mips ;;
 445       sparc*-)     machine=sparc ;;
 446       vax-*)       machine=vax ;;
 447     esac
 448   ;;
 449
 450   ## OpenBSD ports
 451   *-*-openbsd* )
 452     opsys=openbsd
 453     case "${canonical}" in
 454       alpha*)    machine=alpha ;;
 455       x86_64-*)  machine=amdx86-64 ;;
 456       arm-*)     machine=arm ;;
 457       hppa-*)    machine=hp800 ;;
 458       i386-*)    machine=intel386 ;;
 459       powerpc-*) machine=macppc ;;
 460       sparc*)    machine=sparc ;;
 461       vax-*)     machine=vax ;;
 462     esac
 463   ;;
 464
 465   alpha*-*-linux-gnu* )
 466     machine=alpha opsys=gnu-linux
 467   ;;
 468
 469   arm*-*-linux-gnu* )
 470     machine=arm opsys=gnu-linux
 471   ;;
 472
 473   ## Apple Darwin / Mac OS X
 474   *-apple-darwin* )
 475     case "${canonical}" in
 476       i[3456]86-* )  machine=intel386 ;;
 477       powerpc-* )    machine=macppc ;;
 478       x86_64-* )     machine=amdx86-64 ;;
 479       * )            unported=yes ;;
 480     esac
 481     opsys=darwin
 482     # Define CPP as follows to make autoconf work correctly.
 483     CPP="${CC-cc} -E -no-cpp-precomp"
 484     # Use fink packages if available.
 485     if test -d /sw/include && test -d /sw/lib; then
 486       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 487       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 488       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 489     fi
 490   ;;
 491
 492   ## HP 9000 series 700 and 800, running HP/UX
 493   hppa*-hp-hpux10.2* )
 494     machine=hp800 opsys=hpux10-20
 495   ;;
 496   hppa*-hp-hpux1[1-9]* )
 497     machine=hp800 opsys=hpux11
 498     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 499   ;;
 500
 501   hppa*-*-linux-gnu* )
 502     machine=hp800 opsys=gnu-linux
 503   ;;
 504
 505   ## IBM machines
 506   s390-*-linux-gnu* )
 507     machine=ibms390 opsys=gnu-linux
 508   ;;
 509   s390x-*-linux-gnu* )
 510     machine=ibms390x opsys=gnu-linux
 511   ;;
 512   rs6000-ibm-aix4.[23]* )
 513     machine=ibmrs6000 opsys=aix4-2
 514   ;;
 515   powerpc-ibm-aix4.[23]*  )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   rs6000-ibm-aix[56]* )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521   powerpc-ibm-aix[56]*  )
 522     machine=ibmrs6000 opsys=aix4-2
 523   ;;
 524
 525   ## Macintosh PowerPC
 526   powerpc*-*-linux-gnu* )
 527     machine=macppc opsys=gnu-linux
 528   ;;
 529
 530   ## Silicon Graphics machines
 531   ## Iris 4D
 532   mips-sgi-irix6.5 )
 533     machine=iris4d opsys=irix6-5
 534     # Without defining _LANGUAGE_C, things get masked out in the headers
 535     # so that, for instance, grepping for `free' in stdlib.h fails and
 536     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 537     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 538     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 539   ;;
 540
 541   ## Suns
 542   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 543     machine=sparc opsys=gnu-linux
 544   ;;
 545
 546   *-sun-solaris* \
 547     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 548     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 549     case "${canonical}" in
 550       i[3456]86-*-* )     machine=intel386 ;;
 551       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 552       sparc* )          machine=sparc ;;
 553       * )               unported=yes ;;
 554     esac
 555     case "${canonical}" in
 556       *-sunos5.6* | *-solaris2.6* )
 557                 opsys=sol2-6
 558                 NON_GNU_CPP=/usr/ccs/lib/cpp
 559                 RANLIB="ar -ts"
 560                 ;;
 561       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 562                 opsys=sol2-6
 563                 emacs_check_sunpro_c=yes
 564                 NON_GNU_CPP=/usr/ccs/lib/cpp
 565                 ;;
 566       *-sunos5* | *-solaris* )
 567                 opsys=sol2-10
 568                 emacs_check_sunpro_c=yes
 569                 NON_GNU_CPP=/usr/ccs/lib/cpp
 570                 ;;
 571     esac
 572     ## Watch out for a compiler that we know will not work.
 573     case "${canonical}" in
 574      *-solaris* | *-sunos5* )
 575                 if [ "x$CC" = x/usr/ucb/cc ]; then
 576                   ## /usr/ucb/cc doesn't work;
 577                   ## we should find some other compiler that does work.
 578                   unset CC
 579                 fi
 580                 ;;
 581       *) ;;
 582     esac
 583   ;;
 584
 585   ## IA-64
 586   ia64*-*-linux* )
 587     machine=ia64 opsys=gnu-linux
 588   ;;
 589
 590   ## Intel 386 machines where we don't care about the manufacturer.
 591   i[3456]86-*-* )
 592     machine=intel386
 593     case "${canonical}" in
 594       *-cygwin )                opsys=cygwin ;;
 595       *-darwin* )               opsys=darwin
 596                                 CPP="${CC-cc} -E -no-cpp-precomp"
 597                                 ;;
 598       *-linux-gnu* )            opsys=gnu-linux ;;
 599       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 600       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 601       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 602       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 603     esac
 604   ;;
 605
 606   ## m68k Linux-based GNU system
 607   m68k-*-linux-gnu* )
 608     machine=m68k opsys=gnu-linux
 609   ;;
 610
 611   ## Mips Linux-based GNU system
 612   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 613     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 614     machine=mips opsys=gnu-linux
 615   ;;
 616
 617   ## AMD x86-64 Linux-based GNU system
 618   x86_64-*-linux-gnu* )
 619     machine=amdx86-64 opsys=gnu-linux
 620   ;;
 621
 622   ## Tensilica Xtensa Linux-based GNU system
 623   xtensa*-*-linux-gnu* )
 624     machine=xtensa opsys=gnu-linux
 625     ;;
 626
 627   ## SuperH Linux-based GNU system
 628   sh[34]*-*-linux-gnu* )
 629     machine=sh3 opsys=gnu-linux
 630   ;;
 631
 632   * )
 633     unported=yes
 634   ;;
 635 esac
 636
 637 ### If the code above didn't choose an operating system, just choose
 638 ### an operating system based on the configuration name.  You really
 639 ### only want to use this when you have no idea what the right
 640 ### operating system is; if you know what operating systems a machine
 641 ### runs, it's cleaner to make it explicit in the case statement
 642 ### above.
 643 if test x"${opsys}" = x; then
 644   case "${canonical}" in
 645     *-gnu* )                            opsys=gnu ;;
 646     * )
 647       unported=yes
 648     ;;
 649   esac
 650 fi
 651
 652 ]
 653 dnl quotation ends
 654
 655 if test $unported = yes; then
 656   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 657 Check `etc/MACHINES' for recognized configuration names.])
 658 fi
 659
 660 machfile="m/${machine}.h"
 661 opsysfile="s/${opsys}.h"
 662
 663
 664 #### Choose a compiler.
 665 test -n "$CC" && cc_specified=yes
 666
 667 # Save the value of CFLAGS that the user specified.
 668 SPECIFIED_CFLAGS="$CFLAGS"
 669
 670 dnl Sets GCC=yes if using gcc.
 671 AC_PROG_CC
 672
 673 # On Suns, sometimes $CPP names a directory.
 674 if test -n "$CPP" && test -d "$CPP"; then
 675   CPP=
 676 fi
 677
 678 ## If not using gcc, and on Solaris, and no CPP specified, see if
 679 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 680 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 681  test x"$CPP" = x; then
 682   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 683   AC_CACHE_VAL(emacs_cv_sunpro_c,
 684   [AC_TRY_LINK([],
 685 [#ifndef __SUNPRO_C
 686 fail;
 687 #endif
 688 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 689   AC_MSG_RESULT($emacs_cv_sunpro_c)
 690
 691   if test x"$emacs_cv_sunpro_c" = xyes; then
 692     NON_GNU_CPP="$CC -E -Xs"
 693   fi
 694 fi
 695
 696 #### Some systems specify a CPP to use unless we are using GCC.
 697 #### Now that we know whether we are using GCC, we can decide whether
 698 #### to use that one.
 699 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 700 then
 701   CPP="$NON_GNU_CPP"
 702 fi
 703
 704 #### Some systems specify a CC to use unless we are using GCC.
 705 #### Now that we know whether we are using GCC, we can decide whether
 706 #### to use that one.
 707 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 708   test x$cc_specified != xyes
 709 then
 710   CC="$NON_GNU_CC"
 711 fi
 712
 713 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 714 then
 715   CC="$CC $GCC_TEST_OPTIONS"
 716 fi
 717
 718 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 719 then
 720   CC="$CC $NON_GCC_TEST_OPTIONS"
 721 fi
 722
 723 dnl checks for Unix variants
 724 AC_USE_SYSTEM_EXTENSIONS
 725
 726 ### Use -Wno-pointer-sign if the compiler supports it
 727 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 728 SAVE_CFLAGS="$CFLAGS"
 729 CFLAGS="$CFLAGS -Wno-pointer-sign"
 730 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 731 if test $has_option = yes; then
 732    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 733 fi
 734 AC_MSG_RESULT($has_option)
 735 CFLAGS="$SAVE_CFLAGS"
 736 unset has_option
 737 unset SAVE_CFLAGS
 738
 739 ### Use -Wdeclaration-after-statement if the compiler supports it
 740 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 741 SAVE_CFLAGS="$CFLAGS"
 742 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 743 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 744 if test $has_option = yes; then
 745    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 746 fi
 747 AC_MSG_RESULT($has_option)
 748 CFLAGS="$SAVE_CFLAGS"
 749 unset has_option
 750 unset SAVE_CFLAGS
 751
 752 #### Some other nice autoconf tests.
 753
 754 dnl checks for programs
 755 AC_PROG_CPP
 756 AC_PROG_INSTALL
 757 if test "x$RANLIB" = x; then
 758   AC_PROG_RANLIB
 759 fi
 760
 761 ## Although we're running on an amd64 kernel, we're actually compiling for
 762 ## the x86 architecture.  The user should probably have provided an
 763 ## explicit --build to `configure', but if everything else than the kernel
 764 ## is running in i386 mode, we can help them out.
 765 if test "$machine" = "amdx86-64"; then
 766   AC_CHECK_DECL([i386])
 767   if test "$ac_cv_have_decl_i386" = "yes"; then
 768     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 769     machine=intel386
 770     machfile="m/${machine}.h"
 771   fi
 772 fi
 773
 774 AC_PATH_PROG(INSTALL_INFO, install-info)
 775 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 776 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 777 dnl Don't use GZIP, which is used by gzip for additional parameters.
 778 AC_PATH_PROG(GZIP_PROG, gzip)
 779
 780
 781 ## Need makeinfo >= 4.6 (?) to build the manuals.
 782 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 783 dnl By this stage, configure has already checked for egrep and set EGREP,
 784 dnl or exited with an error if no egrep was found.
 785 if test "$MAKEINFO" != "no" && \
 786   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 787    MAKEINFO=no
 788 fi
 789
 790 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 791 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 792 ## therefore in the category of "special tools" not normally required, which
 793 ## configure does not have to check for (eg autoconf itself).
 794 ## In a Bazaar checkout on the other hand, the manuals are not included.
 795 ## So makeinfo is a requirement to build from Bazaar, and configure
 796 ## should test for it as it does for any other build requirement.
 797 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 798 ## with pre-built manuals, from a Bazaar checkout.
 799 if test "$MAKEINFO" = "no"; then
 800   if test "x${with_makeinfo}" = "xno"; then
 801     MAKEINFO=off
 802   elif test ! -e $srcdir/info/emacs; then
 803     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 804 source tree does not seem to have pre-built manuals in the `info' directory.
 805 Either install a suitable version of makeinfo, or re-run configure
 806 with the `--without-makeinfo' option to build without the manuals.] )
 807   fi
 808 fi
 809
 810 dnl Add our options to ac_link now, after it is set up.
 811
 812 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 813 then
 814   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 815 fi
 816
 817 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 818 then
 819   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 820 fi
 821
 822 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 823 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 824 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 825 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 826 dnl if not built to support GNU ld.
 827
 828 late_LDFLAGS=$LDFLAGS
 829 if test "$GCC" = yes; then
 830   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 831 else
 832   LDFLAGS="$LDFLAGS -znocombreloc"
 833 fi
 834
 835 AC_MSG_CHECKING([for -znocombreloc])
 836 AC_LINK_IFELSE([main(){return 0;}],
 837   [AC_MSG_RESULT(yes)],
 838   LDFLAGS=$late_LDFLAGS
 839   [AC_MSG_RESULT(no)])
 840
 841 #### Extract some information from the operating system and machine files.
 842
 843 AC_CHECKING([the machine- and system-dependent files to find out
 844  - which libraries the lib-src programs will want, and
 845  - whether the GNU malloc routines are usable])
 846
 847 ### First figure out CFLAGS (which we use for running the compiler here)
 848 ### and REAL_CFLAGS (which we use for real compilation).
 849 ### The two are the same except on a few systems, where they are made
 850 ### different to work around various lossages.  For example,
 851 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 852 ### as implying static linking.
 853
 854 ### If the CFLAGS env var is specified, we use that value
 855 ### instead of the default.
 856
 857 ### It's not important that this name contain the PID; you can't run
 858 ### two configures in the same directory and have anything work
 859 ### anyway.
 860 tempcname="conftest.c"
 861
 862 echo '
 863 #include "'${srcdir}'/src/'${opsysfile}'"
 864 #include "'${srcdir}'/src/'${machfile}'"
 865
 866 configure___ LIBX=-lX11
 867
 868 #ifdef CANNOT_DUMP
 869 configure___ cannot_dump=yes
 870 #else
 871 configure___ cannot_dump=no
 872 #endif
 873
 874 #ifdef SYSTEM_MALLOC
 875 configure___ system_malloc=yes
 876 #else
 877 configure___ system_malloc=no
 878 #endif
 879
 880 #ifdef USE_MMAP_FOR_BUFFERS
 881 configure___ use_mmap_for_buffers=yes
 882 #else
 883 configure___ use_mmap_for_buffers=no
 884 #endif
 885
 886 #ifndef C_OPTIMIZE_SWITCH
 887 #ifdef __GNUC__
 888 #define C_OPTIMIZE_SWITCH -O2
 889 #else
 890 #define C_OPTIMIZE_SWITCH -O
 891 #endif
 892 #endif
 893
 894 #ifndef C_WARNINGS_SWITCH
 895 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 896 #endif
 897
 898 #ifdef THIS_IS_CONFIGURE
 899
 900 /* Get the CFLAGS for tests in configure.  */
 901 #ifdef __GNUC__
 902 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 903 #else
 904 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 905 #endif
 906
 907 #else /* not THIS_IS_CONFIGURE */
 908
 909 /* Get the CFLAGS for real compilation.  */
 910 #ifdef __GNUC__
 911 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 912 #else
 913 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 914 #endif
 915
 916 #endif /* not THIS_IS_CONFIGURE */
 917 ' > ${tempcname}
 918
 919 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 920
 921 # The value of CPP is a quoted variable reference, so we need to do this
 922 # to get its actual value...
 923 CPP=`eval "echo $CPP"`
 924 [eval `${CPP} -Isrc ${tempcname} \
 925        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 926 if test "x$SPECIFIED_CFLAGS" = x; then
 927   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 928          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 929 else
 930   REAL_CFLAGS="$CFLAGS"
 931 fi]
 932 rm ${tempcname}
 933
 934
 935 AC_SUBST(cannot_dump)
 936
 937 UNEXEC_OBJ=unexelf.o
 938 case "$opsys" in
 939   aix4-2)
 940    UNEXEC_OBJ=unexaix.o
 941    ;;
 942   cygwin)
 943    UNEXEC_OBJ=unexcw.o
 944    ;;
 945   darwin)
 946    UNEXEC_OBJ=unexmacosx.o
 947    ;;
 948   hpux10-20 | hpux11)
 949    UNEXEC_OBJ=unexhp9k800.o
 950    ;;
 951   sol2-10)
 952    # Use the Solaris dldump() function, called from unexsol.c, to dump
 953    # emacs, instead of the generic ELF dump code found in unexelf.c.
 954    # The resulting binary has a complete symbol table, and is better
 955    # for debugging and other observability tools (debuggers, pstack, etc).
 956    #
 957    # If you encounter a problem using dldump(), please consider sending
 958    # a message to the OpenSolaris tools-linking mailing list:
 959    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 960    #
 961    # It is likely that dldump() works with older Solaris too, but this has
 962    # not been tested, so for now this change is for Solaris 10 or newer.
 963    UNEXEC_OBJ=unexsol.o
 964    ;;
 965 esac
 966
 967 LD_SWITCH_SYSTEM=
 968 case "$opsys" in
 969   freebsd)
 970    ## Let `ld' find image libs and similar things in /usr/local/lib.
 971    ## The system compiler, GCC, has apparently been modified to not
 972    ## look there, contrary to what a stock GCC would do.
 973    LD_SWITCH_SYSTEM=-L/usr/local/lib
 974    ;;
 975
 976   gnu-linux)
 977    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 978    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 979    ;;
 980
 981   netbsd)
 982    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 983    ;;
 984
 985   openbsd)
 986    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 987    ## otherwise Emacs dumps core on elf systems.
 988    LD_SWITCH_SYSTEM="-Z"
 989    ;;
 990 esac
 991 AC_SUBST(LD_SWITCH_SYSTEM)
 992
 993 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 994
 995 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 996 ## which has not been defined yet.  When this was handled with cpp,
 997 ## it was expanded to null when configure sourced the s/*.h file.
 998 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 999 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1000 ## (or somesuch), but because it is supposed to go at the _front_
1001 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1002 ## Compare with the gnu-linux case below, which added to the end
1003 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1004 ## LD_SWITCH_SYSTEM_TEMACS.
1005 case "$opsys" in
1006   netbsd|openbsd)
1007    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
1008    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
1009 esac
1010
1011
1012 C_SWITCH_MACHINE=
1013 if test "$machine" = "alpha"; then
1014   AC_CHECK_DECL([__ELF__])
1015   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1016     ## With ELF, make sure that all common symbols get allocated to in the
1017     ## data section.  Otherwise, the dump of temacs may miss variables in
1018     ## the shared library that have been initialized.  For example, with
1019     ## GNU libc, __malloc_initialized would normally be resolved to the
1020     ## shared library's .bss section, which is fatal.
1021     if test "x$GCC" = "xyes"; then
1022       C_SWITCH_MACHINE="-fno-common"
1023     else
1024       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
1025     fi
1026   else
1027     UNEXEC_OBJ=unexalpha.o
1028   fi
1029 fi
1030 AC_SUBST(C_SWITCH_MACHINE)
1031
1032 AC_SUBST(UNEXEC_OBJ)
1033
1034 C_SWITCH_SYSTEM=
1035 ## Some programs in src produce warnings saying certain subprograms
1036 ## are too complex and need a MAXMEM value greater than 2000 for
1037 ## additional optimization.  --nils@exp-math.uni-essen.de
1038 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1039   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1040 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1041 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1042 AC_SUBST(C_SWITCH_SYSTEM)
1043
1044
1045 LIBS_SYSTEM=
1046 case "$opsys" in
1047   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1048   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1049
1050   freebsd) LIBS_SYSTEM="-lutil" ;;
1051
1052   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1053
1054   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1055
1056   ## Motif needs -lgen.
1057   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1058 esac
1059 AC_SUBST(LIBS_SYSTEM)
1060
1061
1062 ### Make sure subsequent tests use flags consistent with the build flags.
1063
1064 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1065   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1066 else
1067   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1068 fi
1069
1070 dnl For AC_FUNC_GETLOADAVG, at least:
1071 AC_CONFIG_LIBOBJ_DIR(src)
1072
1073 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1074 AC_SYS_LARGEFILE
1075
1076
1077 ## If user specified a crt-dir, use that unconditionally.
1078 if test "X$CRT_DIR" = "X"; then
1079
1080   case "$canonical" in
1081     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1082     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1083     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1084     ## For anything else (eg /usr/lib32), it is up the user to specify
1085     ## the location (bug#5655).
1086     ## Test for crtn.o, not just the directory, because sometimes the
1087     ## directory exists but does not have the relevant files (bug#1287).
1088     ## FIXME better to test for binary compatibility somehow.
1089     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1090     ;;
1091
1092     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1093   esac
1094
1095   case "$opsys" in
1096     hpux10-20) CRT_DIR=/lib ;;
1097   esac
1098
1099   ## Default is /usr/lib.
1100   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1101
1102 else
1103
1104   ## Some platforms don't use any of these files, so it is not
1105   ## appropriate to put this test outside the if block.
1106   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1107     AC_MSG_ERROR([crt*.o not found in specified location.])
1108
1109 fi
1110
1111 AC_SUBST(CRT_DIR)
1112
1113 LIB_MATH=-lm
1114 LIB_STANDARD=
1115 START_FILES=
1116
1117 case $opsys in
1118   cygwin )
1119     LIB_MATH=
1120     START_FILES='ecrt0.o'
1121     ;;
1122   darwin )
1123     ## Adding -lm confuses the dynamic linker, so omit it.
1124     LIB_MATH=
1125     START_FILES='pre-crt0.o'
1126     ;;
1127   freebsd )
1128     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1129     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1130     ;;
1131   gnu-linux | gnu-kfreebsd )
1132     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1133     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1134     ;;
1135   hpux10-20 | hpux11 )
1136     LIB_STANDARD=-lc
1137     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1138     ;;
1139   netbsd | openbsd )
1140     if test -f $CRT_DIR/crti.o; then
1141         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1142         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1143     else
1144         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1145         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1146     fi
1147     ;;
1148 esac
1149
1150 AC_SUBST(LIB_MATH)
1151 AC_SUBST(START_FILES)
1152
1153 dnl This function definition taken from Gnome 2.0
1154 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1155 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1156 dnl also defines GSTUFF_PKG_ERRORS on error
1157 AC_DEFUN([PKG_CHECK_MODULES], [
1158   succeeded=no
1159
1160   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1161
1162   if test "$PKG_CONFIG" = "no" ; then
1163      ifelse([$4], , [AC_MSG_ERROR([
1164       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1165   else
1166      PKG_CONFIG_MIN_VERSION=0.9.0
1167      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1168         AC_MSG_CHECKING(for $2)
1169
1170         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1171             AC_MSG_RESULT(yes)
1172             succeeded=yes
1173
1174             AC_MSG_CHECKING($1_CFLAGS)
1175             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1176             AC_MSG_RESULT($$1_CFLAGS)
1177
1178             AC_MSG_CHECKING($1_LIBS)
1179             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1180             AC_MSG_RESULT($$1_LIBS)
1181         else
1182             AC_MSG_RESULT(no)
1183             $1_CFLAGS=""
1184             $1_LIBS=""
1185             ## If we have a custom action on failure, don't print errors, but
1186             ## do set a variable so people can do so.
1187             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1188             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1189         fi
1190
1191         AC_SUBST($1_CFLAGS)
1192         AC_SUBST($1_LIBS)
1193      else
1194         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1195         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1196      fi
1197   fi
1198
1199   if test $succeeded = yes; then
1200      ifelse([$3], , :, [$3])
1201   else
1202      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1203   fi
1204 ])
1205
1206
1207 if test "${with_sound}" != "no"; then
1208   # Sound support for GNU/Linux and the free BSDs.
1209   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1210   # Emulation library used on NetBSD.
1211   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1212   AC_SUBST(LIBSOUND)
1213
1214   ALSA_REQUIRED=1.0.0
1215   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1216   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1217   if test $HAVE_ALSA = yes; then
1218     SAVE_CFLAGS="$CFLAGS"
1219     SAVE_LDFLAGS="$LDFLAGS"
1220     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1221     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1222     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1223                     emacs_alsa_normal=yes,
1224                     emacs_alsa_normal=no)
1225     if test "$emacs_alsa_normal" != yes; then
1226       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1227                      [snd_lib_error_set_handler (0);],
1228                      emacs_alsa_subdir=yes,
1229                      emacs_alsa_subdir=no)
1230       if test "$emacs_alsa_subdir" != yes; then
1231         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1232       fi
1233       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1234     fi
1235
1236     CFLAGS="$SAVE_CFLAGS"
1237     LDFLAGS="$SAVE_LDFLAGS"
1238     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1239     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1240     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1241   fi
1242   AC_SUBST(CFLAGS_SOUND)
1243 fi
1244
1245 dnl checks for header files
1246 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1247   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1248   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1249   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1250   sys/utsname.h pwd.h utmp.h)
1251
1252 AC_MSG_CHECKING(if personality LINUX32 can be set)
1253 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1254                emacs_cv_personality_linux32=yes,
1255                emacs_cv_personality_linux32=no)
1256 AC_MSG_RESULT($emacs_cv_personality_linux32)
1257
1258 if test $emacs_cv_personality_linux32 = yes; then
1259   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1260             [Define to 1 if personality LINUX32 can be set.])
1261 fi
1262
1263 dnl On Solaris 8 there's a compilation warning for term.h because
1264 dnl it doesn't define `bool'.
1265 AC_CHECK_HEADERS(term.h, , , -)
1266 AC_HEADER_STDC
1267 AC_HEADER_TIME
1268 AC_CHECK_DECLS([sys_siglist])
1269 if test $ac_cv_have_decl_sys_siglist != yes; then
1270   # For Tru64, at least:
1271   AC_CHECK_DECLS([__sys_siglist])
1272   if test $ac_cv_have_decl___sys_siglist = yes; then
1273     AC_DEFINE(sys_siglist, __sys_siglist,
1274               [Define to any substitute for sys_siglist.])
1275   fi
1276 fi
1277 AC_HEADER_SYS_WAIT
1278
1279 dnl Some systems have utime.h but don't declare the struct anyplace.
1280 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1281 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1282 #include <sys/time.h>
1283 #include <time.h>
1284 #else
1285 #ifdef HAVE_SYS_TIME_H
1286 #include <sys/time.h>
1287 #else
1288 #include <time.h>
1289 #endif
1290 #endif
1291 #ifdef HAVE_UTIME_H
1292 #include <utime.h>
1293 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1294   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1295 if test $emacs_cv_struct_utimbuf = yes; then
1296   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1297 fi
1298
1299 dnl checks for typedefs
1300 AC_TYPE_SIGNAL
1301
1302 dnl Check for speed_t typedef.
1303 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1304   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1305     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1306 if test $emacs_cv_speed_t = yes; then
1307   AC_DEFINE(HAVE_SPEED_T, 1,
1308            [Define to 1 if `speed_t' is declared by <termios.h>.])
1309 fi
1310
1311 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1312 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1313 #include <sys/time.h>
1314 #include <time.h>
1315 #else
1316 #ifdef HAVE_SYS_TIME_H
1317 #include <sys/time.h>
1318 #else
1319 #include <time.h>
1320 #endif
1321 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1322   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1323 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1324 if test $emacs_cv_struct_timeval = yes; then
1325   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1326 fi
1327
1328 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1329 AC_TRY_COMPILE([#include <math.h>],
1330 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1331   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1332 HAVE_EXCEPTION=$emacs_cv_struct_exception
1333 if test $emacs_cv_struct_exception != yes; then
1334   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1335 fi
1336
1337 AC_CHECK_HEADERS(sys/socket.h)
1338 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1339 #if HAVE_SYS_SOCKET_H
1340 #include <sys/socket.h>
1341 #endif])
1342
1343 dnl checks for structure members
1344 AC_STRUCT_TM
1345 AC_STRUCT_TIMEZONE
1346 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1347                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1348                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1349                 [#include <time.h>])
1350 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1351                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1352                   struct ifreq.ifr_addr], , ,
1353                  [AC_INCLUDES_DEFAULT
1354 #if HAVE_SYS_SOCKET_H
1355 #include <sys/socket.h>
1356 #endif
1357 #if HAVE_NET_IF_H
1358 #include <net/if.h>
1359 #endif])
1360
1361 dnl checks for compiler characteristics
1362
1363 dnl Testing __STDC__ to determine prototype support isn't good enough.
1364 dnl DEC C, for instance, doesn't define it with default options, and
1365 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1366 dnl and void *.
1367 AC_C_PROTOTYPES
1368 AC_C_VOLATILE
1369 AC_C_CONST
1370 dnl This isn't useful because we can't turn on use of `inline' unless
1371 dnl the compiler groks `extern inline'.
1372 dnl AC_C_INLINE
1373 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1374   [AC_TRY_COMPILE(, [void * foo;],
1375                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1376 if test $emacs_cv_void_star = yes; then
1377   AC_DEFINE(POINTER_TYPE, void)
1378 else
1379   AC_DEFINE(POINTER_TYPE, char)
1380 fi
1381 AH_TEMPLATE(POINTER_TYPE,
1382             [Define as `void' if your compiler accepts `void *'; otherwise
1383              define as `char'.])dnl
1384
1385
1386
1387 dnl This could be used for targets which can have both byte sexes.
1388 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1389 dnl AC_C_BIGENDIAN
1390
1391 dnl check for Make feature
1392 AC_PROG_MAKE_SET
1393
1394 DEPFLAGS=
1395 MKDEPDIR=":"
1396 deps_frag=deps.mk
1397 dnl check for GNU Make if we have GCC and autodepend is on.
1398 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1399    AC_MSG_CHECKING([whether we are using GNU Make])
1400    HAVE_GNU_MAKE=no
1401    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1402    if test "x$testval" != x; then
1403       HAVE_GNU_MAKE=yes
1404    else
1405       ac_enable_autodepend=no
1406    fi
1407    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1408    if test $HAVE_GNU_MAKE = yes; then
1409       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1410       SAVE_CFLAGS="$CFLAGS"
1411       CFLAGS="$CFLAGS -MMD -MF deps.d"
1412       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1413       CFLAGS="$SAVE_CFLAGS"
1414       test -f deps.d || ac_enable_autodepend=no
1415       rm -rf deps.d
1416       AC_MSG_RESULT([$ac_enable_autodepend])
1417    fi
1418    if test $ac_enable_autodepend = yes; then
1419       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1420       ## In parallel builds, another make might create depdir between
1421       ## the first test and mkdir, so stick another test on the end.
1422       ## Or use mkinstalldirs?  mkdir -p is not portable.
1423       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1424       deps_frag=autodeps.mk
1425    fi
1426 fi
1427 deps_frag=$srcdir/src/$deps_frag
1428 AC_SUBST(MKDEPDIR)
1429 AC_SUBST(DEPFLAGS)
1430 AC_SUBST_FILE(deps_frag)
1431
1432
1433 dnl checks for operating system services
1434 AC_SYS_LONG_FILE_NAMES
1435
1436 #### Choose a window system.
1437
1438 AC_PATH_X
1439 if test "$no_x" = yes; then
1440   window_system=none
1441 else
1442   window_system=x11
1443 fi
1444
1445 ## Workaround for bug in autoconf <= 2.62.
1446 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1447 ## No need to do anything special for these standard directories.
1448 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1449
1450    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1451
1452 fi
1453
1454 LD_SWITCH_X_SITE_AUX=
1455 LD_SWITCH_X_SITE_AUX_RPATH=
1456 if test "${x_libraries}" != NONE; then
1457   if test -n "${x_libraries}"; then
1458     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1459     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1460     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1461   fi
1462   x_default_search_path=""
1463   x_search_path=${x_libraries}
1464   if test -z "${x_search_path}"; then
1465     x_search_path=/usr/lib
1466   fi
1467   for x_library in `echo ${x_search_path}: | \
1468                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1469     x_search_path="\
1470 ${x_library}/X11/%L/%T/%N%C%S:\
1471 ${x_library}/X11/%l/%T/%N%C%S:\
1472 ${x_library}/X11/%T/%N%C%S:\
1473 ${x_library}/X11/%L/%T/%N%S:\
1474 ${x_library}/X11/%l/%T/%N%S:\
1475 ${x_library}/X11/%T/%N%S"
1476     if test x"${x_default_search_path}" = x; then
1477       x_default_search_path=${x_search_path}
1478     else
1479       x_default_search_path="${x_search_path}:${x_default_search_path}"
1480     fi
1481   done
1482 fi
1483 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1484 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1485
1486 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1487   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1488 fi
1489
1490 if test x"${x_includes}" = x; then
1491   bitmapdir=/usr/include/X11/bitmaps
1492 else
1493   # accumulate include directories that have X11 bitmap subdirectories
1494   bmd_acc="dummyval"
1495   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1496     if test -d "${bmd}/X11/bitmaps"; then
1497       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1498     fi
1499     if test -d "${bmd}/bitmaps"; then
1500       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1501     fi
1502   done
1503   if test ${bmd_acc} != "dummyval"; then
1504     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1505   fi
1506 fi
1507
1508 HAVE_NS=no
1509 NS_IMPL_COCOA=no
1510 NS_IMPL_GNUSTEP=no
1511 tmp_CPPFLAGS="$CPPFLAGS"
1512 tmp_CFLAGS="$CFLAGS"
1513 CPPFLAGS="$CPPFLAGS -x objective-c"
1514 CFLAGS="$CFLAGS -x objective-c"
1515 TEMACS_LDFLAGS2="\${LDFLAGS}"
1516 dnl I don't think it's especially important, but src/Makefile.in
1517 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1518 dnl trailing "/" to it, so now we do it here.
1519 if test "${with_ns}" != no; then
1520   if test "${opsys}" = darwin; then
1521      NS_IMPL_COCOA=yes
1522      ns_appdir=`pwd`/nextstep/Emacs.app/
1523      ns_appbindir=${ns_appdir}Contents/MacOS/
1524      ns_appresdir=${ns_appdir}Contents/Resources
1525      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1526   elif test -f $GNUSTEP_CONFIG_FILE; then
1527      NS_IMPL_GNUSTEP=yes
1528      ns_appdir=`pwd`/nextstep/Emacs.app/
1529      ns_appbindir=${ns_appdir}
1530      ns_appresdir=${ns_appdir}Resources
1531      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1532      dnl FIXME sourcing this several times in subshells seems inefficient.
1533      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1534      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1535      dnl I seemed to need these as well with GNUstep-startup 0.25.
1536      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1537      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1538      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1539        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1540      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1541        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1542      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1543      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1544      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1545      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1546      LIB_STANDARD=
1547      START_FILES=
1548      TEMACS_LDFLAGS2=
1549   fi
1550   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1551                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1552   files are missing or cannot be compiled.])])
1553   NS_HAVE_NSINTEGER=yes
1554   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1555                                      [NSInteger i;])],
1556                     ns_have_nsinteger=yes,
1557                     ns_have_nsinteger=no)
1558   if test $ns_have_nsinteger = no; then
1559     NS_HAVE_NSINTEGER=no
1560   fi
1561 fi
1562 AC_SUBST(TEMACS_LDFLAGS2)
1563
1564 ns_frag=/dev/null
1565 NS_OBJ=
1566 NS_SUPPORT=
1567 if test "${HAVE_NS}" = yes; then
1568   window_system=nextstep
1569   with_xft=no
1570   # set up packaging dirs
1571   exec_prefix=${ns_appbindir}
1572   libexecdir=${ns_appbindir}/libexec
1573   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1574      prefix=${ns_appresdir}
1575   fi
1576   ns_frag=$srcdir/src/ns.mk
1577   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1578   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1579 fi
1580 CFLAGS="$tmp_CFLAGS"
1581 CPPFLAGS="$tmp_CPPFLAGS"
1582 AC_SUBST(NS_OBJ)
1583 AC_SUBST(NS_SUPPORT)
1584 AC_SUBST(LIB_STANDARD)
1585 AC_SUBST_FILE(ns_frag)
1586
1587 case "${window_system}" in
1588   x11 )
1589     HAVE_X_WINDOWS=yes
1590     HAVE_X11=yes
1591     case "${with_x_toolkit}" in
1592       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1593       motif ) USE_X_TOOLKIT=MOTIF ;;
1594       gtk ) with_gtk=yes
1595 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1596 dnl USE_X_TOOLKIT is set.
1597             USE_X_TOOLKIT=none ;;
1598       no ) USE_X_TOOLKIT=none ;;
1599 dnl If user did not say whether to use a toolkit, make this decision later:
1600 dnl use the toolkit if we have gtk, or X11R5 or newer.
1601       * ) USE_X_TOOLKIT=maybe ;;
1602     esac
1603   ;;
1604   nextstep | none )
1605     HAVE_X_WINDOWS=no
1606     HAVE_X11=no
1607     USE_X_TOOLKIT=none
1608   ;;
1609 esac
1610
1611 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1612    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1613    if test "$HAVE_XSERVER" = true ||
1614       test -n "$DISPLAY" ||
1615       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1616         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1617 were found.  You should install the relevant development files for X
1618 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1619 sure you have development files for image handling, i.e.
1620 tiff, gif, jpeg, png and xpm.
1621 If you are sure you want Emacs compiled without X window support, pass
1622   --without-x
1623 to configure.])
1624    fi
1625 fi
1626
1627 ### If we're using X11, we should use the X menu package.
1628 HAVE_MENUS=no
1629 case ${HAVE_X11} in
1630   yes ) HAVE_MENUS=yes ;;
1631 esac
1632
1633 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1634 # Assume not, until told otherwise.
1635 GNU_MALLOC=yes
1636 doug_lea_malloc=yes
1637 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1638 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1639 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1640                emacs_cv_var___after_morecore_hook,
1641 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1642   emacs_cv_var___after_morecore_hook=yes,
1643   emacs_cv_var___after_morecore_hook=no)])
1644 if test $emacs_cv_var___after_morecore_hook = no; then
1645   doug_lea_malloc=no
1646 fi
1647
1648 if test "${system_malloc}" = "yes"; then
1649   GNU_MALLOC=no
1650   GNU_MALLOC_reason="
1651     (The GNU allocators don't work with this system configuration.)"
1652   GMALLOC_OBJ=
1653   VMLIMIT_OBJ=
1654 else
1655   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1656   VMLIMIT_OBJ=vm-limit.o
1657 fi
1658 AC_SUBST(GMALLOC_OBJ)
1659 AC_SUBST(VMLIMIT_OBJ)
1660
1661 if test "$doug_lea_malloc" = "yes" ; then
1662   if test "$GNU_MALLOC" = yes ; then
1663     GNU_MALLOC_reason="
1664       (Using Doug Lea's new malloc from the GNU C Library.)"
1665   fi
1666   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1667             [Define to 1 if you are using the GNU C Library.])
1668
1669   ## Use mmap directly for allocating larger buffers.
1670   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1671   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1672   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1673   case "$opsys" in
1674     gnu*) REL_ALLOC=no ;;
1675   esac
1676 fi
1677
1678 if test x"${REL_ALLOC}" = x; then
1679   REL_ALLOC=${GNU_MALLOC}
1680 fi
1681
1682 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1683 dnl the system configuration file (s/*.h) to turn the use of mmap
1684 dnl in the relocating allocator on.
1685
1686 AC_FUNC_MMAP
1687 if test $use_mmap_for_buffers = yes; then
1688   REL_ALLOC=no
1689 fi
1690
1691 LIBS="$LIBS_SYSTEM $LIBS"
1692
1693 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1694 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1695 AC_CHECK_LIB(dnet, dnet_ntoa)
1696 dnl This causes -lresolv to get used in subsequent tests,
1697 dnl which causes failures on some systems such as HPUX 9.
1698 dnl AC_CHECK_LIB(resolv, gethostbyname)
1699
1700 dnl FIXME replace main with a function we actually want from this library.
1701 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1702
1703 AC_CHECK_LIB(pthreads, cma_open)
1704
1705 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1706 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1707 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1708 ## added to LIBS in configure would never contain the pthreads part,
1709 ## but the value used in Makefiles might.  FIXME?
1710 ##
1711 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1712 ## be harmless on older versions of X where it happens to exist.
1713 test "$opsys" = "aix4-2" && \
1714   test $ac_cv_lib_pthreads_cma_open = yes && \
1715   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1716
1717 dnl Check for need for bigtoc support on IBM AIX
1718
1719 case ${host_os} in
1720 aix*)
1721   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1722     case $GCC in
1723     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1724     *) gdb_cv_bigtoc=-bbigtoc ;;
1725     esac
1726
1727     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1728     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1729   ])
1730   ;;
1731 esac
1732
1733 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1734 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1735 # REAL_CPPFLAGS later on.
1736
1737 REAL_CPPFLAGS="$CPPFLAGS"
1738
1739 if test "${HAVE_X11}" = "yes"; then
1740   DEFS="$C_SWITCH_X_SITE $DEFS"
1741   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1742   LIBS="$LIBX $LIBS"
1743   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1744   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1745
1746   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1747   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1748   # but it's more convenient here to set LD_RUN_PATH
1749   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1750   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1751     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1752     export LD_RUN_PATH
1753   fi
1754
1755   if test "${opsys}" = "gnu-linux"; then
1756     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1757     AC_TRY_LINK([],
1758      [XOpenDisplay ("foo");],
1759      [xlinux_first_failure=no],
1760      [xlinux_first_failure=yes])
1761     if test "${xlinux_first_failure}" = "yes"; then
1762       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1763       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1764       OLD_CPPFLAGS="$CPPFLAGS"
1765       OLD_LIBS="$LIBS"
1766       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1767       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1768       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1769       LIBS="$LIBS -b i486-linuxaout"
1770       AC_TRY_LINK([],
1771        [XOpenDisplay ("foo");],
1772        [xlinux_second_failure=no],
1773        [xlinux_second_failure=yes])
1774       if test "${xlinux_second_failure}" = "yes"; then
1775         # If we get the same failure with -b, there is no use adding -b.
1776         # So take it out.  This plays safe.
1777         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1778         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1779         CPPFLAGS="$OLD_CPPFLAGS"
1780         LIBS="$OLD_LIBS"
1781         AC_MSG_RESULT(no)
1782       else
1783         AC_MSG_RESULT(yes)
1784       fi
1785     else
1786       AC_MSG_RESULT(no)
1787     fi
1788   fi
1789
1790   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1791   # header files included from there.
1792   AC_MSG_CHECKING(for Xkb)
1793   AC_TRY_LINK([#include <X11/Xlib.h>
1794 #include <X11/XKBlib.h>],
1795         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1796         emacs_xkb=yes, emacs_xkb=no)
1797   AC_MSG_RESULT($emacs_xkb)
1798   if test $emacs_xkb = yes; then
1799     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1800   fi
1801
1802   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1803 XScreenNumberOfScreen XSetWMProtocols)
1804 fi
1805
1806 if test "${window_system}" = "x11"; then
1807   AC_MSG_CHECKING(X11 version 6)
1808   AC_CACHE_VAL(emacs_cv_x11_version_6,
1809   [AC_TRY_LINK([#include <X11/Xlib.h>],
1810 [#if XlibSpecificationRelease < 6
1811 fail;
1812 #endif
1813 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1814   if test $emacs_cv_x11_version_6 = yes; then
1815     AC_MSG_RESULT(6 or newer)
1816     AC_DEFINE(HAVE_X11R6, 1,
1817               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1818   else
1819     AC_MSG_RESULT(before 6)
1820   fi
1821 fi
1822
1823
1824 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1825 HAVE_RSVG=no
1826 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1827   if test "${with_rsvg}" != "no"; then
1828     RSVG_REQUIRED=2.11.0
1829     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1830
1831     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1832     AC_SUBST(RSVG_CFLAGS)
1833     AC_SUBST(RSVG_LIBS)
1834
1835     if test ".${RSVG_CFLAGS}" != "."; then
1836       HAVE_RSVG=yes
1837       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1838       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1839       LIBS="$RSVG_LIBS $LIBS"
1840     fi
1841   fi
1842 fi
1843
1844 HAVE_IMAGEMAGICK=no
1845 if test "${with_imagemagick}" != "no"; then
1846   IMAGEMAGICK_MODULE="Wand"
1847   PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, :, :)
1848   AC_SUBST(IMAGEMAGICK_CFLAGS)
1849   AC_SUBST(IMAGEMAGICK_LIBS)
1850
1851   if test ".${IMAGEMAGICK_CFLAGS}" != "."; then
1852     HAVE_IMAGEMAGICK=yes
1853     AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1854     CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1855     LIBS="$IMAGEMAGICK_LIBS $LIBS"
1856   fi
1857
1858   AC_DEFINE(HAVE_MAGICKEXPORTIMAGEPIXELS, 1, [Define to 1 if MagickExportImagePixels is defined.])
1859   AC_CHECK_FUNCS_ONCE(MagickExportImagePixels)
1860
1861 fi
1862
1863
1864 HAVE_GTK=no
1865 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1866   GLIB_REQUIRED=2.6
1867   GTK_REQUIRED=2.6
1868   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1869
1870   dnl Checks for libraries.
1871   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1872   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1873      AC_MSG_ERROR($GTK_PKG_ERRORS)
1874   fi
1875 fi
1876
1877
1878 GTK_OBJ=
1879 if test x"$pkg_check_gtk" = xyes; then
1880
1881   AC_SUBST(GTK_CFLAGS)
1882   AC_SUBST(GTK_LIBS)
1883   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1884   CFLAGS="$CFLAGS $GTK_CFLAGS"
1885   LIBS="$GTK_LIBS $LIBS"
1886   dnl Try to compile a simple GTK program.
1887   GTK_COMPILES=no
1888   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1889   if test "${GTK_COMPILES}" != "yes"; then
1890     if test "$USE_X_TOOLKIT" != "maybe"; then
1891       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1892     fi
1893   else
1894     HAVE_GTK=yes
1895     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1896     GTK_OBJ=gtkutil.o
1897     USE_X_TOOLKIT=none
1898     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1899       :
1900     else
1901       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1902        closing open displays.  This is no problem if you just use
1903        one display, but if you use more than one and close one of them
1904        Emacs may crash.]])
1905       sleep 3
1906     fi
1907   fi
1908
1909 fi
1910 AC_SUBST(GTK_OBJ)
1911
1912
1913 if test "${HAVE_GTK}" = "yes"; then
1914
1915   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1916   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1917   if test "$with_toolkit_scroll_bars" != no; then
1918     with_toolkit_scroll_bars=yes
1919   fi
1920
1921   dnl  Check if we can use multiple displays with this GTK version.
1922   dnl  If gdk_display_open exists, assume all others are there also.
1923   HAVE_GTK_MULTIDISPLAY=no
1924   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1925   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1926     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1927               [Define to 1 if GTK can handle more than one display.])
1928   fi
1929
1930   dnl  Check if we have the old file selection dialog declared and
1931   dnl  in the link library.  In 2.x it may be in the library,
1932   dnl  but not declared if deprecated featured has been selected out.
1933   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1934   HAVE_GTK_FILE_SELECTION=no
1935   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1936                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1937 #include <gtk/gtk.h>])
1938   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1939     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1940                    HAVE_GTK_FILE_SELECTION=no)
1941   fi
1942
1943   dnl  Check if we have the new file chooser dialog
1944   HAVE_GTK_FILE_CHOOSER=no
1945   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1946                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1947 #include <gtk/gtk.h>])
1948   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1949     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1950                    HAVE_GTK_FILE_CHOOSER=no)
1951   fi
1952
1953   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1954      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1955     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1956               [Define to 1 if GTK has both file selection and chooser dialog.])
1957   fi
1958
1959   dnl Check if pthreads are available.  Emacs only needs this when using
1960   dnl gtk_file_chooser under Gnome.
1961   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1962     HAVE_GTK_AND_PTHREAD=no
1963     AC_CHECK_HEADERS(pthread.h)
1964     if test "$ac_cv_header_pthread_h"; then
1965       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1966     fi
1967     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1968       case "${canonical}" in
1969         *-hpux*) ;;
1970         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1971       esac
1972       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1973                [Define to 1 if you have GTK and pthread (-lpthread).])
1974     fi
1975   fi
1976 fi
1977
1978 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1979 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1980 dnl also not configured.
1981 HAVE_DBUS=no
1982 DBUS_OBJ=
1983 if test "${with_dbus}" = "yes"; then
1984    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1985    if test "$HAVE_DBUS" = yes; then
1986      LIBS="$LIBS $DBUS_LIBS"
1987      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1988      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1989      DBUS_OBJ=dbusbind.o
1990    fi
1991 fi
1992 AC_SUBST(DBUS_OBJ)
1993
1994 dnl GConf has been tested under GNU/Linux only.
1995 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1996 HAVE_GCONF=no
1997 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1998    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1999    if test "$HAVE_GCONF" = yes; then
2000       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2001    fi
2002 fi
2003
2004 dnl SELinux is available for GNU/Linux only.
2005 HAVE_LIBSELINUX=no
2006 LIBSELINUX_LIBS=
2007 if test "${with_selinux}" = "yes"; then
2008    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2009    if test "$HAVE_LIBSELINUX" = yes; then
2010       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2011       LIBSELINUX_LIBS=-lselinux
2012    fi
2013 fi
2014 AC_SUBST(LIBSELINUX_LIBS)
2015
2016 dnl Do not put whitespace before the #include statements below.
2017 dnl Older compilers (eg sunos4 cc) choke on it.
2018 HAVE_XAW3D=no
2019 LUCID_LIBW=
2020 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2021   if test "$with_xaw3d" != no; then
2022     AC_MSG_CHECKING(for xaw3d)
2023     AC_CACHE_VAL(emacs_cv_xaw3d,
2024     [AC_TRY_LINK([
2025 #include <X11/Intrinsic.h>
2026 #include <X11/Xaw3d/Simple.h>],
2027       [],
2028       emacs_cv_xaw3d=yes,
2029       emacs_cv_xaw3d=no)])
2030   else
2031     emacs_cv_xaw3d=no
2032   fi
2033   if test $emacs_cv_xaw3d = yes; then
2034     AC_MSG_RESULT([yes; using Lucid toolkit])
2035     USE_X_TOOLKIT=LUCID
2036     HAVE_XAW3D=yes
2037     LUCID_LIBW=-lXaw3d
2038     AC_DEFINE(HAVE_XAW3D, 1,
2039               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2040   else
2041     AC_MSG_RESULT(no)
2042     AC_MSG_CHECKING(for libXaw)
2043     AC_CACHE_VAL(emacs_cv_xaw,
2044     [AC_TRY_LINK([
2045 #include <X11/Intrinsic.h>
2046 #include <X11/Xaw/Simple.h>],
2047       [],
2048       emacs_cv_xaw=yes,
2049       emacs_cv_xaw=no)])
2050     if test $emacs_cv_xaw = yes; then
2051       AC_MSG_RESULT([yes; using Lucid toolkit])
2052       USE_X_TOOLKIT=LUCID
2053       LUCID_LIBW=-lXaw
2054     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2055       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2056     else
2057       AC_MSG_RESULT([no; do not use toolkit by default])
2058       USE_X_TOOLKIT=none
2059     fi
2060   fi
2061 fi
2062
2063 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2064
2065 LIBXTR6=
2066 if test "${USE_X_TOOLKIT}" != "none"; then
2067   AC_MSG_CHECKING(X11 toolkit version)
2068   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2069   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2070 [#if XtSpecificationRelease < 6
2071 fail;
2072 #endif
2073 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2074   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2075   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2076     AC_MSG_RESULT(6 or newer)
2077     AC_DEFINE(HAVE_X11XTR6, 1,
2078               [Define to 1 if you have the X11R6 or newer version of Xt.])
2079     LIBXTR6="-lSM -lICE"
2080     case "$opsys" in
2081       ## Use libw.a along with X11R6 Xt.
2082       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2083     esac
2084   else
2085     AC_MSG_RESULT(before 6)
2086   fi
2087
2088 dnl If using toolkit, check whether libXmu.a exists.
2089 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2090   OLDLIBS="$LIBS"
2091   if test x$HAVE_X11XTR6 = xyes; then
2092     LIBS="-lXt -lSM -lICE $LIBS"
2093   else
2094     LIBS="-lXt $LIBS"
2095   fi
2096   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2097   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2098 fi
2099 AC_SUBST(LIBXTR6)
2100
2101 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2102 dnl Why not just test for libxmu in the normal way?
2103 LIBXMU=-lXmu
2104 case "$machine" in
2105   ## These machines don't supply Xmu.
2106   hpux* | aix4-2 )
2107     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2108     ;;
2109 esac
2110 AC_SUBST(LIBXMU)
2111
2112 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2113 if test "${HAVE_X11}" = "yes"; then
2114   if test "${USE_X_TOOLKIT}" != "none"; then
2115     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2116   fi
2117 fi
2118
2119 LIBXP=
2120 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2121   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2122   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2123     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2124 int x = 5;
2125 #else
2126 Motif version prior to 2.1.
2127 #endif],
2128     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2129   if test $emacs_cv_motif_version_2_1 = yes; then
2130     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2131   else
2132     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2133     # We put this in CFLAGS temporarily to precede other -I options
2134     # that might be in CFLAGS temporarily.
2135     # We put this in CPPFLAGS where it precedes the other -I options.
2136     OLD_CPPFLAGS=$CPPFLAGS
2137     OLD_CFLAGS=$CFLAGS
2138     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2139     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2140     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2141       [int x = 5;],
2142       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2143     if test $emacs_cv_lesstif = yes; then
2144       # Make sure this -I option remains in CPPFLAGS after it is set
2145       # back to REAL_CPPFLAGS.
2146       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2147       # have those other -I options anyway.  Ultimately, having this
2148       # directory ultimately in CPPFLAGS will be enough.
2149       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2150       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2151     else
2152       CFLAGS=$OLD_CFLAGS
2153       CPPFLAGS=$OLD_CPPFLAGS
2154     fi
2155   fi
2156 fi
2157
2158 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2159 dnl using Motif or Xaw3d is available, and unless
2160 dnl --with-toolkit-scroll-bars=no was specified.
2161
2162 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2163             [Define to 1 if we should use toolkit scroll bars.])dnl
2164 USE_TOOLKIT_SCROLL_BARS=no
2165 if test "${with_toolkit_scroll_bars}" != "no"; then
2166   if test "${USE_X_TOOLKIT}" != "none"; then
2167     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2168       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2169       HAVE_XAW3D=no
2170       USE_TOOLKIT_SCROLL_BARS=yes
2171     elif test "${HAVE_XAW3D}" = "yes"; then
2172       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2173       USE_TOOLKIT_SCROLL_BARS=yes
2174     fi
2175   elif test "${HAVE_GTK}" = "yes"; then
2176     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2177     USE_TOOLKIT_SCROLL_BARS=yes
2178   elif test "${HAVE_NS}" = "yes"; then
2179     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2180     USE_TOOLKIT_SCROLL_BARS=yes
2181   fi
2182 fi
2183
2184 dnl See if XIM is available.
2185 AC_TRY_COMPILE([
2186           #include <X11/Xlib.h>
2187           #include <X11/Xresource.h>],
2188          [XIMProc  callback;],
2189          [HAVE_XIM=yes
2190          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2191          HAVE_XIM=no)
2192
2193 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2194
2195 if test "${with_xim}" != "no"; then
2196   AC_DEFINE(USE_XIM, 1,
2197             [Define to 1 if we should use XIM, if it is available.])
2198 fi
2199
2200
2201 if test "${HAVE_XIM}" != "no"; then
2202   late_CFLAGS=$CFLAGS
2203   if test "$GCC" = yes; then
2204     CFLAGS="$CFLAGS --pedantic-errors"
2205   fi
2206   AC_TRY_COMPILE([
2207 #include <X11/Xlib.h>
2208 #include <X11/Xresource.h>],
2209 [Display *display;
2210 XrmDatabase db;
2211 char *res_name;
2212 char *res_class;
2213 XIMProc  callback;
2214 XPointer *client_data;
2215 #ifndef __GNUC__
2216 /* If we're not using GCC, it's probably not XFree86, and this is
2217    probably right, but we can't use something like --pedantic-errors.  */
2218 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2219                                            char*, XIMProc, XPointer*);
2220 #endif
2221 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2222    client_data);],
2223     [emacs_cv_arg6_star=yes])
2224   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2225          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2226 either XPointer or XPointer*.])dnl
2227   if test "$emacs_cv_arg6_star" = yes; then
2228     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2229   else
2230     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2231   fi
2232   CFLAGS=$late_CFLAGS
2233 fi
2234
2235 ### Start of font-backend (under any platform) section.
2236 # (nothing here yet -- this is a placeholder)
2237 ### End of font-backend (under any platform) section.
2238
2239 ### Start of font-backend (under X11) section.
2240 if test "${HAVE_X11}" = "yes"; then
2241    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2242
2243    ## Use -lXft if available, unless `--with-xft=no'.
2244    HAVE_XFT=maybe
2245     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2246       with_xft="no";
2247     fi
2248     if test "x${with_xft}" != "xno"; then
2249
2250       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2251       ## Because xftfont.c uses XRenderQueryExtension, we also
2252       ## need to link to -lXrender.
2253       HAVE_XRENDER=no
2254       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2255       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2256         OLD_CPPFLAGS="$CPPFLAGS"
2257         OLD_CFLAGS="$CFLAGS"
2258         OLD_LIBS="$LIBS"
2259         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2260         CFLAGS="$CFLAGS $XFT_CFLAGS"
2261         XFT_LIBS="-lXrender $XFT_LIBS"
2262         LIBS="$XFT_LIBS $LIBS"
2263         AC_CHECK_HEADER(X11/Xft/Xft.h,
2264           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2265
2266         if test "${HAVE_XFT}" = "yes"; then
2267           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2268             AC_SUBST(XFT_LIBS)
2269           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2270         else
2271           CPPFLAGS="$OLD_CPPFLAGS"
2272           CFLAGS="$OLD_CFLAGS"
2273           LIBS="$OLD_LIBS"
2274         fi                        # "${HAVE_XFT}" = "yes"
2275       fi                          # "$HAVE_XFT" != no
2276     fi                            # "x${with_xft}" != "xno"
2277
2278     dnl For the "Does Emacs use" message at the end.
2279     if test "$HAVE_XFT" != "yes"; then
2280        HAVE_XFT=no
2281     fi
2282
2283
2284     HAVE_FREETYPE=no
2285     ## We used to allow building with FreeType and without Xft.
2286     ## However, the ftx font backend driver is not in good shape.
2287     if test "${HAVE_XFT}" = "yes"; then
2288       dnl As we use Xft, we anyway use freetype.
2289       dnl There's no need for additional CFLAGS and LIBS.
2290       HAVE_FREETYPE=yes
2291       FONTCONFIG_CFLAGS=
2292       FONTCONFIG_LIBS=
2293     fi
2294
2295     HAVE_LIBOTF=no
2296     if test "${HAVE_FREETYPE}" = "yes"; then
2297       AC_DEFINE(HAVE_FREETYPE, 1,
2298                 [Define to 1 if using the freetype and fontconfig libraries.])
2299       if test "${with_libotf}" != "no"; then
2300         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2301                           HAVE_LIBOTF=no)
2302         if test "$HAVE_LIBOTF" = "yes"; then
2303           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2304           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2305                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2306                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2307           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2308             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2309                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2310           fi
2311         fi
2312       fi
2313     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2314     dnl Does the new font backend require it, or can it work without it?
2315     fi
2316
2317     HAVE_M17N_FLT=no
2318     if test "${HAVE_LIBOTF}" = yes; then
2319       if test "${with_m17n_flt}" != "no"; then
2320         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2321         if test "$HAVE_M17N_FLT" = "yes"; then
2322           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2323         fi
2324       fi
2325     fi
2326 else
2327     HAVE_XFT=no
2328     HAVE_FREETYPE=no
2329     HAVE_LIBOTF=no
2330     HAVE_M17N_FLT=no
2331 fi
2332
2333 ### End of font-backend (under X11) section.
2334
2335 AC_SUBST(FREETYPE_CFLAGS)
2336 AC_SUBST(FREETYPE_LIBS)
2337 AC_SUBST(FONTCONFIG_CFLAGS)
2338 AC_SUBST(FONTCONFIG_LIBS)
2339 AC_SUBST(LIBOTF_CFLAGS)
2340 AC_SUBST(LIBOTF_LIBS)
2341 AC_SUBST(M17N_FLT_CFLAGS)
2342 AC_SUBST(M17N_FLT_LIBS)
2343
2344 ### Use -lXpm if available, unless `--with-xpm=no'.
2345 HAVE_XPM=no
2346 LIBXPM=
2347 if test "${HAVE_X11}" = "yes"; then
2348   if test "${with_xpm}" != "no"; then
2349     AC_CHECK_HEADER(X11/xpm.h,
2350       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2351     if test "${HAVE_XPM}" = "yes"; then
2352       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2353       AC_EGREP_CPP(no_return_alloc_pixels,
2354       [#include "X11/xpm.h"
2355 #ifndef XpmReturnAllocPixels
2356 no_return_alloc_pixels
2357 #endif
2358       ], HAVE_XPM=no, HAVE_XPM=yes)
2359
2360       if test "${HAVE_XPM}" = "yes"; then
2361         AC_MSG_RESULT(yes)
2362       else
2363         AC_MSG_RESULT(no)
2364       fi
2365     fi
2366   fi
2367
2368   if test "${HAVE_XPM}" = "yes"; then
2369     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2370     LIBXPM=-lXpm
2371   fi
2372 fi
2373 AC_SUBST(LIBXPM)
2374
2375 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2376 HAVE_JPEG=no
2377 LIBJPEG=
2378 if test "${HAVE_X11}" = "yes"; then
2379   if test "${with_jpeg}" != "no"; then
2380     dnl Checking for jpeglib.h can lose because of a redefinition of
2381     dnl  HAVE_STDLIB_H.
2382     AC_CHECK_HEADER(jerror.h,
2383       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2384   fi
2385
2386   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2387   if test "${HAVE_JPEG}" = "yes"; then
2388     AC_DEFINE(HAVE_JPEG)
2389     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2390         [#include <jpeglib.h>
2391          version=JPEG_LIB_VERSION
2392 ],
2393         [AC_DEFINE(HAVE_JPEG)],
2394         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2395         HAVE_JPEG=no])
2396   fi
2397   if test "${HAVE_JPEG}" = "yes"; then
2398     LIBJPEG=-ljpeg
2399   fi
2400 fi
2401 AC_SUBST(LIBJPEG)
2402
2403 ### Use -lpng if available, unless `--with-png=no'.
2404 HAVE_PNG=no
2405 LIBPNG=
2406 if test "${HAVE_X11}" = "yes"; then
2407   if test "${with_png}" != "no"; then
2408     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2409     # in /usr/include/libpng.
2410     AC_CHECK_HEADERS(png.h libpng/png.h)
2411     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2412       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2413     fi
2414   fi
2415
2416   if test "${HAVE_PNG}" = "yes"; then
2417     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2418     LIBPNG="-lpng -lz -lm"
2419   fi
2420 fi
2421 AC_SUBST(LIBPNG)
2422
2423 ### Use -ltiff if available, unless `--with-tiff=no'.
2424 HAVE_TIFF=no
2425 LIBTIFF=
2426 if test "${HAVE_X11}" = "yes"; then
2427   if test "${with_tiff}" != "no"; then
2428     AC_CHECK_HEADER(tiffio.h,
2429       [tifflibs="-lz -lm"
2430       # At least one tiff package requires the jpeg library.
2431       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2432       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2433   fi
2434
2435   if test "${HAVE_TIFF}" = "yes"; then
2436     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2437     dnl FIXME -lz -lm, as per libpng?
2438     LIBTIFF=-ltiff
2439   fi
2440 fi
2441 AC_SUBST(LIBTIFF)
2442
2443 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2444 HAVE_GIF=no
2445 LIBGIF=
2446 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2447   AC_CHECK_HEADER(gif_lib.h,
2448 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2449 # Earlier versions can crash Emacs.
2450     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2451
2452   if test "$HAVE_GIF" = yes; then
2453     LIBGIF=-lgif
2454   elif test "$HAVE_GIF" = maybe; then
2455 # If gif_lib.h but no libgif, try libungif.
2456     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2457     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2458   fi
2459
2460   if test "${HAVE_GIF}" = "yes"; then
2461     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2462   fi
2463 fi
2464 AC_SUBST(LIBGIF)
2465
2466 dnl Check for required libraries.
2467 if test "${HAVE_X11}" = "yes"; then
2468   MISSING=""
2469   WITH_NO=""
2470   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2471     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2472   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2473     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2474   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2475     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2476   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2477     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2478   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2479     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2480
2481   if test "X${MISSING}" != X; then
2482     AC_MSG_ERROR([The following required libraries were not found:
2483     $MISSING
2484 Maybe some development libraries/packages are missing?
2485 If you don't want to link with them give
2486     $WITH_NO
2487 as options to configure])
2488   fi
2489 fi
2490
2491 ### Use -lgpm if available, unless `--with-gpm=no'.
2492 HAVE_GPM=no
2493 LIBGPM=
2494 MOUSE_SUPPORT=
2495 if test "${with_gpm}" != "no"; then
2496   AC_CHECK_HEADER(gpm.h,
2497     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2498
2499   if test "${HAVE_GPM}" = "yes"; then
2500     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2501     LIBGPM=-lgpm
2502     ## May be reset below.
2503     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2504   fi
2505 fi
2506 AC_SUBST(LIBGPM)
2507
2508 dnl Check for malloc/malloc.h on darwin
2509 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2510
2511 C_SWITCH_X_SYSTEM=
2512 ### Use NeXTstep API to implement GUI.
2513 if test "${HAVE_NS}" = "yes"; then
2514   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2515   if test "${NS_IMPL_COCOA}" = "yes"; then
2516     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2517     GNU_OBJC_CFLAGS=
2518   fi
2519   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2520     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2521     # See also .m.o rule in Makefile.in */
2522     # FIXME: are all these flags really needed?  Document here why.  */
2523     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2524     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2525   fi
2526   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2527     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2528   fi
2529   # We also have mouse menus.
2530   HAVE_MENUS=yes
2531   OTHER_FILES=ns-app
2532 fi
2533
2534
2535 ### Use session management (-lSM -lICE) if available
2536 HAVE_X_SM=no
2537 LIBXSM=
2538 if test "${HAVE_X11}" = "yes"; then
2539   AC_CHECK_HEADER(X11/SM/SMlib.h,
2540     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2541
2542   if test "${HAVE_X_SM}" = "yes"; then
2543     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2544     LIBXSM="-lSM -lICE"
2545     case "$LIBS" in
2546       *-lSM*) ;;
2547       *)      LIBS="$LIBXSM $LIBS" ;;
2548     esac
2549   fi
2550 fi
2551 AC_SUBST(LIBXSM)
2552
2553 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2554 AC_CACHE_CHECK(whether netdb declares h_errno,
2555                emacs_cv_netdb_declares_h_errno,
2556 [AC_TRY_LINK([#include <netdb.h>],
2557   [return h_errno;],
2558   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2559 if test $emacs_cv_netdb_declares_h_errno = yes; then
2560   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2561 fi
2562
2563 AC_FUNC_ALLOCA
2564
2565 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2566 dnl FIXME is there an autoconf test that does the right thing, without
2567 dnl needing to call A_M_E afterwards?
2568 if test x"$ac_cv_func_alloca_works" != xyes; then
2569    AC_MSG_ERROR( [a system implementation of alloca is required] )
2570 fi
2571
2572 # fmod, logb, and frexp are found in -lm on most systems.
2573 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2574 AC_CHECK_LIB(m, sqrt)
2575
2576 # Check for mail-locking functions in a "mail" library.  Probably this should
2577 # have the same check as for liblockfile below.
2578 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2579 if test $have_mail = yes; then
2580   LIBS_MAIL=-lmail
2581   LIBS="$LIBS_MAIL $LIBS"
2582   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2583 else
2584   LIBS_MAIL=
2585 fi
2586 dnl Debian, at least:
2587 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2588 if test $have_lockfile = yes; then
2589    LIBS_MAIL=-llockfile
2590    LIBS="$LIBS_MAIL $LIBS"
2591    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2592 else
2593 # If we have the shared liblockfile, assume we must use it for mail
2594 # locking (e.g. Debian).  If we couldn't link against liblockfile
2595 # (no liblockfile.a installed), ensure that we don't need to.
2596   dnl This works for files generally, not just executables.
2597   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2598   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2599                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2600   if test $ac_cv_prog_liblockfile = yes; then
2601     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2602 This probably means that movemail could lose mail.
2603 There may be a `development' package to install containing liblockfile.])
2604   fi
2605 fi
2606 AC_CHECK_FUNCS(touchlock)
2607 AC_CHECK_HEADERS(maillock.h)
2608 AC_SUBST(LIBS_MAIL)
2609
2610 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2611 ## interlock access to the mail spool.  The alternative is a lock file named
2612 ## /usr/spool/mail/$USER.lock.
2613 mail_lock=no
2614 case "$opsys" in
2615   aix4-2) mail_lock="lockf" ;;
2616
2617   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2618
2619   ## On GNU/Linux systems, both methods are used by various mail programs.
2620   ## I assume most people are using newer mailers that have heard of flock.
2621   ## Change this if you need to.
2622   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2623   ## configure gets the right answers, and that means *NOT* using flock.
2624   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2625   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2626   ## Debian maintainer hasn't provided a clean fix for Emacs.
2627   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2628   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2629   ## correct logic.  -- fx
2630   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2631   ## liblockfile is a Free Software replacement for libmail, used on
2632   ## Debian systems and elsewhere. -rfr.
2633   gnu-*)
2634     mail_lock="flock"
2635     if test $have_mail = yes || test $have_lockfile = yes; then
2636       test $ac_cv_header_maillock_h = yes && mail_lock=no
2637     fi
2638     ;;
2639 esac
2640
2641 BLESSMAIL_TARGET=
2642 case "$mail_lock" in
2643   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2644
2645   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2646
2647   *) BLESSMAIL_TARGET="need-blessmail" ;;
2648 esac
2649 AC_SUBST(BLESSMAIL_TARGET)
2650
2651
2652 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2653 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2654 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2655 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2656 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2657 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2658 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2659 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2660 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2661 cfmakeraw cfsetspeed isnan copysign)
2662
2663 AC_CHECK_HEADERS(sys/un.h)
2664
2665 AC_FUNC_MKTIME
2666 if test "$ac_cv_func_working_mktime" = no; then
2667   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2668 fi
2669
2670 AC_FUNC_GETLOADAVG
2671
2672 AC_FUNC_FSEEKO
2673
2674 # Configure getopt.
2675 m4_include([m4/getopt.m4])
2676 gl_GETOPT_IFELSE([
2677   gl_GETOPT_SUBSTITUTE_HEADER
2678   gl_PREREQ_GETOPT
2679   GETOPTOBJS='getopt.o getopt1.o'
2680 ])
2681 AC_SUBST(GETOPTOBJS)
2682
2683 AC_FUNC_GETPGRP
2684
2685 AC_FUNC_STRFTIME
2686
2687 # UNIX98 PTYs.
2688 AC_CHECK_FUNCS(grantpt)
2689
2690 # PTY-related GNU extensions.
2691 AC_CHECK_FUNCS(getpt)
2692
2693 # Check this now, so that we will NOT find the above functions in ncurses.
2694 # That is because we have not set up to link ncurses in lib-src.
2695 # It's better to believe a function is not available
2696 # than to expect to find it in ncurses.
2697 # Also we need tputs and friends to be able to build at all.
2698 have_tputs_et_al=true
2699 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2700 if test "$have_tputs_et_al" != true; then
2701   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2702 Maybe some development libraries/packages are missing?  Try installing
2703 libncurses-dev(el), libterminfo-dev(el) or similar.])
2704 fi
2705 # Must define this when any termcap library is found.
2706 AC_DEFINE(HAVE_LIBNCURSES, 1,
2707           [Define to 1 if you have the `ncurses' library (-lncurses).])
2708 ## FIXME This was the cpp logic, but I am not sure it is right.
2709 ## The above test has not necessarily found libncurses.
2710 HAVE_LIBNCURSES=yes
2711
2712 ## Use terminfo instead of termcap?
2713 ## Note only system files NOT using terminfo are:
2714 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2715 ## darwin|gnu without ncurses.
2716 TERMINFO=no
2717 LIBS_TERMCAP=
2718 case "$opsys" in
2719   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2720   ## hpux10-20: Use the system provided termcap(3) library.
2721   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2722   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2723   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2724
2725   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2726   ##  The ncurses library has been moved out of the System framework in
2727   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2728   ##  option to use it.
2729   darwin|gnu*)
2730     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2731     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2732       TERMINFO=yes
2733       LIBS_TERMCAP="-lncurses"
2734     fi
2735     ;;
2736
2737   freebsd)
2738     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2739     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2740     [AC_TRY_LINK([#include <osreldate.h>],
2741 [#if __FreeBSD_version < 400000
2742 fail;
2743 #endif
2744 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2745
2746     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2747
2748     if test $emacs_cv_freebsd_terminfo = yes; then
2749       TERMINFO=yes
2750       LIBS_TERMCAP="-lncurses"
2751     else
2752       LIBS_TERMCAP="-ltermcap"
2753     fi
2754     ;;
2755
2756   netbsd)
2757     if test $ac_cv_search_tputs = -lterminfo; then
2758       TERMINFO=yes
2759       LIBS_TERMCAP="-lterminfo"
2760     else
2761       LIBS_TERMCAP="-ltermcap"
2762     fi
2763     ;;
2764
2765 esac
2766
2767 case "$opsys" in
2768   ## hpux: Make sure we get select from libc rather than from libcurses
2769   ##  because libcurses on HPUX 10.10 has a broken version of select.
2770   ##  We used to use -lc -lcurses, but this may be cleaner.
2771   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2772
2773   openbsd) LIBS_TERMCAP="-lncurses" ;;
2774
2775   ## Must use system termcap, if we use any termcap.  It does special things.
2776   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2777 esac
2778
2779 TERMCAP_OBJ=tparam.o
2780 if test $TERMINFO = yes; then
2781   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2782
2783   ## Default used to be -ltermcap.  Add a case above if need something else.
2784   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2785
2786   TERMCAP_OBJ=terminfo.o
2787 fi
2788 AC_SUBST(LIBS_TERMCAP)
2789 AC_SUBST(TERMCAP_OBJ)
2790
2791
2792 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2793 resolv=no
2794 AC_TRY_LINK([#include <netinet/in.h>
2795 #include <arpa/nameser.h>
2796 #include <resolv.h>],
2797     [return res_init();],
2798     have_res_init=yes, have_res_init=no)
2799 if test "$have_res_init" = no; then
2800   OLIBS="$LIBS"
2801   LIBS="$LIBS -lresolv"
2802   AC_MSG_CHECKING(for res_init with -lresolv)
2803   AC_TRY_LINK([#include <netinet/in.h>
2804 #include <arpa/nameser.h>
2805 #include <resolv.h>],
2806     [return res_init();],
2807     have_res_init=yes, have_res_init=no)
2808   AC_MSG_RESULT($have_res_init)
2809   if test "$have_res_init" = yes ; then
2810     resolv=yes
2811   fi
2812   LIBS="$OLIBS"
2813 fi
2814
2815 if test "$have_res_init" = yes; then
2816   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2817 fi
2818
2819 # Do we need the Hesiod library to provide the support routines?
2820 LIBHESIOD=
2821 if test "$with_hesiod" != no ; then
2822   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2823   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2824      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2825                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2826   if test "$resolv" = yes ; then
2827     RESOLVLIB=-lresolv
2828   else
2829     RESOLVLIB=
2830   fi
2831   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2832         hesiod=yes, :, $RESOLVLIB)])
2833
2834   if test x"$hesiod" = xyes; then
2835     AC_DEFINE(HAVE_LIBHESIOD, 1,
2836               [Define to 1 if you have the hesiod library (-lhesiod).])
2837     LIBHESIOD=-lhesiod
2838   fi
2839 fi
2840 AC_SUBST(LIBHESIOD)
2841
2842 # Do we need libresolv (due to res_init or Hesiod)?
2843 if test "$resolv" = yes ; then
2844   AC_DEFINE(HAVE_LIBRESOLV, 1,
2845             [Define to 1 if you have the resolv library (-lresolv).])
2846   LIBRESOLV=-lresolv
2847 else
2848   LIBRESOLV=
2849 fi
2850 AC_SUBST(LIBRESOLV)
2851
2852 # These tell us which Kerberos-related libraries to use.
2853 COM_ERRLIB=
2854 CRYPTOLIB=
2855 KRB5LIB=
2856 DESLIB=
2857 KRB4LIB=
2858
2859 if test "${with_kerberos}" != no; then
2860   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2861   if test $have_com_err = yes; then
2862     COM_ERRLIB=-lcom_err
2863     LIBS="$COM_ERRLIB $LIBS"
2864     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2865   fi
2866   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2867   if test $have_crypto = yes; then
2868     CRYPTOLIB=-lcrypto
2869     LIBS="$CRYPTOLIB $LIBS"
2870     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2871   fi
2872   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2873   if test $have_k5crypto = yes; then
2874     CRYPTOLIB=-lk5crypto
2875     LIBS="$CRYPTOLIB $LIBS"
2876     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2877   fi
2878   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2879   if test $have_krb5=yes; then
2880     KRB5LIB=-lkrb5
2881     LIBS="$KRB5LIB $LIBS"
2882     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2883   fi
2884   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2885   if test "${with_kerberos5}" = no; then
2886     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2887     if test $have_des425 = yes; then
2888       DESLIB=-ldes425
2889       LIBS="$DESLIB $LIBS"
2890       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2891     else
2892       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2893       if test $have_des = yes; then
2894         DESLIB=-ldes
2895         LIBS="$DESLIB $LIBS"
2896         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2897       fi
2898     fi
2899     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2900     if test $have_krb4 = yes; then
2901       KRB4LIB=-lkrb4
2902       LIBS="$KRB4LIB $LIBS"
2903       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2904     else
2905       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2906       if test $have_krb = yes; then
2907         KRB4LIB=-lkrb
2908         LIBS="$KRB4LIB $LIBS"
2909         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2910       fi
2911     fi
2912   fi
2913
2914   if test "${with_kerberos5}" != no; then
2915     AC_CHECK_HEADERS(krb5.h,
2916       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2917                         [#include <krb5.h>])])
2918   else
2919     AC_CHECK_HEADERS(des.h,,
2920                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2921                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2922     AC_CHECK_HEADERS(krb.h,,
2923                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2924                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2925   fi
2926   AC_CHECK_HEADERS(com_err.h)
2927 fi
2928
2929 AC_SUBST(COM_ERRLIB)
2930 AC_SUBST(CRYPTOLIB)
2931 AC_SUBST(KRB5LIB)
2932 AC_SUBST(DESLIB)
2933 AC_SUBST(KRB4LIB)
2934
2935 # Solaris requires -lintl if you want strerror (which calls dgettext)
2936 # to return localized messages.
2937 AC_CHECK_LIB(intl, dgettext)
2938
2939 AC_MSG_CHECKING(whether localtime caches TZ)
2940 AC_CACHE_VAL(emacs_cv_localtime_cache,
2941 [if test x$ac_cv_func_tzset = xyes; then
2942 AC_TRY_RUN([#include <time.h>
2943 extern char **environ;
2944 unset_TZ ()
2945 {
2946   char **from, **to;
2947   for (to = from = environ; (*to = *from); from++)
2948     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2949       to++;
2950 }
2951 char TZ_GMT0[] = "TZ=GMT0";
2952 char TZ_PST8[] = "TZ=PST8";
2953 main()
2954 {
2955   time_t now = time ((time_t *) 0);
2956   int hour_GMT0, hour_unset;
2957   if (putenv (TZ_GMT0) != 0)
2958     exit (1);
2959   hour_GMT0 = localtime (&now)->tm_hour;
2960   unset_TZ ();
2961   hour_unset = localtime (&now)->tm_hour;
2962   if (putenv (TZ_PST8) != 0)
2963     exit (1);
2964   if (localtime (&now)->tm_hour == hour_GMT0)
2965     exit (1);
2966   unset_TZ ();
2967   if (localtime (&now)->tm_hour != hour_unset)
2968     exit (1);
2969   exit (0);
2970 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2971 [# If we have tzset, assume the worst when cross-compiling.
2972 emacs_cv_localtime_cache=yes])
2973 else
2974         # If we lack tzset, report that localtime does not cache TZ,
2975         # since we can't invalidate the cache if we don't have tzset.
2976         emacs_cv_localtime_cache=no
2977 fi])dnl
2978 AC_MSG_RESULT($emacs_cv_localtime_cache)
2979 if test $emacs_cv_localtime_cache = yes; then
2980   AC_DEFINE(LOCALTIME_CACHE, 1,
2981             [Define to 1 if localtime caches TZ.])
2982 fi
2983
2984 if test "x$HAVE_TIMEVAL" = xyes; then
2985   AC_CHECK_FUNCS(gettimeofday)
2986   if test $ac_cv_func_gettimeofday = yes; then
2987     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2988                    emacs_cv_gettimeofday_two_arguments,
2989     [AC_TRY_COMPILE([
2990 #ifdef TIME_WITH_SYS_TIME
2991 #include <sys/time.h>
2992 #include <time.h>
2993 #else
2994 #ifdef HAVE_SYS_TIME_H
2995 #include <sys/time.h>
2996 #else
2997 #include <time.h>
2998 #endif
2999 #endif],
3000       [struct timeval time;
3001        gettimeofday (&time, 0);],
3002       emacs_cv_gettimeofday_two_arguments=yes,
3003       emacs_cv_gettimeofday_two_arguments=no)])
3004     if test $emacs_cv_gettimeofday_two_arguments = no; then
3005       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3006                 [Define to 1 if gettimeofday accepts only one argument.])
3007     fi
3008   fi
3009 fi
3010
3011 ok_so_far=yes
3012 AC_CHECK_FUNC(socket, , ok_so_far=no)
3013 if test $ok_so_far = yes; then
3014   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3015 fi
3016 if test $ok_so_far = yes; then
3017   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3018 fi
3019 if test $ok_so_far = yes; then
3020 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3021   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3022             [Define to 1 if you have inet sockets.])
3023 fi
3024
3025 AC_CHECK_HEADERS(sys/ioctl.h)
3026
3027 if test -f /usr/lpp/X11/bin/smt.exp; then
3028   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3029             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3030 fi
3031
3032 AC_MSG_CHECKING(whether system supports dynamic ptys)
3033 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3034   AC_MSG_RESULT(yes)
3035   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3036 else
3037   AC_MSG_RESULT(no)
3038 fi
3039
3040 AC_FUNC_FORK
3041
3042 dnl Adapted from Haible's version.
3043 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3044   [AC_TRY_LINK([#include <langinfo.h>],
3045     [char* cs = nl_langinfo(CODESET);],
3046     emacs_cv_langinfo_codeset=yes,
3047     emacs_cv_langinfo_codeset=no)
3048   ])
3049 if test $emacs_cv_langinfo_codeset = yes; then
3050   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3051     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3052 fi
3053
3054 AC_CHECK_TYPES(size_t)
3055
3056 AC_TYPE_MBSTATE_T
3057
3058 dnl Restrict could probably be used effectively other than in regex.c.
3059 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3060   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3061                   emacs_cv_c_restrict=yes,
3062                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3063                                   emacs_cv_c_restrict=__restrict,
3064                                   emacs_cv_c_restrict=no)])])
3065 case "$emacs_cv_c_restrict" in
3066   yes) emacs_restrict=restrict;;
3067   no) emacs_restrict="";;
3068   *) emacs_restrict="$emacs_cv_c_restrict";;
3069 esac
3070 if test "$emacs_restrict" != __restrict; then
3071   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3072     [Define to compiler's equivalent of C99 restrict keyword.
3073      Don't define if equivalent is `__restrict'.])
3074 fi
3075
3076 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3077   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3078                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3079 if test "$emacs_cv_c_restrict_arr" = yes; then
3080   AC_DEFINE(__restrict_arr, __restrict,
3081     [Define to compiler's equivalent of C99 restrict keyword in array
3082      declarations.  Define as empty for no equivalent.])
3083 fi
3084
3085 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3086 dnl how the tty code is related to POSIX and/or other versions of termios.
3087 dnl The following looks like a useful start.
3088 dnl
3089 dnl AC_SYS_POSIX_TERMIOS
3090 dnl if test $ac_cv_sys_posix_termios = yes; then
3091 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3092 dnl                                and macros for terminal control.])
3093 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3094 dnl fi
3095
3096 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3097
3098 # Set up the CFLAGS for real compilation, so we can substitute it.
3099 CFLAGS="$REAL_CFLAGS"
3100 CPPFLAGS="$REAL_CPPFLAGS"
3101
3102 ## Hack to detect a buggy GCC version.
3103 if test "x$GCC" = xyes \
3104    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3105    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3106    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3107    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3108 fi
3109
3110 #### Find out which version of Emacs this is.
3111 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3112          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3113 if test x"${version}" = x; then
3114   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3115 fi
3116 if test x"${version}" != x"$PACKAGE_VERSION"; then
3117   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3118 fi
3119
3120 ### Specify what sort of things we'll be editing into Makefile and config.h.
3121 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3122 AC_SUBST(version)
3123 AC_SUBST(configuration)
3124 ## Unused?
3125 AC_SUBST(canonical)
3126 AC_SUBST(srcdir)
3127 AC_SUBST(prefix)
3128 AC_SUBST(exec_prefix)
3129 AC_SUBST(bindir)
3130 AC_SUBST(datadir)
3131 AC_SUBST(sharedstatedir)
3132 AC_SUBST(libexecdir)
3133 AC_SUBST(mandir)
3134 AC_SUBST(infodir)
3135 AC_SUBST(lispdir)
3136 AC_SUBST(locallisppath)
3137 AC_SUBST(lisppath)
3138 AC_SUBST(x_default_search_path)
3139 AC_SUBST(etcdir)
3140 AC_SUBST(archlibdir)
3141 AC_SUBST(docdir)
3142 AC_SUBST(bitmapdir)
3143 AC_SUBST(gamedir)
3144 AC_SUBST(gameuser)
3145 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3146 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3147 ## end of LIBX_BASE, but nothing ever set it.
3148 AC_SUBST(LD_SWITCH_X_SITE)
3149 AC_SUBST(C_SWITCH_X_SITE)
3150 AC_SUBST(C_SWITCH_X_SYSTEM)
3151 AC_SUBST(CFLAGS)
3152 ## Used in lwlib/Makefile.in.
3153 AC_SUBST(X_TOOLKIT_TYPE)
3154 AC_SUBST(machfile)
3155 AC_SUBST(opsysfile)
3156 AC_SUBST(GETLOADAVG_LIBS)
3157 AC_SUBST(ns_appdir)
3158 AC_SUBST(ns_appbindir)
3159 AC_SUBST(ns_appresdir)
3160 AC_SUBST(ns_appsrc)
3161 AC_SUBST(GNU_OBJC_CFLAGS)
3162 AC_SUBST(OTHER_FILES)
3163
3164 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3165                    [Define to the canonical Emacs configuration name.])
3166 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3167                    [Define to the options passed to configure.])
3168 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3169                    [Define to the used machine dependent file.])
3170 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3171                    [Define to the used os dependent file.])
3172
3173 XMENU_OBJ=
3174 XOBJ=
3175 FONT_OBJ=
3176 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3177   AC_DEFINE(HAVE_X_WINDOWS, 1,
3178             [Define to 1 if you want to use the X window system.])
3179   XMENU_OBJ=xmenu.o
3180   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3181   FONT_OBJ=xfont.o
3182   if test "$HAVE_XFT" = "yes"; then
3183     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3184   elif test "$HAVE_FREETYPE" = "yes"; then
3185     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3186   fi
3187   AC_SUBST(FONT_OBJ)
3188 fi
3189 AC_SUBST(XMENU_OBJ)
3190 AC_SUBST(XOBJ)
3191 AC_SUBST(FONT_OBJ)
3192
3193 WIDGET_OBJ=
3194 MOTIF_LIBW=
3195 if test "${USE_X_TOOLKIT}" != "none" ; then
3196   WIDGET_OBJ=widget.o
3197   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3198   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3199     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3200   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3201     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3202     MOTIF_LIBW=-lXm
3203     case "$opsys" in
3204       gnu-linux)
3205         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3206         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3207         ;;
3208
3209       unixware)
3210         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3211         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3212         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3213         ;;
3214
3215       aix4-2)
3216         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3217         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3218         ;;
3219     esac
3220     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3221   fi
3222 fi
3223 AC_SUBST(WIDGET_OBJ)
3224
3225 TOOLKIT_LIBW=
3226 case "$USE_X_TOOLKIT" in
3227   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3228   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3229   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3230 esac
3231 AC_SUBST(TOOLKIT_LIBW)
3232
3233 if test "$USE_X_TOOLKIT" = "none"; then
3234   LIBXT_OTHER="\$(LIBXSM)"
3235   OLDXMENU_TARGET="really-oldXMenu"
3236 else
3237   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3238   OLDXMENU_TARGET="really-lwlib"
3239 fi
3240 AC_SUBST(LIBXT_OTHER)
3241
3242 ## The X Menu stuff is present in the X10 distribution, but missing
3243 ## from X11.  If we have X10, just use the installed library;
3244 ## otherwise, use our own copy.
3245 if test "${HAVE_X11}" = "yes" ; then
3246   AC_DEFINE(HAVE_X11, 1,
3247             [Define to 1 if you want to use version 11 of X windows.
3248              Otherwise, Emacs expects to use version 10.])
3249
3250   if test "$USE_X_TOOLKIT" = "none"; then
3251     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3252   else
3253     OLDXMENU="\${lwlibdir}liblw.a"
3254   fi
3255   LIBXMENU="\$(OLDXMENU)"
3256   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3257   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3258 else
3259   ## For a syntactically valid Makefile; not actually used for anything.
3260   ## See comments in src/Makefile.in.
3261   OLDXMENU=nothing
3262   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3263   if test "${HAVE_X_WINDOWS}" = "yes"; then
3264     LIBXMENU="-lXMenu"
3265   else
3266     LIBXMENU=
3267   fi
3268   LIBX_OTHER=
3269   OLDXMENU_DEPS=
3270 fi
3271
3272 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3273   OLDXMENU_TARGET=
3274   OLDXMENU=nothing
3275   LIBXMENU=
3276   OLDXMENU_DEPS=
3277 fi
3278
3279 AC_SUBST(OLDXMENU_TARGET)
3280 AC_SUBST(OLDXMENU)
3281 AC_SUBST(LIBXMENU)
3282 AC_SUBST(LIBX_OTHER)
3283 AC_SUBST(OLDXMENU_DEPS)
3284
3285 if test "${HAVE_MENUS}" = "yes" ; then
3286   AC_DEFINE(HAVE_MENUS, 1,
3287             [Define to 1 if you have mouse menus.
3288              (This is automatic if you use X, but the option to specify it remains.)
3289              It is also defined with other window systems that support xmenu.c.])
3290 fi
3291
3292 if test "${GNU_MALLOC}" = "yes" ; then
3293   AC_DEFINE(GNU_MALLOC, 1,
3294             [Define to 1 if you want to use the GNU memory allocator.])
3295 fi
3296
3297 RALLOC_OBJ=
3298 if test "${REL_ALLOC}" = "yes" ; then
3299   AC_DEFINE(REL_ALLOC, 1,
3300             [Define REL_ALLOC if you want to use the relocating allocator for
3301              buffer space.])
3302
3303   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3304 fi
3305 AC_SUBST(RALLOC_OBJ)
3306
3307 if test "$opsys" = "cygwin"; then
3308   CYGWIN_OBJ="sheap.o"
3309   ## Cygwin differs because of its unexec().
3310   PRE_ALLOC_OBJ=
3311   POST_ALLOC_OBJ=lastfile.o
3312 else
3313   CYGWIN_OBJ=
3314   PRE_ALLOC_OBJ=lastfile.o
3315   POST_ALLOC_OBJ=
3316 fi
3317 AC_SUBST(CYGWIN_OBJ)
3318 AC_SUBST(PRE_ALLOC_OBJ)
3319 AC_SUBST(POST_ALLOC_OBJ)
3320
3321
3322 case "$opsys" in
3323   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3324
3325   darwin)
3326    ## The -headerpad option tells ld (see man page) to leave room at the
3327    ## end of the header for adding load commands.  Needed for dumping.
3328    ## 0x690 is the total size of 30 segment load commands (at 56
3329    ## each); under Cocoa 31 commands are required.
3330    if test "$HAVE_NS" = "yes"; then
3331      libs_nsgui="-framework AppKit"
3332      headerpad_extra=6C8
3333    else
3334      libs_nsgui=
3335      headerpad_extra=690
3336    fi
3337    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3338
3339    ## This is here because src/Makefile.in did some extra fiddling around
3340    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3341    ##   #ifndef LD_SWITCH_SYSTEM
3342    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3343    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3344    ## not using gcc, darwin system not on an alpha (ie darwin, since
3345    ## darwin + alpha does not occur).
3346    ## Because this was done in src/Makefile.in, the resulting part of
3347    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3348    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3349    ## rather than LD_SWITCH_SYSTEM.
3350    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3351      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3352    ;;
3353
3354   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3355   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3356   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3357   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3358   ## had different values in configure (in ac_link) and src/Makefile.in.
3359   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3360   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3361
3362   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3363 esac
3364
3365 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3366   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3367 fi
3368
3369 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3370
3371
3372 LINKER=
3373 ORDINARY_LINK=
3374 case "$opsys" in
3375   ## gnu: GNU needs its own crt0.
3376   aix4-2|darwin|gnu|usg5-4|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3377
3378   cygwin) LINKER="\$(CC)" ;;
3379
3380   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3381   ## library search parth, i.e. it won't search /usr/lib for libc and
3382   ## friends.  Using -nostartfiles instead avoids this problem, and
3383   ## will also work on earlier NetBSD releases.
3384   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3385
3386   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3387   ##   MkLinux/LinuxPPC needs this.
3388   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3389   gnu-*)
3390     case "$machine" in
3391       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3392     esac
3393     ;;
3394 esac
3395
3396
3397 PRE_EDIT_LDFLAGS=
3398 POST_EDIT_LDFLAGS=
3399 if test "x$ORDINARY_LINK" = "xyes"; then
3400
3401   LINKER="\$(CC)"
3402   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3403
3404 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3405 ## (bsd-common), freebsd, gnu-* not on macppc|ibms390x, hpux*.
3406 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3407
3408   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3409   ## places that are difficult to figure out at make time.  Fortunately,
3410   ## these same versions allow you to pass arbitrary flags on to the
3411   ## linker, so there is no reason not to use it as a linker.
3412   ##
3413   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3414   ## searching for libraries in its internal directories, so we have to
3415   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3416   LINKER="\$(CC) -nostdlib"
3417   ## GCC passes any argument prefixed with -Xlinker directly to the linker.
3418   ## See prefix-args.c for an explanation of why we do not do this with the
3419   ## shell''s ``for'' construct.  Note that sane people do not have '.' in
3420   ## their paths, so we must use ./prefix-args.
3421   ## TODO either make prefix-args check ORDINARY_LINK internally,
3422   ## or remove it altogether (bug#6184), removing the need for this hack.
3423   PRE_EDIT_LDFLAGS='`./prefix-args -Xlinker'
3424   POST_EDIT_LDFLAGS='`'
3425 fi
3426 AC_SUBST(PRE_EDIT_LDFLAGS)
3427 AC_SUBST(POST_EDIT_LDFLAGS)
3428
3429 test "x$LINKER" = "x" && LINKER=ld
3430 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3431 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3432
3433 AC_SUBST(LINKER)
3434
3435
3436 ## FIXME? The logic here is not precisely the same as that above.
3437 ## There is no check here for a pre-defined LINKER.
3438 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3439 LIB_GCC=
3440 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3441
3442   case "$opsys" in
3443     ## cygwin: don't link against static libgcc.
3444     cygwin|freebsd|netbsd|openbsd) LIB_GCC= ;;
3445
3446     gnu-*)
3447       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3448       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3449       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3450       if test "$machine" = "arm"; then
3451         LIB_GCC="-lgcc_s"
3452       else
3453         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3454         ## immediately undefine it again and redefine it to empty.
3455         ## Was the C_SWITCH_X_SITE part really necessary?
3456 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3457         LIB_GCC=
3458       fi
3459       ;;
3460
3461     ## Ask GCC where to find libgcc.a.
3462     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3463   esac
3464 fi                              dnl if $GCC
3465 AC_SUBST(LIB_GCC)
3466
3467
3468 TOOLTIP_SUPPORT=
3469 WINDOW_SUPPORT=
3470 ## If we're using X11/GNUstep, define some consequences.
3471 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3472   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3473   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3474   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3475   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3476
3477   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3478   test "$HAVE_X_WINDOWS" = "yes" && \
3479     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3480
3481 fi
3482 AC_SUBST(MOUSE_SUPPORT)
3483 AC_SUBST(TOOLTIP_SUPPORT)
3484 AC_SUBST(WINDOW_SUPPORT)
3485
3486
3487 AH_TOP([/* GNU Emacs site configuration template file.
3488    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3489      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3490
3491 This file is part of GNU Emacs.
3492
3493 GNU Emacs is free software: you can redistribute it and/or modify
3494 it under the terms of the GNU General Public License as published by
3495 the Free Software Foundation, either version 3 of the License, or
3496 (at your option) any later version.
3497
3498 GNU Emacs is distributed in the hope that it will be useful,
3499 but WITHOUT ANY WARRANTY; without even the implied warranty of
3500 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3501 GNU General Public License for more details.
3502
3503 You should have received a copy of the GNU General Public License
3504 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3505
3506
3507 /* No code in Emacs #includes config.h twice, but some bits of code
3508    intended to work with other packages as well (like gmalloc.c)
3509    think they can include it as many times as they like.  */
3510 #ifndef EMACS_CONFIG_H
3511 #define EMACS_CONFIG_H
3512 ])dnl
3513
3514 AH_BOTTOM([
3515 /* Define AMPERSAND_FULL_NAME if you use the convention
3516    that & in the full name stands for the login id.  */
3517 /* Turned on June 1996 supposing nobody will mind it.  */
3518 #define AMPERSAND_FULL_NAME
3519
3520 /* Define HAVE_SOUND if we have sound support.  We know it works
3521    and compiles only on the specified platforms.   For others,
3522    it probably doesn't make sense to try.  */
3523
3524 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
3525 #ifdef HAVE_MACHINE_SOUNDCARD_H
3526 #define HAVE_SOUND 1
3527 #endif
3528 #ifdef HAVE_SYS_SOUNDCARD_H
3529 #define HAVE_SOUND 1
3530 #endif
3531 #ifdef HAVE_SOUNDCARD_H
3532 #define HAVE_SOUND 1
3533 #endif
3534 #ifdef HAVE_ALSA
3535 #define HAVE_SOUND 1
3536 #endif
3537 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
3538
3539 /* If using GNU, then support inline function declarations.  */
3540 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3541    generally, because even if non-gcc compilers accept `inline', they
3542    may reject `extern inline'.  */
3543 #if defined (__GNUC__) && defined (OPTIMIZE)
3544 #define INLINE __inline__
3545 #else
3546 #define INLINE
3547 #endif
3548
3549 /* `subprocesses' should be defined if you want to
3550    have code for asynchronous subprocesses
3551    (as used in M-x compile and M-x shell).
3552    Only MSDOS does not support this (it overrides
3553    this in its config_opsysfile below).  */
3554
3555 #define subprocesses
3556
3557 /* Include the os and machine dependent files.  */
3558 #include config_opsysfile
3559 #include config_machfile
3560
3561 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3562   (There is probably a better place to do this, but right now the Cocoa
3563    side does this in s/darwin.h and we cannot
3564    parallel this exactly since GNUstep is multi-OS.  */
3565 #ifdef HAVE_NS
3566 # ifdef NS_IMPL_GNUSTEP
3567 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3568 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3569 #  define SYSTEM_PURESIZE_EXTRA 30000
3570 # endif /* NS_IMPL_GNUSTEP */
3571 #endif /* HAVE_NS */
3572
3573 /* SIGTYPE is the macro we actually use.  */
3574 #ifndef SIGTYPE
3575 #define SIGTYPE RETSIGTYPE
3576 #endif
3577
3578 #ifdef emacs /* Don't do this for lib-src.  */
3579 /* Tell regex.c to use a type compatible with Emacs.  */
3580 #define RE_TRANSLATE_TYPE Lisp_Object
3581 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3582 #ifdef make_number
3583 /* If make_number is a macro, use it.  */
3584 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3585 #else
3586 /* If make_number is a function, avoid it.  */
3587 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3588 #endif
3589 #endif
3590
3591 /* Avoid link-time collision with system mktime if we will use our own.  */
3592 #if ! HAVE_MKTIME || BROKEN_MKTIME
3593 #define mktime emacs_mktime
3594 #endif
3595
3596 #define my_strftime nstrftime   /* for strftime.c */
3597
3598 /* Some of the files of Emacs which are intended for use with other
3599    programs assume that if you have a config.h file, you must declare
3600    the type of getenv.  */
3601 extern char *getenv ();
3602
3603 /* These default definitions are good for almost all machines.
3604    The exceptions override them in m/MACHINE.h.  */
3605
3606 #ifndef BITS_PER_CHAR
3607 #define BITS_PER_CHAR 8
3608 #endif
3609
3610 #ifndef BITS_PER_SHORT
3611 #define BITS_PER_SHORT 16
3612 #endif
3613
3614 /* Note that lisp.h uses this in a preprocessor conditional, so it
3615    would not work to use sizeof.  That being so, we do all of them
3616    without sizeof, for uniformity's sake.  */
3617 #ifndef BITS_PER_INT
3618 #define BITS_PER_INT 32
3619 #endif
3620
3621 #ifndef BITS_PER_LONG
3622 #ifdef _LP64
3623 #define BITS_PER_LONG 64
3624 #else
3625 #define BITS_PER_LONG 32
3626 #endif
3627 #endif
3628
3629 /* Define if the compiler supports function prototypes.  It may do so
3630    but not define __STDC__ (e.g. DEC C by default) or may define it as
3631    zero.  */
3632 #undef PROTOTYPES
3633 /* For mktime.c:  */
3634 #ifndef __P
3635 # if defined PROTOTYPES
3636 #  define __P(args) args
3637 # else
3638 #  define __P(args) ()
3639 # endif  /* GCC.  */
3640 #endif /* __P */
3641
3642 #ifdef HAVE_STRING_H
3643 #include <string.h>
3644 #endif
3645
3646 #ifdef HAVE_STRINGS_H
3647 #include <strings.h>  /* May be needed for bcopy & al.  */
3648 #endif
3649
3650 #ifdef HAVE_STDLIB_H
3651 #include <stdlib.h>
3652 #endif
3653
3654 #ifdef HAVE_ALLOCA_H
3655 # include <alloca.h>
3656 #elif defined __GNUC__
3657 # define alloca __builtin_alloca
3658 #elif defined _AIX
3659 # define alloca __alloca
3660 #else
3661 # include <stddef.h>
3662 # ifdef  __cplusplus
3663 extern "C"
3664 # endif
3665 void *alloca (size_t);
3666 #endif
3667
3668 #ifndef HAVE_SIZE_T
3669 typedef unsigned size_t;
3670 #endif
3671
3672 /* Define HAVE_X_I18N if we have usable i18n support.  */
3673
3674 #ifdef HAVE_X11R6
3675 #define HAVE_X_I18N
3676 #endif
3677
3678 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3679
3680 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3681 #define HAVE_X11R6_XIM
3682 #endif
3683
3684 #if defined __GNUC__ && (__GNUC__ > 2 \
3685                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3686 #define NO_RETURN       __attribute__ ((__noreturn__))
3687 #else
3688 #define NO_RETURN       /* nothing */
3689 #endif
3690
3691 /* These won't be used automatically yet.  We also need to know, at least,
3692    that the stack is continuous.  */
3693 #ifdef __GNUC__
3694 #  ifndef GC_SETJMP_WORKS
3695   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3696 #    define GC_SETJMP_WORKS 1
3697 #  endif
3698 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3699 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3700 #  endif
3701 #endif
3702
3703 #ifndef HAVE_BCOPY
3704 #define bcopy(a,b,s) memcpy (b,a,s)
3705 #endif
3706 #ifndef HAVE_BZERO
3707 #define bzero(a,s) memset (a,0,s)
3708 #endif
3709 #ifndef HAVE_BCMP
3710 #define BCMP memcmp
3711 #endif
3712
3713 #endif /* EMACS_CONFIG_H */
3714
3715 /*
3716 Local Variables:
3717 mode: c
3718 End:
3719 */
3720 ])dnl
3721
3722 #### Report on what we decided to do.
3723 #### Report GTK as a toolkit, even if it doesn't use Xt.
3724 #### It makes printing result more understandable as using GTK sets
3725 #### toolkit_scroll_bars to yes by default.
3726 if test "${HAVE_GTK}" = "yes"; then
3727   USE_X_TOOLKIT=GTK
3728 fi
3729
3730 echo "
3731 Configured for \`${canonical}'.
3732
3733   Where should the build process find the source code?    ${srcdir}
3734   What operating system and machine description files should Emacs use?
3735         \`${opsysfile}' and \`${machfile}'
3736   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3737   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3738   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3739   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3740   What window system should Emacs use?                    ${window_system}
3741   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3742
3743 if test -n "${x_includes}"; then
3744 echo "  Where do we find X Windows header files?                ${x_includes}"
3745 else
3746 echo "  Where do we find X Windows header files?                Standard dirs"
3747 fi
3748 if test -n "${x_libraries}"; then
3749 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3750 else
3751 echo "  Where do we find X Windows libraries?                   Standard dirs"
3752 fi
3753
3754 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3755 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3756 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3757 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3758 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3759 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3760 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3761 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3762 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3763 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3764 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3765 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3766
3767 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3768 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3769 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3770 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3771
3772 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3773 echo
3774
3775 if test $USE_XASSERTS = yes; then
3776    echo "  Compiling with asserts turned on."
3777    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3778 fi
3779
3780 echo
3781
3782 if test "$HAVE_NS" = "yes"; then
3783    echo
3784    echo "You must run \"make install\" in order to test the built application.
3785 The installed application will go to nextstep/Emacs.app and can be
3786 run or moved from there."
3787    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3788       echo "The application will be fully self-contained."
3789     else
3790       echo "The lisp resources for the application will be installed under ${prefix}.
3791 You may need to run \"make install\" with sudo.  The application will fail
3792 to run if these resources are not installed."
3793    fi
3794    echo
3795 fi
3796
3797 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3798   echo "D-Bus integration has been tested for GNU/Linux only."
3799   echo
3800 fi
3801
3802
3803 # Remove any trailing slashes in these variables.
3804 [test "${prefix}" != NONE &&
3805   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3806 test "${exec_prefix}" != NONE &&
3807   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3808
3809 dnl You might wonder (I did) why epaths.h is generated by running make,
3810 dnl rather than just letting configure generate it from epaths.in.
3811 dnl One reason is that the various paths are not fully expanded (see above);
3812 dnl eg gamedir=${prefix}/var/games/emacs.
3813 dnl Secondly, the GNU Coding standards require that one should be able
3814 dnl to run `make prefix=/some/where/else' and override the values set
3815 dnl by configure.  This also explains the `move-if-change' test and
3816 dnl the use of force in the `epaths-force' rule in Makefile.in.
3817 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3818         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3819         doc/lispref/Makefile src/Makefile \
3820         lwlib/Makefile lisp/Makefile leim/Makefile, [
3821
3822 ### Make the necessary directories, if they don't exist.
3823 for dir in etc lisp ; do
3824   test -d ${dir} || mkdir ${dir}
3825 done
3826
3827 echo creating src/epaths.h
3828 ${MAKE-make} epaths-force
3829
3830 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3831   echo creating src/.gdbinit
3832   echo source $srcdir/src/.gdbinit > src/.gdbinit
3833 fi
3834
3835 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3836
3837 m4_if(dnl       Do not change this comment
3838    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3839 )dnl