code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 334 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 335 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 336
 337 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 338 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 339 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 340
 341 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 342 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 343 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 344 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 345 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 346 On by default on Mac OS X.])],[],[with_ns=maybe])
 347 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 348
 349 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 350 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 351 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 352 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 353 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 354 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 355 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 356 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 357
 358 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 359  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 360  [ case "${withval}" in
 361     y | ye | yes )      val=yes ;;
 362     n | no )            val=no  ;;
 363     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 364     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 365     g | gf | gfi | gfil | gfile )       val=gfile ;;
 366     w | w3 | w32 )      val=w32 ;;
 367     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 368 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 369 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 370 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 371     ;;
 372    esac
 373    with_file_notification=$val
 374  ],
 375  [with_file_notification=$with_features])
 376
 377 OPTION_DEFAULT_OFF([xwidgets],
 378   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 379
 380 ## For the times when you want to build Emacs but don't have
 381 ## a suitable makeinfo, and can live without the manuals.
 382 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 383 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 384
 385 ## This might be a 'configure' arg.
 386 AC_SUBST([ACLOCAL_PATH])
 387
 388 ## Makefile.in needs the cache file name.
 389 AC_SUBST(cache_file)
 390
 391 ## This is an option because I do not know if all info/man support
 392 ## compressed files, nor how to test if they do so.
 393 OPTION_DEFAULT_ON([compress-install],
 394   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 395 make GZIP_PROG= install])
 396
 397 AC_ARG_WITH(gameuser,dnl
 398 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 399                 [user for shared game score files.
 400                 An argument prefixed by ':' specifies a group instead.])])
 401 gameuser=
 402 gamegroup=
 403 # We don't test if we can actually chown/chgrp here, because configure
 404 # may run without root privileges.  lib-src/Makefile.in will handle
 405 # any errors due to missing user/group gracefully.
 406 case ${with_gameuser} in
 407   no) ;;
 408   "" | yes) gamegroup=games ;;
 409   :*) gamegroup=${with_gameuser#:} ;;
 410   *) gameuser=${with_gameuser} ;;
 411 esac
 412
 413 AC_ARG_WITH([gnustep-conf],dnl
 414 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 415    [name of GNUstep configuration file to use on systems where the command
 416     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 417     /etc/GNUstep/GNUstep.conf])])
 418 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 419   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 420 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 421      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 422
 423 AC_ARG_ENABLE(ns-self-contained,
 424 [AS_HELP_STRING([--disable-ns-self-contained],
 425                 [disable self contained build under NeXTstep])],
 426    EN_NS_SELF_CONTAINED=$enableval,
 427    EN_NS_SELF_CONTAINED=yes)
 428
 429 locallisppathset=no
 430 AC_ARG_ENABLE(locallisppath,
 431 [AS_HELP_STRING([--enable-locallisppath=PATH],
 432                 [directories Emacs should search for lisp files specific
 433                  to this site])],
 434 if test "${enableval}" = "no"; then
 435   locallisppath=
 436 elif test "${enableval}" != "yes"; then
 437   locallisppath=${enableval} locallisppathset=yes
 438 fi)
 439
 440 AC_ARG_ENABLE(checking,
 441 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 442                 [enable expensive run-time checks.  With LIST,
 443                  enable only specific categories of checks.
 444                  Categories are: all,yes,no.
 445                  Flags are: stringbytes, stringoverrun, stringfreelist,
 446                  xmallocoverrun, conslist, glyphs])],
 447 [ac_checking_flags="${enableval}"],[])
 448 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 449 for check in $ac_checking_flags
 450 do
 451         case $check in
 452         # these set all the flags to specific states
 453         yes)            ac_enable_checking=1 ;;
 454         no)             ac_enable_checking= ;
 455                         ac_gc_check_stringbytes= ;
 456                         ac_gc_check_string_overrun= ;
 457                         ac_gc_check_string_free_list= ;
 458                         ac_xmalloc_overrun= ;
 459                         ac_gc_check_cons_list= ;
 460                         ac_glyphs_debug= ;;
 461         all)            ac_enable_checking=1 ;
 462                         ac_gc_check_stringbytes=1 ;
 463                         ac_gc_check_string_overrun=1 ;
 464                         ac_gc_check_string_free_list=1 ;
 465                         ac_xmalloc_overrun=1 ;
 466                         ac_gc_check_cons_list=1 ;
 467                         ac_glyphs_debug=1 ;;
 468         # these enable particular checks
 469         stringbytes)    ac_gc_check_stringbytes=1 ;;
 470         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 471         stringfreelist) ac_gc_check_string_free_list=1 ;;
 472         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 473         conslist)       ac_gc_check_cons_list=1 ;;
 474         glyphs)         ac_glyphs_debug=1 ;;
 475         *)      AC_MSG_ERROR(unknown check category $check) ;;
 476         esac
 477 done
 478 IFS="$ac_save_IFS"
 479
 480 if test x$ac_enable_checking != x ; then
 481   AC_DEFINE(ENABLE_CHECKING, 1,
 482 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 483 fi
 484 if test x$ac_gc_check_stringbytes != x ; then
 485   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 486 [Define this temporarily to hunt a bug.  If defined, the size of
 487    strings is redundantly recorded in sdata structures so that it can
 488    be compared to the sizes recorded in Lisp strings.])
 489 fi
 490 if test x$ac_gc_check_string_overrun != x ; then
 491   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 492 [Define this to check for short string overrun.])
 493 fi
 494 if test x$ac_gc_check_string_free_list != x ; then
 495   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 496 [Define this to check the string free list.])
 497 fi
 498 if test x$ac_xmalloc_overrun != x ; then
 499   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 500 [Define this to check for malloc buffer overrun.])
 501 fi
 502 if test x$ac_gc_check_cons_list != x ; then
 503   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 504 [Define this to check for errors in cons list.])
 505 fi
 506 if test x$ac_glyphs_debug != x ; then
 507   AC_DEFINE(GLYPH_DEBUG, 1,
 508 [Define this to enable glyphs debugging code.])
 509 fi
 510
 511 AC_ARG_ENABLE(check-lisp-object-type,
 512 [AS_HELP_STRING([--enable-check-lisp-object-type],
 513                 [enable compile time checks for the Lisp_Object data type.
 514                 This is useful for development for catching certain types of bugs.])],
 515 if test "${enableval}" != "no"; then
 516    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 517    [Define this to enable compile time checks for the Lisp_Object data type.])
 518 fi)
 519
 520
 521 dnl The name of this option is unfortunate.  It predates, and has no
 522 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 523 dnl Actually, it stops it working.
 524 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 525 AC_ARG_ENABLE(profiling,
 526 [AS_HELP_STRING([--enable-profiling],
 527                 [build emacs with low-level, gprof profiling support.
 528                 Mainly useful for debugging Emacs itself.  May not work on
 529                 all platforms.  Stops profiler.el working.])],
 530 [ac_enable_profiling="${enableval}"],[])
 531 if test x$ac_enable_profiling != x ; then
 532    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 533 else
 534    PROFILING_CFLAGS=
 535 fi
 536 AC_SUBST(PROFILING_CFLAGS)
 537
 538 AC_ARG_ENABLE(autodepend,
 539 [AS_HELP_STRING([--enable-autodepend],
 540                 [automatically generate dependencies to .h-files.
 541                  Requires gcc, enabled if found.])],
 542 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 543
 544 AC_ARG_ENABLE(gtk-deprecation-warnings,
 545 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 546                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 547 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 548
 549 BUILD_DETAILS=
 550 AC_ARG_ENABLE([build-details],
 551   [AS_HELP_STRING([--disable-build-details],
 552                   [Make the build more deterministic by omitting host
 553                    names, time stamps, etc. from the output.])],
 554   [test "$enableval" = no && BUILD_DETAILS=--no-build-details])
 555 AC_SUBST([BUILD_DETAILS])
 556
 557 dnl This used to use changequote, but, apart from 'changequote is evil'
 558 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 559 dnl the great gob of text.  Thus it's not processed for possible expansion.
 560 dnl Just make sure the brackets remain balanced.
 561 dnl
 562 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 563 dnl indicated by comments.
 564 dnl quotation begins
 565 [
 566
 567 ### If you add support for a new configuration, add code to this
 568 ### switch statement to recognize your configuration name and select
 569 ### the appropriate opsys.
 570
 571 ### As far as handling version numbers on operating systems is
 572 ### concerned, make sure things will fail in a fixable way.  If
 573 ### /etc/MACHINES doesn't say anything about version numbers, be
 574 ### prepared to handle anything reasonably.  If version numbers
 575 ### matter, be sure /etc/MACHINES says something about it.
 576
 577 opsys='' unported=no
 578 case "${canonical}" in
 579
 580   ## GNU/Linux and similar ports
 581   *-*-linux* )
 582     opsys=gnu-linux
 583   ;;
 584
 585   ## FreeBSD ports
 586   *-*-freebsd* )
 587     opsys=freebsd
 588   ;;
 589
 590   ## DragonFly ports
 591   *-*-dragonfly* )
 592     opsys=dragonfly
 593   ;;
 594
 595   ## FreeBSD kernel + glibc based userland
 596   *-*-kfreebsd*gnu* )
 597     opsys=gnu-kfreebsd
 598   ;;
 599
 600   ## NetBSD ports
 601   *-*-netbsd* )
 602     opsys=netbsd
 603   ;;
 604
 605   ## OpenBSD ports
 606   *-*-openbsd* | *-*-mirbsd* )
 607     opsys=openbsd
 608   ;;
 609
 610   ## Apple Darwin / Mac OS X
 611   *-apple-darwin* )
 612     case "${canonical}" in
 613       *-apple-darwin[0-9].*) unported=yes ;;
 614       i[3456]86-* | x86_64-* )  ;;
 615       * )            unported=yes ;;
 616     esac
 617     opsys=darwin
 618     ## FIXME: Find a way to use Fink if available (Bug#11507).
 619   ;;
 620
 621   ## Chromium Native Client
 622   *-nacl )
 623     opsys=nacl
 624   ;;
 625
 626   ## Cygwin ports
 627   *-*-cygwin )
 628     opsys=cygwin
 629   ;;
 630
 631   ## HP 9000 series 700 and 800, running HP/UX
 632   hppa*-hp-hpux10.2* )
 633     opsys=hpux10-20
 634   ;;
 635   hppa*-hp-hpux1[1-9]* )
 636     opsys=hpux11
 637     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 638   ;;
 639
 640   ## IBM machines
 641   rs6000-ibm-aix4.[23]* )
 642     opsys=aix4-2
 643   ;;
 644   powerpc-ibm-aix4.[23]*  )
 645     opsys=aix4-2
 646   ;;
 647   rs6000-ibm-aix[56]* )
 648     opsys=aix4-2
 649   ;;
 650   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 651     opsys=aix4-2
 652   ;;
 653
 654   ## Suns
 655   *-sun-solaris* \
 656     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 657     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 658     case "${canonical}" in
 659       i[3456]86-*-* )   ;;
 660       amd64-*-*|x86_64-*-*) ;;
 661       sparc* )          ;;
 662       * )               unported=yes ;;
 663     esac
 664     case "${canonical}" in
 665       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 666                 opsys=sol2-10
 667                 emacs_check_sunpro_c=yes
 668                 ;;
 669       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 670       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 671       *-sunos5.6* | *-solaris2.6* )
 672                 opsys=sol2-6
 673                 RANLIB="ar -ts"
 674                 ;;
 675       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 676       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 677                 opsys=sol2-6
 678                 emacs_check_sunpro_c=yes
 679                 ;;
 680     esac
 681     ## Watch out for a compiler that we know will not work.
 682     case "${canonical}" in
 683      *-solaris* | *-sunos5* )
 684                 if [ "x$CC" = x/usr/ucb/cc ]; then
 685                   ## /usr/ucb/cc doesn't work;
 686                   ## we should find some other compiler that does work.
 687                   unset CC
 688                 fi
 689                 ;;
 690       *) ;;
 691     esac
 692   ;;
 693
 694   ## Intel 386 machines where we don't care about the manufacturer.
 695   i[3456]86-*-* )
 696     case "${canonical}" in
 697       *-darwin* )               opsys=darwin ;;
 698       *-mingw* )
 699                 opsys=mingw32
 700                 # MinGW overrides and adds some system headers in nt/inc.
 701                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 702                 ;;
 703       *-sysv4.2uw* )            opsys=unixware ;;
 704       *-sysv5uw* )              opsys=unixware ;;
 705       *-sysv5OpenUNIX* )        opsys=unixware ;;
 706       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 707     esac
 708   ;;
 709
 710   # MinGW64
 711   x86_64-*-* )
 712     case "${canonical}" in
 713       *-mingw* )
 714                 opsys=mingw32
 715                 # MinGW overrides and adds some system headers in nt/inc.
 716                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 717                 ;;
 718       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 719     esac
 720   ;;
 721
 722   * )
 723     unported=yes
 724   ;;
 725 esac
 726
 727 ### If the code above didn't choose an operating system, just choose
 728 ### an operating system based on the configuration name.  You really
 729 ### only want to use this when you have no idea what the right
 730 ### operating system is; if you know what operating systems a machine
 731 ### runs, it's cleaner to make it explicit in the case statement
 732 ### above.
 733 if test x"${opsys}" = x; then
 734   case "${canonical}" in
 735     *-gnu* )                            opsys=gnu ;;
 736     * )
 737       unported=yes
 738     ;;
 739   esac
 740 fi
 741
 742 ]
 743 dnl quotation ends
 744
 745 if test $unported = yes; then
 746   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 747 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 748 Check 'etc/MACHINES' for recognized configuration names.])
 749 fi
 750
 751 #### Choose a compiler.
 752
 753 dnl Don't bother to test for C89.
 754 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 755
 756 dnl Sets GCC=yes if using gcc.
 757 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 758 if test -n "$XCRUN"; then
 759   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 760   test -n "$AR" && export AR
 761 fi
 762
 763 dnl Emacs needs C99 or later.
 764 gl_PROG_CC_C99
 765
 766 AM_PROG_CC_C_O
 767
 768 if test x$GCC = xyes; then
 769   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 770 fi
 771
 772 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 773 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 774 dnl that clash with MinGW.
 775 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 776
 777 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 778 AC_DEFUN([gl_CRYPTO_CHECK])
 779 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 780 # as we don't use them.
 781 AC_DEFUN([gl_FCNTL_O_FLAGS])
 782 # Avoid gnulib's test for pthread_sigmask.
 783 funcs=
 784 for func in $ac_func_list; do
 785   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 786 done
 787 ac_func_list=$funcs
 788 # Use the system putenv even if it lacks GNU features, as we don't need them,
 789 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 790 AC_CHECK_FUNCS_ONCE([putenv])
 791 AC_DEFUN([gl_FUNC_PUTENV],
 792   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 793
 794 # Initialize gnulib right after choosing the compiler.
 795 dnl Amongst other things, this sets AR and ARFLAGS.
 796 gl_EARLY
 797
 798 if test "$ac_test_CFLAGS" != set; then
 799   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 800   # if -g3 works and the user does not specify CFLAGS.
 801   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 802   case $CFLAGS in
 803     '-g')
 804       emacs_g3_CFLAGS='-g3';;
 805     '-g -O2')
 806       emacs_g3_CFLAGS='-g3 -O2';;
 807     *)
 808       emacs_g3_CFLAGS='';;
 809   esac
 810   if test -n "$emacs_g3_CFLAGS"; then
 811     emacs_save_CFLAGS=$CFLAGS
 812     CFLAGS=$emacs_g3_CFLAGS
 813     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 814       [emacs_cv_prog_cc_g3],
 815       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 816          [emacs_cv_prog_cc_g3=yes],
 817          [emacs_cv_prog_cc_g3=no])])
 818     if test $emacs_cv_prog_cc_g3 != yes; then
 819       CFLAGS=$emacs_save_CFLAGS
 820     fi
 821     if test $opsys = mingw32; then
 822       CFLAGS="$CFLAGS -gdwarf-2"
 823     fi
 824   fi
 825
 826   case $CFLAGS in
 827     *-O*) ;;
 828     *)
 829       # No optimization flag was inferred for this non-GCC compiler.
 830       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 831       emacs_save_CFLAGS=$CFLAGS
 832       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 833       CFLAGS=${CFLAGS}-O
 834       AC_CACHE_CHECK([whether $CC accepts -O],
 835         [emacs_cv_prog_cc_o],
 836         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 837            [emacs_cv_prog_cc_o=yes],
 838            [emacs_cv_prog_cc_o=no])])
 839       if test $emacs_cv_prog_cc_o != yes; then
 840         CFLAGS=$emacs_save_CFLAGS
 841       fi ;;
 842   esac
 843 fi
 844
 845 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 846 # ---------------------------------------------------------------------------
 847 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 848 # Otherwise, run RUN-IF-NOT-FOUND.
 849 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 850   [AC_PREPROC_IFELSE(
 851     [AC_LANG_PROGRAM(
 852       [[
 853 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 854 /* ok */
 855 #else
 856 # error "your version of gcc is older than $1.$2"
 857 #endif
 858       ]]),
 859     ], [$3], [$4])
 860   ]
 861 )
 862
 863 AC_ARG_ENABLE([gcc-warnings],
 864   [AS_HELP_STRING([--enable-gcc-warnings@<:@=TYPE@:>@],
 865                   [control generation of GCC warnings.  The TYPE 'yes'
 866                    means to fail if any warnings are issued; 'warn-only'
 867                    means issue warnings without failing (default for
 868                    developer builds); 'no' means disable warnings
 869                    (default for non-developer builds).])],
 870   [case $enableval in
 871      yes|no|warn-only) ;;
 872      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 873    esac
 874    gl_gcc_warnings=$enableval],
 875   [# By default, use 'warn-only' if it looks like the invoker of 'configure'
 876    # is a developer as opposed to a builder.  This is most likely true
 877    # if GCC is recent enough and there is a .git subdirectory;
 878    # however, if there is also a .tarball-version file it is probably
 879    # just a release imported into Git for patch management.
 880    gl_gcc_warnings=no
 881    test -d "$srcdir"/.git && test ! -f "$srcdir"/.tarball-version &&
 882      gl_GCC_VERSION_IFELSE([5], [3], [gl_gcc_warnings=warn-only])]
 883 )
 884
 885 # clang is unduly picky about some things.
 886 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 887   [AC_COMPILE_IFELSE(
 888      [AC_LANG_PROGRAM([[
 889           #ifndef __clang__
 890             error "not clang";
 891           #endif
 892         ]])],
 893      [emacs_cv_clang=yes],
 894      [emacs_cv_clang=no])])
 895
 896 # When compiling with GCC, prefer -isystem to -I when including system
 897 # include files, to avoid generating useless diagnostics for the files.
 898 AS_IF([test $gl_gcc_warnings = no],
 899  [
 900   isystem='-I'
 901   AS_IF([test "$emacs_cv_clang" = yes],
 902    [
 903      # Turn off some warnings if supported.
 904      gl_WARN_ADD([-Wno-switch])
 905      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 906      gl_WARN_ADD([-Wno-pointer-sign])
 907      gl_WARN_ADD([-Wno-string-plus-int])
 908      gl_WARN_ADD([-Wno-unknown-attributes])
 909    ])
 910  ],[
 911   isystem='-isystem '
 912
 913   # This, $nw, is the list of warnings we disable.
 914   nw=
 915
 916   case $with_x_toolkit in
 917     lucid | athena | motif)
 918        # Old toolkits mishandle 'const'.
 919        nw="$nw -Wwrite-strings"
 920        ;;
 921   esac
 922   AS_IF([test $gl_gcc_warnings = yes],
 923     [gl_WARN_ADD([-Werror], [WERROR_CFLAGS])])
 924   AC_SUBST([WERROR_CFLAGS])
 925
 926   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 927   nw="$nw -Woverlength-strings"     # Not a problem these days
 928   nw="$nw -Wformat-nonliteral"      # we do this a lot
 929   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 930   nw="$nw -Wswitch-default"         # Too many warnings for now
 931   nw="$nw -Winline"                 # OK to ignore 'inline'
 932   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 933                                     # signed overflow has undefined behavior
 934   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 935   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 936   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 937
 938   # Emacs doesn't care about shadowing; see
 939   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 940   nw="$nw -Wshadow"
 941
 942   # Emacs's use of alloca inhibits protecting the stack.
 943   nw="$nw -Wstack-protector"
 944
 945   # Emacs's use of partly-const functions such as Fgnutls_available_p
 946   # make this option problematic.
 947   nw="$nw -Wsuggest-attribute=const"
 948
 949   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 950   # option problematic.
 951   nw="$nw -Wsuggest-attribute=pure"
 952
 953   # This part is merely for shortening the command line,
 954   # since -Wall implies -Wswitch.
 955   nw="$nw -Wswitch"
 956
 957   # This part is merely for shortening the command line,
 958   # since -Wno-FOO needs to be added below regardless.
 959   nw="$nw -Wmissing-field-initializers"
 960   nw="$nw -Wtype-limits"
 961   nw="$nw -Wunused-parameter"
 962
 963   if test $emacs_cv_clang = yes; then
 964     nw="$nw -Wcast-align"
 965   fi
 966
 967   gl_MANYWARN_ALL_GCC([ws])
 968   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 969   for w in $ws; do
 970     gl_WARN_ADD([$w])
 971   done
 972   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 973   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 974   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 975   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 976   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 977   gl_WARN_ADD([-Wno-format-nonliteral])
 978
 979   # More things that clang is unduly picky about.
 980   if test $emacs_cv_clang = yes; then
 981     gl_WARN_ADD([-Wno-format-extra-args])
 982     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 983     gl_WARN_ADD([-Wno-unused-command-line-argument])
 984     gl_WARN_ADD([-Wno-unused-value])
 985   fi
 986
 987   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 988   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 989   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 990   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 991       without upsetting glibc 2.15+. */
 992    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 993         && defined __OPTIMIZE__ && __OPTIMIZE__)
 994    # define _FORTIFY_SOURCE 2
 995    #endif
 996   ])
 997
 998   # We use a slightly smaller set of warning options for lib/.
 999   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
1000   nw=
1001   nw="$nw -Wunused-macros"
1002
1003   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1004   AC_SUBST([GNULIB_WARN_CFLAGS])
1005  ])
1006
1007 edit_cflags="
1008   s,///*,/,g
1009   s/^/ /
1010   s/ -I/ $isystem/g
1011   s/^ //
1012 "
1013
1014 AC_ARG_ENABLE(link-time-optimization,
1015 [AS_HELP_STRING([--enable-link-time-optimization],
1016                 [build emacs with link-time optimization.
1017                  This requires GCC 4.5.0 or later, or clang.
1018                  (Note that clang support is experimental - see INSTALL.)
1019                  It also makes Emacs harder to debug, and when we tried it
1020                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1021                  recommended for typical use.])],
1022 if test "${enableval}" != "no"; then
1023    ac_lto_supported=no
1024    if test $emacs_cv_clang = yes; then
1025       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1026       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1027       if test -x "$GOLD_PLUGIN"; then
1028          LTO="-flto"
1029       fi
1030    elif test x$GCC = xyes; then
1031       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1032       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1033       if test x$CPUS != x; then
1034          LTO="-flto=$CPUS"
1035       else
1036          LTO="-flto"
1037       fi
1038    else
1039       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1040    fi
1041    if test -z "$LTO"; then
1042       ac_lto_supported=no
1043    else
1044       old_CFLAGS=$CFLAGS
1045       CFLAGS="$CFLAGS $LTO"
1046       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1047          [ac_lto_supported=yes], [ac_lto_supported=no])
1048          CFLAGS="$old_CFLAGS"
1049    fi
1050    AC_MSG_RESULT([$ac_lto_supported])
1051    if test "$ac_lto_supported" = "yes"; then
1052       CFLAGS="$CFLAGS $LTO"
1053       if test x$emacs_cv_clang = xyes; then
1054          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1055          # WARNING: 'ar --plugin ...' doesn't work without
1056          # command, so plugin name is appended to ARFLAGS.
1057          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1058          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1059       else
1060         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1061         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1062         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1063         dnl dump core on Fedora 20, so play it safe for now.
1064         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1065           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1066       fi
1067    fi
1068 fi)
1069
1070 dnl Prefer silent make output.  For verbose output, use
1071 dnl 'configure --disable-silent-rules' or 'make V=1' .
1072 AM_SILENT_RULES([yes])
1073 dnl Port to Automake 1.11.
1074 dnl This section can be removed once we assume Automake 1.14 or later.
1075 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1076 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1077 AC_SUBST([AM_V])
1078 AM_SUBST_NOTMAKE([AM_V])
1079 AC_SUBST([AM_DEFAULT_V])
1080 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1081 AC_SUBST([AM_DEFAULT_VERBOSITY])
1082
1083 dnl Some other nice autoconf tests.
1084 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1085 dnl AC_PROG_INSTALL
1086 dnl AC_PROG_MKDIR_P
1087 dnl if test "x$RANLIB" = x; then
1088 dnl   AC_PROG_RANLIB
1089 dnl fi
1090
1091
1092 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1093 dnl can be made to directories.  This is not relevant for our usage, and
1094 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1095 dnl hosted on AFS, both examples where simple links work, but links to
1096 dnl directories fail.  We use a cut-down version instead.
1097 dnl AC_PROG_LN_S
1098
1099 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1100 rm -f conf$$ conf$$.file
1101
1102 LN_S_FILEONLY='cp -p'
1103
1104 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1105 dnl random program in the current directory.
1106 if (echo >conf$$.file) 2>/dev/null; then
1107   if ln -s conf$$.file conf$$ 2>/dev/null; then
1108     if test "$opsys" = "mingw32"; then
1109       LN_S_FILEONLY='/bin/ln -s'
1110     else
1111       LN_S_FILEONLY='ln -s'
1112     fi
1113   elif ln conf$$.file conf$$ 2>/dev/null; then
1114     if test "$opsys" = "mingw32"; then
1115       LN_S_FILEONLY=/bin/ln
1116     else
1117       LN_S_FILEONLY=ln
1118     fi
1119   fi
1120 fi
1121
1122 rm -f conf$$ conf$$.file
1123
1124 if test "$LN_S_FILEONLY" = "ln -s"; then
1125    AC_MSG_RESULT([yes])
1126 else
1127    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1128 fi
1129
1130 AC_SUBST(LN_S_FILEONLY)
1131
1132
1133 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1134 dnl doesn't support links to directories, as in "ln file dir".  But that
1135 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1136 dnl executables at "make install" time.
1137 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1138 dnl for more details.
1139 if test "$opsys" = "mingw32"; then
1140   LN_S="/bin/ln"
1141 fi
1142
1143 dnl On some Debian versions, "install-info" prints irritating messages
1144 dnl "This is not dpkg install-info anymore, but GNU install-info"
1145 dnl if called via an absolute file name.
1146 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1147 dnl Sadly some people may have an old ginstall-info installed on
1148 dnl non-Debian systems, so we can't use this.
1149 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1150 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1151
1152 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1153   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1154 dnl Don't use GZIP, which is used by gzip for additional parameters.
1155 AC_PATH_PROG(GZIP_PROG, gzip)
1156
1157 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1158    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1159
1160 if test $opsys = gnu-linux; then
1161   AC_PATH_PROG(PAXCTL, paxctl,,
1162     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1163   if test "X$PAXCTL" != X; then
1164     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1165     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1166       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1167       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1168   fi
1169
1170   if test "${SETFATTR+set}" != set; then
1171     AC_CACHE_CHECK([for setfattr],
1172       [emacs_cv_prog_setfattr],
1173       [touch conftest.tmp
1174        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1175          emacs_cv_prog_setfattr=yes
1176        else
1177          emacs_cv_prog_setfattr=no
1178        fi])
1179     if test "$emacs_cv_prog_setfattr" = yes; then
1180       SETFATTR=setfattr
1181     else
1182       SETFATTR=
1183     fi
1184     rm -f conftest.tmp
1185     AC_SUBST([SETFATTR])
1186   fi
1187 fi
1188
1189 ## Need makeinfo >= 4.7 (?) to build the manuals.
1190 if test "$MAKEINFO" != "no"; then
1191   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1192     MAKEINFO=makeinfo
1193   fi
1194   case `($MAKEINFO --version) 2>/dev/null` in
1195     *' (GNU texinfo) '4.[[7-9]]* | \
1196     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1197     *' (GNU texinfo) '[[5-9]]* | \
1198     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1199     *) MAKEINFO=no;;
1200   esac
1201 fi
1202
1203 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1204 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1205 ## therefore in the category of "special tools" not normally required, which
1206 ## configure does not have to check for (eg autoconf itself).
1207 ## In a repository checkout on the other hand, the manuals are not included.
1208 ## So makeinfo is a requirement to build from the repository, and configure
1209 ## should test for it as it does for any other build requirement.
1210 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1211 ## with pre-built manuals, from a repository checkout.
1212 HAVE_MAKEINFO=yes
1213
1214 if test "$MAKEINFO" = "no"; then
1215   MAKEINFO=makeinfo
1216   if test "x${with_makeinfo}" = "xno"; then
1217     HAVE_MAKEINFO=no
1218   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1219     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1220 source tree does not seem to have pre-built manuals in the 'info' directory.
1221 Either install a suitable version of makeinfo, or re-run configure
1222 with the '--without-makeinfo' option to build without the manuals.] )
1223   fi
1224 fi
1225 AC_SUBST(HAVE_MAKEINFO)
1226
1227 if test $opsys = mingw32; then
1228    DOCMISC_W32=efaq-w32
1229 else
1230    DOCMISC_W32=
1231 fi
1232 AC_SUBST(DOCMISC_W32)
1233
1234 dnl Add our options to ac_link now, after it is set up.
1235
1236 if test x$GCC = xyes; then
1237   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1238     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1239 else
1240   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1241     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1242 fi
1243
1244 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1245 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1246 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1247 dnl if not built to support GNU ld.
1248
1249 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1250 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1251 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1252 dnl   Eg "make LDFLAGS=... all" could run into problems,
1253 dnl   http://bugs.debian.org/684788
1254 dnl * unnecessary, since temacs is the only thing that actually needs it.
1255 dnl   Indeed this is where it was originally, prior to:
1256 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1257 late_LDFLAGS="$LDFLAGS"
1258 if test x$GCC = xyes; then
1259   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1260 else
1261   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1262 fi
1263
1264 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1265
1266 AC_MSG_CHECKING([for -znocombreloc])
1267 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1268   [AC_MSG_RESULT(yes)],
1269   LDFLAGS_NOCOMBRELOC=
1270   [AC_MSG_RESULT(no)])
1271
1272 LDFLAGS="$late_LDFLAGS"
1273
1274 AC_CACHE_CHECK([whether addresses are sanitized],
1275   [emacs_cv_sanitize_address],
1276   [AC_COMPILE_IFELSE(
1277      [AC_LANG_PROGRAM(
1278         [[#ifndef __has_feature
1279           #define __has_feature(f) 0
1280           #endif
1281           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1282           #else
1283            error "Addresses are not sanitized.";
1284           #endif
1285         ]])],
1286      [emacs_cv_sanitize_address=yes],
1287      [emacs_cv_sanitize_address=no])])
1288
1289 dnl The function dump-emacs will not be defined and temacs will do
1290 dnl (load "loadup") automatically unless told otherwise.
1291 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1292 case "$opsys" in
1293   nacl) CANNOT_DUMP=yes ;;
1294 esac
1295
1296 if test "$CANNOT_DUMP" = "yes"; then
1297   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1298 elif test "$emacs_cv_sanitize_address" = yes; then
1299   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1300 fi
1301
1302 AC_SUBST(CANNOT_DUMP)
1303
1304
1305 UNEXEC_OBJ=unexelf.o
1306 case "$opsys" in
1307   # MSDOS uses unexcoff.o
1308   aix4-2)
1309    UNEXEC_OBJ=unexaix.o
1310    ;;
1311   cygwin)
1312    UNEXEC_OBJ=unexcw.o
1313    ;;
1314   darwin)
1315    UNEXEC_OBJ=unexmacosx.o
1316    ;;
1317   hpux10-20 | hpux11)
1318    UNEXEC_OBJ=unexhp9k800.o
1319    ;;
1320   mingw32)
1321    UNEXEC_OBJ=unexw32.o
1322    ;;
1323   sol2-10)
1324    # Use the Solaris dldump() function, called from unexsol.c, to dump
1325    # emacs, instead of the generic ELF dump code found in unexelf.c.
1326    # The resulting binary has a complete symbol table, and is better
1327    # for debugging and other observability tools (debuggers, pstack, etc).
1328    #
1329    # If you encounter a problem using dldump(), please consider sending
1330    # a message to the OpenSolaris tools-linking mailing list:
1331    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1332    #
1333    # It is likely that dldump() works with older Solaris too, but this has
1334    # not been tested, so for now this change is for Solaris 10 or newer.
1335    UNEXEC_OBJ=unexsol.o
1336    ;;
1337 esac
1338
1339 LD_SWITCH_SYSTEM=
1340 case "$opsys" in
1341   freebsd|dragonfly)
1342    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1343    ## The system compiler, GCC, has apparently been modified to not
1344    ## look there, contrary to what a stock GCC would do.
1345 ### It's not our place to do this.  See bug#10313#17.
1346 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1347       :
1348    ;;
1349
1350   gnu-linux)
1351    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1352    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1353    ;;
1354
1355   netbsd)
1356 ### It's not our place to do this.  See bug#10313#17.
1357 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1358       :
1359    ;;
1360
1361   openbsd)
1362    ## Han Boetes <han@boetes.org> says this is necessary,
1363    ## otherwise Emacs dumps core on elf systems.
1364    LD_SWITCH_SYSTEM="-Z"
1365    ;;
1366 esac
1367 AC_SUBST(LD_SWITCH_SYSTEM)
1368
1369 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1370
1371 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1372 ## which has not been defined yet.  When this was handled with cpp,
1373 ## it was expanded to null when configure sourced the s/*.h file.
1374 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1375 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1376 ## (or somesuch), but because it is supposed to go at the _front_
1377 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1378 ## Compare with the gnu-linux case below, which added to the end
1379 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1380 ## LD_SWITCH_SYSTEM_TEMACS.
1381 case "$opsys" in
1382   netbsd|openbsd)
1383    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1384 esac
1385
1386
1387 C_SWITCH_MACHINE=
1388 case $canonical in
1389  alpha*)
1390   AC_CHECK_DECL([__ELF__])
1391   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1392     ## With ELF, make sure that all common symbols get allocated to in the
1393     ## data section.  Otherwise, the dump of temacs may miss variables in
1394     ## the shared library that have been initialized.  For example, with
1395     ## GNU libc, __malloc_initialized would normally be resolved to the
1396     ## shared library's .bss section, which is fatal.
1397     if test "x$GCC" = "xyes"; then
1398       C_SWITCH_MACHINE="-fno-common"
1399     else
1400       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1401     fi
1402   else
1403       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1404       dnl albeit under the mistaken assumption that said file
1405       dnl was no longer used.
1406       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1407   fi
1408   ;;
1409 esac
1410 AC_SUBST(C_SWITCH_MACHINE)
1411
1412 AC_SUBST(UNEXEC_OBJ)
1413
1414 C_SWITCH_SYSTEM=
1415 ## Some programs in src produce warnings saying certain subprograms
1416 ## are too complex and need a MAXMEM value greater than 2000 for
1417 ## additional optimization.  --nils@exp-math.uni-essen.de
1418 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1419   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1420 if test "$opsys" = "mingw32"; then
1421   case "$canonical" in
1422     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1423     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1424   esac
1425 fi
1426 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1427 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1428 AC_SUBST(C_SWITCH_SYSTEM)
1429
1430
1431 LIBS_SYSTEM=
1432 case "$opsys" in
1433   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1434   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1435
1436   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1437
1438   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1439
1440   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1441
1442   ## Motif needs -lgen.
1443   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1444 esac
1445
1446 AC_SUBST(LIBS_SYSTEM)
1447
1448 ### Make sure subsequent tests use flags consistent with the build flags.
1449
1450 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1451   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1452 else
1453   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1454 fi
1455
1456 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1457 AC_DEFUN([AC_TYPE_SIZE_T])
1458 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1459 AC_DEFUN([AC_TYPE_UID_T])
1460
1461 # sqrt and other floating-point functions such as fmod and frexp
1462 # are found in -lm on many systems.
1463 OLD_LIBS=$LIBS
1464 AC_SEARCH_LIBS([sqrt], [m])
1465 if test "X$LIBS" = "X$OLD_LIBS"; then
1466   LIB_MATH=
1467 else
1468   LIB_MATH=$ac_cv_search_sqrt
1469 fi
1470 LIBS=$OLD_LIBS
1471
1472 dnl Current possibilities handled by sed (aix4-2 -> aix,
1473 dnl gnu-linux -> gnu/linux, etc.):
1474 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux.
1475 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1476 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1477
1478 case $opsys in
1479   cygwin )
1480     LIB_MATH=
1481     ;;
1482   darwin )
1483     ## Adding -lm confuses the dynamic linker, so omit it.
1484     LIB_MATH=
1485     ;;
1486   freebsd | dragonfly )
1487     SYSTEM_TYPE=berkeley-unix
1488     ;;
1489   gnu-linux | gnu-kfreebsd )
1490     ;;
1491   hpux10-20 | hpux11 )
1492     ;;
1493   mingw32 )
1494     LIB_MATH=
1495     SYSTEM_TYPE=windows-nt
1496     ;;
1497   dnl NB this may be adjusted below.
1498   netbsd | openbsd )
1499     SYSTEM_TYPE=berkeley-unix
1500     ;;
1501
1502   sol2* | unixware )
1503     SYSTEM_TYPE=usg-unix-v
1504     ;;
1505
1506 esac
1507
1508 AC_SUBST(LIB_MATH)
1509 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1510   [The type of system you are compiling for; sets 'system-type'.])
1511
1512
1513 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1514 pre_PKG_CONFIG_LIBS=$LIBS
1515
1516 PKG_PROG_PKG_CONFIG(0.9.0)
1517
1518 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1519 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1520 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1521 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1522 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1523 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1524 dnl actions.
1525 AC_DEFUN([EMACS_CHECK_MODULES],
1526   [PKG_CHECK_MODULES([$1], [$2],
1527      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1528       m4_default([$3], [HAVE_$1=yes])],
1529      [m4_default([$4], [HAVE_$1=no])])])
1530
1531 HAVE_SOUND=no
1532 if test "${with_sound}" != "no"; then
1533   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1534   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1535     have_sound_header=yes, [], [
1536     #ifdef __MINGW32__
1537     #define WIN32_LEAN_AND_MEAN
1538     #include <windows.h>
1539     #endif
1540     ])
1541   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1542     AC_MSG_ERROR([OSS sound support requested but not found.])
1543
1544   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1545     # Emulation library used on NetBSD.
1546     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1547     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1548       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1549     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1550     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1551   fi
1552   AC_SUBST(LIBSOUND)
1553
1554   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1555     ALSA_REQUIRED=1.0.0
1556     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1557     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1558     if test $HAVE_ALSA = yes; then
1559       SAVE_CFLAGS="$CFLAGS"
1560       SAVE_LIBS="$LIBS"
1561       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1562       LIBS="$ALSA_LIBS $LIBS"
1563       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1564                       emacs_alsa_normal=yes,
1565                     emacs_alsa_normal=no)
1566       if test "$emacs_alsa_normal" != yes; then
1567         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1568                        [[snd_lib_error_set_handler (0);]])],
1569                        emacs_alsa_subdir=yes,
1570                      emacs_alsa_subdir=no)
1571         if test "$emacs_alsa_subdir" != yes; then
1572           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1573         fi
1574         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1575       fi
1576
1577       CFLAGS="$SAVE_CFLAGS"
1578       LIBS="$SAVE_LIBS"
1579       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1580       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1581       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1582     elif test "${with_sound}" = "alsa"; then
1583       AC_MSG_ERROR([ALSA sound support requested but not found.])
1584     fi
1585   fi                            dnl with_sound = alsa|yes
1586
1587   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1588   dnl compiles only on the specified platforms.  For others, it
1589   dnl probably doesn't make sense to try.
1590   dnl FIXME So surely we should bypass this whole section if not using
1591   dnl one of these platforms?
1592   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1593      case "$opsys" in
1594        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1595        dnl Adjust the --with-sound help text if you change this.
1596        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1597          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1598          HAVE_SOUND=yes
1599          ;;
1600      esac
1601   fi
1602
1603   AC_SUBST(CFLAGS_SOUND)
1604 fi
1605
1606 dnl checks for header files
1607 AC_CHECK_HEADERS_ONCE(
1608   malloc.h
1609   sys/systeminfo.h
1610   sys/sysinfo.h
1611   coff.h pty.h
1612   sys/resource.h
1613   sys/utsname.h pwd.h utmp.h util.h)
1614
1615 AC_MSG_CHECKING(if personality LINUX32 can be set)
1616 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1617                emacs_cv_personality_linux32=yes,
1618                emacs_cv_personality_linux32=no)
1619 AC_MSG_RESULT($emacs_cv_personality_linux32)
1620
1621 if test $emacs_cv_personality_linux32 = yes; then
1622   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1623             [Define to 1 if personality LINUX32 can be set.])
1624 fi
1625
1626 # Note that Solaris has sys/sysinfo.h which defines struct
1627 # sysinfo as well.  To make sure that we're using GNU/Linux
1628 # sysinfo, we explicitly set one of its fields.
1629 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1630   AC_MSG_CHECKING([if Linux sysinfo may be used])
1631   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1632                                      [[struct sysinfo si;
1633                                        si.totalram = 0;
1634                                        sysinfo (&si)]])],
1635     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1636   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1637   if test $emacs_cv_linux_sysinfo = yes; then
1638     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1639     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1640                                        [[struct sysinfo si; return si.mem_unit]])],
1641       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1642                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1643   fi
1644 fi
1645
1646 dnl On Solaris 8 there's a compilation warning for term.h because
1647 dnl it doesn't define 'bool'.
1648 AC_CHECK_HEADERS(term.h, , , -)
1649 AC_HEADER_TIME
1650 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1651                                       ]])
1652 if test $ac_cv_have_decl_sys_siglist != yes; then
1653   # For Tru64, at least:
1654   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1655                                           ]])
1656 fi
1657 AC_HEADER_SYS_WAIT
1658
1659 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1660 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1661 #if HAVE_SYS_SOCKET_H
1662 #include <sys/socket.h>
1663 #endif])
1664 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1665 #if HAVE_SYS_SOCKET_H
1666 #include <sys/socket.h>
1667 #endif])
1668 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1669 #if HAVE_SYS_SOCKET_H
1670 #include <sys/socket.h>
1671 #endif])
1672
1673 dnl checks for structure members
1674 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1675                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1676                   struct ifreq.ifr_addr,
1677                   struct ifreq.ifr_addr.sa_len], , ,
1678                  [AC_INCLUDES_DEFAULT
1679 #if HAVE_SYS_SOCKET_H
1680 #include <sys/socket.h>
1681 #endif
1682 #if HAVE_NET_IF_H
1683 #include <net/if.h>
1684 #endif])
1685
1686 dnl Check for endianness.
1687 dnl AC_C_BIGENDIAN is done by gnulib.
1688
1689 dnl check for Make feature
1690
1691 AUTO_DEPEND=no
1692 dnl check if we have GCC and autodepend is on.
1693 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1694    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1695    SAVE_CFLAGS="$CFLAGS"
1696    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1697    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1698    CFLAGS="$SAVE_CFLAGS"
1699    test -f deps.d || ac_enable_autodepend=no
1700    rm -rf deps.d
1701    AC_MSG_RESULT([$ac_enable_autodepend])
1702    if test $ac_enable_autodepend = yes; then
1703       AUTO_DEPEND=yes
1704    fi
1705 fi
1706 AC_SUBST(AUTO_DEPEND)
1707
1708 dnl checks for operating system services
1709 AC_SYS_LONG_FILE_NAMES
1710
1711 #### Choose a window system.
1712
1713 ## We leave window_system equal to none if
1714 ## we end up building without one.  Any new window system should
1715 ## set window_system to an appropriate value and add objects to
1716 ## window-system-specific substs.
1717
1718 window_system=none
1719 AC_PATH_X
1720 if test "$no_x" != yes; then
1721   window_system=x11
1722 fi
1723
1724 LD_SWITCH_X_SITE_RPATH=
1725 if test "${x_libraries}" != NONE; then
1726   if test -n "${x_libraries}"; then
1727     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1728     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1729       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1730     `
1731   fi
1732   x_default_search_path=""
1733   x_search_path=${x_libraries}
1734   if test -z "${x_search_path}"; then
1735     x_search_path=/usr/lib
1736   fi
1737   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1738                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1739     x_search_path="\
1740 ${x_library}/X11/%L/%T/%N%C%S:\
1741 ${x_library}/X11/%l/%T/%N%C%S:\
1742 ${x_library}/X11/%T/%N%C%S:\
1743 ${x_library}/X11/%L/%T/%N%S:\
1744 ${x_library}/X11/%l/%T/%N%S:\
1745 ${x_library}/X11/%T/%N%S"
1746     if test x"${x_default_search_path}" = x; then
1747       x_default_search_path=${x_search_path}
1748     else
1749       x_default_search_path="${x_search_path}:${x_default_search_path}"
1750     fi
1751   done
1752 fi
1753 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1754
1755 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1756   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1757 fi
1758
1759 if test x"${x_includes}" = x; then
1760   bitmapdir=/usr/include/X11/bitmaps
1761 else
1762   # accumulate include directories that have X11 bitmap subdirectories
1763   bmd_acc=
1764   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1765     if test -d "${bmd}/X11/bitmaps"; then
1766       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1767     fi
1768     if test -d "${bmd}/bitmaps"; then
1769       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1770     fi
1771   done
1772   bitmapdir=${bmd_acc#:}
1773 fi
1774
1775 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1776 HAVE_NS=no
1777 NS_GNUSTEP_CONFIG=no
1778 NS_IMPL_COCOA=no
1779 NS_IMPL_GNUSTEP=no
1780 tmp_CPPFLAGS="$CPPFLAGS"
1781 tmp_CFLAGS="$CFLAGS"
1782 CPPFLAGS="$CPPFLAGS -x objective-c"
1783 CFLAGS="$CFLAGS -x objective-c"
1784 GNU_OBJC_CFLAGS=
1785 LIBS_GNUSTEP=
1786 if test "${with_ns}" != no; then
1787   if test "${opsys}" = darwin; then
1788      NS_IMPL_COCOA=yes
1789      ns_appdir=`pwd`/nextstep/Emacs.app
1790      ns_appbindir=${ns_appdir}/Contents/MacOS
1791      ns_appresdir=${ns_appdir}/Contents/Resources
1792      ns_appsrc=Cocoa/Emacs.base
1793      ns_fontfile=macfont.o
1794   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1795      NS_IMPL_GNUSTEP=yes
1796      NS_GNUSTEP_CONFIG=yes
1797      GNU_OBJC_CFLAGS=$flags
1798      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1799   elif test -f $GNUSTEP_CONFIG_FILE; then
1800      NS_IMPL_GNUSTEP=yes
1801      dnl FIXME sourcing this several times in subshells seems inefficient.
1802      GNUSTEP_SYSTEM_HEADERS=$(
1803        . $GNUSTEP_CONFIG_FILE
1804        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1805      )
1806      GNUSTEP_SYSTEM_LIBRARIES=$(
1807        . $GNUSTEP_CONFIG_FILE
1808        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1809      )
1810      dnl I seemed to need these as well with GNUstep-startup 0.25.
1811      GNUSTEP_LOCAL_HEADERS=$(
1812        . $GNUSTEP_CONFIG_FILE
1813        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1814      )
1815      GNUSTEP_LOCAL_LIBRARIES=$(
1816        . $GNUSTEP_CONFIG_FILE
1817        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1818      )
1819      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1820        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1821      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1822        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1823      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1824      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1825      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1826      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1827      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1828      dnl If they had chosen to either define it or not, we could have
1829      dnl just used AC_CHECK_DECL here.
1830      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1831        emacs_cv_objc_exceptions,
1832 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1833 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1834 1;
1835 #else
1836 fail;
1837 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1838      if test $emacs_cv_objc_exceptions = yes; then
1839        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1840        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1841          [Define if GNUstep uses ObjC exceptions.])
1842        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1843      fi
1844   fi
1845   if test $NS_IMPL_GNUSTEP = yes; then
1846      ns_appdir=`pwd`/nextstep/Emacs.app
1847      ns_appbindir=${ns_appdir}
1848      ns_appresdir=${ns_appdir}/Resources
1849      ns_appsrc=GNUstep/Emacs.base
1850      ns_fontfile=nsfont.o
1851   fi
1852
1853   dnl This is only used while we test the NS headers, it gets reset below.
1854   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1855   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1856
1857   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1858                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1859 are required for a Nextstep build are missing or cannot be compiled.
1860 Either fix this, or re-configure with the option '--without-ns'.])])
1861
1862   macfont_file=""
1863   if test "${NS_IMPL_COCOA}" = "yes"; then
1864     AC_MSG_CHECKING([for OSX 10.6 or newer])
1865     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1866                                      [
1867 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1868 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1869  ; /* OK */
1870 #else
1871  error "OSX 10.6 or newer required";
1872 #endif
1873 #endif
1874                     ])],
1875                     ns_osx_have_106=yes,
1876                     ns_osx_have_106=no)
1877     AC_MSG_RESULT([$ns_osx_have_106])
1878
1879     if test $ns_osx_have_106 = no; then
1880        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1881     fi
1882   fi
1883 fi
1884
1885 AC_SUBST(LIBS_GNUSTEP)
1886
1887 INSTALL_ARCH_INDEP_EXTRA=install-etc
1888 ns_self_contained=no
1889 NS_OBJ=
1890 NS_OBJC_OBJ=
1891 if test "${HAVE_NS}" = yes; then
1892   if test "$with_toolkit_scroll_bars" = "no"; then
1893     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1894   fi
1895
1896   window_system=nextstep
1897   # set up packaging dirs
1898   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1899      ns_self_contained=yes
1900      prefix=${ns_appresdir}
1901      exec_prefix=${ns_appbindir}
1902      dnl This one isn't really used, only archlibdir is.
1903      libexecdir="\${ns_appbindir}/libexec"
1904      archlibdir="\${ns_appbindir}/libexec"
1905      etcdocdir="\${ns_appresdir}/etc"
1906      etcdir="\${ns_appresdir}/etc"
1907      dnl FIXME maybe set datarootdir instead.
1908      dnl That would also get applications, icons, man.
1909      infodir="\${ns_appresdir}/info"
1910      mandir="\${ns_appresdir}/man"
1911      lispdir="\${ns_appresdir}/lisp"
1912      test "$locallisppathset" = no && locallisppath=""
1913      INSTALL_ARCH_INDEP_EXTRA=
1914   fi
1915
1916   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1917 fi
1918 CFLAGS="$tmp_CFLAGS"
1919 CPPFLAGS="$tmp_CPPFLAGS"
1920 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1921 AC_SUBST(ns_self_contained)
1922 AC_SUBST(NS_OBJ)
1923 AC_SUBST(NS_OBJC_OBJ)
1924
1925 HAVE_W32=no
1926 W32_OBJ=
1927 W32_LIBS=
1928 EMACSRES=
1929 CLIENTRES=
1930 CLIENTW=
1931 W32_RES_LINK=
1932 EMACS_MANIFEST=
1933 UPDATE_MANIFEST=
1934 if test "${with_w32}" != no; then
1935   case "${opsys}" in
1936     cygwin)
1937       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1938              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1939                    cannot be found.])])
1940     ;;
1941     mingw32)
1942     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1943     ;;
1944     *)
1945       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1946     ;;
1947   esac
1948 fi
1949
1950 if test "${opsys}" = "mingw32"; then
1951   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1952   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1953      #include <windows.h>
1954      #include <usp10.h>]],
1955    [[PIMAGE_NT_HEADERS pHeader;
1956      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1957    [emacs_cv_w32api=yes
1958     HAVE_W32=yes],
1959    emacs_cv_w32api=no)
1960   AC_MSG_RESULT($emacs_cv_w32api)
1961   if test "${emacs_cv_w32api}" = "no"; then
1962     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1963   fi
1964 fi
1965
1966 FIRSTFILE_OBJ=
1967 NTDIR=
1968 LIBS_ECLIENT=
1969 LIB_WSOCK32=
1970 NTLIB=
1971 CM_OBJ="cm.o"
1972 XARGS_LIMIT=
1973 if test "${HAVE_W32}" = "yes"; then
1974   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1975   if test "$with_toolkit_scroll_bars" = "no"; then
1976     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1977   fi
1978   AC_CHECK_TOOL(WINDRES, [windres],
1979                 [AC_MSG_ERROR([No resource compiler found.])])
1980   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1981   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1982   EMACSRES="emacs.res"
1983   case "$canonical" in
1984     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1985     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1986   esac
1987   dnl Construct something of the form "24,4,0,0" with 4 components.
1988   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1989
1990   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1991   AC_SUBST(comma_version)
1992   AC_SUBST(comma_space_version)
1993   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1994   if test "${opsys}" = "cygwin"; then
1995     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1996     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1997     # Tell the linker that emacs.res is an object (which we compile from
1998     # the rc file), not a linker script.
1999     W32_RES_LINK="-Wl,emacs.res"
2000   else
2001     UPDATE_MANIFEST=update-game-score.exe.manifest
2002     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
2003     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
2004     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
2005     W32_RES_LINK="\$(EMACSRES)"
2006     CLIENTRES="emacsclient.res"
2007     CLIENTW="emacsclientw\$(EXEEXT)"
2008     FIRSTFILE_OBJ=firstfile.o
2009     NTDIR=nt
2010     CM_OBJ=
2011     LIBS_ECLIENT="-lcomctl32"
2012     LIB_WSOCK32="-lwsock32"
2013     NTLIB="ntlib.$ac_objext"
2014     XARGS_LIMIT="-s 10000"
2015   fi
2016 fi
2017 AC_SUBST(W32_OBJ)
2018 AC_SUBST(W32_LIBS)
2019 AC_SUBST(EMACSRES)
2020 AC_SUBST(EMACS_MANIFEST)
2021 AC_SUBST(UPDATE_MANIFEST)
2022 AC_SUBST(CLIENTRES)
2023 AC_SUBST(CLIENTW)
2024 AC_SUBST(W32_RES_LINK)
2025 AC_SUBST(FIRSTFILE_OBJ)
2026 AC_SUBST(NTDIR)
2027 AC_SUBST(CM_OBJ)
2028 AC_SUBST(LIBS_ECLIENT)
2029 AC_SUBST(LIB_WSOCK32)
2030 AC_SUBST(NTLIB)
2031 AC_SUBST(XARGS_LIMIT)
2032
2033 if test "${HAVE_W32}" = "yes"; then
2034   window_system=w32
2035   with_xft=no
2036 fi
2037
2038 ## $window_system is now set to the window system we will
2039 ## ultimately use.
2040
2041 term_header=
2042 HAVE_X_WINDOWS=no
2043 HAVE_X11=no
2044 USE_X_TOOLKIT=none
2045
2046 case "${window_system}" in
2047   x11 )
2048     HAVE_X_WINDOWS=yes
2049     HAVE_X11=yes
2050     term_header=xterm.h
2051     case "${with_x_toolkit}" in
2052       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2053       motif ) USE_X_TOOLKIT=MOTIF ;;
2054       gtk ) with_gtk=yes
2055             term_header=gtkutil.h
2056 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2057 dnl USE_X_TOOLKIT is set.
2058             USE_X_TOOLKIT=none ;;
2059       gtk2 ) with_gtk2=yes
2060              term_header=gtkutil.h
2061              USE_X_TOOLKIT=none ;;
2062       gtk3 ) with_gtk3=yes
2063              term_header=gtkutil.h
2064              USE_X_TOOLKIT=none ;;
2065       no ) USE_X_TOOLKIT=none ;;
2066 dnl If user did not say whether to use a toolkit, make this decision later:
2067 dnl use the toolkit if we have gtk, or X11R5 or newer.
2068       * ) USE_X_TOOLKIT=maybe ;;
2069     esac
2070   ;;
2071   nextstep )
2072     term_header=nsterm.h
2073   ;;
2074   w32 )
2075     term_header=w32term.h
2076   ;;
2077 esac
2078
2079 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2080    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2081    if test "$HAVE_XSERVER" = true ||
2082       test -n "$DISPLAY" ||
2083       {
2084         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2085         test "$emacs_libX11" != '/usr/lib/libX11.*'
2086       }
2087    then
2088         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2089 were found.  You should install the relevant development files for X
2090 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2091 sure you have development files for image handling, i.e.
2092 tiff, gif, jpeg, png and xpm.
2093 If you are sure you want Emacs compiled without X window support, pass
2094   --without-x
2095 to configure.])
2096    fi
2097 fi
2098
2099 # Does the opsystem file prohibit the use of the GNU malloc?
2100 # Assume not, until told otherwise.
2101 GNU_MALLOC=yes
2102
2103 AC_CACHE_CHECK(
2104   [whether malloc is Doug Lea style],
2105   [emacs_cv_var_doug_lea_malloc],
2106   [emacs_cv_var_doug_lea_malloc=no
2107    dnl Hooks do not work with address sanitization.
2108    if test "$emacs_cv_sanitize_address" != yes; then
2109      AC_LINK_IFELSE(
2110        [AC_LANG_PROGRAM(
2111           [[#include <malloc.h>
2112             static void hook (void) {}]],
2113           [[malloc_set_state (malloc_get_state ());
2114             __after_morecore_hook = hook;
2115             __malloc_initialize_hook = hook;]])],
2116        [emacs_cv_var_doug_lea_malloc=yes])
2117    fi])
2118 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2119
2120 system_malloc=$emacs_cv_sanitize_address
2121
2122 hybrid_malloc=
2123
2124 case "$opsys" in
2125   ## darwin ld insists on the use of malloc routines in the System framework.
2126   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2127   cygwin) hybrid_malloc=yes;;
2128 esac
2129
2130 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2131    && test "${UNEXEC_OBJ}" = unexelf.o; then
2132   hybrid_malloc=yes
2133 fi
2134
2135 GMALLOC_OBJ=
2136 HYBRID_MALLOC=
2137 if test "${system_malloc}" = "yes"; then
2138   AC_DEFINE([SYSTEM_MALLOC], 1,
2139     [Define to 1 to use the system memory allocator, even if it is not
2140      Doug Lea style.])
2141   GNU_MALLOC=no
2142   GNU_MALLOC_reason="
2143     (The GNU allocators don't work with this system configuration.)"
2144   VMLIMIT_OBJ=
2145 elif test "$hybrid_malloc" = yes; then
2146   AC_DEFINE(HYBRID_MALLOC, 1,
2147     [Define to use gmalloc before dumping and the system malloc after.])
2148   HYBRID_MALLOC=1
2149   GNU_MALLOC=
2150   GNU_MALLOC_reason="only before dumping"
2151   GMALLOC_OBJ=gmalloc.o
2152   VMLIMIT_OBJ=
2153 else
2154   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2155   VMLIMIT_OBJ=vm-limit.o
2156
2157   AC_CHECK_HEADERS([sys/vlimit.h])
2158   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2159     [AC_LINK_IFELSE(
2160        [AC_LANG_PROGRAM(
2161          [[extern char data_start[]; char ch;]],
2162          [[return data_start < &ch;]])],
2163        [emacs_cv_data_start=yes],
2164        [emacs_cv_data_start=no])])
2165   if test $emacs_cv_data_start = yes; then
2166     AC_DEFINE([HAVE_DATA_START], 1,
2167       [Define to 1 if data_start is the address of the start
2168        of the main data segment.])
2169   fi
2170 fi
2171 AC_SUBST([HYBRID_MALLOC])
2172 AM_CONDITIONAL([HYBRID_MALLOC_LIB], [test -n "$HYBRID_MALLOC"])
2173 AC_SUBST(GMALLOC_OBJ)
2174 AC_SUBST(VMLIMIT_OBJ)
2175
2176 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2177   if test "$GNU_MALLOC" = yes ; then
2178     GNU_MALLOC_reason="
2179       (Using Doug Lea's new malloc from the GNU C Library.)"
2180   fi
2181   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2182     [Define to 1 if the system memory allocator is Doug Lea style,
2183      with malloc hooks and malloc_set_state.])
2184
2185   ## Use mmap directly for allocating larger buffers.
2186   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2187   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2188   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2189   case "$opsys" in
2190     mingw32|gnu*) REL_ALLOC=no ;;
2191   esac
2192 fi
2193
2194 if test x"${REL_ALLOC}" = x; then
2195   REL_ALLOC=${GNU_MALLOC}
2196 fi
2197
2198 use_mmap_for_buffers=no
2199 case "$opsys" in
2200   cygwin|mingw32) use_mmap_for_buffers=yes ;;
2201 esac
2202
2203 AC_FUNC_MMAP
2204 if test $use_mmap_for_buffers = yes; then
2205   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2206   REL_ALLOC=no
2207 fi
2208
2209 LIBS="$LIBS_SYSTEM $LIBS"
2210
2211 dnl FIXME replace main with a function we actually want from this library.
2212 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2213
2214 dnl Check for the POSIX thread library.
2215 LIB_PTHREAD=
2216 AC_CHECK_HEADERS_ONCE(pthread.h)
2217 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2218   AC_CACHE_CHECK([for pthread library],
2219     [emacs_cv_pthread_lib],
2220     [emacs_cv_pthread_lib=no
2221      OLD_LIBS=$LIBS
2222      for emacs_pthread_lib in 'none needed' -lpthread; do
2223        case $emacs_pthread_lib in
2224          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2225        esac
2226        AC_LINK_IFELSE(
2227          [AC_LANG_PROGRAM(
2228             [[#include <pthread.h>
2229               #include <signal.h>
2230               sigset_t old_mask, new_mask;
2231               void noop (void) {}]],
2232             [[pthread_t th = pthread_self ();
2233               int status = 0;
2234               status += pthread_create (&th, 0, 0, 0);
2235               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2236               status += pthread_kill (th, 0);
2237               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2238                      || defined DOUG_LEA_MALLOC)
2239               /* Test for pthread_atfork only if gmalloc uses it,
2240                  as older-style hosts like MirBSD 10 lack it.  */
2241               status += pthread_atfork (noop, noop, noop);
2242               #endif
2243               return status;]])],
2244          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2245        LIBS=$OLD_LIBS
2246        if test "$emacs_cv_pthread_lib" != no; then
2247          break
2248        fi
2249      done])
2250   if test "$emacs_cv_pthread_lib" != no; then
2251     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2252     case $emacs_cv_pthread_lib in
2253       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2254     esac
2255     ac_cv_func_pthread_sigmask=yes
2256     # Some systems optimize for single-threaded programs by default, and
2257     # need special flags to disable these optimizations. For example, the
2258     # definition of 'errno' in <errno.h>.
2259     case $opsys in
2260       hpux* | sol*)
2261         AC_DEFINE([_REENTRANT], 1,
2262           [Define to 1 if your system requires this in multithreaded code.]);;
2263       aix4-2)
2264         AC_DEFINE([_THREAD_SAFE], 1,
2265           [Define to 1 if your system requires this in multithreaded code.]);;
2266     esac
2267   fi
2268 fi
2269 AC_SUBST([LIB_PTHREAD])
2270
2271 dnl Check for need for bigtoc support on IBM AIX
2272
2273 case ${host_os} in
2274 aix*)
2275   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2276     case $GCC in
2277     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2278     *) gdb_cv_bigtoc=-bbigtoc ;;
2279     esac
2280
2281     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2282     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2283   ])
2284   ;;
2285 esac
2286
2287 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2288 # is for the tests that follow.  We set them back later on.
2289
2290 REAL_CFLAGS="$CFLAGS"
2291 REAL_CPPFLAGS="$CPPFLAGS"
2292 REAL_LIBS="$LIBS"
2293
2294 if test "${HAVE_X11}" = "yes"; then
2295   DEFS="$C_SWITCH_X_SITE $DEFS"
2296   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2297   LIBS="-lX11 $LIBS"
2298   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2299   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2300
2301   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2302   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2303   # but it's more convenient here to set LD_RUN_PATH since this
2304   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2305   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2306     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2307     export LD_RUN_PATH
2308   fi
2309
2310   if test "${opsys}" = "gnu-linux"; then
2311     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2312     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2313      [[XOpenDisplay ("foo");]])],
2314      [xgnu_linux_first_failure=no],
2315      [xgnu_linux_first_failure=yes])
2316     if test "${xgnu_linux_first_failure}" = "yes"; then
2317       OLD_CPPFLAGS="$CPPFLAGS"
2318       OLD_LIBS="$LIBS"
2319       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2320       LIBS="$LIBS -b i486-linuxaout"
2321       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2322        [[XOpenDisplay ("foo");]])],
2323        [xgnu_linux_second_failure=no],
2324        [xgnu_linux_second_failure=yes])
2325       if test "${xgnu_linux_second_failure}" = "yes"; then
2326         # If we get the same failure with -b, there is no use adding -b.
2327         # So leave it out.  This plays safe.
2328         AC_MSG_RESULT(no)
2329       else
2330         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2331         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2332         AC_MSG_RESULT(yes)
2333       fi
2334       CPPFLAGS=$OLD_CPPFLAGS
2335       LIBS=$OLD_LIBS
2336     else
2337       AC_MSG_RESULT(no)
2338     fi
2339   fi
2340
2341   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2342   # header files included from there.
2343   AC_MSG_CHECKING(for Xkb)
2344   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2345 #include <X11/XKBlib.h>]],
2346         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2347         emacs_xkb=yes, emacs_xkb=no)
2348   AC_MSG_RESULT($emacs_xkb)
2349   if test $emacs_xkb = yes; then
2350     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2351   fi
2352
2353   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2354 XScreenNumberOfScreen)
2355 fi
2356
2357 if test "${window_system}" = "x11"; then
2358   AC_MSG_CHECKING(X11 version 6)
2359   AC_CACHE_VAL(emacs_cv_x11_version_6,
2360   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2361 [[#if XlibSpecificationRelease < 6
2362 fail;
2363 #endif
2364 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2365   if test $emacs_cv_x11_version_6 = yes; then
2366     AC_MSG_RESULT(6 or newer)
2367     AC_DEFINE(HAVE_X11R6, 1,
2368               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2369     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2370     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2371     ## XIM support.
2372     case "$opsys" in
2373       sol2-*) : ;;
2374       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2375            [Define if you have usable X11R6-style XIM support.])
2376          ;;
2377     esac
2378   else
2379     AC_MSG_RESULT(before 6)
2380   fi
2381 fi
2382
2383
2384 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2385 HAVE_RSVG=no
2386 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2387   if test "${with_rsvg}" != "no"; then
2388     RSVG_REQUIRED=2.11.0
2389     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2390
2391     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2392     AC_SUBST(RSVG_CFLAGS)
2393     AC_SUBST(RSVG_LIBS)
2394
2395     if test $HAVE_RSVG = yes; then
2396       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2397       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2398       # Windows loads librsvg dynamically
2399       if test "${opsys}" = "mingw32"; then
2400         RSVG_LIBS=
2401       fi
2402     fi
2403   fi
2404 fi
2405
2406 HAVE_IMAGEMAGICK=no
2407 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2408   if test "${with_imagemagick}" != "no"; then
2409     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2410     ## 6.8.2 makes Emacs crash; see Bug#13867.
2411     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2412     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2413     AC_SUBST(IMAGEMAGICK_CFLAGS)
2414     AC_SUBST(IMAGEMAGICK_LIBS)
2415
2416     if test $HAVE_IMAGEMAGICK = yes; then
2417       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2418       OLD_CFLAGS=$CFLAGS
2419       OLD_LIBS=$LIBS
2420       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2421       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2422       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers MagickAutoOrientImage)
2423       CFLAGS=$OLD_CFLAGS
2424       LIBS=$OLD_LIBS
2425     fi
2426   fi
2427 fi
2428
2429 AC_CHECK_LIB(anl, getaddrinfo_a, HAVE_GETADDRINFO_A=yes)
2430 if test "${HAVE_GETADDRINFO_A}" = "yes"; then
2431   AC_DEFINE(HAVE_GETADDRINFO_A, 1,
2432 [Define to 1 if you have getaddrinfo_a for asynchronous DNS resolution.])
2433   GETADDRINFO_A_LIBS="-lanl"
2434   AC_SUBST(GETADDRINFO_A_LIBS)
2435 fi
2436
2437 HAVE_GTK=no
2438 GTK_OBJ=
2439 gtk_term_header=$term_header
2440 check_gtk2=no
2441 gtk3_pkg_errors=
2442 if test "${opsys}" != "mingw32"; then
2443   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2444     GLIB_REQUIRED=2.28
2445     GTK_REQUIRED=3.0
2446     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2447
2448     dnl Checks for libraries.
2449     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2450       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2451     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2452        AC_MSG_ERROR($GTK_PKG_ERRORS)
2453     fi
2454     if test "$pkg_check_gtk" = "yes"; then
2455        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2456        GTK_OBJ=emacsgtkfixed.o
2457        gtk_term_header=gtkutil.h
2458        USE_GTK_TOOLKIT="GTK3"
2459        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2460          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2461            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2462          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2463            [Define to 1 to disable Glib deprecation warnings.])
2464        fi
2465     else
2466        check_gtk2=yes
2467        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2468     fi
2469   fi
2470
2471   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2472     GLIB_REQUIRED=2.10
2473     GTK_REQUIRED=2.10
2474     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2475
2476     dnl Checks for libraries.
2477     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2478       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2479     if test "$pkg_check_gtk" = "no" &&
2480        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2481     then
2482       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2483     fi
2484     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2485   fi
2486 fi
2487
2488 OLD_CFLAGS=$CFLAGS
2489 OLD_LIBS=$LIBS
2490
2491 if test x"$pkg_check_gtk" = xyes; then
2492
2493   AC_SUBST(GTK_LIBS)
2494   CFLAGS="$CFLAGS $GTK_CFLAGS"
2495   LIBS="$GTK_LIBS $LIBS"
2496   dnl Try to compile a simple GTK program.
2497   AC_MSG_CHECKING([whether GTK compiles])
2498   GTK_COMPILES=no
2499   AC_LINK_IFELSE(
2500     [AC_LANG_PROGRAM(
2501        [[/* Check the Gtk and Glib APIs.  */
2502          #include <gtk/gtk.h>
2503          #include <glib-object.h>
2504          static void
2505          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2506          {}
2507        ]],
2508        [[
2509          GtkSettings *gs = 0;
2510          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2511             strict C prohibits this.  Use gtk_main_iteration to test that the
2512             libraries are there.  */
2513          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2514                                     0, 0, 0, G_CALLBACK (callback), 0))
2515            gtk_main_iteration ();
2516        ]])],
2517     [GTK_COMPILES=yes])
2518   AC_MSG_RESULT([$GTK_COMPILES])
2519   if test "${GTK_COMPILES}" != "yes"; then
2520     GTK_OBJ=
2521     if test "$USE_X_TOOLKIT" != "maybe"; then
2522       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2523     fi
2524   else
2525     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2526     HAVE_GTK=yes
2527     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2528     GTK_OBJ="gtkutil.o $GTK_OBJ"
2529     term_header=$gtk_term_header
2530     USE_X_TOOLKIT=none
2531     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2532        closing open displays.  This is no problem if you just use
2533        one display, but if you use more than one and close one of them
2534        Emacs may crash.
2535        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2536     sleep 3
2537   fi
2538
2539 fi
2540 AC_SUBST(GTK_OBJ)
2541
2542
2543 if test "${HAVE_GTK}" = "yes"; then
2544
2545   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2546   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2547   if test "$with_toolkit_scroll_bars" != no; then
2548     with_toolkit_scroll_bars=yes
2549   fi
2550
2551   dnl  Check if we have the old file selection dialog declared and
2552   dnl  in the link library.  In 2.x it may be in the library,
2553   dnl  but not declared if deprecated featured has been selected out.
2554   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2555   HAVE_GTK_FILE_SELECTION=no
2556   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2557                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2558 #include <gtk/gtk.h>])
2559   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2560     AC_CHECK_FUNCS(gtk_file_selection_new)
2561   fi
2562
2563   dnl Same as above for gtk_handle_box.
2564   HAVE_GTK_HANDLE_BOX=no
2565   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2566                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2567 #include <gtk/gtk.h>])
2568   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2569     AC_CHECK_FUNCS(gtk_handle_box_new)
2570   fi
2571
2572   dnl Same as above for gtk_tearoff_menu_item.
2573   HAVE_GTK_TEAROFF_MENU_ITEM=no
2574   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2575                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2576 #include <gtk/gtk.h>])
2577   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2578     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2579   fi
2580
2581   dnl Check for functions introduced in 2.14 and later.
2582   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2583                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2584                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2585                  gtk_orientable_set_orientation \
2586                  gtk_window_set_has_resize_grip)
2587
2588  term_header=gtkutil.h
2589 fi
2590
2591
2592 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2593 HAVE_XWIDGETS=no
2594 XWIDGETS_OBJ=
2595 if test "$with_xwidgets" != "no"; then
2596   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2597     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2598
2599   WEBKIT_REQUIRED=1.4.0
2600   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2601   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2602   HAVE_XWIDGETS=$HAVE_WEBKIT
2603   test $HAVE_XWIDGETS = yes ||
2604     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2605
2606   XWIDGETS_OBJ=xwidget.o
2607   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2608 fi
2609 AC_SUBST(XWIDGETS_OBJ)
2610
2611 CFLAGS=$OLD_CFLAGS
2612 LIBS=$OLD_LIBS
2613
2614 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2615 dnl other platforms.
2616 HAVE_DBUS=no
2617 DBUS_OBJ=
2618 if test "${with_dbus}" = "yes"; then
2619    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2620    if test "$HAVE_DBUS" = yes; then
2621      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2622      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2623      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2624      dnl D-Bus 1.5.12.
2625      OLD_LIBS=$LIBS
2626      LIBS="$LIBS $DBUS_LIBS"
2627      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2628                     dbus_type_is_valid \
2629                     dbus_validate_bus_name \
2630                     dbus_validate_path \
2631                     dbus_validate_interface \
2632                     dbus_validate_member)
2633      LIBS=$OLD_LIBS
2634      DBUS_OBJ=dbusbind.o
2635    fi
2636 fi
2637 AC_SUBST(DBUS_CFLAGS)
2638 AC_SUBST(DBUS_LIBS)
2639 AC_SUBST(DBUS_OBJ)
2640
2641 dnl GSettings has been tested under GNU/Linux only.
2642 HAVE_GSETTINGS=no
2643 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2644    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2645    if test "$HAVE_GSETTINGS" = "yes"; then
2646       old_CFLAGS=$CFLAGS
2647       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2648       old_LIBS=$LIBS
2649       LIBS="$LIBS $GSETTINGS_LIBS"
2650       AC_MSG_CHECKING([whether GSettings is in gio])
2651       AC_LINK_IFELSE(
2652          [AC_LANG_PROGRAM(
2653              [[/* Check that gsettings really is present.  */
2654              #include <glib-object.h>
2655              #include <gio/gio.h>
2656              ]],
2657              [[
2658                GSettings *settings;
2659                GVariant *val = g_settings_get_value (settings, "");
2660              ]])],
2661          [], HAVE_GSETTINGS=no)
2662       AC_MSG_RESULT([$HAVE_GSETTINGS])
2663
2664       if test "$HAVE_GSETTINGS" = "yes"; then
2665         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2666         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2667         SETTINGS_LIBS="$GSETTINGS_LIBS"
2668       fi
2669       CFLAGS=$old_CFLAGS
2670       LIBS=$old_LIBS
2671    fi
2672 fi
2673
2674 dnl GConf has been tested under GNU/Linux only.
2675 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2676 HAVE_GCONF=no
2677 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2678    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2679    if test "$HAVE_GCONF" = yes; then
2680       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2681       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2682       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2683       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2684    fi
2685 fi
2686
2687 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2688     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2689     if test "$HAVE_GOBJECT" = "yes"; then
2690        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2691        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2692     fi
2693     SAVE_CFLAGS="$CFLAGS"
2694     SAVE_LIBS="$LIBS"
2695     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2696     LIBS="$SETTINGS_LIBS $LIBS"
2697     CFLAGS="$SAVE_CFLAGS"
2698     LIBS="$SAVE_LIBS"
2699 fi
2700 AC_SUBST(SETTINGS_CFLAGS)
2701 AC_SUBST(SETTINGS_LIBS)
2702
2703
2704 dnl SELinux is available for GNU/Linux only.
2705 HAVE_LIBSELINUX=no
2706 LIBSELINUX_LIBS=
2707 if test "${with_selinux}" = "yes"; then
2708    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2709    if test "$HAVE_LIBSELINUX" = yes; then
2710       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2711       LIBSELINUX_LIBS=-lselinux
2712    fi
2713 fi
2714 AC_SUBST(LIBSELINUX_LIBS)
2715
2716 HAVE_GNUTLS=no
2717 if test "${with_gnutls}" = "yes" ; then
2718   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2719     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2720   if test "${HAVE_GNUTLS}" = "yes"; then
2721     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2722     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2723       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2724   fi
2725
2726   # Windows loads GnuTLS dynamically
2727   if test "${opsys}" = "mingw32"; then
2728     LIBGNUTLS_LIBS=
2729   fi
2730 fi
2731
2732 AC_SUBST(LIBGNUTLS_LIBS)
2733 AC_SUBST(LIBGNUTLS_CFLAGS)
2734
2735 NOTIFY_OBJ=
2736 NOTIFY_SUMMARY=no
2737
2738 dnl MS Windows native file monitor is available for mingw32 only.
2739 case $with_file_notification,$opsys in
2740   w32,cygwin)
2741     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2742     this is only supported on MS-Windows native and MinGW32 builds.
2743     Consider using gfile instead.])
2744     ;;
2745   w32,* | yes,mingw32)
2746     AC_CHECK_HEADER(windows.h)
2747     if test "$ac_cv_header_windows_h" = yes ; then
2748        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2749        NOTIFY_OBJ=w32notify.o
2750        NOTIFY_SUMMARY="yes (w32)"
2751     fi ;;
2752 esac
2753
2754 dnl inotify is available only on GNU/Linux.
2755 case $with_file_notification,$NOTIFY_OBJ in
2756   inotify, | yes,)
2757     AC_CHECK_HEADER(sys/inotify.h)
2758     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2759         AC_CHECK_FUNC(inotify_init1)
2760         if test "$ac_cv_func_inotify_init1" = yes; then
2761           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2762           NOTIFY_OBJ=inotify.o
2763           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2764        fi
2765     fi ;;
2766 esac
2767
2768 dnl kqueue is available on BSD-like systems.
2769 case $with_file_notification,$NOTIFY_OBJ in
2770   kqueue,* | yes,)
2771     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2772     if test "$HAVE_KQUEUE" = "yes"; then
2773        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2774        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2775        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2776        NOTIFY_LIBS=$KQUEUE_LIBS
2777        NOTIFY_OBJ=kqueue.o
2778        NOTIFY_SUMMARY="yes -lkqueue"
2779     else
2780        AC_SEARCH_LIBS(kqueue, [])
2781        if test "$ac_cv_search_kqueue" != no; then
2782          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2783          NOTIFY_OBJ=kqueue.o
2784          NOTIFY_SUMMARY="yes (kqueue)"
2785        fi
2786     fi ;;
2787 esac
2788
2789 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2790 dnl has been added in glib 2.24.  It has been tested under
2791 dnl GNU/Linux only.
2792 case $with_file_notification,$NOTIFY_OBJ in
2793   gfile,* | yes,)
2794     if test "${HAVE_NS}" = yes; then
2795        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2796 Consider kqueue instead.])
2797     else
2798        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2799        if test "$HAVE_GFILENOTIFY" = "yes"; then
2800           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2801           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2802           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2803           NOTIFY_OBJ=gfilenotify.o
2804           NOTIFY_SUMMARY="yes -lgio (gfile)"
2805        fi
2806     fi ;;
2807 esac
2808
2809 case $with_file_notification,$NOTIFY_OBJ in
2810   yes,* | no,* | *,?*) ;;
2811   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2812 esac
2813
2814 if test -n "$NOTIFY_OBJ"; then
2815    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2816 fi
2817 AC_SUBST(NOTIFY_CFLAGS)
2818 AC_SUBST(NOTIFY_LIBS)
2819 AC_SUBST(NOTIFY_OBJ)
2820
2821 dnl Do not put whitespace before the #include statements below.
2822 dnl Older compilers (eg sunos4 cc) choke on it.
2823 HAVE_XAW3D=no
2824 LUCID_LIBW=
2825 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2826   if test "$with_xaw3d" != no; then
2827     AC_CACHE_VAL(emacs_cv_xaw3d,
2828     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2829 #include <X11/Intrinsic.h>
2830 #include <X11/Xaw3d/Simple.h>]],
2831       [[]])],
2832       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2833                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2834       emacs_cv_xaw3d=no)])
2835   else
2836     emacs_cv_xaw3d=no
2837   fi
2838   if test $emacs_cv_xaw3d = yes; then
2839     AC_MSG_CHECKING(for xaw3d)
2840     AC_MSG_RESULT([yes; using Lucid toolkit])
2841     USE_X_TOOLKIT=LUCID
2842     HAVE_XAW3D=yes
2843     LUCID_LIBW=-lXaw3d
2844     AC_DEFINE(HAVE_XAW3D, 1,
2845               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2846   else
2847     AC_MSG_CHECKING(for xaw3d)
2848     AC_MSG_RESULT(no)
2849     AC_MSG_CHECKING(for libXaw)
2850     AC_CACHE_VAL(emacs_cv_xaw,
2851     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2852 #include <X11/Intrinsic.h>
2853 #include <X11/Xaw/Simple.h>]],
2854       [[]])],
2855       emacs_cv_xaw=yes,
2856       emacs_cv_xaw=no)])
2857     if test $emacs_cv_xaw = yes; then
2858       AC_MSG_RESULT([yes; using Lucid toolkit])
2859       USE_X_TOOLKIT=LUCID
2860       LUCID_LIBW=-lXaw
2861     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2862       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2863     else
2864       AC_MSG_ERROR([No X toolkit could be found.
2865 If you are sure you want Emacs compiled without an X toolkit, pass
2866   --with-x-toolkit=no
2867 to configure.  Otherwise, install the development libraries for the toolkit
2868 that you want to use (e.g. Gtk+) and re-run configure.])
2869     fi
2870   fi
2871 fi
2872
2873 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2874
2875 LIBXTR6=
2876 LIBXMU=
2877 if test "${USE_X_TOOLKIT}" != "none"; then
2878   AC_MSG_CHECKING(X11 toolkit version)
2879   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2880   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2881 [[#if XtSpecificationRelease < 6
2882 fail;
2883 #endif
2884 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2885   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2886   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2887     AC_MSG_RESULT(6 or newer)
2888     AC_DEFINE(HAVE_X11XTR6, 1,
2889               [Define to 1 if you have the X11R6 or newer version of Xt.])
2890     LIBXTR6="-lSM -lICE"
2891     case "$opsys" in
2892       ## Use libw.a along with X11R6 Xt.
2893       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2894     esac
2895   else
2896     AC_MSG_RESULT(before 6)
2897   fi
2898
2899 dnl If using toolkit, check whether libXmu.a exists.
2900 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2901   OLDLIBS="$LIBS"
2902   if test x$HAVE_X11XTR6 = xyes; then
2903     OTHERLIBS='-lXt -lSM -lICE'
2904   else
2905     OTHERLIBS='-lXt'
2906   fi
2907   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2908   if test "X$LIBS" != "X$OLDLIBS"; then
2909     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2910   fi
2911   LIBS=$OLDLIBS
2912   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2913 fi
2914 AC_SUBST(LIBXTR6)
2915 AC_SUBST(LIBXMU)
2916
2917 LIBXP=
2918 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2919   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2920   if test -d /usr/include/openmotif; then
2921     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2922     emacs_cv_openmotif=yes
2923     case "$canonical" in
2924       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2925       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2926       ;;
2927       *)
2928       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2929     esac
2930   else
2931     emacs_cv_openmotif=no
2932   fi
2933   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2934   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2935     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2936 int x = 5;
2937 #else
2938 Motif version prior to 2.1.
2939 #endif]])],
2940     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2941   if test $emacs_cv_motif_version_2_1 = yes; then
2942     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2943     if test x$emacs_cv_openmotif = xyes; then
2944       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2945     fi
2946   else
2947     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2948     # We put this in CFLAGS temporarily to precede other -I options
2949     # that might be in CFLAGS temporarily.
2950     # We put this in CPPFLAGS where it precedes the other -I options.
2951     OLD_CPPFLAGS=$CPPFLAGS
2952     OLD_CFLAGS=$CFLAGS
2953     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2954     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2955     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2956       [[int x = 5;]])],
2957       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2958     if test $emacs_cv_lesstif = yes; then
2959       # Make sure this -I option remains in CPPFLAGS after it is set
2960       # back to REAL_CPPFLAGS.
2961       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2962       # have those other -I options anyway.  Ultimately, having this
2963       # directory ultimately in CPPFLAGS will be enough.
2964       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2965       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2966     else
2967       CFLAGS=$OLD_CFLAGS
2968       CPPFLAGS=$OLD_CPPFLAGS
2969     fi
2970   fi
2971   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2972     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2973 fi
2974
2975 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2976 dnl using Motif or Xaw3d is available, and unless
2977 dnl --with-toolkit-scroll-bars=no was specified.
2978
2979 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2980             [Define to 1 if we should use toolkit scroll bars.])dnl
2981 USE_TOOLKIT_SCROLL_BARS=no
2982 if test "${with_toolkit_scroll_bars}" != "no"; then
2983   if test "${USE_X_TOOLKIT}" != "none"; then
2984     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2985       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2986       HAVE_XAW3D=no
2987       USE_TOOLKIT_SCROLL_BARS=yes
2988     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2989       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2990       USE_TOOLKIT_SCROLL_BARS=yes
2991     fi
2992   elif test "${HAVE_GTK}" = "yes"; then
2993     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2994     USE_TOOLKIT_SCROLL_BARS=yes
2995   elif test "${HAVE_NS}" = "yes"; then
2996     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2997     USE_TOOLKIT_SCROLL_BARS=yes
2998   elif test "${HAVE_W32}" = "yes"; then
2999     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3000     USE_TOOLKIT_SCROLL_BARS=yes
3001   fi
3002 fi
3003
3004 dnl See if XIM is available.
3005 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3006           #include <X11/Xlib.h>
3007           #include <X11/Xresource.h>]],
3008          [[XIMProc  callback;]])],
3009          [HAVE_XIM=yes
3010          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
3011          HAVE_XIM=no)
3012
3013 dnl '--with-xim' now controls only the initial value of use_xim at run time.
3014
3015 if test "${with_xim}" != "no"; then
3016   AC_DEFINE(USE_XIM, 1,
3017             [Define to 1 if we should use XIM, if it is available.])
3018 fi
3019
3020
3021 if test "${HAVE_XIM}" != "no"; then
3022   late_CFLAGS=$CFLAGS
3023   if test "$GCC" = yes; then
3024     CFLAGS="$CFLAGS --pedantic-errors"
3025   fi
3026   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3027 #include <X11/Xlib.h>
3028 #include <X11/Xresource.h>]],
3029 [[Display *display;
3030 XrmDatabase db;
3031 char *res_name;
3032 char *res_class;
3033 XIMProc  callback;
3034 XPointer *client_data;
3035 #ifndef __GNUC__
3036 /* If we're not using GCC, it's probably not XFree86, and this is
3037    probably right, but we can't use something like --pedantic-errors.  */
3038 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3039                                            char*, XIMProc, XPointer*);
3040 #endif
3041 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3042    client_data);]])],
3043     [emacs_cv_arg6_star=yes])
3044   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3045          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3046 either XPointer or XPointer*.])dnl
3047   if test "$emacs_cv_arg6_star" = yes; then
3048     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3049   else
3050     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3051   fi
3052   CFLAGS=$late_CFLAGS
3053 fi
3054
3055 ### Start of font-backend (under any platform) section.
3056 # (nothing here yet -- this is a placeholder)
3057 ### End of font-backend (under any platform) section.
3058
3059 ### Start of font-backend (under X11) section.
3060 if test "${HAVE_X11}" = "yes"; then
3061     ## Use -lXft if available, unless '--with-xft=no'.
3062     HAVE_XFT=maybe
3063     if test "x${with_x}" = "xno"; then
3064       with_xft="no";
3065     fi
3066
3067     if test "$with_xft" != no; then
3068       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3069       with_xft=$HAVE_FONTCONFIG
3070     fi
3071
3072     if test "x${with_xft}" != "xno"; then
3073
3074       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3075       ## Because xftfont.c uses XRenderQueryExtension, we also
3076       ## need to link to -lXrender.
3077       HAVE_XRENDER=no
3078       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3079       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3080         OLD_CPPFLAGS="$CPPFLAGS"
3081         OLD_CFLAGS="$CFLAGS"
3082         OLD_LIBS="$LIBS"
3083         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3084         CFLAGS="$CFLAGS $XFT_CFLAGS"
3085         XFT_LIBS="-lXrender $XFT_LIBS"
3086         LIBS="$XFT_LIBS $LIBS"
3087         AC_CHECK_HEADER(X11/Xft/Xft.h,
3088           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3089           [[#include <X11/X.h>]])
3090
3091         if test "${HAVE_XFT}" = "yes"; then
3092           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3093             AC_SUBST(XFT_LIBS)
3094           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3095         fi                        # "${HAVE_XFT}" = "yes"
3096         CPPFLAGS=$OLD_CPPFLAGS
3097         CFLAGS=$OLD_CFLAGS
3098         LIBS=$OLD_LIBS
3099       fi                          # "$HAVE_XFT" != no
3100     fi                            # "x${with_xft}" != "xno"
3101
3102     ## We used to allow building with FreeType and without Xft.
3103     ## However, the ftx font backend driver is not in good shape.
3104     if test "$HAVE_XFT" != "yes"; then
3105        dnl For the "Does Emacs use" message at the end.
3106        HAVE_XFT=no
3107        HAVE_FREETYPE=no
3108     else
3109        dnl Strict linkers fail with
3110        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3111        dnl if -lfreetype is not specified.
3112        dnl The following is needed to set FREETYPE_LIBS.
3113        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3114
3115        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3116     fi
3117
3118     HAVE_LIBOTF=no
3119     if test "${HAVE_FREETYPE}" = "yes"; then
3120       AC_DEFINE(HAVE_FREETYPE, 1,
3121                 [Define to 1 if using the freetype and fontconfig libraries.])
3122       if test "${with_libotf}" != "no"; then
3123         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3124         if test "$HAVE_LIBOTF" = "yes"; then
3125           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3126           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3127                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3128                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3129           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3130             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3131                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3132           fi
3133         fi
3134       fi
3135     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3136     dnl Does the new font backend require it, or can it work without it?
3137     fi
3138
3139     HAVE_M17N_FLT=no
3140     if test "${HAVE_LIBOTF}" = yes; then
3141       if test "${with_m17n_flt}" != "no"; then
3142         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3143         if test "$HAVE_M17N_FLT" = "yes"; then
3144           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3145         fi
3146       fi
3147     fi
3148 else
3149     HAVE_XFT=no
3150     HAVE_FREETYPE=no
3151     HAVE_LIBOTF=no
3152     HAVE_M17N_FLT=no
3153 fi
3154
3155 ### End of font-backend (under X11) section.
3156
3157 AC_SUBST(FREETYPE_CFLAGS)
3158 AC_SUBST(FREETYPE_LIBS)
3159 AC_SUBST(FONTCONFIG_CFLAGS)
3160 AC_SUBST(FONTCONFIG_LIBS)
3161 AC_SUBST(LIBOTF_CFLAGS)
3162 AC_SUBST(LIBOTF_LIBS)
3163 AC_SUBST(M17N_FLT_CFLAGS)
3164 AC_SUBST(M17N_FLT_LIBS)
3165
3166 HAVE_CAIRO=no
3167 if test "${HAVE_X11}" = "yes"; then
3168   if test "${with_cairo}" != "no"; then
3169     CAIRO_REQUIRED=1.12.0
3170     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3171     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3172     if test $HAVE_CAIRO = yes; then
3173       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3174     else
3175       AC_MSG_ERROR([cairo requested but not found.])
3176     fi
3177
3178     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3179     LIBS="$LIBS $CAIRO_LIBS"
3180     AC_SUBST(CAIRO_CFLAGS)
3181     AC_SUBST(CAIRO_LIBS)
3182   fi
3183 fi
3184
3185 if test "${HAVE_X11}" = "yes"; then
3186   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3187     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3188   if test "${HAVE_XCB}" = "yes"; then
3189     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3190     if test "${HAVE_X11_XCB}" = "yes"; then
3191       AC_DEFINE(USE_XCB, 1,
3192 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3193    X11/XCB programming.])
3194       XCB_LIBS="-lX11-xcb -lxcb"
3195       AC_SUBST(XCB_LIBS)
3196     fi
3197   fi
3198 fi
3199
3200 ### Use -lXpm if available, unless '--with-xpm=no'.
3201 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3202 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3203 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3204 ### LDFLAGS) accordingly.
3205 HAVE_XPM=no
3206 LIBXPM=
3207 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3208   if test "${with_xpm}" != "no"; then
3209     SAVE_CPPFLAGS="$CPPFLAGS"
3210     SAVE_LDFLAGS="$LDFLAGS"
3211     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3212     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3213     AC_CHECK_HEADER(X11/xpm.h,
3214       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3215     if test "${HAVE_XPM}" = "yes"; then
3216       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3217       AC_EGREP_CPP(no_return_alloc_pixels,
3218       [#include "X11/xpm.h"
3219 #ifndef XpmReturnAllocPixels
3220 no_return_alloc_pixels
3221 #endif
3222       ], HAVE_XPM=no, HAVE_XPM=yes)
3223
3224       if test "${HAVE_XPM}" = "yes"; then
3225         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3226         AC_MSG_RESULT(yes)
3227       else
3228         AC_MSG_RESULT(no)
3229         CPPFLAGS="$SAVE_CPPFLAGS"
3230         LDFLAGS="$SAVE_LDFLAGS"
3231       fi
3232     fi
3233   fi
3234
3235   if test "${HAVE_XPM}" = "yes"; then
3236     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3237     LIBXPM=-lXpm
3238   fi
3239 fi
3240
3241 if test "${HAVE_X11}" = "yes"; then
3242   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3243   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3244
3245   if test "${with_xpm}" != "no"; then
3246     AC_CHECK_HEADER(X11/xpm.h,
3247       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3248     if test "${HAVE_XPM}" = "yes"; then
3249       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3250       AC_EGREP_CPP(no_return_alloc_pixels,
3251       [#include "X11/xpm.h"
3252 #ifndef XpmReturnAllocPixels
3253 no_return_alloc_pixels
3254 #endif
3255       ], HAVE_XPM=no, HAVE_XPM=yes)
3256
3257       if test "${HAVE_XPM}" = "yes"; then
3258         AC_MSG_RESULT(yes)
3259       else
3260         AC_MSG_RESULT(no)
3261       fi
3262     fi
3263   fi
3264
3265   if test "${HAVE_XPM}" = "yes"; then
3266     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3267     LIBXPM=-lXpm
3268   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3269     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3270     LIBXPM=-lXpm
3271   fi
3272 fi
3273
3274 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3275 ### slightly different requirements wrt image libraries (it doesn't
3276 ### use -lXpm because it loads the xpm shared library dynamically at
3277 ### run time).
3278 if test "${opsys}" = "mingw32"; then
3279   if test "${with_xpm}" != "no"; then
3280     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3281 #define FOR_MSW 1])
3282   fi
3283
3284   if test "${HAVE_XPM}" = "yes"; then
3285     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3286   fi
3287 fi
3288
3289 AC_SUBST(LIBXPM)
3290
3291 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3292 HAVE_JPEG=no
3293 LIBJPEG=
3294 if test "${with_jpeg}" != "no"; then
3295   AC_CACHE_CHECK([for jpeglib 6b or later],
3296     [emacs_cv_jpeglib],
3297     [OLD_LIBS=$LIBS
3298      for emacs_cv_jpeglib in yes -ljpeg no; do
3299        case $emacs_cv_jpeglib in
3300          yes) ;;
3301          no) break;;
3302          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3303        esac
3304        AC_LINK_IFELSE(
3305          [AC_LANG_PROGRAM(
3306             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3307               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3308               #include <jpeglib.h>
3309               #include <jerror.h>
3310               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3311               struct jpeg_decompress_struct cinfo;
3312             ]],
3313             [[
3314               jpeg_create_decompress (&cinfo);
3315               WARNMS (&cinfo, JWRN_JPEG_EOF);
3316               jpeg_destroy_decompress (&cinfo);
3317             ]])],
3318          [emacs_link_ok=yes],
3319          [emacs_link_ok=no])
3320        LIBS=$OLD_LIBS
3321        test $emacs_link_ok = yes && break
3322      done])
3323   if test "$emacs_cv_jpeglib" != no; then
3324     HAVE_JPEG=yes
3325     AC_DEFINE([HAVE_JPEG], 1,
3326       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3327     ### mingw32 doesn't use -ljpeg, since it loads the library
3328     ### dynamically when needed, and doesn't want a run-time
3329     ### dependency on the jpeglib DLL.
3330     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3331     && LIBJPEG=$emacs_cv_jpeglib
3332   fi
3333 fi
3334 AC_SUBST(LIBJPEG)
3335
3336 HAVE_ZLIB=no
3337 LIBZ=
3338 if test "${with_zlib}" != "no"; then
3339   OLIBS=$LIBS
3340   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3341   LIBS=$OLIBS
3342   case $ac_cv_search_inflateEnd in
3343     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3344   esac
3345 fi
3346 if test "${HAVE_ZLIB}" = "yes"; then
3347   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3348   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3349   if test "${opsys}" = "mingw32"; then
3350      LIBZ=
3351   fi
3352 fi
3353 AC_SUBST(LIBZ)
3354
3355 ### Dynamic modules support
3356 LIBMODULES=
3357 HAVE_MODULES=no
3358 MODULES_OBJ=
3359 MODULES_SUFFIX=
3360 if test "${with_modules}" != "no"; then
3361   if test "$opsys" = "gnu-linux"; then
3362     LIBMODULES="-ldl"
3363     MODULES_SUFFIX=".so"
3364     HAVE_MODULES=yes
3365   elif test "$opsys" = "cygwin"; then
3366     MODULES_SUFFIX=".dll"
3367     HAVE_MODULES=yes
3368   elif test "$opsys" = "darwin"; then
3369     MODULES_SUFFIX=".so"
3370     HAVE_MODULES=yes
3371   elif test "$opsys" = "mingw32"; then
3372     MODULES_SUFFIX=".dll"
3373     HAVE_MODULES=yes
3374   else
3375     # BSD system have dlopen in the libc
3376     AC_CHECK_FUNC(dlopen, [MODULES_SUFFIX=".so"]
3377                           [HAVE_MODULES=yes], [])
3378   fi
3379
3380   if test "${HAVE_MODULES}" = no; then
3381     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3382   else
3383     SAVE_LIBS=$LIBS
3384     LIBS="$LIBS $LIBMODULES"
3385     AC_CHECK_FUNCS([dladdr dlfunc])
3386     LIBS=$SAVE_LIBS
3387   fi
3388 fi
3389
3390 if test "${HAVE_MODULES}" = yes; then
3391    MODULES_OBJ="dynlib.o emacs-module.o"
3392    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3393    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3394      [System extension for dynamic libraries])
3395 fi
3396 AC_SUBST(MODULES_OBJ)
3397 AC_SUBST(LIBMODULES)
3398
3399 ### Use -lpng if available, unless '--with-png=no'.
3400 HAVE_PNG=no
3401 LIBPNG=
3402 PNG_CFLAGS=
3403 if test "${NS_IMPL_COCOA}" = yes; then
3404   : # Nothing to do
3405 elif test "${with_png}" != no; then
3406   # mingw32 loads the library dynamically.
3407   if test "$opsys" = mingw32; then
3408     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3409   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3410     AC_MSG_CHECKING([for png])
3411     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3412     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3413       # libpng-config does not work; configure by hand.
3414       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3415       # in /usr/include/libpng.
3416       if test -r /usr/include/libpng/png.h &&
3417          test ! -r /usr/include/png.h; then
3418         png_cflags=-I/usr/include/libpng
3419       else
3420         png_cflags=
3421       fi
3422       png_libs='-lpng'
3423     }
3424     SAVE_CFLAGS=$CFLAGS
3425     SAVE_LIBS=$LIBS
3426     CFLAGS="$CFLAGS $png_cflags"
3427     LIBS="$png_libs -lz -lm $LIBS"
3428     AC_LINK_IFELSE(
3429       [AC_LANG_PROGRAM([[#include <png.h>]],
3430          [[return !png_get_channels (0, 0);]])],
3431       [HAVE_PNG=yes
3432        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3433        LIBPNG=$png_libs
3434        # $LIBPNG requires explicit -lz in some cases.
3435        # We don't know what those cases are, exactly, so play it safe and
3436        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3437        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3438          LIBPNG="$LIBPNG -lz"
3439        fi])
3440     CFLAGS=$SAVE_CFLAGS
3441     LIBS=$SAVE_LIBS
3442     AC_MSG_RESULT([$HAVE_PNG])
3443   fi
3444 fi
3445 if test $HAVE_PNG = yes; then
3446   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3447
3448   SAVE_CFLAGS=$CFLAGS
3449   CFLAGS="$CFLAGS $PNG_CFLAGS"
3450   AC_CHECK_DECL([png_longjmp],
3451     [],
3452     [AC_DEFINE([PNG_DEPSTRUCT], [],
3453        [Define to empty to suppress deprecation warnings when building
3454         with --enable-gcc-warnings and with libpng versions before 1.5,
3455         which lack png_longjmp.])],
3456     [[#include <png.h>
3457     ]])
3458   CFLAGS=$SAVE_CFLAGS
3459 fi
3460 AC_SUBST(LIBPNG)
3461 AC_SUBST(PNG_CFLAGS)
3462
3463 ### Use -ltiff if available, unless '--with-tiff=no'.
3464 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3465 HAVE_TIFF=no
3466 LIBTIFF=
3467 if test "${opsys}" = "mingw32"; then
3468   if test "${with_tiff}" != "no"; then
3469     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3470   fi
3471   if test "${HAVE_TIFF}" = "yes"; then
3472     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3473   fi
3474 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3475   if test "${with_tiff}" != "no"; then
3476     AC_CHECK_HEADER(tiffio.h,
3477       [tifflibs="-lz -lm"
3478       # At least one tiff package requires the jpeg library.
3479       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3480       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3481   fi
3482
3483   if test "${HAVE_TIFF}" = "yes"; then
3484     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3485     dnl FIXME -lz -lm, as per libpng?
3486     LIBTIFF=-ltiff
3487   fi
3488 fi
3489 AC_SUBST(LIBTIFF)
3490
3491 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3492 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3493 HAVE_GIF=no
3494 LIBGIF=
3495 if test "${opsys}" = "mingw32"; then
3496   if test "${with_gif}" != "no"; then
3497     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3498   fi
3499   if test "${HAVE_GIF}" = "yes"; then
3500     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3501   fi
3502 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3503         || test "${HAVE_W32}" = "yes"; then
3504   AC_CHECK_HEADER(gif_lib.h,
3505 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3506 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3507     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3508         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3509
3510   if test "$HAVE_GIF" = yes; then
3511     LIBGIF=-lgif
3512   elif test "$HAVE_GIF" = maybe; then
3513 # If gif_lib.h but no libgif, try libungif.
3514     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3515     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3516   fi
3517
3518   if test "${HAVE_GIF}" = "yes"; then
3519     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3520   fi
3521 fi
3522 AC_SUBST(LIBGIF)
3523
3524 dnl Check for required libraries.
3525 if test "${HAVE_X11}" = "yes"; then
3526   MISSING=""
3527   WITH_NO=""
3528   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3529     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3530   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3531     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3532   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3533     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3534   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3535     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3536   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3537     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3538
3539   if test "X${MISSING}" != X; then
3540     AC_MSG_ERROR([The following required libraries were not found:
3541     $MISSING
3542 Maybe some development libraries/packages are missing?
3543 If you don't want to link with them give
3544     $WITH_NO
3545 as options to configure])
3546   fi
3547 fi
3548
3549 ### Use -lgpm if available, unless '--with-gpm=no'.
3550 HAVE_GPM=no
3551 LIBGPM=
3552 if test "${with_gpm}" != "no"; then
3553   AC_CHECK_HEADER(gpm.h,
3554     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3555
3556   if test "${HAVE_GPM}" = "yes"; then
3557     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3558     LIBGPM=-lgpm
3559   fi
3560 fi
3561 AC_SUBST(LIBGPM)
3562
3563 dnl Check for malloc/malloc.h on darwin
3564 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3565
3566 GNUSTEP_CFLAGS=
3567 ### Use NeXTstep API to implement GUI.
3568 if test "${HAVE_NS}" = "yes"; then
3569   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3570   if test "${NS_IMPL_COCOA}" = "yes"; then
3571     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3572   fi
3573   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3574     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3575     if test $NS_GNUSTEP_CONFIG != yes; then
3576       # See also .m.o rule in src/Makefile.in.  */
3577       # FIXME: are all these flags really needed?  Document here why.  */
3578       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3579       ## Extra CFLAGS applied to src/*.m files.
3580       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3581     fi
3582   fi
3583   OTHER_FILES=ns-app
3584 fi
3585
3586 ### Use session management (-lSM -lICE) if available
3587 HAVE_X_SM=no
3588 LIBXSM=
3589 if test "${HAVE_X11}" = "yes"; then
3590   AC_CHECK_HEADER(X11/SM/SMlib.h,
3591     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3592
3593   if test "${HAVE_X_SM}" = "yes"; then
3594     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3595     LIBXSM="-lSM -lICE"
3596   fi
3597 fi
3598 AC_SUBST(LIBXSM)
3599
3600 ### Use XRandr (-lXrandr) if available
3601 HAVE_XRANDR=no
3602 if test "${HAVE_X11}" = "yes"; then
3603   XRANDR_REQUIRED=1.2.2
3604   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3605   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3606   if test $HAVE_XRANDR = no; then
3607     # Test old way in case pkg-config doesn't have it (older machines).
3608     # Include Xrender.h by hand to work around bug in older Xrandr.h
3609     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3610     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3611       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3612       [], [AC_INCLUDES_DEFAULT
3613 #include <X11/extensions/Xrender.h>])
3614     if test $HAVE_XRANDR = yes; then
3615       XRANDR_LIBS=-lXrandr
3616     fi
3617   fi
3618   if test $HAVE_XRANDR = yes; then
3619     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3620   fi
3621 fi
3622 AC_SUBST(XRANDR_CFLAGS)
3623 AC_SUBST(XRANDR_LIBS)
3624
3625 ### Use Xinerama (-lXinerama) if available
3626 HAVE_XINERAMA=no
3627 if test "${HAVE_X11}" = "yes"; then
3628   XINERAMA_REQUIRED=1.0.2
3629   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3630   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3631   if test $HAVE_XINERAMA = no; then
3632     # Test old way in case pkg-config doesn't have it (older machines).
3633     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3634       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3635     if test $HAVE_XINERAMA = yes; then
3636       XINERAMA_LIBS=-lXinerama
3637     fi
3638   fi
3639   if test $HAVE_XINERAMA = yes; then
3640     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3641   fi
3642 fi
3643 AC_SUBST(XINERAMA_CFLAGS)
3644 AC_SUBST(XINERAMA_LIBS)
3645
3646 ### Use Xfixes (-lXfixes) if available
3647 HAVE_XFIXES=no
3648 if test "${HAVE_X11}" = "yes"; then
3649   XFIXES_REQUIRED=4.0.0
3650   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3651   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3652   if test $HAVE_XFIXES = no; then
3653     # Test old way in case pkg-config doesn't have it (older machines).
3654     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3655       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3656     if test $HAVE_XFIXES = yes; then
3657       XFIXES_LIBS=-lXfixes
3658     fi
3659   fi
3660   if test $HAVE_XFIXES = yes; then
3661     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3662   fi
3663 fi
3664 AC_SUBST(XFIXES_CFLAGS)
3665 AC_SUBST(XFIXES_LIBS)
3666
3667 ### Use libxml (-lxml2) if available
3668 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3669 HAVE_LIBXML2=no
3670 if test "${with_xml2}" != "no"; then
3671   ### I'm not sure what the version number should be, so I just guessed.
3672   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3673   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3674   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3675     SAVE_CPPFLAGS="$CPPFLAGS"
3676     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3677       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3678       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3679       case $xcsdkdir in
3680         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3681         xcsdkdir="" ;;
3682       esac
3683     fi
3684     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3685     AC_CHECK_HEADER(libxml/HTMLparser.h,
3686       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3687                      [#include <libxml/HTMLparser.h>])])
3688     CPPFLAGS="$SAVE_CPPFLAGS"
3689     if test "${HAVE_LIBXML2}" = "yes"; then
3690       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3691       LIBXML2_LIBS="-lxml2"
3692     fi
3693   fi
3694   if test "${HAVE_LIBXML2}" = "yes"; then
3695     if test "${opsys}" != "mingw32"; then
3696       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3697         [$LIBXML2_LIBS])
3698     else
3699       LIBXML2_LIBS=""
3700     fi
3701     if test "${HAVE_LIBXML2}" = "yes"; then
3702       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3703     else
3704       LIBXML2_LIBS=""
3705       LIBXML2_CFLAGS=""
3706     fi
3707   fi
3708 fi
3709 AC_SUBST(LIBXML2_LIBS)
3710 AC_SUBST(LIBXML2_CFLAGS)
3711
3712 # Check for mail-locking functions in a "mail" library.  Probably this should
3713 # have the same check as for liblockfile below.
3714 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3715 if test $have_mail = yes; then
3716   LIBS_MAIL=-lmail
3717   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3718
3719   OLD_LIBS=$LIBS
3720   LIBS="$LIBS_MAIL $LIBS"
3721   AC_CHECK_FUNCS(touchlock)
3722   LIBS=$OLD_LIBS
3723 else
3724   LIBS_MAIL=
3725 fi
3726 dnl Debian, at least:
3727 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3728 if test $have_lockfile = yes; then
3729    LIBS_MAIL=-llockfile
3730    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3731 else
3732 # If we have the shared liblockfile, assume we must use it for mail
3733 # locking (e.g. Debian).  If we couldn't link against liblockfile
3734 # (no liblockfile.a installed), ensure that we don't need to.
3735   dnl This works for files generally, not just executables.
3736   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3737   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3738                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3739   if test $ac_cv_prog_liblockfile = yes; then
3740     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3741 This probably means that movemail could lose mail.
3742 There may be a 'development' package to install containing liblockfile.])
3743   fi
3744 fi
3745 AC_CHECK_HEADERS_ONCE(maillock.h)
3746 AC_SUBST(LIBS_MAIL)
3747
3748 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3749 ## interlock access to the mail spool.  The alternative is a lock file named
3750 ## /usr/spool/mail/$USER.lock.
3751 mail_lock=no
3752 case "$opsys" in
3753   aix4-2) mail_lock="lockf" ;;
3754
3755   gnu|freebsd|dragonfly|netbsd|openbsd|darwin) mail_lock="flock" ;;
3756
3757   ## On GNU/Linux systems, both methods are used by various mail programs.
3758   ## I assume most people are using newer mailers that have heard of flock.
3759   ## Change this if you need to.
3760   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3761   ## configure gets the right answers, and that means *NOT* using flock.
3762   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3763   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3764   ## Debian maintainer hasn't provided a clean fix for Emacs.
3765   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3766   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3767   ## correct logic.  -- fx
3768   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3769   ## liblockfile is a Free Software replacement for libmail, used on
3770   ## Debian systems and elsewhere. -rfr.
3771   gnu-*)
3772     mail_lock="flock"
3773     if test $have_mail = yes || test $have_lockfile = yes; then
3774       test $ac_cv_header_maillock_h = yes && mail_lock=no
3775     fi
3776     ;;
3777
3778   mingw32)
3779     mail_lock="none-needed" ;;
3780 esac
3781
3782 BLESSMAIL_TARGET=
3783 case "$mail_lock" in
3784   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3785
3786   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3787
3788   none-needed) ;;
3789
3790   *) BLESSMAIL_TARGET="need-blessmail" ;;
3791 esac
3792 AC_SUBST(BLESSMAIL_TARGET)
3793
3794 OLD_LIBS=$LIBS
3795 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3796 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3797 getrusage get_current_dir_name \
3798 lrand48 random rint \
3799 select getpagesize setlocale newlocale \
3800 getrlimit setrlimit shutdown \
3801 pthread_sigmask strsignal setitimer \
3802 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3803 gai_strerror sync \
3804 getpwent endpwent getgrent endgrent \
3805 cfmakeraw cfsetspeed copysign __executable_start log2)
3806 LIBS=$OLD_LIBS
3807
3808 dnl No need to check for posix_memalign if aligned_alloc works.
3809 AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3810 AC_CHECK_DECLS([aligned_alloc], [], [], [[#include <stdlib.h>]])
3811
3812 dnl Cannot use AC_CHECK_FUNCS
3813 AC_CACHE_CHECK([for __builtin_unwind_init],
3814                emacs_cv_func___builtin_unwind_init,
3815 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3816                 emacs_cv_func___builtin_unwind_init=yes,
3817                 emacs_cv_func___builtin_unwind_init=no)])
3818 if test $emacs_cv_func___builtin_unwind_init = yes; then
3819   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3820             [Define to 1 if you have the '__builtin_unwind_init' function.])
3821 fi
3822
3823 AC_CHECK_HEADERS_ONCE(sys/un.h)
3824
3825 AC_FUNC_FSEEKO
3826
3827 # UNIX98 PTYs.
3828 AC_CHECK_FUNCS(grantpt)
3829
3830 # PTY-related GNU extensions.
3831 AC_CHECK_FUNCS(getpt posix_openpt)
3832
3833 # Check this now, so that we will NOT find the above functions in ncurses.
3834 # That is because we have not set up to link ncurses in lib-src.
3835 # It's better to believe a function is not available
3836 # than to expect to find it in ncurses.
3837 # Also we need tputs and friends to be able to build at all.
3838 AC_MSG_CHECKING([for library containing tputs])
3839 # Run a test program that contains a call to tputs, a call that is
3840 # never executed.  This tests whether a pre-'main' dynamic linker
3841 # works with the library.  It's too much trouble to actually call
3842 # tputs in the test program, due to portability hassles.  When
3843 # cross-compiling, assume the test program will run if it links.
3844 AC_DEFUN([tputs_link_source], [
3845   AC_LANG_SOURCE(
3846      [[extern void tputs (const char *, int, int (*)(int));
3847        int main (int argc, char **argv)
3848        {
3849           if (argc == 10000)
3850             tputs (argv[0], 0, 0);
3851           return 0;
3852        }]])
3853 ])
3854 if test "${opsys}" = "mingw32"; then
3855   msg='none required'
3856 else
3857   # Maybe curses should be tried earlier?
3858   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3859   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3860     OLIBS=$LIBS
3861     if test -z "$tputs_library"; then
3862       LIBS_TERMCAP=
3863       msg='none required'
3864     else
3865       LIBS_TERMCAP=-l$tputs_library
3866       msg=$LIBS_TERMCAP
3867       LIBS="$LIBS_TERMCAP $LIBS"
3868     fi
3869     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3870       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3871     LIBS=$OLIBS
3872     if test "X$msg" != Xno; then
3873       break
3874     fi
3875   done
3876 fi
3877 AC_MSG_RESULT([$msg])
3878 if test "X$msg" = Xno; then
3879   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3880 The following libraries were tried (in order):
3881   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3882 Please try installing whichever of these libraries is most appropriate
3883 for your system, together with its header files.
3884 For example, a libncurses-dev(el) or similar package.])
3885 fi
3886
3887 ## Use termcap instead of terminfo?
3888 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3889 TERMINFO=yes
3890 ## FIXME?  In the cases below where we unconditionally set
3891 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3892 ## if that was found above to have tputs.
3893 ## Should we use the gnu* logic everywhere?
3894 case "$opsys" in
3895   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3896   ##  The ncurses library has been moved out of the System framework in
3897   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3898   ##  option to use it.
3899   darwin) LIBS_TERMCAP="-lncurses" ;;
3900
3901   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3902
3903   freebsd)
3904     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3905     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3906     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3907 [[#if __FreeBSD_version < 400000
3908 fail;
3909 #endif
3910 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3911
3912     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3913
3914     if test $emacs_cv_freebsd_terminfo = yes; then
3915       LIBS_TERMCAP="-lncurses"
3916     else
3917       TERMINFO=no
3918       LIBS_TERMCAP="-ltermcap"
3919     fi
3920     ;;
3921
3922   mingw32)
3923     TERMINFO=no
3924     LIBS_TERMCAP=
3925     ;;
3926
3927   netbsd)
3928     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3929       TERMINFO=no
3930       LIBS_TERMCAP="-ltermcap"
3931     fi
3932     ;;
3933
3934   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3935
3936   ## hpux: Make sure we get select from libc rather than from libcurses
3937   ##  because libcurses on HPUX 10.10 has a broken version of select.
3938   ##  We used to use -lc -lcurses, but this may be cleaner.
3939   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3940   # set that way, now it uses the default).  Isn't this a contradiction?
3941   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3942
3943 esac
3944
3945 TERMCAP_OBJ=tparam.o
3946 if test $TERMINFO = yes; then
3947   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3948   TERMCAP_OBJ=terminfo.o
3949 fi
3950 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3951   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3952 fi
3953 AC_SUBST(LIBS_TERMCAP)
3954 AC_SUBST(TERMCAP_OBJ)
3955
3956 # GNU/Linux-specific timer functions.
3957 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3958   [AC_COMPILE_IFELSE(
3959      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3960                       ]],
3961                       [[timerfd_create (CLOCK_REALTIME,
3962                                         TFD_CLOEXEC | TFD_NONBLOCK);
3963                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3964      [emacs_cv_have_timerfd=yes],
3965      [emacs_cv_have_timerfd=no])])
3966 if test "$emacs_cv_have_timerfd" = yes; then
3967   AC_DEFINE([HAVE_TIMERFD], 1,
3968     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3969 fi
3970
3971 # Alternate stack for signal handlers.
3972 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3973                [emacs_cv_alternate_stack],
3974   [AC_COMPILE_IFELSE(
3975      [AC_LANG_PROGRAM([[#include <signal.h>
3976                       ]],
3977                       [[stack_t ss;
3978                         struct sigaction sa;
3979                         ss.ss_sp = malloc (SIGSTKSZ);
3980                         ss.ss_size = SIGSTKSZ;
3981                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3982                         sigaltstack (&ss, 0);
3983                         sigaction (SIGSEGV, &sa, 0);]])],
3984      [emacs_cv_alternate_stack=yes],
3985      [emacs_cv_alternate_stack=no])])
3986
3987 # Do we need the Hesiod library to provide the support routines?
3988 dnl FIXME?  Should we be skipping this on Darwin too?
3989 LIBHESIOD=
3990 LIBRESOLV=
3991 if test "$with_hesiod" != no ; then
3992   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3993   resolv=no
3994   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3995      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3996                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3997   if test "$resolv" = yes ; then
3998     RESOLVLIB=-lresolv
3999   else
4000     RESOLVLIB=
4001   fi
4002   hesiod=no
4003   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4004         hesiod=yes, :, $RESOLVLIB)])
4005
4006   if test x"$hesiod" = xyes; then
4007     LIBHESIOD=-lhesiod
4008     LIBRESOLV=$RESOLVLIB
4009   fi
4010 fi
4011 AC_SUBST(LIBHESIOD)
4012 AC_SUBST(LIBRESOLV)
4013
4014 # These tell us which Kerberos-related libraries to use.
4015 COM_ERRLIB=
4016 CRYPTOLIB=
4017 KRB5LIB=
4018 DESLIB=
4019 KRB4LIB=
4020
4021 if test "${with_kerberos}" != no; then
4022   OLD_LIBS=$LIBS
4023   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4024   if test $have_com_err = yes; then
4025     COM_ERRLIB=-lcom_err
4026     LIBS="$COM_ERRLIB $LIBS"
4027   fi
4028   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4029   if test $have_crypto = yes; then
4030     CRYPTOLIB=-lcrypto
4031     LIBS="$CRYPTOLIB $LIBS"
4032   fi
4033   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4034   if test $have_k5crypto = yes; then
4035     CRYPTOLIB=-lk5crypto
4036     LIBS="$CRYPTOLIB $LIBS"
4037   fi
4038   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4039   if test $have_krb5=yes; then
4040     KRB5LIB=-lkrb5
4041     LIBS="$KRB5LIB $LIBS"
4042   fi
4043   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4044   if test "${with_kerberos5}" = no; then
4045     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4046     if test $have_des425 = yes; then
4047       DESLIB=-ldes425
4048       LIBS="$DESLIB $LIBS"
4049     else
4050       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4051       if test $have_des = yes; then
4052         DESLIB=-ldes
4053         LIBS="$DESLIB $LIBS"
4054       fi
4055     fi
4056     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4057     if test $have_krb4 = yes; then
4058       KRB4LIB=-lkrb4
4059       LIBS="$KRB4LIB $LIBS"
4060     else
4061       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4062       if test $have_krb = yes; then
4063         KRB4LIB=-lkrb
4064         LIBS="$KRB4LIB $LIBS"
4065       fi
4066     fi
4067   fi
4068
4069   if test "${with_kerberos5}" != no; then
4070     AC_CHECK_HEADERS(krb5.h,
4071       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4072                         [#include <krb5.h>])])
4073   else
4074     AC_CHECK_HEADERS(krb.h,,
4075                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4076                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4077   fi
4078   AC_CHECK_HEADERS(com_err.h)
4079   LIBS=$OLD_LIBS
4080 fi
4081
4082 AC_SUBST(COM_ERRLIB)
4083 AC_SUBST(CRYPTOLIB)
4084 AC_SUBST(KRB5LIB)
4085 AC_SUBST(DESLIB)
4086 AC_SUBST(KRB4LIB)
4087
4088 AC_CHECK_HEADERS(valgrind/valgrind.h)
4089
4090 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4091
4092 AC_CHECK_FUNCS_ONCE(tzset)
4093
4094 ok_so_far=yes
4095 AC_CHECK_FUNC(socket, , ok_so_far=no)
4096 if test $ok_so_far = yes; then
4097   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4098 fi
4099 if test $ok_so_far = yes; then
4100   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4101 fi
4102 if test $ok_so_far = yes; then
4103 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4104   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4105             [Define to 1 if you have inet sockets.])
4106 fi
4107
4108 AC_FUNC_FORK
4109
4110 AC_CHECK_FUNCS(snprintf)
4111
4112 dnl Check for glib.  This differs from other library checks in that
4113 dnl Emacs need not link to glib unless some other library is already
4114 dnl linking to glib.  Although glib provides no facilities that Emacs
4115 dnl needs for its own purposes, when glib is present Emacs needs to
4116 dnl use primitives like g_main_context_query to avoid clashing with
4117 dnl glib at a low level.
4118 dnl
4119 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4120 XGSELOBJ=
4121 OLDCFLAGS="$CFLAGS"
4122 OLDLIBS="$LIBS"
4123 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4124 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4125 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4126 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4127 AC_MSG_CHECKING([whether GLib is linked in])
4128 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4129         [[#include <glib.h>
4130         ]],
4131         [[g_print ("Hello world");]])],
4132      [links_glib=yes],
4133      [links_glib=no])
4134 AC_MSG_RESULT([$links_glib])
4135 if test "${links_glib}" = "yes"; then
4136   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4137   if test "$HAVE_NS" = no;then
4138     XGSELOBJ=xgselect.o
4139   fi
4140 fi
4141 CFLAGS="$OLDCFLAGS"
4142 LIBS="$OLDLIBS"
4143 AC_SUBST(XGSELOBJ)
4144
4145 dnl Adapted from Haible's version.
4146 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4147   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4148     [[char* cs = nl_langinfo(CODESET);]])],
4149     emacs_cv_langinfo_codeset=yes,
4150     emacs_cv_langinfo_codeset=no)
4151   ])
4152 if test $emacs_cv_langinfo_codeset = yes; then
4153   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4154     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4155 fi
4156
4157 AC_TYPE_MBSTATE_T
4158
4159 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4160 dnl how the tty code is related to POSIX and/or other versions of termios.
4161 dnl The following looks like a useful start.
4162 dnl
4163 dnl AC_SYS_POSIX_TERMIOS
4164 dnl if test $ac_cv_sys_posix_termios = yes; then
4165 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4166 dnl                                and macros for terminal control.])
4167 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4168 dnl fi
4169
4170 dnl Turned on June 1996 supposing nobody will mind it.
4171 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4172 if test "${opsys}" != "mingw32"; then
4173    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4174      in the full name stands for the login id.])
4175 fi
4176
4177 dnl Everybody supports this, except MS.
4178 dnl Seems like the kind of thing we should be testing for, though.
4179 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4180 if test "${opsys}" != "mingw32"; then
4181   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4182 fi
4183
4184 dnl Everybody supports this, except MS-DOS.
4185 dnl Seems like the kind of thing we should be testing for, though.
4186 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4187 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4188   4.2-compatible sockets.])
4189
4190 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4191
4192 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4193   a null file, or a data sink.])
4194 if test "${opsys}" = "mingw32"; then
4195   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4196 else
4197   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4198 fi
4199
4200 if test "${opsys}" = "mingw32"; then
4201   SEPCHAR=';'
4202 else
4203   SEPCHAR=':'
4204 fi
4205 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4206 dnl This is for MinGW, and is used in test/Makefile.in.
4207 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4208 dnl decides that a command-line argument to be passed to a MinGW program
4209 dnl is a PATH-style list of directories.  But that heuristics plays it
4210 dnl safe, and only does the replacement when it is _absolutely_ sure it
4211 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4212 dnl which breaks in-tree builds.  So we do this manually instead.
4213 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4214 dnl be computed as ':' in MSYS Bash.
4215 AC_SUBST(SEPCHAR)
4216
4217 dnl Everybody supports this, except MS-DOS.
4218 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4219
4220 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4221
4222
4223 AC_DEFINE(DIRECTORY_SEP, ['/'],
4224   [Character that separates directories in a file name.])
4225
4226 if test "${opsys}" = "mingw32"; then
4227   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4228     [Returns true if character is a device separator.])
4229
4230   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4231     [Returns true if character is a directory separator.])
4232
4233   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4234     [Returns true if character is any form of separator.])
4235 else
4236   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4237     [Returns true if character is a device separator.])
4238
4239   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4240     [Returns true if character is a directory separator.])
4241
4242   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4243     [Returns true if character is any form of separator.])
4244 fi
4245
4246 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4247
4248 case $opsys in
4249   aix4-2)
4250     dnl Unfortunately without libXmu we cannot support EditRes.
4251     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4252       AC_DEFINE(NO_EDITRES, 1)
4253     fi
4254     ;;
4255
4256   hpux*)
4257     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4258     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4259     AC_DEFINE(NO_EDITRES, 1)
4260     ;;
4261 esac
4262
4263
4264 case $opsys in
4265   sol2* | unixware )
4266     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4267     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4268     dnl need the constant to dimension an array.  So wire in the appropriate
4269     dnl value here.
4270     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4271     ;;
4272 esac
4273
4274 emacs_broken_SIGIO=no
4275
4276 case $opsys in
4277   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4278   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4279   hpux* | nacl | openbsd | sol2* | unixware )
4280     emacs_broken_SIGIO=yes
4281     ;;
4282
4283   aix4-2)
4284     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4285     dnl the way this system works, libc functions that return malloced
4286     dnl memory use the libc malloc implementation. Calling xfree or
4287     dnl xrealloc on the results of such functions results in a crash.
4288     dnl
4289     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4290     dnl but that does not currently work on this system.
4291     dnl
4292     dnl It is possible to completely override the malloc implementation on
4293     dnl AIX, but that involves putting the malloc functions in a shared
4294     dnl library and setting the MALLOCTYPE environment variable to point to
4295     dnl that shared library.
4296     dnl
4297     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4298     dnl to avoid a crash just use the Emacs implementation for that function.
4299     dnl
4300     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4301     dnl of this file, so that we do not check for get_current_dir_name
4302     dnl on AIX.  But that might be fragile if something else ends
4303     dnl up testing for get_current_dir_name as a dependency.
4304     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4305       get_current_dir_name should not be used.])
4306     ;;
4307
4308   freebsd)
4309     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4310     dnl writes/reads on a PTY, read(2) returns bogus data:
4311     dnl
4312     dnl write(2)  1022 bytes
4313     dnl write(2)   954 bytes, get EAGAIN
4314     dnl read(2)   1024 bytes in process_read_output
4315     dnl read(2)     11 bytes in process_read_output
4316     dnl
4317     dnl That is, read(2) returns more bytes than have ever been written
4318     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4319     dnl successfully after processing (for example with CRs added if the
4320     dnl terminal is set up that way which it is here).  The same bytes will
4321     dnl be seen again in a later read(2), without the CRs.
4322     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4323       work around an issue when reading from a PTY.])
4324     ;;
4325 esac
4326
4327 case $opsys in
4328   gnu-* | sol2-10 )
4329     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4330     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4331   ;;
4332 esac
4333
4334 case $opsys in
4335   darwin | dragonfly | freebsd | netbsd | openbsd )
4336     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4337       close a pty to make it a controlling terminal (it is already a
4338       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4339   ;;
4340 esac
4341
4342 dnl FIXME Surely we can test for this rather than hard-code it.
4343 case $opsys in
4344   netbsd | openbsd) sound_device="/dev/audio" ;;
4345   *) sound_device="/dev/dsp" ;;
4346 esac
4347
4348 dnl Used in sound.c
4349 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4350   [Name of the default sound device.])
4351
4352
4353 dnl Emacs can read input using SIGIO and buffering characters itself,
4354 dnl or using CBREAK mode and making C-g cause SIGINT.
4355 dnl The choice is controlled by the variable interrupt_input.
4356 dnl
4357 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4358 dnl
4359 dnl Emacs uses the presence of the USABLE_SIGIO macro
4360 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4361 dnl INTERRUPT_INPUT to decide whether to use it by default.
4362 dnl
4363 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4364 dnl CBREAK mode has two disadvantages
4365 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4366 dnl I hear that in system V this problem does not exist.
4367 dnl 2) Control-G causes output to be discarded.
4368 dnl I do not know whether this can be fixed in system V.
4369 dnl
4370 dnl Another method of doing input is planned but not implemented.
4371 dnl It would have Emacs fork off a separate process
4372 dnl to read the input and send it to the true Emacs process
4373 dnl through a pipe.
4374 case $opsys in
4375   darwin | gnu-linux | gnu-kfreebsd )
4376     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4377   ;;
4378 esac
4379
4380
4381 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4382 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4383 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4384 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4385 dnl taking float or double parameters.
4386 case $opsys in
4387   cygwin|gnu|gnu-linux|gnu-kfreebsd|freebsd|netbsd|openbsd)
4388     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4389       file defines 'NeedWidePrototypes' as 'NO'.])
4390   ;;
4391 esac
4392
4393
4394 dnl Used in process.c, this must be a loop, even if it only runs once.
4395 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4396 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4397 dnl trying suffixes 0-16.
4398 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4399   first PTY, if PTYs are supported.])
4400 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4401 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4402   end of a PTY, if non-standard.])
4403 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4404   end of a PTY, if non-standard.])
4405
4406 case $opsys in
4407   aix4-2 )
4408     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4409     dnl You allocate a pty by opening /dev/ptc to get the master side.
4410     dnl To get the name of the slave side, you just ttyname() the master side.
4411     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4412     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4413     ;;
4414
4415   cygwin )
4416     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4417     dnl multi-line AC_DEFINEs are hard. :(
4418     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4419     AC_DEFINE(PTY_NAME_SPRINTF, [])
4420     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4421     ;;
4422
4423   gnu | openbsd )
4424     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4425     ;;
4426
4427   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4428     dnl if HAVE_GRANTPT
4429     if test "x$ac_cv_func_grantpt" = xyes; then
4430       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4431       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4432       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4433       dnl to prevent sigchld_handler from intercepting the child's death.
4434       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4435       dnl if HAVE_POSIX_OPENPT
4436       if test "x$ac_cv_func_posix_openpt" = xyes; then
4437         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4438         AC_DEFINE(PTY_NAME_SPRINTF, [])
4439       dnl if HAVE_GETPT
4440       elif test "x$ac_cv_func_getpt" = xyes; then
4441         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4442         AC_DEFINE(PTY_NAME_SPRINTF, [])
4443       else
4444         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4445       fi
4446     else
4447       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4448     fi
4449     ;;
4450
4451   hpux*)
4452     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4453     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4454     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4455     ;;
4456
4457   sol2* )
4458     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4459     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4460     dnl from intercepting that death.  If any child but grantpt's should die
4461     dnl within, it should be caught after sigrelse(2).
4462     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4463     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4464     ;;
4465
4466   unixware )
4467     dnl Comments are as per sol2*.
4468     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4469     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4470     ;;
4471 esac
4472
4473
4474 case $opsys in
4475   sol2* | unixware )
4476     dnl This change means that we don't loop through allocate_pty too
4477     dnl many times in the (rare) event of a failure.
4478     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4479     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4480     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4481     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4482     ;;
4483 esac
4484
4485
4486 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4487 "typing" a signal character on the pty.])
4488
4489 case $opsys in
4490   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4491   aix4-2 | cygwin | gnu | dragonfly | freebsd | netbsd | openbsd | darwin )
4492     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4493     ;;
4494
4495   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4496   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4497   gnu-linux | gnu-kfreebsd )
4498
4499     AC_MSG_CHECKING([for signals via characters])
4500     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4501 #include <linux/version.h>
4502 #if LINUX_VERSION_CODE < 0x20400
4503 # error "Linux version too old"
4504 #endif
4505       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4506
4507     AC_MSG_RESULT([$emacs_signals_via_chars])
4508     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4509     ;;
4510 esac
4511
4512
4513 AH_TEMPLATE(TAB3, [Undocumented.])
4514
4515 case $opsys in
4516   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4517
4518   gnu | dragonfly | freebsd | netbsd | openbsd )
4519     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4520     AC_DEFINE(TAB3, OXTABS)
4521     ;;
4522
4523   gnu-linux | gnu-kfreebsd )
4524     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4525 #ifndef __ia64__
4526 # error "not ia64"
4527 #endif
4528       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4529         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4530         [Mark a secondary stack, like the register stack on the ia64.]), [])
4531     ;;
4532
4533   hpux*)
4534     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4535       run_time_remap; for HPUX.])
4536     ;;
4537 esac
4538
4539
4540 dnl This won't be used automatically yet.  We also need to know, at least,
4541 dnl that the stack is continuous.
4542 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4543   registers relevant for conservative garbage collection in the jmp_buf.])
4544
4545
4546 case $opsys in
4547   dnl Not all the architectures are tested, but there are Debian packages
4548   dnl for SCM and/or Guile on them, so the technique must work.  See also
4549   dnl comments in alloc.c concerning setjmp and gcc.
4550   dnl Fixme: it's probably safe to just use the GCC conditional below.
4551   gnu-linux | gnu-kfreebsd )
4552     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4553 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4554   || defined __alpha__ || defined __mips__ || defined __s390__ \
4555   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4556   || defined __ia64__ || defined __sh__
4557 /* ok */
4558 #else
4559 # error "setjmp not known to work on this arch"
4560 #endif
4561     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4562     ;;
4563 esac
4564
4565
4566 if test x$GCC = xyes; then
4567    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4568    AC_DEFINE(GC_SETJMP_WORKS, 1)
4569 else
4570   case $opsys in
4571     aix* | dragonfly | freebsd | netbsd | openbsd | sol2* )
4572       AC_DEFINE(GC_SETJMP_WORKS, 1)
4573       ;;
4574   esac
4575 fi                              dnl GCC?
4576
4577 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4578 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4579   [AC_LINK_IFELSE(
4580      [AC_LANG_PROGRAM(
4581        [[#include <setjmp.h>
4582          #ifdef __MINGW32__
4583          # define _longjmp longjmp
4584          #endif
4585        ]],
4586        [[jmp_buf j;
4587          if (! _setjmp (j))
4588            _longjmp (j, 1);]])],
4589      [emacs_cv_func__setjmp=yes],
4590      [emacs_cv_func__setjmp=no])])
4591 if test $emacs_cv_func__setjmp = yes; then
4592   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4593 fi
4594
4595 # We need to preserve signal mask to handle C stack overflows.
4596 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4597   [AC_LINK_IFELSE(
4598      [AC_LANG_PROGRAM(
4599        [[#include <setjmp.h>
4600        ]],
4601        [[sigjmp_buf j;
4602          if (! sigsetjmp (j, 1))
4603            siglongjmp (j, 1);]])],
4604      [emacs_cv_func_sigsetjmp=yes],
4605      [emacs_cv_func_sigsetjmp=no])])
4606 if test $emacs_cv_func_sigsetjmp = yes; then
4607   AC_DEFINE([HAVE_SIGSETJMP], 1,
4608     [Define to 1 if sigsetjmp and siglongjmp work.])
4609 fi
4610
4611 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4612   yes,yes,* | *,*,mingw32)
4613     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4614       [Define to 1 if C stack overflow can be handled in some cases.]);;
4615 esac
4616
4617 case $opsys in
4618   sol2* | unixware )
4619     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4620     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4621     dnl and this is all we need.
4622     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4623     ;;
4624 esac
4625
4626
4627 case $opsys in
4628   hpux* | sol2* )
4629     dnl Used in xfaces.c.
4630     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4631       some systems, where it requires time.h.])
4632     ;;
4633 esac
4634
4635
4636 dnl Define symbols to identify the version of Unix this is.
4637 dnl Define all the symbols that apply correctly.
4638 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4639 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4640 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4641 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4642
4643 case $opsys in
4644   aix4-2)
4645     AC_DEFINE(USG, [])
4646     dnl This symbol should be defined on AIX Version 3  ???????
4647     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4648 #ifndef _AIX
4649 # error "_AIX not defined"
4650 #endif
4651     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4652     ;;
4653
4654   cygwin)
4655     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4656     ;;
4657
4658   darwin)
4659     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4660     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4661     dnl distinguish OS X from pure Darwin.
4662     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4663     ;;
4664
4665   gnu-linux | gnu-kfreebsd )
4666     AC_DEFINE(USG, [])
4667     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4668     ;;
4669
4670   hpux*)
4671     AC_DEFINE(USG, [])
4672     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4673     ;;
4674
4675   mingw32)
4676     AC_DEFINE(DOS_NT, [])
4677     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4678     if test "x$ac_enable_checking" != "x" ; then
4679       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4680     fi
4681     ;;
4682
4683   sol2*)
4684     AC_DEFINE(USG, [])
4685     AC_DEFINE(USG5_4, [])
4686     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4687     ;;
4688
4689   unixware)
4690     AC_DEFINE(USG, [])
4691     AC_DEFINE(USG5_4, [])
4692     ;;
4693 esac
4694
4695 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4696   [case $opsys in
4697      aix4-2 | nacl)
4698        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4699        emacs_cv_usable_FIONREAD=no
4700        ;;
4701
4702      mingw32)
4703        emacs_cv_usable_FIONREAD=yes
4704        ;;
4705
4706      *)
4707        AC_COMPILE_IFELSE(
4708          [AC_LANG_PROGRAM([[#include <sys/types.h>
4709                             #include <sys/ioctl.h>
4710                             #ifdef USG5_4
4711                             # include <sys/filio.h>
4712                             #endif
4713                           ]],
4714                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4715          [emacs_cv_usable_FIONREAD=yes],
4716          [emacs_cv_usable_FIONREAD=no])
4717        ;;
4718    esac])
4719 if test $emacs_cv_usable_FIONREAD = yes; then
4720   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4721
4722   if test $emacs_broken_SIGIO = no; then
4723     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4724       [AC_COMPILE_IFELSE(
4725          [AC_LANG_PROGRAM([[#include <fcntl.h>
4726                             #include <signal.h>
4727                           ]],
4728                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4729          [emacs_cv_usable_SIGIO=yes],
4730          [emacs_cv_usable_SIGIO=no])],
4731       [emacs_cv_usable_SIGIO=yes],
4732       [emacs_cv_usable_SIGIO=no])
4733     if test $emacs_cv_usable_SIGIO = yes; then
4734       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4735     fi
4736   fi
4737 fi
4738
4739 case $opsys in
4740   hpux11)
4741     dnl It works to open the pty's tty in the parent (Emacs), then
4742     dnl close and reopen it in the child.
4743     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4744       works to open a pty's tty in the parent process, then close and
4745       reopen it in the child.])
4746     ;;
4747
4748   sol2-10)
4749     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4750       on Solaris.])
4751     ;;
4752 esac
4753
4754 # Set up the CFLAGS for real compilation, so we can substitute it.
4755 CFLAGS="$REAL_CFLAGS"
4756 CPPFLAGS="$REAL_CPPFLAGS"
4757 LIBS="$REAL_LIBS"
4758
4759 ## Hack to detect a buggy GCC version.
4760 if test "$GCC" = yes && \
4761    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4762   case $CFLAGS in
4763     *-fno-optimize-sibling-calls*) ;;
4764     *-O@<:@23@:>@*)
4765       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4766   esac
4767 fi
4768
4769 version=$PACKAGE_VERSION
4770
4771 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4772 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4773   [Short copyright string for this version of Emacs.])
4774 AC_SUBST(copyright)
4775
4776 ### Specify what sort of things we'll be editing into Makefile and config.h.
4777 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4778 AC_SUBST(version)
4779 AC_SUBST(configuration)
4780 ## Unused?
4781 AC_SUBST(canonical)
4782 AC_SUBST(srcdir)
4783 AC_SUBST(prefix)
4784 AC_SUBST(exec_prefix)
4785 AC_SUBST(bindir)
4786 AC_SUBST(datadir)
4787 AC_SUBST(sharedstatedir)
4788 AC_SUBST(libexecdir)
4789 AC_SUBST(mandir)
4790 AC_SUBST(infodir)
4791 AC_SUBST(lispdir)
4792 AC_SUBST(standardlisppath)
4793 AC_SUBST(locallisppath)
4794 AC_SUBST(lisppath)
4795 AC_SUBST(x_default_search_path)
4796 AC_SUBST(etcdir)
4797 AC_SUBST(archlibdir)
4798 AC_SUBST(etcdocdir)
4799 AC_SUBST(bitmapdir)
4800 AC_SUBST(gamedir)
4801 AC_SUBST(gameuser)
4802 AC_SUBST(gamegroup)
4803 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4804 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4805 ## end of LIBX_BASE, but nothing ever set it.
4806 AC_SUBST(LD_SWITCH_X_SITE)
4807 AC_SUBST(C_SWITCH_X_SITE)
4808 AC_SUBST(GNUSTEP_CFLAGS)
4809 AC_SUBST(CFLAGS)
4810 ## Used in lwlib/Makefile.in.
4811 AC_SUBST(X_TOOLKIT_TYPE)
4812 AC_SUBST(ns_appdir)
4813 AC_SUBST(ns_appbindir)
4814 AC_SUBST(ns_appresdir)
4815 AC_SUBST(ns_appsrc)
4816 AC_SUBST(GNU_OBJC_CFLAGS)
4817 AC_SUBST(OTHER_FILES)
4818
4819 if test -n "${term_header}"; then
4820     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4821         [Define to the header for the built-in window system.])
4822 fi
4823
4824 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4825                    [Define to the canonical Emacs configuration name.])
4826 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4827                    [Define to the options passed to configure.])
4828 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4829   define this to include extra configuration information.])
4830
4831 case $opsys in
4832   mingw32)
4833     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4834     ;;
4835 esac
4836
4837 XMENU_OBJ=
4838 XOBJ=
4839 FONT_OBJ=
4840 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4841   AC_DEFINE(HAVE_X_WINDOWS, 1,
4842             [Define to 1 if you want to use the X window system.])
4843   XMENU_OBJ=xmenu.o
4844   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4845   FONT_OBJ=xfont.o
4846   if test "$HAVE_CAIRO" = "yes"; then
4847     FONT_OBJ="ftfont.o ftcrfont.o"
4848   elif test "$HAVE_XFT" = "yes"; then
4849     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4850   elif test "$HAVE_FREETYPE" = "yes"; then
4851     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4852   fi
4853   AC_SUBST(FONT_OBJ)
4854 fi
4855 AC_SUBST(XMENU_OBJ)
4856 AC_SUBST(XOBJ)
4857 AC_SUBST(FONT_OBJ)
4858
4859 WIDGET_OBJ=
4860 MOTIF_LIBW=
4861 if test "${USE_X_TOOLKIT}" != "none" ; then
4862   WIDGET_OBJ=widget.o
4863   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4864   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4865     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4866   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4867     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4868     MOTIF_LIBW=-lXm
4869     case "$opsys" in
4870       gnu-linux)
4871         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4872         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4873         ;;
4874
4875       unixware)
4876         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4877         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4878         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4879         ;;
4880
4881       aix4-2)
4882         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4883         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4884         ;;
4885     esac
4886     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4887   fi
4888 fi
4889 AC_SUBST(WIDGET_OBJ)
4890
4891 TOOLKIT_LIBW=
4892 case "$USE_X_TOOLKIT" in
4893   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4894   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4895   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4896 esac
4897 if test "$HAVE_XWIDGETS" = "yes"; then
4898   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4899 fi
4900 AC_SUBST(TOOLKIT_LIBW)
4901
4902 if test "${opsys}" != "mingw32"; then
4903   if test "$USE_X_TOOLKIT" = "none"; then
4904     LIBXT_OTHER="\$(LIBXSM)"
4905   else
4906     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4907   fi
4908 fi
4909 AC_SUBST(LIBXT_OTHER)
4910
4911 if test "${HAVE_X11}" = "yes" ; then
4912   AC_DEFINE(HAVE_X11, 1,
4913             [Define to 1 if you want to use version 11 of X windows.])
4914   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4915 else
4916   LIBX_OTHER=
4917 fi
4918 AC_SUBST(LIBX_OTHER)
4919
4920 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4921   LIBXMENU=
4922 elif test "$USE_X_TOOLKIT" = none; then
4923   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4924 else
4925   LIBXMENU='$(lwlibdir)/liblw.a'
4926 fi
4927 AC_SUBST(LIBXMENU)
4928
4929 AC_CACHE_CHECK([for struct alignment],
4930   [emacs_cv_struct_alignment],
4931   [AC_COMPILE_IFELSE(
4932      [AC_LANG_PROGRAM([[#include <stddef.h>
4933                         struct __attribute__ ((aligned (8))) s { char c; };
4934                         struct t { char c; struct s s; };
4935                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4936                       ]])],
4937      [emacs_cv_struct_alignment=yes],
4938      [emacs_cv_struct_alignment=no])])
4939 if test "$emacs_cv_struct_alignment" = yes; then
4940   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4941     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4942      structure to an N-byte boundary.])
4943 fi
4944
4945 if test "${GNU_MALLOC}" = "yes" ; then
4946   AC_DEFINE(GNU_MALLOC, 1,
4947             [Define to 1 if you want to use the GNU memory allocator.])
4948 fi
4949
4950 RALLOC_OBJ=
4951 if test "${REL_ALLOC}" = "yes" ; then
4952   AC_DEFINE(REL_ALLOC, 1,
4953             [Define REL_ALLOC if you want to use the relocating allocator for
4954              buffer space.])
4955
4956   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4957 fi
4958 AC_SUBST(RALLOC_OBJ)
4959
4960 if test "$opsys" = "cygwin"; then
4961   CYGWIN_OBJ="cygw32.o"
4962   ## Cygwin differs because of its unexec().
4963   PRE_ALLOC_OBJ=
4964   POST_ALLOC_OBJ=lastfile.o
4965 elif test "$opsys" = "mingw32"; then
4966   CYGWIN_OBJ=
4967   PRE_ALLOC_OBJ=
4968   POST_ALLOC_OBJ=lastfile.o
4969 else
4970   CYGWIN_OBJ=
4971   PRE_ALLOC_OBJ=lastfile.o
4972   POST_ALLOC_OBJ=
4973 fi
4974 AC_SUBST(CYGWIN_OBJ)
4975 AC_SUBST(PRE_ALLOC_OBJ)
4976 AC_SUBST(POST_ALLOC_OBJ)
4977
4978 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4979 dnl verbatim defined above.  The tricky name is apropos, as this hack
4980 dnl makes Fortify go sour!
4981 AH_VERBATIM([FORTIFY_SOUR],
4982 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4983    The workaround disables some useful run-time checking, so it
4984    should be conditional to the platforms with the performance bug.
4985    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4986 #if defined __APPLE__ && defined __GNUC__
4987 # ifndef _DONT_USE_CTYPE_INLINE_
4988 #  define _DONT_USE_CTYPE_INLINE_
4989 # endif
4990 # ifndef _FORTIFY_SOURCE
4991 #  define _FORTIFY_SOURCE 0
4992 # endif
4993 #endif
4994 ])
4995
4996 # If user asks to omit features, disable optional features that gnulib
4997 # might otherwise enable.
4998 if test "$with_features" = no && test "$enable_acl" != yes; then
4999   enable_acl=no
5000 fi
5001
5002 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5003 # it temporarily reverts them to their pre-pkg-config values,
5004 # because gnulib needs to work with both src (which uses the
5005 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5006 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5007 # and it therefore needs to run in an environment where LIBS does not
5008 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5009 # for some package unrelated to lib-src.
5010 SAVE_CFLAGS=$CFLAGS
5011 SAVE_LIBS=$LIBS
5012 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5013 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5014 gl_ASSERT_NO_GNULIB_POSIXCHECK
5015 gl_ASSERT_NO_GNULIB_TESTS
5016 gl_INIT
5017 CFLAGS=$SAVE_CFLAGS
5018 LIBS=$SAVE_LIBS
5019
5020 if test "${opsys}" = "mingw32"; then
5021   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5022   # Remove unneeded switches from the value of CC that goes to Makefiles
5023   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5024 fi
5025
5026 case "$opsys" in
5027   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5028
5029   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5030
5031   darwin)
5032    ## The -headerpad option tells ld (see man page) to leave room at the
5033    ## end of the header for adding load commands.  Needed for dumping.
5034    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5035    ## architecture (where they are 78 bytes each). The actual number of
5036    ## load commands added is not consistent but normally ranges from
5037    ## about 14 to about 34. Setting it high gets us plenty of slop and
5038    ## only costs about 1.5K of wasted binary space.
5039    headerpad_extra=1000
5040    if test "$HAVE_NS" = "yes"; then
5041      libs_nsgui="-framework AppKit"
5042      if test "$NS_IMPL_COCOA" = "yes"; then
5043         libs_nsgui="$libs_nsgui -framework IOKit"
5044      fi
5045    else
5046      libs_nsgui=
5047    fi
5048    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5049
5050    ## This is here because src/Makefile.in did some extra fiddling around
5051    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5052    ## LD_SWITCH_SYSTEM_TEMACS instead,
5053    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5054      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5055    ;;
5056
5057   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5058   ## find X at run-time.
5059   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5060   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5061   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5062   ## had different values in configure (in ac_link) and src/Makefile.in.
5063   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5064   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5065
5066   mingw32)
5067    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5068    case "$canonical" in
5069      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5070      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5071    esac
5072    ;;
5073
5074   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5075 esac
5076
5077 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5078 # with "hardened" GCC configurations for some reason (Bug#18784).
5079 # We don't know why -nopie works, but not segfaulting is better than
5080 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5081 # clang keeps warning that it does not understand -nopie, and pre-4.6
5082 # GCC has a similar problem (Bug#20338).
5083 AC_CACHE_CHECK([whether $CC accepts -nopie],
5084   [emacs_cv_prog_cc_nopie],
5085   [emacs_save_c_werror_flag=$ac_c_werror_flag
5086    emacs_save_LDFLAGS=$LDFLAGS
5087    ac_c_werror_flag=yes
5088    LDFLAGS="$LDFLAGS -nopie"
5089    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5090      [emacs_cv_prog_cc_nopie=yes],
5091      [emacs_cv_prog_cc_nopie=no])
5092    ac_c_werror_flag=$emacs_save_c_werror_flag
5093    LDFLAGS=$emacs_save_LDFLAGS])
5094 if test "$emacs_cv_prog_cc_nopie" = yes; then
5095   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5096 fi
5097
5098 if test x$ac_enable_profiling != x ; then
5099   case $opsys in
5100     *freebsd | gnu-linux) ;;
5101     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5102   esac
5103 fi
5104
5105 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5106
5107 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5108
5109 ## Common for all window systems
5110 if test "$window_system" != "none"; then
5111   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5112   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5113   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5114 fi
5115
5116 AC_SUBST(WINDOW_SYSTEM_OBJ)
5117
5118 AH_TOP([/* GNU Emacs site configuration template file.
5119
5120 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5121   Free Software Foundation, Inc.
5122
5123 This file is part of GNU Emacs.
5124
5125 GNU Emacs is free software: you can redistribute it and/or modify
5126 it under the terms of the GNU General Public License as published by
5127 the Free Software Foundation, either version 3 of the License, or (at
5128 your option) any later version.
5129
5130 GNU Emacs is distributed in the hope that it will be useful,
5131 but WITHOUT ANY WARRANTY; without even the implied warranty of
5132 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5133 GNU General Public License for more details.
5134
5135 You should have received a copy of the GNU General Public License
5136 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5137
5138
5139 /* No code in Emacs #includes config.h twice, but some bits of code
5140    intended to work with other packages as well (like gmalloc.c)
5141    think they can include it as many times as they like.  */
5142 #ifndef EMACS_CONFIG_H
5143 #define EMACS_CONFIG_H
5144 ])dnl
5145
5146 AH_BOTTOM([#include <conf_post.h>
5147
5148 #endif /* EMACS_CONFIG_H */
5149
5150 /*
5151 Local Variables:
5152 mode: c
5153 End:
5154 */
5155 ])dnl
5156
5157 #### Report on what we decided to do.
5158 #### Report GTK as a toolkit, even if it doesn't use Xt.
5159 #### It makes printing result more understandable as using GTK sets
5160 #### toolkit_scroll_bars to yes by default.
5161 if test "${HAVE_GTK}" = "yes"; then
5162   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5163 fi
5164
5165 if test $USE_ACL -ne 0; then
5166   ACL_SUMMARY="yes $LIB_ACL"
5167 else
5168   ACL_SUMMARY=no
5169 fi
5170
5171 emacs_standard_dirs='Standard dirs'
5172 AS_ECHO(["
5173 Configured for '${canonical}'.
5174
5175   Where should the build process find the source code?    ${srcdir}
5176   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5177   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5178   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5179   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5180   What window system should Emacs use?                    ${window_system}
5181   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5182   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5183   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5184
5185 optsep=
5186 emacs_config_features=
5187 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5188   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5189   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5190   XWIDGETS; do
5191
5192     case $opt in
5193       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5194       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5195       *) eval val=\${HAVE_$opt} ;;
5196     esac
5197     case x$val in
5198       xno|xnone|x) continue ;;
5199     esac
5200     case $opt in
5201       X_TOOLKIT)
5202         case $val in
5203           GTK*|LUCID|MOTIF) opt=$val ;;
5204           *) continue ;;
5205         esac
5206       ;;
5207     esac
5208     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5209     optsep=' '
5210 done
5211 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5212   [Summary of some of the main features enabled by configure.])
5213
5214 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5215   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5216   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5217   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5218   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5219   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5220   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5221   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5222   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5223   Does Emacs support sound?                               ${HAVE_SOUND}
5224   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5225   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5226   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5227   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5228   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5229   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5230   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5231   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5232   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5233   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5234   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5235   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5236   Does Emacs use -lxft?                                   ${HAVE_XFT}
5237   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5238   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5239   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5240   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5241 "])
5242
5243 if test -n "${EMACSDATA}"; then
5244    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5245 fi
5246 if test -n "${EMACSDOC}"; then
5247    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5248 fi
5249
5250 echo
5251
5252 if test "$HAVE_NS" = "yes"; then
5253    echo
5254    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5255 The installed application will go to nextstep/Emacs.app and can be
5256 run or moved from there."])
5257    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5258       echo "The application will be fully self-contained."
5259     else
5260       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5261 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5262 to run if these resources are not installed."])
5263    fi
5264    echo
5265 fi
5266
5267 if test "${opsys}" = "cygwin"; then
5268   case `uname -r` in
5269     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5270            echo
5271            ;;
5272   esac
5273 fi
5274
5275 # Remove any trailing slashes in these variables.
5276 case $prefix in
5277   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5278 esac
5279 case $exec_prefix in
5280   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5281 esac
5282
5283 if test "$HAVE_NS" = "yes"; then
5284   if test "$NS_IMPL_GNUSTEP" = yes; then
5285     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5286       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5287     ns_check_file=Resources/Info-gnustep.plist
5288   else
5289     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5290       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5291     ns_check_file=Contents/Info.plist
5292   fi
5293   AC_SUBST(ns_check_file)
5294 fi
5295
5296 dnl config.status treats $srcdir specially, so I think this is ok...
5297 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5298
5299 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5300 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5301 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5302 dnl (else you get "no 'Makefile.am' found for any configure output").
5303 dnl This will work, but you get a config.status that is not quite right
5304 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5305 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5306 dnl it seems better to just live with the duplication.
5307 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5308
5309 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5310        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5311        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5312        leim/Makefile nextstep/Makefile nt/Makefile])
5313
5314 dnl test/ is not present in release tarfiles.
5315 opt_makefile=test/Makefile
5316
5317 if test -f "$srcdir/$opt_makefile.in"; then
5318   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5319   dnl Again, it's best not to use a variable.  Though you can add
5320   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5321   AC_CONFIG_FILES([test/Makefile])
5322 fi
5323
5324
5325 dnl The admin/ directory used to be excluded from tarfiles.
5326 if test -d $srcdir/admin; then
5327   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5328   AC_CONFIG_FILES([admin/charsets/Makefile])
5329   AC_CONFIG_FILES([admin/unidata/Makefile])
5330   AC_CONFIG_FILES([admin/grammars/Makefile])
5331 fi                              dnl -d admin
5332
5333
5334 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5335
5336 AC_SUBST(SUBDIR_MAKEFILES_IN)
5337
5338 dnl You might wonder (I did) why epaths.h is generated by running make,
5339 dnl rather than just letting configure generate it from epaths.in.
5340 dnl One reason is that the various paths are not fully expanded (see above);
5341 dnl eg gamedir=${prefix}/var/games/emacs.
5342 dnl Secondly, the GNU Coding standards require that one should be able
5343 dnl to run 'make prefix=/some/where/else' and override the values set
5344 dnl by configure.  This also explains the 'move-if-change' test and
5345 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5346 AC_CONFIG_COMMANDS([src/epaths.h], [
5347 if test "${opsys}" = "mingw32"; then
5348   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5349 else
5350   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5351 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5352 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5353
5354 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5355 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5356 dnl or a symlink?
5357 AC_CONFIG_COMMANDS([src/.gdbinit], [
5358 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5359   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5360 fi
5361 ])
5362
5363 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5364 dnl See comments for etc-refcards-emacsver.tex.
5365 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5366 dnl it is not quite the same.  But we are generating in $srcdir.
5367 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5368 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5369 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5370 ])
5371
5372 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5373 dnl then a directory etc/refcards is created in the build directory,
5374 dnl which is probably harmless, but confusing (in out-of-tree builds).
5375 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5376 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5377 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5378 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5379 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5380 ])
5381
5382 AC_OUTPUT
5383
5384 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])