code.delx.au - gnu-emacs/blob - config.bat

   1 @echo off
   2 rem   ----------------------------------------------------------------------
   3 rem   Configuration script for MSDOS
   4 rem   Copyright (C) 1994 Free Software Foundation, Inc.
   5
   6 rem   This file is part of GNU Emacs.
   7
   8 rem   GNU Emacs is free software; you can redistribute it and/or modify
   9 rem   it under the terms of the GNU General Public License as published by
  10 rem   the Free Software Foundation; either version 2, or (at your option)
  11 rem   any later version.
  12
  13 rem   GNU Emacs is distributed in the hope that it will be useful,
  14 rem   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 rem   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 rem   GNU General Public License for more details.
  17
  18 rem   You should have received a copy of the GNU General Public License
  19 rem   along with GNU Emacs; see the file COPYING.  If not, write to
  20 rem   the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  21 rem   ----------------------------------------------------------------------
  22 rem   YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:
  23 rem
  24 rem   + msdos version 3 or better.
  25 rem   + djgpp version 1,11 maint 4 or better.
  26 rem   + make utility that allows breaking of the 128 chars limit on
  27 rem     command lines.  ndmake (as of version 4.5) won't work due to a
  28 rem     line length limit.
  29 rem   + rm, mv, chmod (From GNU file utilities).
  30 rem   + sed.
  31 rem
  32 rem   You must install in directory c:/emacs or change this script.
  33 rem   ----------------------------------------------------------------------
  34 if not "%2" == "" goto usage
  35 if "%1" == "msdos" goto msdos
  36 if "%1" == "msdos-X11" goto msdos11
  37 :usage
  38 echo Usage: config msdos
  39 rem echo    or  config msdos-X11 -- don't even think about it
  40 echo [Read the script before you run it; also check that you have all the
  41 echo necessary utilities.]
  42 goto end
  43 rem   ----------------------------------------------------------------------
  44 :msdos11
  45 set X11=y
  46 goto msdoscommon
  47 rem   ----------------------------------------------------------------------
  48 :msdos
  49 set X11=
  50 :msdoscommon
  51 rem   Change to the Emacs root -- assume we are there
  52 rem cd c:\emacs
  53 rem   ----------------------------------------------------------------------
  54 Echo Configuring the source directory...
  55 cd src
  56 set PATHSH=paths-h.in
  57 if exist %PATHSH% goto src1
  58 set PATHSH=paths.h-in
  59 if exist %PATHSH% goto src1
  60 echo config: *** The file originally called "src/paths.h.in" cannot be found.
  61 cd ..
  62 goto end
  63 :src1
  64 set CONFIGH=config-h.in
  65 if exist %CONFIGH% goto src2
  66 set CONFIGH=config.h-in
  67 if exist %CONFIGH% goto src2
  68 echo config: *** The file originally called "src/config.h.in" cannot be found.
  69 cd ..
  70 goto end
  71 :src2
  72 set MAKEFILEIN=makefile.in-in
  73 if exist %MAKEFILEIN% goto src3
  74 set MAKEFILEIN=makefile-in.in
  75 if exist %MAKEFILEIN% goto src3
  76 echo makefile: *** The file originally called "src/makefile.in.in" cannot be found.
  77 cd ..
  78 goto end
  79 :src3
  80
  81 rem   Create "paths.h"
  82 rm -f paths.h
  83 sed -e "s!/lib/emacs!!" -e "s!/usr/local!c:/emacs!" -e "s!/data!/etc!" <%PATHSH% >paths.h
  84
  85 rem   Create "config.h"
  86 rm -f config.h config.tmp
  87 cp %CONFIGH% config.tmp
  88 if "%X11%" == "" goto src4
  89 sed -f ../msdos/sed4.inp <%CONFIGH% >config.tmp
  90 :src4
  91 sed -f ../msdos/sed2.inp <config.tmp >config.h
  92 rm -f config.tmp
  93
  94 rem   On my system dir.h gets in the way.  It's a VMS file so who cares.
  95 if exist dir.h ren dir.h vmsdir.h
  96
  97 rem   Create "makefile" from "makefile.in.in" using a context patch.
  98 rm -f makefile junk.c
  99 cp %MAKEFILEIN% junk.c
 100 gcc -E junk.c | sed -f ../msdos/sed1.inp >makefile
 101 rm -f junk.c
 102 cd ..
 103 rem   ----------------------------------------------------------------------
 104 Echo Configuring the library source directory...
 105 cd lib-src
 106 rem   Create "makefile" from "makefile.in".
 107 sed -e "s@^# \(Generated.*\)$@/* \1 */@" -e "s@/\*\*/#\(.*\)$@/* \1 */@" <Makefile.in >junk.c
 108 gcc -E -I. -I../src junk.c | sed -e "s/^ /      /" -e "/^#/d" -e "/^[   \f]*$/d" >Makefile.new
 109 sed -f ../msdos/sed3.inp <makefile.new >makefile
 110 cd ..
 111 rem   ----------------------------------------------------------------------
 112 Echo Configuring the main directory...
 113 copy msdos\mainmake makefile >nul
 114 rem   ----------------------------------------------------------------------
 115 :end
 116 set X11=
 117 set MAKEFILEIN=
 118 set PATHSH=
 119 set CONFIGH=
 120