code.delx.au - offlineimap/blob - src/Data/Syncable.hs

   1 {- offlineimap component
   2 Copyright (C) 2002-2008 John Goerzen <jgoerzen@complete.org>
   3
   4 This program is free software; you can redistribute it and/or modify
   5 it under the terms of the GNU General Public License as published by
   6 the Free Software Foundation; either version 2 of the License, or
   7 (at your option) any later version.
   8
   9 This program is distributed in the hope that it will be useful,
  10 but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 GNU General Public License for more details.
  13
  14 You should have received a copy of the GNU General Public License
  15 along with this program; if not, write to the Free Software
  16 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17 -}
  18
  19 {-
  20 The OfflineIMAP v6 algorithm worked like this:
  21
  22 call remoterepos.syncfoldersto(localrepos, [statusrepos])
  23
  24 for each folder, call
  25  syncfolder(remotename, remoterepos, remotefolder, localrepos, statusrepos, quick)
  26    this:
  27    sets localfolder = local folder
  28    adds localfolder to mbnames
  29    sets statusfolder = status folder
  30    if localfolder.getuidvalidity() == None, removes anything in statusfolder
  31
  32    statusfolder.cachemessagelist()
  33
  34    localfolder.cachemessagelist()
  35
  36    Check UID validity
  37    Save UID validity
  38
  39    remotefolder.cachemessagelist()
  40
  41    if not statusfolder.isnewfolder():
  42         # Delete local copies of remote messages.  This way,
  43         # if a message's flag is modified locally but it has been
  44         # deleted remotely, we'll delete it locally.  Otherwise, we
  45         # try to modify a deleted message's flags!  This step
  46         # need only be taken if a statusfolder is present; otherwise,
  47         # there is no action taken *to* the remote repository.
  48         remotefolder.syncmessagesto_delete(localfolder, [localfolder,
  49                                                          statusfolder])
  50         localfolder.syncmessagesto(statusfolder, [remotefolder, statusfolder])
  51
  52    # Synchroonize remote changes
  53    remotefolder.syncmessagesto(localfolder, [localfolder, statusfolder])
  54
  55    # Make sure the status folder is up-to-date.
  56    ui.syncingmessages(localrepos, localfolder, statusrepos, statusfolder)
  57    localfolder.syncmessagesto(statusfolder)
  58    statusfolder.save()
  59    localrepos.restore_atime()
  60
  61
  62
  63 call forgetfolders on local and remote
  64 -}
  65
  66 module Data.Syncable where
  67 import qualified Data.Map as Map
  68
  69 type SyncCollection k v = Map.Map k v
  70
  71 data (Eq k, Ord k, Show k, Show v) =>
  72     SyncCommand k v =
  73            DeleteItem k
  74          | CopyItem k v
  75          | ModifyContent k v
  76     deriving (Eq, Ord, Show)
  77
  78 pairToFunc :: (a -> b -> c) -> (a, b) -> c
  79 pairToFunc func (a, b) = func a b
  80
  81 {- | Perform a bi-directional sync.  Compared to the last known state of
  82 the child, evaluate the new states of the master and child.  Return a list of
  83 changes to make to the master and list of changes to make to the child to
  84 bring them into proper sync.
  85
  86 In the event that both master and child previously had an item, and the payload
  87 of the item has changed on both ends, the payload as given in the child
  88 will take precedence.  If both previously had an item, and it changed on only
  89 one end, the new value "wins".
  90
  91 This relationship should hold:
  92
  93 >let (masterCmds, childCmds) = syncBiDir masterState childState lastChildState
  94 >unaryApplyChanges masterState masterCmds ==
  95 > unaryApplyChanges childState childCmds
  96
  97 This relationship is validated in the test suite that accompanies this
  98 software.
  99
 100 -}
 101 syncBiDir :: (Ord k, Show k, Show v, Eq v) =>
 102             SyncCollection k v  -- ^ Present state of master
 103          -> SyncCollection k v  -- ^ Present state of child
 104          -> SyncCollection k v  -- ^ Last state of child
 105          -> ([SyncCommand k v], [SyncCommand k v]) -- ^ Changes to make to (master, child)
 106 syncBiDir masterstate childstate lastchildstate =
 107     (masterchanges, childchanges)
 108     where masterchanges = (map DeleteItem .
 109                           findDeleted childstate masterstate $ lastchildstate)
 110                           ++
 111                           (map (pairToFunc CopyItem) .
 112                            findAdded childstate masterstate $ lastchildstate)
 113                           ++ (map (pairToFunc ModifyContent) . Map.toList $ masterPayloadChanges)
 114           childchanges = (map DeleteItem .
 115                           findDeleted masterstate childstate $ lastchildstate)
 116                          ++
 117                          (map (pairToFunc CopyItem) .
 118                           findAdded masterstate childstate $ lastchildstate)
 119                          ++ (map (pairToFunc ModifyContent) . Map.toList $ childPayloadChanges)
 120           masterPayloadChanges =
 121               Map.intersection
 122                  (Map.union (findModified childstate lastchildstate)
 123                   (findModified childstate masterstate))
 124                  masterstate
 125           -- The child's payload takes precedence, so we are going to
 126           -- calculate the changes made on the master to apply to the client,
 127           -- then subtract out any items in the master changes that have the
 128           -- same key.
 129           childPayloadChanges =
 130               Map.intersection
 131                  (Map.difference (findModified masterstate lastchildstate)
 132                   (findModified childstate lastchildstate))
 133                  childstate
 134
 135 {- | Compares two SyncCollections, and returns the commands that, when
 136 applied to the first collection, would yield the second. -}
 137 diffCollection :: (Ord k, Show k, Show v) =>
 138                   SyncCollection k v
 139                -> SyncCollection k v
 140                -> [SyncCommand k v]
 141 diffCollection coll1 coll2 =
 142     (map DeleteItem . findDeleted coll2 coll1 $ coll1) ++
 143     (map (pairToFunc CopyItem) . findAdded coll2 coll1 $ coll1)
 144
 145 {- | Returns a list of keys that exist in state2 and lastchildstate
 146 but not in state1 -}
 147 findDeleted :: Ord k =>
 148                SyncCollection k v -> SyncCollection k v -> SyncCollection k v ->
 149                [k]
 150 findDeleted state1 state2 lastchildstate =
 151     Map.keys . Map.difference (Map.intersection state2 lastchildstate) $ state1
 152
 153 {- | Returns a list of keys that exist in state1 but in neither
 154 state2 nor lastchildstate -}
 155 findAdded :: (Ord k, Eq k) =>
 156                SyncCollection k v -> SyncCollection k v -> SyncCollection k v ->
 157                [(k, v)]
 158 findAdded state1 state2 lastchildstate =
 159     Map.toList . Map.difference state1 . Map.union state2 $ lastchildstate
 160
 161 {- Finds all items that exist in both state1 and lastchildstate in which the payload
 162 is different in state1 than it was in lastchildstate.  Returns the key and new
 163 payload for each such item found. -}
 164 findModified :: (Ord k, Eq v) =>
 165                 SyncCollection k v -> SyncCollection k v -> SyncCollection k v
 166 findModified state1 lastchildstate =
 167     Map.mapMaybe id .
 168     Map.intersectionWith (\v1 v2 -> if v1 /= v2 then Just v1 else Nothing)
 169        state1 $ lastchildstate
 170
 171 {- | Apply the specified changes to the given SyncCollection.  Returns
 172 a new SyncCollection with the changes applied.  If changes are specified
 173 that would apply to UIDs that do not exist in the source list, these changes
 174 are silently ignored. -}
 175 unaryApplyChanges :: (Eq k, Ord k, Show k, Show v) =>
 176                      SyncCollection k v -> [SyncCommand k v] -> SyncCollection k v
 177 unaryApplyChanges collection commands =
 178     let makeChange collection (DeleteItem key) =
 179             Map.delete key collection
 180         makeChange collection (CopyItem key val) =
 181             Map.insert key val collection
 182     in foldl makeChange collection commands