code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23
  24 m4_define(PA_MAJOR, [0])
  25 m4_define(PA_MINOR, [9])
  26 m4_define(PA_MICRO, [1])
  27
  28 AC_INIT([polypaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  29 AC_CONFIG_SRCDIR([src/daemon/main.c])
  30 AC_CONFIG_HEADERS([config.h])
  31 AM_INIT_AUTOMAKE([foreign -Wall])
  32
  33 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  34 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  35
  36 AC_SUBST(PA_API_VERSION, 9)
  37 AC_SUBST(PA_PROTOCOL_VERSION, 9)
  38
  39 AC_SUBST(LIBPOLYP_VERSION_INFO, [0:0:0])
  40 AC_SUBST(LIBPOLYPCORE_VERSION_INFO, [0:1:0])
  41 AC_SUBST(LIBPOLYP_SIMPLE_VERSION_INFO, [0:0:0])
  42 AC_SUBST(LIBPOLYP_BROWSE_VERSION_INFO, [0:0:0])
  43 AC_SUBST(LIBPOLYP_MAINLOOP_GLIB_VERSION_INFO, [0:0:0])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 #### Platform hacks ####
  51
  52 case $host in
  53    *-*-solaris* )
  54       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  55       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  56       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  57       ;;
  58 esac
  59
  60 #### Checks for programs. ####
  61
  62 # CC
  63
  64 AC_PROG_CC
  65 AC_PROG_GCC_TRADITIONAL
  66 AC_GNU_SOURCE
  67
  68 # M4
  69
  70 AC_PATH_PROG([M4], [m4 gm4], [no])
  71 if test "x$M4" = xno ; then
  72    AC_MSG_ERROR([m4 missing])
  73 fi
  74
  75 # GCC flags
  76
  77 test_gcc_flag() {
  78     AC_LANG_CONFTEST([int main() {}])
  79     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  80     ret=$?
  81     rm -f conftest.o
  82     return $ret
  83 }
  84
  85 # If using GCC specify some additional parameters
  86 if test "x$GCC" = "xyes" ; then
  87
  88     # We use gnu99 instead of c99 because many have interpreted the standard
  89     # in a way that int64_t isn't defined on non-64 bit platforms.
  90     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  91
  92     for flag in $DESIRED_FLAGS ; do
  93         AC_MSG_CHECKING([whether $CC accepts $flag])
  94         if test_gcc_flag $flag ; then
  95            CFLAGS="$CFLAGS $flag"
  96            AC_MSG_RESULT([yes])
  97         else
  98            AC_MSG_RESULT([no])
  99         fi
 100     done
 101 fi
 102
 103 # LYNX documentation generation
 104 AC_ARG_ENABLE(lynx,
 105         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
 106 [case "${enableval}" in
 107   yes) lynx=yes ;;
 108   no)  lynx=no ;;
 109   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
 110 esac],[lynx=auto])
 111
 112 if test x$lynx != xno ; then
 113    AC_CHECK_PROG(have_lynx, lynx, yes, no)
 114
 115    if test x$have_lynx = xno ; then
 116        if test x$lynx = xyes ; then
 117            AC_MSG_ERROR([*** lynx not found])
 118        else
 119            AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
 120        fi
 121    fi
 122 fi
 123
 124 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
 125
 126 #### libtool stuff ####
 127
 128 AC_LTDL_ENABLE_INSTALL
 129 AC_LIBLTDL_INSTALLABLE
 130 AC_SUBST(LTDLINCL)
 131 AC_SUBST(LIBLTDL)
 132 AC_LIBTOOL_DLOPEN
 133 AC_LIBTOOL_WIN32_DLL
 134 AC_PROG_LIBTOOL
 135 AC_CONFIG_SUBDIRS(libltdl)
 136
 137 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 138     AC_MSG_ERROR([[
 139
 140         *** Cannot find the libltdl development files.
 141         *** Maybe you need to install the libltdl-dev package.
 142         ]])
 143 fi
 144
 145 #### Determine build environment ####
 146
 147 os_is_win32=0
 148
 149 case "$host_os" in
 150         mingw*)
 151         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 152         os_is_win32=1
 153                 ;;
 154         esac
 155
 156 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 157
 158 ###################################
 159 #   Basic environment checks      #
 160 ###################################
 161
 162 #### Checks for header files. ####
 163
 164 # ISO
 165 AC_HEADER_STDC
 166
 167 # POSIX
 168 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h iconv.h netdb.h netinet/in.h \
 169     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 170     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 171     syslog.h])
 172 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 173 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 174
 175 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 176 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 177
 178 # XPG4-UNIX
 179 AC_CHECK_HEADERS([sys/poll.h])
 180
 181 # Linux
 182 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 183
 184 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 185
 186 # Solaris
 187 AC_CHECK_HEADERS([sys/filio.h])
 188
 189 # Windows
 190 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 191
 192 # Other
 193 AC_CHECK_HEADERS([sys/ioctl.h])
 194
 195 #### Typdefs, structures, etc. ####
 196
 197 AC_C_CONST
 198 AC_C_BIGENDIAN
 199 AC_TYPE_PID_T
 200 AC_TYPE_SIZE_T
 201 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 202     [Define ssize_t if it is not done by the standard libs.])])
 203 AC_TYPE_OFF_T
 204 AC_TYPE_SIGNAL
 205 AC_TYPE_UID_T
 206
 207 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 208 HAVE_SIGXCPU=1
 209 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 210 ], [HAVE_SIGXCPU=0])
 211 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 212
 213 # Solaris lacks this
 214 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 215     [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])
 216
 217 #### Check for libs ####
 218
 219 # ISO
 220 AC_SEARCH_LIBS([pow], [m])
 221
 222 # POSIX
 223 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 224 AC_SEARCH_LIBS([dlopen], [dl])
 225
 226 # BSD
 227 AC_SEARCH_LIBS([connect], [socket])
 228
 229 # Non-standard
 230
 231 # This magic is needed so we do not needlessly add static libs to the win32
 232 # build, disabling its ability to make dlls.
 233 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 234
 235 #### Check for functions ####
 236
 237 # POSIX
 238 AC_FUNC_FORK
 239 AC_FUNC_GETGROUPS
 240 AC_FUNC_SELECT_ARGTYPES
 241 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 242     getuid inet_ntop inet_pton nanosleep pipe setpgid setsid sigaction sleep])
 243 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 244
 245 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 246
 247 # X/OPEN
 248 AC_CHECK_FUNCS([readlink])
 249
 250 # SUSv2
 251 AC_CHECK_FUNCS([ctime_r usleep])
 252
 253 # SUSv3
 254 AC_CHECK_FUNCS([strerror_r])
 255
 256 # BSD
 257 AC_CHECK_FUNCS([lstat])
 258
 259 # Non-standard
 260
 261 AC_CHECK_FUNCS(setresuid)
 262 AC_CHECK_FUNCS(setreuid)
 263
 264 #### POSIX threads ####
 265
 266 ACX_PTHREAD
 267
 268 #### Large File-Support (LFS) ####
 269
 270 AC_SYS_LARGEFILE
 271
 272 ###################################
 273 #      External libraries         #
 274 ###################################
 275
 276 #### X11 (optional) ####
 277
 278 HAVE_X11=0
 279
 280 # The macro tests the host, not the build target
 281 if test "x$os_is_win32" != "x1" ; then
 282     AC_PATH_XTRA
 283     test "x$no_x" != "xyes" && HAVE_X11=1
 284 fi
 285
 286 AC_SUBST(HAVE_X11)
 287 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 288 if test "x$HAVE_X11" = "x1" ; then
 289     AC_DEFINE([HAVE_X11], 1, [Have X11])
 290 fi
 291
 292 #### Capabilities (optional) ####
 293
 294 CAP_LIBS=''
 295
 296 AC_ARG_WITH(
 297         [caps],
 298         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 299
 300 if test "x${with_caps}" != "xno"; then
 301     AC_SEARCH_LIBS([cap_init], [cap], [], [
 302                     if test "x${with_caps}" = "xyes" ; then
 303                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 304                     fi])
 305     AC_CHECK_HEADERS([sys/capability.h], [], [
 306                     if test "x${with_caps}" = "xyes" ; then
 307                         AC_MSG_ERROR([*** POSIX caps headers not found])
 308                     fi])
 309 fi
 310
 311 #### pkg-config ####
 312
 313 # Check for pkg-config manually first, as if its not installed the
 314 # PKG_PROG_PKG_CONFIG macro won't be defined.
 315 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 316
 317 if test x"$have_pkg_config" = "xno"; then
 318     AC_MSG_ERROR(pkg-config is required to install this program)
 319 fi
 320
 321 PKG_PROG_PKG_CONFIG
 322
 323 #### Sample rate conversion ####
 324
 325 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 326 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 327 AC_SUBST(LIBSAMPLERATE_LIBS)
 328
 329 #### Sound file ####
 330
 331 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 332 AC_SUBST(LIBSNDFILE_CFLAGS)
 333 AC_SUBST(LIBSNDFILE_LIBS)
 334
 335 #### OSS support (optional) ####
 336
 337 AC_ARG_ENABLE([oss],
 338     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 339     [case "${enableval}" in yes) oss=yes ;; no) oss=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;; esac],[oss=auto])
 340 if test "x${oss}" != xno ; then
 341     AC_CHECK_HEADERS([sys/soundcard.h], [
 342     HAVE_OSS=1
 343     AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 344     ], [HAVE_OSS=0 ; if test "x$oss" = xyes ; then AC_MSG_ERROR([*** OSS support not found]) ; fi])
 345 else HAVE_OSS=0; fi
 346 AC_SUBST(HAVE_OSS)
 347 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 348
 349
 350 #### ALSA support (optional) ####
 351
 352 AC_ARG_ENABLE([alsa],
 353     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 354     [case "${enableval}" in yes) alsa=yes ;; no) alsa=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;; esac],[alsa=auto])
 355 if test "x${alsa}" != xno ; then
 356     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [
 357     HAVE_ALSA=1
 358     AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 359     ], [HAVE_ALSA=0 ; if test "x$alsa" = xyes ; then AC_MSG_ERROR([*** ALSA support not found]) ; fi])
 360 else HAVE_ALSA=0 ; fi
 361 AC_SUBST(ASOUNDLIB_CFLAGS)
 362 AC_SUBST(ASOUNDLIB_LIBS)
 363 AC_SUBST(HAVE_ALSA)
 364 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 365
 366 #### Solaris audio support (optional) ####
 367
 368 AC_ARG_ENABLE([solaris],
 369     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 370     [case "${enableval}" in yes) solaris=yes ;; no) solaris=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;; esac],[solaris=auto])
 371 if test "x${solaris}" != xno ; then
 372     AC_CHECK_HEADERS([sys/audio.h], [
 373     HAVE_SOLARIS=1
 374     AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 375     ], [HAVE_SOLARIS=0 ; if test "x$solaris" = xyes ; then AC_MSG_ERROR([*** Solaris audio support not found]) ; fi])
 376 else HAVE_SOLARIS=0 ; fi
 377 AC_SUBST(HAVE_SOLARIS)
 378 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 379
 380 #### GLib 2 support (optional) ####
 381
 382 AC_ARG_ENABLE([glib2],
 383     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 384     [case "${enableval}" in yes) glib2=yes ;; no) glib2=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;; esac],[glib2=auto])
 385 if test "x${glib2}" != xno ; then
 386     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, [HAVE_GLIB20=0 ; if test "x$glib2" = xyes ; then AC_MSG_ERROR([*** GLib 2 support not found]) ; fi])
 387 else HAVE_GLIB20=0 ; fi
 388 AC_SUBST(GLIB20_CFLAGS)
 389 AC_SUBST(GLIB20_LIBS)
 390 AC_SUBST(HAVE_GLIB20)
 391 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 392
 393 #### GLib 1 support (optional) ####
 394
 395 AC_ARG_ENABLE([glib1],
 396     AC_HELP_STRING([--disable-glib1], [Disable optional GLib 1 support]),
 397     [case "${enableval}" in yes) glib1=yes ;; no) glib1=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib1) ;; esac],[glib1=auto])
 398 if test "x${glib1}" != xno ; then
 399     PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, [HAVE_GLIB12=0 ; if test "x$glib1" = xyes ; then AC_MSG_ERROR([*** GLib 1 support not found]) ; fi])
 400 else HAVE_GLIB12=0 ; fi
 401 AC_SUBST(GLIB12_CFLAGS)
 402 AC_SUBST(GLIB12_LIBS)
 403 AC_SUBST(HAVE_GLIB12)
 404 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 405
 406 #### Howl support (optional) ####
 407
 408 AC_ARG_ENABLE([howl],
 409     AC_HELP_STRING([--disable-howl], [Disable optional Howl support]),
 410     [case "${enableval}" in yes) howl=yes ;; no) howl=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-howl) ;; esac],[howl=auto])
 411 if test "x${howl}" != xno ; then
 412     PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, PKG_CHECK_MODULES(HOWL, [ avahi-compat-howl >= 0.9.8 ], HAVE_HOWL=1, [HAVE_HOWL=0 ; if test "x$howl" = xyes ; then AC_MSG_ERROR([*** Howl support not found]) ; fi]))
 413 else HAVE_HOWL=0 ; fi
 414 AC_SUBST(HOWL_CFLAGS)
 415 AC_SUBST(HOWL_LIBS)
 416 AC_SUBST(HAVE_HOWL)
 417 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 418
 419 ### LIBOIL ####
 420
 421 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 422 AC_SUBST(LIBOIL_CFLAGS)
 423 AC_SUBST(LIBOIL_LIBS)
 424
 425 ### JACK (optional) ####
 426
 427 AC_ARG_ENABLE([jack],
 428     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 429     [case "${enableval}" in yes) jack=yes ;; no) jack=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;; esac],[jack=auto])
 430 if test "x${jack}" != xno ; then
 431     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ], HAVE_JACK=1, [HAVE_JACK=0 ; if test "x$jack" = xyes ; then AC_MSG_ERROR([*** JACK support not found]) ; fi])
 432 else HAVE_JACK=0 ; fi
 433 AC_SUBST(JACK_CFLAGS)
 434 AC_SUBST(JACK_LIBS)
 435 AC_SUBST(HAVE_JACK)
 436 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 437
 438 #### Async DNS support (optional) ####
 439
 440 AC_ARG_ENABLE([asyncns],
 441     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 442     [case "${enableval}" in yes) asyncns=yes ;; no) asyncns=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;; esac],[asyncns=auto])
 443 if test "x${asyncns}" != xno ; then
 444     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, [HAVE_LIBASYNCNS=0 ; if test "x$asyncns" = xyes ; then AC_MSG_ERROR([*** Async DNS support not found]) ; fi])
 445 else HAVE_LIBASYNCNS=0 ; fi
 446 AC_SUBST(LIBASYNCNS_CFLAGS)
 447 AC_SUBST(LIBASYNCNS_LIBS)
 448 AC_SUBST(HAVE_LIBASYNCNS)
 449 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 450
 451 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 452    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 453 fi
 454
 455 #### TCP wrappers (optional) ####
 456
 457 AC_ARG_ENABLE([tcpwrap],
 458     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 459     [case "${enableval}" in yes) tcpwrap=yes ;; no) tcpwrap=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;; esac],[tcpwrap=auto])
 460 if test "x${tcpwrap}" != xno ; then
 461     ACX_LIBWRAP
 462     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 463         AC_MSG_ERROR([*** TCP wrappers support not found])
 464     fi
 465 else LIBWRAP_LIBS= ; fi
 466 AC_SUBST(LIBWRAP_LIBS)
 467
 468 #### LIRC support (optional) ####
 469
 470 AC_ARG_ENABLE([lirc],
 471     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 472     [case "${enableval}" in yes) lirc=yes ;; no) lirc=no ;; *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;; esac],[lirc=auto])
 473 if test "x${lirc}" != xno ; then
 474     ACX_LIRC
 475     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 476         AC_MSG_ERROR([*** LIRC support not found])
 477     fi
 478 else HAVE_LIRC=0 ; fi
 479 AC_SUBST(LIRC_CFLAGS)
 480 AC_SUBST(LIRC_LIBS)
 481 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 482
 483 ###################################
 484 #            Output               #
 485 ###################################
 486
 487 AC_ARG_ENABLE(
 488         [static-bins],
 489         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 490         [STATIC_BINS=1], [STATIC_BINS=0])
 491 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 492
 493 AC_ARG_WITH(
 494         [preopen-mods],
 495         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 496         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 497 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 498 if test "x$PREOPEN_MODS" != "xall" ; then
 499     tmpLIBS=""
 500     for mod in $PREOPEN_MODS; do
 501         tmpLIBS="$tmpLIBS module-$mod.la"
 502     done
 503     PREOPEN_MODS="$tmpLIBS"
 504     AC_SUBST(PREOPEN_MODS)
 505 fi
 506
 507 AC_ARG_WITH(
 508         [module-dir],
 509         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/polypaudio-${PA_MAJORMINOR}/modules/]),
 510         [modlibexecdir=$withval], [modlibexecdir="${libdir}/polypaudio-${PA_MAJORMINOR}/modules/"])
 511
 512 AC_SUBST(modlibexecdir)
 513
 514 AC_ARG_ENABLE(
 515         [force-preopen],
 516         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 517         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 518 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 519
 520 AC_CONFIG_FILES([
 521 Makefile
 522 src/Makefile
 523 polyplib.pc
 524 polyplib-simple.pc
 525 polyplib-browse.pc
 526 polyplib-glib-mainloop.pc
 527 polyplib-glib12-mainloop.pc
 528 doc/Makefile
 529 doc/README.html
 530 doc/cli.html
 531 doc/daemon.html
 532 doc/modules.html
 533 doxygen/Makefile
 534 doxygen/doxygen.conf
 535 src/polyp/version.h
 536 doc/FAQ.html
 537 ])
 538 AC_OUTPUT