code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23 AC_INIT([polypaudio],[0.8],[mzcbylcnhqvb (at) 0pointer (dot) de])
  24 AC_CONFIG_SRCDIR([polyp/main.c])
  25 AC_CONFIG_HEADERS([config.h])
  26 AM_INIT_AUTOMAKE([foreign -Wall])
  27
  28 AC_SUBST(PA_MAJORMINOR, "$PACKAGE_VERSION")
  29 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  30
  31 AC_SUBST(PA_API_VERSION, 8)
  32
  33 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  34    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  35    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  36 fi
  37
  38 #### Checks for programs. ####
  39
  40 # CC
  41
  42 AC_PROG_CC
  43 AC_PROG_GCC_TRADITIONAL
  44 AC_GNU_SOURCE
  45
  46 # M4
  47
  48 AC_PATH_PROG([M4], [m4 gm4], [no])
  49 if test "x$M4" = xno ; then
  50    AC_MSG_ERROR([m4 missing])
  51 fi
  52
  53 # GCC flags
  54
  55 test_gcc_flag() {
  56     AC_LANG_CONFTEST([int main() {}])
  57     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  58     ret=$?
  59     rm -f conftest.o
  60     return $ret
  61 }
  62
  63 # If using GCC specify some additional parameters
  64 if test "x$GCC" = "xyes" ; then
  65
  66     DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  67
  68     if test "x$HAVE_NETLINK" = "xyes" ; then
  69         # Test whether rtnetlink.h can be included when compiled with -std=c99
  70         # some distributions (e.g. archlinux) have broken headers that dont
  71         # define __u64 with -std=c99
  72         AC_MSG_CHECKING([checking whether rtnetlink.h can be included with -std=c99])
  73         OLDCFLAGS="$CFLAGS"
  74         CFLAGS="-std=c99"
  75         AC_TRY_COMPILE([#include <linux/rtnetlink.h>], [],
  76             use_stdc99=yes, use_stdc99=no)
  77
  78         if test x"$use_stdc99" = xyes; then
  79             DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
  80             AC_MSG_RESULT([yes])
  81         else
  82             AC_MSG_RESULT([no])
  83         fi
  84
  85         CFLAGS="$OLDCFLAGS"
  86     else
  87         DESIRED_FLAGS="-std=c99 $DESIRED_FLAGS"
  88     fi
  89
  90     for flag in $DESIRED_FLAGS ; do
  91         AC_MSG_CHECKING([whether $CC accepts $flag])
  92         if test_gcc_flag $flag ; then
  93            CFLAGS="$CFLAGS $flag"
  94            AC_MSG_RESULT([yes])
  95         else
  96            AC_MSG_RESULT([no])
  97         fi
  98     done
  99 fi
 100
 101 # LYNX documentation generation
 102 AC_ARG_ENABLE(lynx,
 103         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
 104 [case "${enableval}" in
 105   yes) lynx=yes ;;
 106   no)  lynx=no ;;
 107   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
 108 esac],[lynx=yes])
 109
 110 if test x$lynx = xyes ; then
 111    AC_CHECK_PROG(have_lynx, lynx, yes, no)
 112
 113    if test x$have_lynx = xno ; then
 114      AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
 115    fi
 116 fi
 117
 118 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
 119
 120 #### libtool stuff ####
 121
 122 AC_LTDL_ENABLE_INSTALL
 123 AC_LIBLTDL_INSTALLABLE
 124 AC_SUBST(LTDLINCL)
 125 AC_SUBST(LIBLTDL)
 126 AC_LIBTOOL_DLOPEN
 127 AC_LIBTOOL_WIN32_DLL
 128 AC_PROG_LIBTOOL
 129 AC_CONFIG_SUBDIRS(libltdl)
 130
 131 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 132     AC_MSG_ERROR([[
 133
 134         *** Cannot find the libltdl development files.
 135         *** Maybe you need to install the libltdl-dev package.
 136         ]])
 137 fi
 138
 139 #### Determine build environment ####
 140
 141 os_is_win32=0
 142
 143 case "$host_os" in
 144         mingw*)
 145         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 146         os_is_win32=1
 147                 ;;
 148         esac
 149
 150 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 151
 152 ###################################
 153 #   Basic environment checks      #
 154 ###################################
 155
 156 #### Checks for header files. ####
 157
 158 # ISO
 159 AC_HEADER_STDC
 160
 161 # POSIX
 162 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 163     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 164     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 165     syslog.h])
 166 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 167 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 168
 169 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 170 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 171
 172 # XPG4-UNIX
 173 AC_CHECK_HEADERS([sys/poll.h])
 174
 175 # Linux
 176 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 177
 178 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 179
 180 # Windows
 181 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 182
 183 # Other
 184 AC_CHECK_HEADERS([sys/ioctl.h])
 185
 186 #### Typdefs, structures, etc. ####
 187
 188 AC_C_CONST
 189 AC_C_BIGENDIAN
 190 AC_TYPE_PID_T
 191 AC_TYPE_SIZE_T
 192 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 193     [Define ssize_t if it is not done by the standard libs.])])
 194 AC_TYPE_OFF_T
 195 AC_TYPE_SIGNAL
 196 AC_TYPE_UID_T
 197
 198 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 199 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 200
 201 # Solaris lacks this
 202 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 203     [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])
 204
 205 #### Check for libs ####
 206
 207 # ISO
 208 AC_CHECK_LIB([m], [pow])
 209
 210 # POSIX
 211 AC_CHECK_LIB([rt], [sched_setscheduler])
 212
 213 # BSD
 214 AC_CHECK_LIB([socket], [connect])
 215
 216 # Non-standard
 217
 218 # This magic is needed so we do not needlessly add static libs to the win32
 219 # build, disabling its ability to make dlls.
 220 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 221
 222 #### Check for functions ####
 223
 224 # POSIX
 225 AC_FUNC_FORK
 226 AC_FUNC_GETGROUPS
 227 AC_FUNC_SELECT_ARGTYPES
 228 AC_CHECK_FUNCS([getaddrinfo getgrgid_r getpwuid_r gettimeofday getuid \
 229     inet_ntop nanosleep setpgid setsid sigaction sleep])
 230 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 231
 232 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 233
 234 # X/OPEN
 235 AC_CHECK_FUNCS([readlink])
 236
 237 # SUSv2
 238 AC_CHECK_FUNCS([ctime_r usleep])
 239
 240 # BSD
 241 AC_CHECK_FUNCS([lstat])
 242
 243 # Non-standard
 244
 245 AC_CHECK_FUNCS(setresuid)
 246 AC_CHECK_FUNCS(setreuid)
 247
 248 #### POSIX threads ####
 249
 250 ACX_PTHREAD
 251
 252 ###################################
 253 #      External libraries         #
 254 ###################################
 255
 256 #### X11 (optional) ####
 257
 258 HAVE_X11=0
 259
 260 # The macro tests the host, not the build target
 261 if test "x$os_is_win32" != "x1" ; then
 262     AC_PATH_XTRA
 263     test "x$no_x" != "xyes" && HAVE_X11=1
 264 fi
 265
 266 AC_SUBST(HAVE_X11)
 267 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 268 if test "x$HAVE_X11" = "x1" ; then
 269     AC_DEFINE([HAVE_X11], 1, [Have X11])
 270 fi
 271
 272 #### Capabilities (optional) ####
 273
 274 CAP_LIBS=''
 275
 276 AC_ARG_WITH(
 277         [caps],
 278         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 279
 280 if test "x${with_caps}" != "xno"; then
 281     AC_CHECK_LIB(cap, cap_init, [CAP_LIBS='-lcap'], [CAP_LIBS=''])
 282     AC_CHECK_HEADERS([sys/capability.h])
 283 fi
 284 AC_SUBST(CAP_LIBS)
 285
 286 #### pkg-config ####
 287
 288 # Check for pkg-config manually first, as if its not installed the
 289 # PKG_PROG_PKG_CONFIG macro won't be defined.
 290 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 291
 292 if test x"$have_pkg_config" = "xno"; then
 293     AC_MSG_ERROR(pkg-config is required to install this program)
 294 fi
 295
 296 PKG_PROG_PKG_CONFIG
 297
 298 #### Sample rate conversion ####
 299
 300 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 301 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 302 AC_SUBST(LIBSAMPLERATE_LIBS)
 303
 304 #### Sound file ####
 305
 306 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 307 AC_SUBST(LIBSNDFILE_CFLAGS)
 308 AC_SUBST(LIBSNDFILE_LIBS)
 309
 310 #### OSS support (optional) ####
 311
 312 AC_CHECK_HEADERS([sys/soundcard.h], [HAVE_OSS=1], [HAVE_OSS=0])
 313 AC_SUBST(HAVE_OSS)
 314 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 315
 316 #### ALSA support (optional) ####
 317
 318 PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [HAVE_ALSA=1], [HAVE_ALSA=0])
 319 AC_SUBST(ASOUNDLIB_CFLAGS)
 320 AC_SUBST(ASOUNDLIB_LIBS)
 321 AC_SUBST(HAVE_ALSA)
 322 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 323
 324 #### Solaris audio support (optional) ####
 325
 326 AC_CHECK_HEADERS([sys/audio.h], [HAVE_SOLARIS=1], [HAVE_SOLARIS=0])
 327 AC_SUBST(HAVE_SOLARIS)
 328 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 329
 330 #### GLib 2 support (optional) ####
 331
 332 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)
 333 AC_SUBST(GLIB20_CFLAGS)
 334 AC_SUBST(GLIB20_LIBS)
 335 AC_SUBST(HAVE_GLIB20)
 336 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 337
 338 #### GLib 1 support (optional) ####
 339
 340 PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, HAVE_GLIB12=0)
 341 AC_SUBST(GLIB12_CFLAGS)
 342 AC_SUBST(GLIB12_LIBS)
 343 AC_SUBST(HAVE_GLIB12)
 344 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 345
 346 #### Howl support (optional) ####
 347
 348 PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, HAVE_HOWL=0)
 349 AC_SUBST(HOWL_CFLAGS)
 350 AC_SUBST(HOWL_LIBS)
 351 AC_SUBST(HAVE_HOWL)
 352 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 353
 354 #### Async DNS support (optional) ####
 355
 356 PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)
 357 AC_SUBST(LIBASYNCNS_CFLAGS)
 358 AC_SUBST(LIBASYNCNS_LIBS)
 359 AC_SUBST(HAVE_LIBASYNCNS)
 360 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 361
 362 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 363    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 364 fi
 365
 366 #### TCP wrappers (optional) ####
 367
 368 ACX_LIBWRAP
 369 AC_SUBST(LIBWRAP_LIBS)
 370
 371 #### LIRC support (optional) ####
 372
 373 ACX_LIRC
 374 AC_SUBST(LIRC_CFLAGS)
 375 AC_SUBST(LIRC_LIBS)
 376 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 377
 378 ###################################
 379 #            Output               #
 380 ###################################
 381
 382 AC_ARG_ENABLE(
 383         [static-bins],
 384         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 385         [STATIC_BINS=1], [STATIC_BINS=0])
 386 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 387
 388 AC_ARG_WITH(
 389         [preopen-mods],
 390         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 391         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 392 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 393 if test "x$PREOPEN_MODS" != "xall" ; then
 394     tmpLIBS=""
 395     for mod in $PREOPEN_MODS; do
 396         tmpLIBS="$tmpLIBS module-$mod.la"
 397     done
 398     PREOPEN_MODS="$tmpLIBS"
 399     AC_SUBST(PREOPEN_MODS)
 400 fi
 401
 402 AC_CONFIG_FILES([
 403 Makefile
 404 polyp/Makefile
 405 polyplib.pc
 406 polyplib-simple.pc
 407 polyplib-mainloop.pc
 408 polyplib-browse.pc
 409 polyplib-error.pc
 410 polyplib-glib-mainloop.pc
 411 polyplib-glib12-mainloop.pc
 412 doc/Makefile
 413 doc/README.html
 414 doc/cli.html
 415 doc/daemon.html
 416 doc/modules.html
 417 doxygen/Makefile
 418 doxygen/doxygen.conf
 419 polyp/polyplib-version.h
 420 doc/FAQ.html
 421 ])
 422 AC_OUTPUT