]> code.delx.au - pulseaudio/blob - configure.ac
delx.au / code / pulseaudio / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
Merge branch 'passthrough'
[pulseaudio] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4 # This file is part of PulseAudio.
5 #
6 # Copyright 2004-2008 Lennart Poettering
7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
8 #
9 # PulseAudio is free software; you can redistribute it and/or modify it
10 # under the terms of the GNU Lesser General Public License as published by
11 # the Free Software Foundation; either version 2 of the License, or
12 # (at your option) any later version.
13 #
14 # PulseAudio is distributed in the hope that it will be useful, but
15 # WITHOUT ANY WARRANTY; without even the implied warranty of
16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
17 # General Public License for more details.
18 #
19 # You should have received a copy of the GNU Lesser General Public License
20 # along with PulseAudio; if not, write to the Free Software Foundation,
21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
22
23 AC_PREREQ(2.63)
24
25 AC_INIT([pulseaudio],[m4_esyscmd(./git-version-gen .tarball-version)],[mzchyfrnhqvb (at) 0pointer (dot) net])
26 AC_CONFIG_SRCDIR([src/daemon/main.c])
27 AC_CONFIG_MACRO_DIR([m4])
28 AC_CONFIG_HEADERS([config.h])
29 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax])
30
31 m4_define(pa_major, `echo $VERSION | cut -d. -f1 | cut -d- -f1`)
32 m4_define(pa_minor, `echo $VERSION | cut -d. -f2 | cut -d- -f1`)
33
34 AC_SUBST(PA_MAJOR, pa_major)
35 AC_SUBST(PA_MINOR, pa_minor)
36 AC_SUBST(PA_MAJORMINOR, pa_major.pa_minor)
37 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
38
39 AC_SUBST(PA_API_VERSION, 12)
40 AC_SUBST(PA_PROTOCOL_VERSION, 21)
41
42 # The stable ABI for client applications, for the version info x:y:z
43 # always will hold y=z
44 AC_SUBST(LIBPULSE_VERSION_INFO, [12:3:12])
45
46 # A simplified, synchronous, ABI-stable interface for client
47 # applications, for the version info x:y:z always will hold y=z
48 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:3:0])
49
50 # The ABI-stable network browsing interface for client applications,
51 # for the version info x:y:z always will hold y=z
52 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
53
54 # The ABI-stable GLib adapter for client applications, for the version
55 # info x:y:z always will hold y=z
56 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:4:0])
57
58 AC_CANONICAL_HOST
59 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
60
61 AC_CHECK_PROG([STOW], [stow], [yes], [no])
62
63 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
64 AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
65 ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
66 ])
67
68 AM_SILENT_RULES([yes])
69
70 #### Checks for programs. ####
71
72 # mkdir -p
73
74 AC_PROG_MKDIR_P
75
76 # CC
77
78 AC_PROG_CC
79 AC_PROG_CC_C99
80 AM_PROG_CC_C_O
81 AC_PROG_GCC_TRADITIONAL
82 AC_USE_SYSTEM_EXTENSIONS
83
84 #### Platform hacks ####
85
86 case $host in
87 *-*-solaris* )
88 AC_DEFINE(_XOPEN_SOURCE, 600, Needed to get declarations for msg_control and msg_controllen on Solaris)
89 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
90 ;;
91 *-*-darwin* )
92 AC_DEFINE([_DARWIN_C_SOURCE], [200112L], [Needed to get NSIG on Mac OS X])
93 ;;
94 esac
95
96 # M4
97
98 AC_CHECK_PROGS([M4], gm4 m4, no)
99 if test "x$M4" = xno ; then
100 AC_MSG_ERROR([m4 missing])
101 fi
102
103 dnl Compiler flags
104
105 # Some compilers (e.g. clang) default to a warning on an unkown command line option.
106 # Change that temporarily to an error, for the CC_CHECK_CFLAGS_APPEND macro to work.
107 save_CC="$CC"
108 CC="$CC -Werror"
109 CC_CHECK_CFLAGS_APPEND([-Wall -W -Wextra -pipe -Wno-long-long -Wvla -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing -Wwrite-strings -Wno-unused-parameter -ffast-math -Wp,-D_FORTIFY_SOURCE=2 -fno-common -fdiagnostics-show-option])
110 CC="$save_CC"
111
112 dnl Linker flags.
113 dnl Check whether the linker supports the -version-script option.
114
115 dnl This variable is used to make sure ${srcdir} is expanded and not
116 dnl passed to the CC_CHECK_LDFLAGS macro as a name.
117 tmp_ldflag="-Wl,-version-script=${srcdir}/src/map-file"
118
119 CC_CHECK_LDFLAGS([${tmp_ldflag}],
120 [VERSIONING_LDFLAGS='-Wl,-version-script=$(srcdir)/map-file'])
121 AC_SUBST([VERSIONING_LDFLAGS])
122
123 dnl Use immediate (now) bindings; avoids the funky re-call in itself
124 dnl the -z now syntax is lifted from Sun's linker and works with GNU's too
125 dnl other linkes might be added later
126 CC_CHECK_LDFLAGS([-Wl,-z,now], [IMMEDIATE_LDFLAGS="-Wl,-z,now"])
127 AC_SUBST([IMMEDIATE_LDFLAGS])
128
129 dnl On ELF systems we don't want the libraries to be unloaded since we
130 dnl don't clean them up properly, so we request the nodelete flag to be
131 dnl enabled.
132 dnl
133 dnl On other systems, we don't really know how to do that, but it's
134 dnl welcome if somebody can tell.
135 CC_CHECK_LDFLAGS([-Wl,-z,nodelete], [NODELETE_LDFLAGS="-Wl,-z,nodelete"])
136 AC_SUBST([NODELETE_LDFLAGS])
137
138 dnl Check for the proper way to build libraries that have no undefined
139 dnl symbols; on some hosts this needs to be avoided but the macro
140 dnl takes care of it.
141 CC_NOUNDEFINED
142
143 dnl Check whether to build tests by default (as compile-test) or not
144 AC_ARG_ENABLE([default-build-tests],
145 AS_HELP_STRING([--disable-default-build-tests], [Build test programs only during make check]))
146
147 AM_CONDITIONAL([BUILD_TESTS_DEFAULT], [test "x$enable_default_build_tests" != "xno"])
148
149 # Native atomic operation support
150 AC_ARG_ENABLE([atomic-arm-linux-helpers],
151 AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]))
152
153 AC_ARG_ENABLE([atomic-arm-memory-barrier],
154 AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]))
155
156 if test "x$enable_atomic_arm_memory_barrier" = "xyes"; then
157 AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers])
158 fi
159
160 AC_ARG_ENABLE(mac-universal,
161 AS_HELP_STRING([--enable-mac-universal], [Build Mac universal binaries]),
162 enable_mac_universal=$enableval, enable_mac_universal="no")
163
164 AC_ARG_WITH(mac-version-min,
165 AS_HELP_STRING([--with-mac-version-min=<version>], [Defines the earliest version of MacOS X that the executables will run on.]),
166 mac_version_min=$withval, mac_version_min="10.5")
167
168 AC_ARG_WITH(mac-sysroot,
169 AS_HELP_STRING([--with-mac-sysroot=<path>], [SDK basedir to use as the logical root directory for headers and libraries.]),
170 mac_sysroot=$withval, mac_sysroot="/Developer/SDKs/MacOSX10.5.sdk")
171
172 AC_MSG_CHECKING([target operating system])
173 case $host in
174 *-*-linux*)
175 AC_MSG_RESULT([linux])
176 pulse_target_os=linux
177 ;;
178 *-*-darwin*)
179 AC_MSG_RESULT([darwin])
180 pulse_target_os=darwin
181
182 LDFLAGS="$LDFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
183 CFLAGS="$CFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
184
185 if test "x$enable_mac_universal" = "xyes" ; then
186 mac_arches="-arch i386 -arch x86_64"
187 LDFLAGS="$LDFLAGS $mac_arches"
188 CFLAGS="$CFLAGS $mac_arches"
189 fi
190 ;;
191 *)
192 AC_MSG_RESULT([unknown])
193 pulse_target_os=unknown
194 ;;
195 esac
196
197 # If everything else fails use libatomic_ops
198 need_libatomic_ops=yes
199
200 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
201 pulseaudio_cv_sync_bool_compare_and_swap,
202 [AC_LINK_IFELSE(
203 AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
204 [pulseaudio_cv_sync_bool_compare_and_swap=yes],
205 [pulseaudio_cv_sync_bool_compare_and_swap=no])
206 ])
207
208 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
209 AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
210 need_libatomic_ops=no
211 else
212 # HW specific atomic ops stuff
213 AC_MSG_CHECKING([architecture for native atomic operations])
214 case $host in
215 arm*)
216 AC_MSG_RESULT([arm])
217 AC_MSG_CHECKING([whether we can use Linux kernel helpers])
218 # The Linux kernel helper functions have been there since 2.6.16. However
219 # compile time checking for kernel version in cross compile environment
220 # (which is usually the case for arm cpu) is tricky (or impossible).
221 if test "x$pulse_target_os" = "xlinux" && test "x$enable_atomic_arm_linux_helpers" != "xno"; then
222 AC_MSG_RESULT([yes])
223 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
224 need_libatomic_ops=no
225 else
226 AC_MSG_RESULT([no])
227 AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
228 pulseaudio_cv_support_arm_atomic_ops,
229 [AC_COMPILE_IFELSE(
230 AC_LANG_PROGRAM([],
231 [[volatile int a=0;
232 int o=0, n=1, r;
233 asm volatile ("ldrex %0, [%1]\n"
234 "subs %0, %0, %2\n"
235 "strexeq %0, %3, [%1]\n"
236 : "=&r" (r)
237 : "r" (&a), "Ir" (o), "r" (n)
238 : "cc");
239 return (a==1 ? 0 : -1);
240 ]]),
241 [pulseaudio_cv_support_arm_atomic_ops=yes],
242 [pulseaudio_cv_support_arm_atomic_ops=no])
243 ])
244 AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
245 AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARM atomic instructions.])
246 need_libatomic_ops=no
247 ])
248 fi
249 ;;
250 *-netbsdelf5*)
251 AC_MSG_RESULT([yes])
252 need_libatomic_ops=no
253 ;;
254 *-freebsd*)
255 AC_MSG_RESULT([yes])
256 need_libatomic_ops=no
257 ;;
258 *)
259 AC_MSG_RESULT([unknown])
260 ;;
261 esac
262 fi
263
264 # If we're on ARM, check for the ARMV6 instructions we need */
265 case $host in
266 arm*)
267 AC_CACHE_CHECK([support for required armv6 instructions],
268 pulseaudio_cv_support_armv6,
269 [AC_COMPILE_IFELSE(
270 AC_LANG_PROGRAM([],
271 [[volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
272 asm volatile ("ldr r0, %2 \n"
273 "ldr r2, %3 \n"
274 "ldr r3, %4 \n"
275 "ssat r1, #8, r0 \n"
276 "str r1, %0 \n"
277 "pkhbt r1, r3, r2, LSL #8 \n"
278 "str r1, %1 \n"
279 : "=m" (a), "=m" (b)
280 : "m" (a), "m" (b), "m" (c)
281 : "r0", "r1", "r2", "r3", "cc");
282 return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
283 ]]),
284 [pulseaudio_cv_support_armv6=yes],
285 [pulseaudio_cv_support_armv6=no])
286 ])
287 AS_IF([test "$pulseaudio_cv_support_armv6" = "yes"], [
288 AC_DEFINE([HAVE_ARMV6], 1, [Have ARMv6 instructions.])
289 ])
290 ;;
291 *)
292 ;;
293 esac
294
295 CC_CHECK_TLS
296
297 AC_CACHE_CHECK([whether $CC knows _Bool],
298 pulseaudio_cv__Bool,
299 [AC_COMPILE_IFELSE(
300 AC_LANG_PROGRAM([], [[_Bool b;]]),
301 [pulseaudio_cv__Bool=yes],
302 [pulseaudio_cv__Bool=no])
303 ])
304
305 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], [
306 AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
307 ])
308
309 #### libtool stuff ####
310 LT_PREREQ(2.2)
311 LT_INIT([dlopen win32-dll disable-static])
312
313 dnl Unfortunately, even up to libtool 2.2.6a there is no way to know
314 dnl exactly which version of libltdl is present in the system, so we
315 dnl just assume that it's a working version as long as we have the
316 dnl library and the header files.
317 dnl
318 dnl As an extra safety device, check for lt_dladvise_init() which is
319 dnl only implemented in libtool 2.x, and refine as we go if we have
320 dnl refined requirements.
321 dnl
322 dnl Check the header files first since the system may have a
323 dnl libltdl.so for runtime, but no headers, and we want to bail out as
324 dnl soon as possible.
325 dnl
326 dnl We don't need any special variable for this though, since the user
327 dnl can give the proper place to find libltdl through the standard
328 dnl variables like LDFLAGS and CPPFLAGS.
329
330 AC_CHECK_HEADER([ltdl.h],
331 [AC_CHECK_LIB([ltdl], [lt_dladvise_init], [LIBLTDL=-lltdl], [LIBLTDL=])],
332 [LIBLTDL=])
333
334 AS_IF([test "x$LIBLTDL" = "x"],
335 [AC_MSG_ERROR([Unable to find libltdl version 2. Makes sure you have libtool 2.2 or later installed.])])
336 AC_SUBST([LIBLTDL])
337
338 #### Determine build environment ####
339
340 os_is_win32=0
341 os_is_darwin=0
342
343 case "$host_os" in
344 mingw*)
345 AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
346 os_is_win32=1
347 ;;
348 darwin*)
349 AC_DEFINE([OS_IS_DARWIN], 1, [Build target is Darwin.])
350 os_is_darwin=1
351 ;;
352 esac
353
354 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
355 AM_CONDITIONAL(OS_IS_DARWIN, test "x$os_is_darwin" = "x1")
356
357 ###################################
358 # Basic environment checks #
359 ###################################
360
361 #### Checks for header files. ####
362
363 # ISO
364 AC_HEADER_STDC
365
366 # POSIX
367 AC_CHECK_HEADERS_ONCE([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
368 netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
369 sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
370 sys/uio.h syslog.h sys/dl.h dlfcn.h linux/sockios.h])
371 AC_CHECK_HEADERS([netinet/ip.h], [], [],
372 [#include <sys/types.h>
373 #if HAVE_NETINET_IN_H
374 # include <netinet/in.h>
375 #endif
376 #if HAVE_NETINET_IN_SYSTM_H
377 # include <netinet/in_systm.h>
378 #endif
379 ])
380 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
381 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
382
383 # Linux
384 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
385 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
386
387 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
388
389 # Solaris
390 AC_CHECK_HEADERS_ONCE([sys/filio.h])
391
392 # Windows
393 AC_CHECK_HEADERS_ONCE([windows.h winsock2.h ws2tcpip.h])
394
395 # NetBSD
396 AC_CHECK_HEADERS_ONCE([sys/atomic.h])
397
398 # Other
399 AC_CHECK_HEADERS_ONCE([sys/ioctl.h])
400 AC_CHECK_HEADERS_ONCE([byteswap.h])
401 AC_CHECK_HEADERS_ONCE([sys/syscall.h])
402 AC_CHECK_HEADERS_ONCE([sys/eventfd.h])
403 AC_CHECK_HEADERS_ONCE([execinfo.h])
404 AC_CHECK_HEADERS_ONCE([langinfo.h])
405 AC_CHECK_HEADERS_ONCE([regex.h pcreposix.h])
406
407 #### Typdefs, structures, etc. ####
408
409 AC_C_CONST
410 AC_C_BIGENDIAN
411 AC_TYPE_PID_T
412 AC_TYPE_SIZE_T
413 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
414 [Define ssize_t if it is not done by the standard libs.])])
415 AC_TYPE_OFF_T
416
417 AC_TYPE_UID_T
418 AC_CHECK_DECLS(environ)
419
420 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
421 HAVE_SIGXCPU=1
422 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
423 ], [HAVE_SIGXCPU=0])
424 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
425
426 # Solaris lacks this
427 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
428 [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
429 [AC_DEFINE([INADDR_NONE], [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
430
431 #### POSIX threads ####
432
433 ACX_PTHREAD
434
435 #### Check for libs ####
436
437 # ISO
438 AC_SEARCH_LIBS([pow], [m])
439
440 # POSIX
441 AC_SEARCH_LIBS([sched_setscheduler], [rt])
442 AC_SEARCH_LIBS([dlopen], [dl])
443 AC_SEARCH_LIBS([shm_open], [rt])
444 AC_SEARCH_LIBS([inet_ntop], [nsl])
445 AC_SEARCH_LIBS([timer_create], [rt])
446 AC_SEARCH_LIBS([pthread_setaffinity_np], [pthread])
447 AC_SEARCH_LIBS([pthread_getname_np], [pthread])
448 AC_SEARCH_LIBS([pthread_setname_np], [pthread])
449
450 # BSD
451 AC_SEARCH_LIBS([connect], [socket])
452 AC_SEARCH_LIBS([backtrace], [execinfo])
453
454 # Darwin/OS X
455 if test "x$os_is_darwin" = "x1" ; then
456 AC_MSG_CHECKING([looking for Apple CoreService Framework])
457 # How do I check a framework "library" - AC_CHECK_LIB prob. won't work??, just assign LIBS & hope
458 AC_CHECK_HEADER([/Developer/Headers/FlatCarbon/CoreServices.h],
459 [LIBS="$LIBS -framework CoreServices"],
460 [AC_MSG_ERROR([CoreServices.h header file not found]) ])
461
462 AC_MSG_RESULT([ok])
463 AC_DEFINE([HAVE_CLOCK_GETTIME], 1, [Using clock_gettime() replacement])
464 HAVE_BONJOUR=1
465 fi
466
467 AC_SUBST(HAVE_BONJOUR)
468 AM_CONDITIONAL([HAVE_BONJOUR], [test "x$HAVE_BONJOUR" = x1])
469
470 # Windows
471 AC_SEARCH_LIBS([regexec], [pcreposix])
472 # This magic is needed so we do not needlessly add static libs to the win32 build, disabling its ability to make dlls.
473 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
474
475 #### Check for functions ####
476
477 # ISO
478 AC_CHECK_FUNCS_ONCE([lrintf strtof])
479
480 # POSIX
481 AC_FUNC_FORK
482 AC_FUNC_GETGROUPS
483 AC_FUNC_SELECT_ARGTYPES
484 AC_CHECK_FUNCS_ONCE([chmod chown fstat fchown fchmod clock_gettime getaddrinfo getgrgid_r getgrnam_r \
485 getpwnam_r getpwuid_r gettimeofday getuid mlock nanosleep \
486 pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
487 sigaction sleep symlink sysconf uname pthread_setaffinity_np pthread_getname_np pthread_setname_np])
488 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
489
490 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
491
492 # X/OPEN
493 AC_CHECK_FUNCS_ONCE([readlink])
494
495 # SUSv2
496 AC_CHECK_FUNCS_ONCE([ctime_r usleep])
497
498 # SUSv3
499 AC_CHECK_FUNCS_ONCE([strerror_r])
500
501 # BSD
502 AC_CHECK_FUNCS_ONCE([lstat])
503
504 # Non-standard
505
506 AC_CHECK_FUNCS_ONCE([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l pipe2 accept4])
507
508 AC_FUNC_ALLOCA
509
510 AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
511 pulseaudio_cv_PTHREAD_PRIO_INHERIT,
512 [save_CC=$CC; CC=$PTHREAD_CC
513 save_CFLAGS=$CFLAGS; CFLAGS=$PTHREAD_CFLAGS
514 save_LIBS=$LIBS; LIBS=$PTHREAD_LIBS
515 AC_LINK_IFELSE(
516 AC_LANG_PROGRAM(
517 [[
518 #include <pthread.h>
519 ]],
520 [[int i = PTHREAD_PRIO_INHERIT;]]),
521 [pulseaudio_cv_PTHREAD_PRIO_INHERIT=yes],
522 [pulseaudio_cv_PTHREAD_PRIO_INHERIT=no])
523 CC=$save_CC
524 CFLAGS=$save_CFLAGS
525 LIBS=$save_LIBS
526 ])
527
528 AS_IF([test "$pulseaudio_cv_PTHREAD_PRIO_INHERIT" = "yes"], [
529 AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
530 ])
531
532 AC_DEFINE_UNQUOTED(PA_CFLAGS,"$CFLAGS", [The CFLAGS used during compilation])
533
534 AC_CHECK_FUNCS([regexec], [HAVE_REGEX=1], [HAVE_REGEX=0])
535 AM_CONDITIONAL(HAVE_REGEX, [test "x$HAVE_REGEX" = "x1"])
536
537 #### Large File-Support (LFS) ####
538
539 AC_SYS_LARGEFILE
540
541 # Check for open64 to know if the current system does have open64() and similar functions
542 AC_CHECK_FUNCS_ONCE([open64])
543
544 #### [lib]iconv ####
545
546 AM_ICONV
547
548 IT_PROG_INTLTOOL([0.35.0])
549 GETTEXT_PACKAGE=pulseaudio
550 AC_SUBST([GETTEXT_PACKAGE])
551 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
552 AM_GLIB_GNU_GETTEXT
553
554 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
555 AC_SUBST(pulselocaledir)
556
557 ###################################
558 # External libraries #
559 ###################################
560
561 #### pkg-config ####
562
563 PKG_PROG_PKG_CONFIG
564
565 #### X11 (optional) ####
566
567 AC_ARG_ENABLE([x11],
568 AS_HELP_STRING([--disable-x11],[Disable optional X11 support]))
569
570 AS_IF([test "x$enable_x11" != "xno"],
571 [PKG_CHECK_MODULES(X11, [ x11-xcb xcb >= 1.6 ice sm xtst ], HAVE_X11=1, HAVE_X11=0)],
572 HAVE_X11=0)
573
574 AS_IF([test "x$enable_x11" = "xyes" && test "x$HAVE_X11" = "x0"],
575 [AC_MSG_ERROR([*** X11 not found])])
576
577 AC_SUBST(X11_CFLAGS)
578 AC_SUBST(X11_LIBS)
579 AC_SUBST(HAVE_X11)
580 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
581 AS_IF([test "x$HAVE_X11" = "x1"], AC_DEFINE([HAVE_X11], 1, [Have X11?]))
582
583 #### Capabilities (optional) ####
584
585 CAP_LIBS=''
586
587 AC_ARG_WITH(
588 [caps],
589 AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
590
591 if test "x${with_caps}" != "xno"; then
592 AC_SEARCH_LIBS([cap_init], [cap], [], [
593 if test "x${with_caps}" = "xyes" ; then
594 AC_MSG_ERROR([*** POSIX caps libraries not found])
595 fi])
596 AC_CHECK_HEADERS([sys/capability.h], [], [
597 if test "x${with_caps}" = "xyes" ; then
598 AC_MSG_ERROR([*** POSIX caps headers not found])
599 fi])
600 fi
601
602 #### Valgrind (optional) ####
603
604 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
605
606 #### json parsing ####
607
608 PKG_CHECK_MODULES(LIBJSON, [ json >= 0.9 ])
609 AC_SUBST(LIBJSON_CFLAGS)
610 AC_SUBST(LIBJSON_LIBS)
611
612 #### Sound file ####
613
614 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.20 ])
615 AC_SUBST(LIBSNDFILE_CFLAGS)
616 AC_SUBST(LIBSNDFILE_LIBS)
617
618 PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ])
619 AC_SUBST(LIBSPEEX_CFLAGS)
620 AC_SUBST(LIBSPEEX_LIBS)
621
622 #### atomic-ops ###
623
624 AC_MSG_CHECKING([whether we need libatomic_ops])
625 if test "x$need_libatomic_ops" = "xyes"; then
626 AC_MSG_RESULT([yes])
627 AC_CHECK_HEADERS([atomic_ops.h], [], [
628 AC_MSG_ERROR([*** libatomic-ops headers not found])
629 ])
630
631 # Win32 does not need the lib and breaks horribly if we try to include it
632 if test "x$os_is_win32" != "x1" ; then
633 LIBS="$LIBS -latomic_ops"
634 fi
635 else
636 AC_MSG_RESULT([no])
637 fi
638
639 #### Libsamplerate support (optional) ####
640
641 AC_ARG_ENABLE([samplerate],
642 AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]))
643
644 AS_IF([test "x$enable_samplerate" != "xno"],
645 [PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ], HAVE_LIBSAMPLERATE=1, HAVE_LIBSAMPLERATE=0)],
646 HAVE_LIBSAMPLERATE=0)
647
648 AS_IF([test "x$enable_samplerate" = "xyes" && test "x$HAVE_LIBSAMPLERATE" = "x0"],
649 [AC_MSG_ERROR([*** Libsamplerate not found])])
650
651 AC_SUBST(LIBSAMPLERATE_CFLAGS)
652 AC_SUBST(LIBSAMPLERATE_LIBS)
653 AC_SUBST(HAVE_LIBSAMPLERATE)
654 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
655 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?]))
656
657 #### Database support ####
658
659 AC_ARG_WITH([database],
660 AS_HELP_STRING([--with-database=auto|tdb|gdbm|simple],[Choose database backend.]),[],[with_database=auto])
661
662
663 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xtdb"],
664 [PKG_CHECK_MODULES(TDB, [ tdb ], HAVE_TDB=1, HAVE_TDB=0)],
665 HAVE_TDB=0)
666 AS_IF([test "x$HAVE_TDB" = "x1"], with_database=tdb)
667
668 AS_IF([test "x$with_database" = "xtdb" && test "x$HAVE_TDB" = "x0"],
669 [AC_MSG_ERROR([*** tdb not found])])
670
671
672 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xgdbm"],
673 [
674 HAVE_GDBM=1
675 AC_CHECK_LIB(gdbm, gdbm_open, [], HAVE_GDBM=0)
676 AC_CHECK_HEADERS(gdbm.h, [], HAVE_GDBM=0)
677 ],
678 HAVE_GDBM=0)
679 AS_IF([test "x$HAVE_GDBM" = "x1"],
680 [
681 with_database=gdbm
682 GDBM_CFLAGS=
683 GDBM_LIBS=-lgdbm
684 ])
685
686 AS_IF([test "x$with_database" = "xgdbm" && test "x$HAVE_GDBM" = "x0"],
687 [AC_MSG_ERROR([*** gdbm not found])])
688
689
690 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xsimple"],
691 HAVE_SIMPLEDB=1,
692 HAVE_SIMPLEDB=0)
693 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], with_database=simple)
694
695 AS_IF([test "x$HAVE_TDB" != x1 -a "x$HAVE_GDBM" != x1 -a "x$HAVE_SIMPLEDB" != x1],
696 AC_MSG_ERROR([*** missing database backend]))
697
698
699 AC_SUBST(TDB_CFLAGS)
700 AC_SUBST(TDB_LIBS)
701 AC_SUBST(HAVE_TDB)
702 AM_CONDITIONAL([HAVE_TDB], [test "x$HAVE_TDB" = x1])
703 AS_IF([test "x$HAVE_TDB" = "x1"], AC_DEFINE([HAVE_TDB], 1, [Have tdb?]))
704
705 AC_SUBST(GDBM_CFLAGS)
706 AC_SUBST(GDBM_LIBS)
707 AC_SUBST(HAVE_GDBM)
708 AM_CONDITIONAL([HAVE_GDBM], [test "x$HAVE_GDBM" = x1])
709 AS_IF([test "x$HAVE_GDBM" = "x1"], AC_DEFINE([HAVE_GDBM], 1, [Have gdbm?]))
710
711 AC_SUBST(HAVE_SIMPLEDB)
712 AM_CONDITIONAL([HAVE_SIMPLEDB], [test "x$HAVE_SIMPLEDB" = x1])
713 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], AC_DEFINE([HAVE_SIMPLEDB], 1, [Have simple?]))
714
715 #### OSS support (optional) ####
716
717 AC_ARG_ENABLE([oss-output],
718 AS_HELP_STRING([--disable-oss-output],[Disable optional OSS output support]))
719
720 AC_ARG_ENABLE([oss-wrapper],
721 AS_HELP_STRING([--disable-oss-wrapper],[Disable optional OSS wrapper support]))
722
723 AS_IF([test "x$enable_oss_output" != "xno" -o "x$enable_oss_wrapper" != "xno"],
724 [AC_CHECK_HEADERS([sys/soundcard.h], HAVE_OSS=1, HAVE_OSS=0)],
725 HAVE_OSS=0)
726
727 AS_IF([test "x$enable_oss_output" = "xyes" -o "x$enable_oss_wrapper" = "xyes" && test "x$HAVE_OSS" = "x0"],
728 [AC_MSG_ERROR([*** OSS support not found])])
729
730 AS_IF([test "x$enable_oss_output" != "xno"],
731 [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_OUTPUT=1, HAVE_OSS_OUTPUT=0)],
732 HAVE_OSS_OUTPUT=0)
733
734 AS_IF([test "x$enable_oss_wrapper" != "xno"],
735 [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_WRAPPER=1, HAVE_OSS_WRAPPER=0)],
736 HAVE_OSS_WRAPPER=0)
737
738 AC_SUBST(HAVE_OSS)
739 AM_CONDITIONAL([HAVE_OSS_OUTPUT], [test "x$HAVE_OSS_OUTPUT" = "x1"])
740 AM_CONDITIONAL([HAVE_OSS_WRAPPER], [test "x$HAVE_OSS_WRAPPER" = "x1"])
741 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], AC_DEFINE([HAVE_OSS_OUTPUT], 1, [Have OSS output?]))
742 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], AC_DEFINE([HAVE_OSS_WRAPPER], 1, [Have OSS wrapper (padsp)?]))
743
744 #### CoreAudio support (optional) ####
745
746 AC_ARG_ENABLE([coreaudio-output],
747 AS_HELP_STRING([--disable-coreaudio-output],[Disable optional CoreAudio output support]))
748
749 AS_IF([test "x$enable_coreaudio_output" != "xno"],
750 [AC_CHECK_HEADERS([CoreAudio/CoreAudio.h], HAVE_COREAUDIO=1, HAVE_COREAUDIO=0)],
751 HAVE_COREAUDIO=0)
752
753 AS_IF([test "x$enable_coreaudio_output" = "xyes" && test "x$HAVE_COREAUDIO" = "x0"],
754 [AC_MSG_ERROR([*** CoreAudio output support not found])])
755
756 AC_SUBST(HAVE_COREAUDIO)
757 AM_CONDITIONAL([HAVE_COREAUDIO], [test "x$HAVE_COREAUDIO" = "x1" && test "x$enable_coreaudio_output" != "xno"])
758
759 #### ALSA support (optional) ####
760
761 AC_ARG_ENABLE([alsa],
762 AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]))
763
764 AS_IF([test "x$enable_alsa" != "xno"],
765 [PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.19 ], HAVE_ALSA=1, HAVE_ALSA=0)],
766 HAVE_ALSA=0)
767
768 AS_IF([test "x$enable_alsa" = "xyes" && test "x$HAVE_ALSA" = "x0"],
769 [AC_MSG_ERROR([*** Needed alsa >= 1.0.19 support not found])])
770
771 AC_SUBST(ASOUNDLIB_CFLAGS)
772 AC_SUBST(ASOUNDLIB_LIBS)
773 AC_SUBST(HAVE_ALSA)
774 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
775 AS_IF([test "x$HAVE_ALSA" = "x1"], AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?]))
776
777 #### Solaris audio support (optional) ####
778
779 AC_ARG_ENABLE([solaris],
780 AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]))
781
782 AS_IF([test "x$enable_solaris" != "xno"],
783 [AC_CHECK_HEADERS([sys/audio.h], HAVE_SOLARIS=1, HAVE_SOLARIS=0)],
784 HAVE_SOLARIS=0)
785
786 AS_IF([test "x$enable_solaris" = "xyes" && test "x$HAVE_SOLARIS" = "x0"],
787 [AC_MSG_ERROR([*** Solaris audio support not found])])
788
789 AC_SUBST(HAVE_SOLARIS)
790 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
791 AS_IF([test "x$HAVE_SOLARIS" = "x1"], AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?]))
792
793 #### WaveOut audio support (optional) ####
794
795 AC_ARG_ENABLE([waveout],
796 AS_HELP_STRING([--disable-waveout],[Disable optional WaveOut audio support]))
797
798 AS_IF([test "x$enable_waveout" != "xno"],
799 [AC_CHECK_HEADERS([mmsystem.h], HAVE_WAVEOUT=1, HAVE_WAVEOUT=0, [#include <windows.h>])],
800 HAVE_WAVEOUT=0)
801
802 AS_IF([test "x$enable_waveout" = "xyes" && test "x$HAVE_WAVEOUT" = "x0"],
803 [AC_MSG_ERROR([*** WaveOut audio support not found])])
804
805 AC_SUBST(HAVE_WAVEOUT)
806 AM_CONDITIONAL([HAVE_WAVEOUT], [test "x$HAVE_WAVEOUT" = x1])
807 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], AC_DEFINE([HAVE_WAVEOUT], 1, [Have WaveOut audio?]))
808
809 #### GLib 2 support (optional) ####
810
811 AC_ARG_ENABLE([glib2],
812 AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]))
813
814 AS_IF([test "x$enable_glib2" != "xno"],
815 [PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)],
816 HAVE_GLIB20=0)
817
818 AS_IF([test "x$enable_glib2" = "xyes" && test "x$HAVE_GLIB20" = "x0"],
819 [AC_MSG_ERROR([*** GLib 2 support not found])])
820
821 AC_SUBST(GLIB20_CFLAGS)
822 AC_SUBST(GLIB20_LIBS)
823 AC_SUBST(HAVE_GLIB20)
824 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
825 AS_IF([test "x$HAVE_GLIB20" = "x1"], AC_DEFINE([HAVE_GLIB], 1, [Have GLIB?]))
826
827 #### GTK2 support (optional) ####
828
829 AC_ARG_ENABLE([gtk2],
830 AS_HELP_STRING([--disable-gtk2],[Disable optional Gtk+ 2 support]))
831
832 AS_IF([test "x$enable_gtk2" != "xno"],
833 [PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ], HAVE_GTK20=1, HAVE_GTK20=0)],
834 HAVE_GTK20=0)
835
836 AS_IF([test "x$enable_gtk2" = "xyes" && test "x$HAVE_GTK20" = "x0"],
837 [AC_MSG_ERROR([*** Gtk+ 2 support not found])])
838
839 AC_SUBST(GTK20_CFLAGS)
840 AC_SUBST(GTK20_LIBS)
841 AC_SUBST(HAVE_GTK20)
842 AM_CONDITIONAL([HAVE_GTK20], [test "x$HAVE_GTK20" = x1])
843 AS_IF([test "x$HAVE_GTK20" = "x1"], AC_DEFINE([HAVE_GTK], 1, [Have GTK?]))
844
845 #### GConf support (optional) ####
846
847 AC_ARG_ENABLE([gconf],
848 AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]))
849
850 AS_IF([test "x$enable_gconf" != "xno"],
851 [PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 gobject-2.0 ], HAVE_GCONF=1, HAVE_GCONF=0)],
852 HAVE_GCONF=0)
853
854 AS_IF([test "x$enable_gconf" = "xyes" && test "x$HAVE_GCONF" = "x0"],
855 [AC_MSG_ERROR([*** GConf support not found])])
856
857 AC_SUBST(GCONF_CFLAGS)
858 AC_SUBST(GCONF_LIBS)
859 AC_SUBST(HAVE_GCONF)
860 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
861
862 #### Avahi support (optional) ####
863
864 AC_ARG_ENABLE([avahi],
865 AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]))
866
867 AS_IF([test "x$enable_avahi" != "xno"],
868 [PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ], HAVE_AVAHI=1, HAVE_AVAHI=0)],
869 HAVE_AVAHI=0)
870
871 AS_IF([test "x$enable_avahi" = "xyes" && test "x$HAVE_AVAHI" = "x0"],
872 [AC_MSG_ERROR([*** Avahi support not found])])
873
874 AC_SUBST(AVAHI_CFLAGS)
875 AC_SUBST(AVAHI_LIBS)
876 AC_SUBST(HAVE_AVAHI)
877 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
878
879 ### JACK (optional) ####
880
881 AC_ARG_ENABLE([jack],
882 AS_HELP_STRING([--disable-jack],[Disable optional JACK support]))
883
884 AS_IF([test "x$enable_jack" != "xno"],
885 [PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ], HAVE_JACK=1, HAVE_JACK=0)],
886 HAVE_JACK=0)
887
888 AS_IF([test "x$enable_jack" = "xyes" && test "x$HAVE_JACK" = "x0"],
889 [AC_MSG_ERROR([*** JACK support not found])])
890
891 AC_SUBST(JACK_CFLAGS)
892 AC_SUBST(JACK_LIBS)
893 AC_SUBST(HAVE_JACK)
894 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
895
896 #### Async DNS support (optional) ####
897
898 AC_ARG_ENABLE([asyncns],
899 AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]))
900
901 AS_IF([test "x$enable_asyncns" != "xno"],
902 [PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)],
903 HAVE_LIBASYNCNS=0)
904
905 AS_IF([test "x$enable_asyncns" = "xyes" && test "x$HAVE_LIBASYNCNS" = "x0"],
906 [AC_MSG_ERROR([*** Async DNS support not found])])
907
908 AC_SUBST(LIBASYNCNS_CFLAGS)
909 AC_SUBST(LIBASYNCNS_LIBS)
910 AC_SUBST(HAVE_LIBASYNCNS)
911 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
912 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?]))
913
914 #### TCP wrappers (optional) ####
915
916 AC_ARG_ENABLE([tcpwrap],
917 AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]))
918
919 AS_IF([test "x$enable_tcpwrap" != "xno"],
920 [
921 ACX_LIBWRAP
922 AS_IF([test "x$LIBWRAP_LIBS" != "x"], HAVE_TCPWRAP=1, HAVE_TCPWRAP=0)
923 ],
924 HAVE_TCPWRAP=0)
925
926 AS_IF([test "x$enable_tcpwrap" = "xyes" && test "x$HAVE_TCPWRAP" = "x0"],
927 [AC_MSG_ERROR([*** TCP wrappers support not found])])
928
929 AC_SUBST(LIBWRAP_LIBS)
930
931 #### LIRC support (optional) ####
932
933 AC_ARG_ENABLE([lirc],
934 AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]))
935
936 AS_IF([test "x$enable_lirc" != "xno"],
937 [ACX_LIRC],
938 HAVE_LIRC=0)
939
940 AS_IF([test "x$enable_lirc" = "xyes" && test "x$HAVE_LIRC" = "x0"],
941 [AC_MSG_ERROR([*** LIRC support not found])])
942
943 AC_SUBST(LIRC_CFLAGS)
944 AC_SUBST(LIRC_LIBS)
945 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
946
947 #### HAL support (optional) ####
948
949 AC_ARG_ENABLE([hal],
950 AS_HELP_STRING([--disable-hal],[Disable optional HAL support]))
951
952 AS_IF([test "x$enable_hal" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
953 [PKG_CHECK_MODULES(HAL, [ hal >= 0.5.11 ], HAVE_HAL=1, HAVE_HAL=0)],
954 HAVE_HAL=0)
955
956 AS_IF([test "x$enable_hal" = "xyes" && test "x$HAVE_HAL" = "x0"],
957 [AC_MSG_ERROR([*** HAL support not found])])
958
959 AC_SUBST(HAL_CFLAGS)
960 AC_SUBST(HAL_LIBS)
961 AC_SUBST(HAVE_HAL)
962 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
963 AS_IF([test "x$HAVE_HAL" = "x1"], AC_DEFINE([HAVE_HAL], 1, [Have HAL.]))
964
965 #### UDEV support (optional) ####
966
967 AC_ARG_ENABLE([udev],
968 AS_HELP_STRING([--disable-udev],[Disable optional UDEV support]))
969
970 AS_IF([test "x$enable_udev" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
971 [PKG_CHECK_MODULES(UDEV, [ libudev >= 143 ], HAVE_UDEV=1, HAVE_UDEV=0)],
972 HAVE_UDEV=0)
973
974 AS_IF([test "x$enable_udev" = "xyes" && test "x$HAVE_UDEV" = "x0"],
975 [AC_MSG_ERROR([*** UDEV support not found])])
976
977 AC_SUBST(UDEV_CFLAGS)
978 AC_SUBST(UDEV_LIBS)
979 AC_SUBST(HAVE_UDEV)
980 AM_CONDITIONAL([HAVE_UDEV], [test "x$HAVE_UDEV" = x1])
981 AS_IF([test "x$HAVE_UDEV" = "x1"], AC_DEFINE([HAVE_UDEV], 1, [Have UDEV.]))
982
983 #### BlueZ support (optional) ####
984
985 AC_ARG_ENABLE([bluez],
986 AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]))
987
988 AS_IF([test "x$enable_bluez" != "xno"],
989 [PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ], HAVE_BLUEZ=1, HAVE_BLUEZ=0)],
990 HAVE_BLUEZ=0)
991
992 AS_IF([test "x$enable_bluez" = "xyes" && test "x$HAVE_BLUEZ" = "x0"],
993 [AC_MSG_ERROR([*** BLUEZ support not found])])
994
995 AC_SUBST(BLUEZ_CFLAGS)
996 AC_SUBST(BLUEZ_LIBS)
997 AC_SUBST(HAVE_BLUEZ)
998 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
999
1000 #### D-Bus support (optional) ####
1001
1002 AC_ARG_ENABLE([dbus],
1003 AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]))
1004
1005 AS_IF([test "x$enable_dbus" != "xno"],
1006 [PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ], HAVE_DBUS=1, HAVE_DBUS=0)],
1007 HAVE_DBUS=0)
1008
1009 AS_IF([test "x$enable_dbus" = "xyes" && test "x$HAVE_DBUS" = "x0"],
1010 [AC_MSG_ERROR([*** D-Bus support not found])])
1011
1012 AS_IF([test "x$HAVE_DBUS" = "x1"],
1013 [
1014 saved_LIBS="$LIBS"
1015 LIBS="$LIBS $DBUS_LIBS"
1016 CFLAGS="$CFLAGS $DBUS_CFLAGS"
1017 AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
1018 LIBS="$saved_LIBS"
1019 ])
1020
1021 AC_SUBST(DBUS_CFLAGS)
1022 AC_SUBST(DBUS_LIBS)
1023 AC_SUBST(HAVE_DBUS)
1024 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
1025 AS_IF([test "x$HAVE_DBUS" = "x1"], AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.]))
1026
1027 # HAL and BlueZ depend on D-Bus: So double check if they were explicitly enabled.
1028 if test "x$HAVE_DBUS" != "x1" ; then
1029 HAVE_HAL=0
1030 if test "x$enable_hal" = "xyes"; then
1031 AC_MSG_ERROR([*** D-Bus support is required by HAL])
1032 fi
1033
1034 HAVE_BLUEZ=0
1035 if test "x$enable_bluez" = "xyes"; then
1036 AC_MSG_ERROR([*** D-Bus support is required by BLUEZ])
1037 fi
1038 fi
1039
1040 #### HAL compat support (optional) ####
1041
1042 AC_ARG_ENABLE([hal-compat],
1043 AS_HELP_STRING([--disable-hal-compat],[Disable optional HAL->udev transition compatibility support]))
1044
1045 if test "x$enable_hal_compat" != "xno" -a "x$HAVE_HAL" = "x0" -a "x$HAVE_UDEV" = "x1"; then
1046 HAVE_HAL_COMPAT=1
1047 AC_DEFINE([HAVE_HAL_COMPAT], 1, [Have HAL compatibility.])
1048 else
1049 HAVE_HAL_COMPAT=0
1050 fi
1051
1052 AC_SUBST(HAVE_HAL_COMPAT)
1053 AM_CONDITIONAL([HAVE_HAL_COMPAT], [test "x$HAVE_HAL_COMPAT" = x1])
1054
1055 ### IPv6 connection support (optional) ###
1056
1057 AC_ARG_ENABLE([ipv6],
1058 AS_HELP_STRING([--disable-ipv6],[Disable optional IPv6 support]))
1059
1060 if test "x$enable_ipv6" != "xno"; then
1061 AC_DEFINE([HAVE_IPV6], [1], [Define this to enable IPv6 connection support])
1062 HAVE_IPV6=1
1063 else
1064 HAVE_IPV6=0
1065 fi
1066
1067 #### OpenSSL support (optional) ####
1068
1069 AC_ARG_ENABLE([openssl],
1070 AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]))
1071
1072 AS_IF([test "x$enable_openssl" != "xno"],
1073 [PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ], HAVE_OPENSSL=1, HAVE_OPENSSL=0)],
1074 HAVE_OPENSSL=0)
1075
1076 AS_IF([test "x$enable_openssl" = "xyes" && test "x$HAVE_OPENSSL" = "x0"],
1077 [AC_MSG_ERROR([*** OpenSSL support not found])])
1078
1079 AC_SUBST(OPENSSL_CFLAGS)
1080 AC_SUBST(OPENSSL_LIBS)
1081 AC_SUBST(HAVE_OPENSSL)
1082 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1083 AS_IF([test "x$HAVE_OPENSSL" = "x1"], AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL]))
1084
1085 #### FFTW (optional) ####
1086 AC_ARG_WITH([fftw],
1087 AS_HELP_STRING([--without-fftw],[Omit FFTW-using modules (equalizer)]))
1088
1089 AS_IF([test "x$with_fftw" != "xno"],
1090 [PKG_CHECK_MODULES(FFTW, [ fftw3f ], HAVE_FFTW=1, HAVE_FFTW=0)],
1091 HAVE_FFTW=0)
1092
1093 AM_CONDITIONAL([HAVE_FFTW], [test "x$HAVE_FFTW" = "x1"])
1094
1095 ### ORC (optional) ###
1096 ORC_CHECK([0.4.11])
1097
1098 ### Build and Install man pages ###
1099 AC_ARG_ENABLE([manpages],
1100 AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]))
1101
1102 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" != "xno"])
1103
1104 #### PulseAudio system group & user #####
1105
1106 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1107 if test -z "$with_system_user" ; then
1108 PA_SYSTEM_USER=pulse
1109 else
1110 PA_SYSTEM_USER=$with_system_user
1111 fi
1112 AC_SUBST(PA_SYSTEM_USER)
1113 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1114
1115 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1116 if test -z "$with_system_group" ; then
1117 PA_SYSTEM_GROUP=pulse
1118 else
1119 PA_SYSTEM_GROUP=$with_system_group
1120 fi
1121 AC_SUBST(PA_SYSTEM_GROUP)
1122 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1123
1124 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1125 if test -z "$with_access_group" ; then
1126 PA_ACCESS_GROUP=pulse-access
1127 else
1128 PA_ACCESS_GROUP=$with_access_group
1129 fi
1130 AC_SUBST(PA_ACCESS_GROUP)
1131 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1132
1133 AC_ARG_ENABLE([per-user-esound-socket],
1134 AS_HELP_STRING([--disable-per-user-esound-socket],[Use global esound socket directory /tmp/.esd/socket.]))
1135
1136 if test "x$enable_per_user_esound_socket" != "xno"; then
1137 USE_PER_USER_ESOUND_SOCKET=1
1138 AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1139 else
1140 USE_PER_USER_ESOUND_SOCKET=0
1141 fi
1142
1143 #### PulseAudio system runtime dir ####
1144 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1145 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1146 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1147 AC_SUBST(PA_SYSTEM_CONFIG_PATH)
1148 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1149 AC_SUBST(PA_SYSTEM_STATE_PATH)
1150
1151 ###################################
1152 # Output #
1153 ###################################
1154
1155 AC_ARG_ENABLE([legacy-runtime-dir],
1156 AS_HELP_STRING([--disable-legacy-runtime-dir], [Try to connect on legacy (< 0.9.12) socket paths.]))
1157 if test "x$enable_legacy_runtime_dir" != "xno" ; then
1158 AC_DEFINE(ENABLE_LEGACY_RUNTIME_DIR, [1], [Legacy runtime dir])
1159 fi
1160
1161 AC_ARG_ENABLE([static-bins],
1162 AS_HELP_STRING([--enable-static-bins],[Statically link executables.]))
1163
1164 if test "x$enable_static_bins" = "xyes"; then
1165 STATIC_BINS=1
1166 else
1167 STATIC_BINS=0
1168 fi
1169
1170 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1171
1172 AC_ARG_WITH(
1173 [preopen-mods],
1174 AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1175 [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1176 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1177 if test "x$PREOPEN_MODS" != "xall" ; then
1178 tmpLIBS=""
1179 for mod in $PREOPEN_MODS; do
1180 tmpLIBS="$tmpLIBS module-$mod.la"
1181 done
1182 PREOPEN_MODS="$tmpLIBS"
1183 AC_SUBST(PREOPEN_MODS)
1184 fi
1185
1186 AC_ARG_WITH(
1187 [module-dir],
1188 AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules]),
1189 [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules"])
1190
1191 AC_SUBST(modlibexecdir)
1192
1193 AC_ARG_WITH(
1194 [udev-rules-dir],
1195 AS_HELP_STRING([--with-udev-rules-dir],[Directory where to install udev rules to (defaults to /lib/udev/rules.d)]),
1196 [udevrulesdir=$withval], [udevrulesdir="/lib/udev/rules.d"])
1197
1198 AC_SUBST(udevrulesdir)
1199
1200 AC_ARG_ENABLE([force-preopen],
1201 AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]))
1202
1203 if test "x$enable_force_preopen" = "xyes"; then
1204 FORCE_PREOPEN=yes
1205 else
1206 FORCE_PREOPEN=no
1207 fi
1208
1209 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1210
1211 AC_CONFIG_FILES([
1212 Makefile
1213 src/Makefile
1214 man/Makefile
1215 libpulse.pc
1216 libpulse-simple.pc
1217 libpulse-browse.pc
1218 libpulse-mainloop-glib.pc
1219 doxygen/Makefile
1220 doxygen/doxygen.conf
1221 src/pulse/version.h
1222 po/Makefile.in
1223 ])
1224
1225 AC_OUTPUT
1226
1227 # ==========================================================================
1228
1229 AS_IF([test "x$HAVE_X11" = "x1"], ENABLE_X11=yes, ENABLE_X11=no)
1230 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], ENABLE_OSS_OUTPUT=yes, ENABLE_OSS_OUTPUT=no)
1231 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], ENABLE_OSS_WRAPPER=yes, ENABLE_OSS_WRAPPER=no)
1232 AS_IF([test "x$HAVE_ALSA" = "x1"], ENABLE_ALSA=yes, ENABLE_ALSA=no)
1233 AS_IF([test "x$HAVE_COREAUDIO" = "x1"], ENABLE_COREAUDIO=yes, ENABLE_COREAUDIO=no)
1234 AS_IF([test "x$HAVE_SOLARIS" = "x1"], ENABLE_SOLARIS=yes, ENABLE_SOLARIS=no)
1235 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], ENABLE_WAVEOUT=yes, ENABLE_WAVEOUT=no)
1236 AS_IF([test "x$HAVE_GLIB20" = "x1"], ENABLE_GLIB20=yes, ENABLE_GLIB20=no)
1237 AS_IF([test "x$HAVE_GTK20" = "x1"], ENABLE_GTK20=yes, ENABLE_GTK20=no)
1238 AS_IF([test "x$HAVE_GCONF" = "x1"], ENABLE_GCONF=yes, ENABLE_GCONF=no)
1239 AS_IF([test "x$HAVE_AVAHI" = "x1"], ENABLE_AVAHI=yes, ENABLE_AVAHI=no)
1240 AS_IF([test "x$HAVE_JACK" = "x1"], ENABLE_JACK=yes, ENABLE_JACK=no)
1241 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], ENABLE_LIBASYNCNS=yes, ENABLE_LIBASYNCNS=no)
1242 AS_IF([test "x$HAVE_LIRC" = "x1"], ENABLE_LIRC=yes, ENABLE_LIRC=no)
1243 AS_IF([test "x$HAVE_DBUS" = "x1"], ENABLE_DBUS=yes, ENABLE_DBUS=no)
1244 AS_IF([test "x$HAVE_HAL" = "x1"], ENABLE_HAL=yes, ENABLE_HAL=no)
1245 AS_IF([test "x$HAVE_UDEV" = "x1"], ENABLE_UDEV=yes, ENABLE_UDEV=no)
1246 AS_IF([test "x$HAVE_BLUEZ" = "x1"], ENABLE_BLUEZ=yes, ENABLE_BLUEZ=no)
1247 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], ENABLE_HAL_COMPAT=yes, ENABLE_HAL_COMPAT=no)
1248 AS_IF([test "x$HAVE_TCPWRAP" = "x1"], ENABLE_TCPWRAP=yes, ENABLE_TCPWRAP=no)
1249 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], ENABLE_LIBSAMPLERATE=yes, ENABLE_LIBSAMPLERATE=no)
1250 AS_IF([test "x$HAVE_IPV6" = "x1"], ENABLE_IPV6=yes, ENABLE_IPV6=no)
1251 AS_IF([test "x$HAVE_OPENSSL" = "x1"], ENABLE_OPENSSL=yes, ENABLE_OPENSSL=no)
1252 AS_IF([test "x$HAVE_FFTW" = "x1"], ENABLE_FFTW=yes, ENABLE_FFTW=no)
1253 AS_IF([test "x$HAVE_ORC" = "xyes"], ENABLE_ORC=yes, ENABLE_ORC=no)
1254 AS_IF([test "x$HAVE_TDB" = "x1"], ENABLE_TDB=yes, ENABLE_TDB=no)
1255 AS_IF([test "x$HAVE_GDBM" = "x1"], ENABLE_GDBM=yes, ENABLE_GDBM=no)
1256 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], ENABLE_SIMPLEDB=yes, ENABLE_SIMPLEDB=no)
1257 AS_IF([test "x$USE_PER_USER_ESOUND_SOCKET" = "x1"], ENABLE_PER_USER_ESOUND_SOCKET=yes, ENABLE_PER_USER_ESOUND_SOCKET=no)
1258
1259 echo "
1260 ---{ $PACKAGE_NAME $VERSION }---
1261
1262 prefix: ${prefix}
1263 sysconfdir: ${sysconfdir}
1264 localstatedir: ${localstatedir}
1265 System Runtime Path: ${PA_SYSTEM_RUNTIME_PATH}
1266 System State Path: ${PA_SYSTEM_STATE_PATH}
1267 System Config Path: ${PA_SYSTEM_CONFIG_PATH}
1268 Compiler: ${CC}
1269 CFLAGS: ${CFLAGS}
1270 LIBS: ${LIBS}
1271
1272 Enable X11: ${ENABLE_X11}
1273 Enable OSS Output: ${ENABLE_OSS_OUTPUT}
1274 Enable OSS Wrapper: ${ENABLE_OSS_WRAPPER}
1275 Enable Alsa: ${ENABLE_ALSA}
1276 Enable CoreAudio: ${ENABLE_COREAUDIO}
1277 Enable Solaris: ${ENABLE_SOLARIS}
1278 Enable WaveOut: ${ENABLE_WAVEOUT}
1279 Enable GLib 2.0: ${ENABLE_GLIB20}
1280 Enable Gtk+ 2.0: ${ENABLE_GTK20}
1281 Enable GConf: ${ENABLE_GCONF}
1282 Enable Avahi: ${ENABLE_AVAHI}
1283 Enable Jack: ${ENABLE_JACK}
1284 Enable Async DNS: ${ENABLE_LIBASYNCNS}
1285 Enable LIRC: ${ENABLE_LIRC}
1286 Enable D-Bus: ${ENABLE_DBUS}
1287 Enable HAL: ${ENABLE_HAL}
1288 Enable BlueZ: ${ENABLE_BLUEZ}
1289 Enable udev: ${ENABLE_UDEV}
1290 Enable HAL->udev compat: ${ENABLE_HAL_COMPAT}
1291 Enable TCP Wrappers: ${ENABLE_TCPWRAP}
1292 Enable libsamplerate: ${ENABLE_LIBSAMPLERATE}
1293 Enable IPv6: ${ENABLE_IPV6}
1294 Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1295 Enable fftw: ${ENABLE_FFTW}
1296 Enable orc: ${ENABLE_ORC}
1297 Database
1298 tdb: ${ENABLE_TDB}
1299 gdbm: ${ENABLE_GDBM}
1300 simple database: ${ENABLE_SIMPLEDB}
1301
1302 System User: ${PA_SYSTEM_USER}
1303 System Group: ${PA_SYSTEM_GROUP}
1304 Access Group: ${PA_ACCESS_GROUP}
1305 Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1306 Force preopen: ${FORCE_PREOPEN}
1307 Preopened modules: ${PREOPEN_MODS}
1308 "
1309
1310 if test "${ENABLE_DBUS}" = "no" && test "x$os_is_win32" != "x1" ; then
1311 echo "
1312 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1313 You do not have D-Bus support enabled. It is strongly recommended
1314 that you enable D-Bus support if your platform supports it.
1315 Many parts of PulseAudio use D-Bus, from ConsoleKit interaction
1316 to the Device Reservation Protocol to speak to JACK, Bluetooth
1317 support and even a native control protocol for communicating and
1318 controling the PulseAudio daemon itself.
1319 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1320 "
1321 fi
1322
1323 if test "${ENABLE_UDEV}" = "no" && test "x$os_is_win32" != "x1" ; then
1324 echo "
1325 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1326 You do not have udev support enabled. It is strongly recommended
1327 that you enable udev support if your platform supports it as it is
1328 the primary method used to detect hardware audio devices (on Linux)
1329 and is thus a critical part of PulseAudio on that platform.
1330 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1331 "
1332 fi