code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.62)
  24
  25 m4_define(PA_MAJOR, [0])
  26 m4_define(PA_MINOR, [9])
  27 m4_define(PA_MICRO, [11])
  28
  29 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzchyfrnhqvb (at) 0pointer (dot) net])
  30 AC_CONFIG_SRCDIR([src/daemon/main.c])
  31 AC_CONFIG_MACRO_DIR([m4])
  32 AC_CONFIG_HEADERS([config.h])
  33 AM_INIT_AUTOMAKE([foreign 1.10 -Wall])
  34
  35 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  36 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
  37
  38 AC_SUBST(PA_API_VERSION, 12)
  39 AC_SUBST(PA_PROTOCOL_VERSION, 14)
  40
  41 # The stable ABI for client applications, for the version info x:y:z
  42 # always will hold y=z
  43 AC_SUBST(LIBPULSE_VERSION_INFO, [5:0:5])
  44
  45 # A simplified, synchronous, ABI-stable interface for client
  46 # applications, for the version info x:y:z always will hold y=z
  47 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:1:0])
  48
  49 # The ABI-stable network browsing interface for client applications,
  50 # for the version info x:y:z always will hold y=z
  51 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  52
  53 # The ABI-stable GLib adapter for client applications, for the version
  54 # info x:y:z always will hold y=z
  55 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:3:0])
  56
  57 # An internally used, ABI-unstable library that contains the
  58 # PulseAudio core, SONAMEs are bumped on every release, version info
  59 # suffix will always be 0:0
  60 AC_SUBST(LIBPULSECORE_VERSION_INFO, [6:0:0])
  61
  62 AC_CANONICAL_HOST
  63 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  64
  65 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  66    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  67    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  68 fi
  69
  70 #### Platform hacks ####
  71
  72 case $host in
  73    *-*-solaris* )
  74       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  75       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  76       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  77       ;;
  78 esac
  79
  80 #### Checks for programs. ####
  81
  82 # mkdir -p
  83
  84 AC_PROG_MKDIR_P
  85
  86 # CC
  87
  88 AC_PROG_CC
  89 AM_PROG_CC_C_O
  90 AC_PROG_GCC_TRADITIONAL
  91 AC_GNU_SOURCE
  92
  93 # M4
  94
  95 AC_PATH_PROG([M4], [m4 gm4], [no])
  96 if test "x$M4" = xno ; then
  97    AC_MSG_ERROR([m4 missing])
  98 fi
  99
 100 # GCC flags
 101
 102 test_gcc_flag() {
 103     AC_LANG_CONFTEST([int main(int argc, char*argv[]) {}])
 104     $CC -c conftest.c $CFLAGS -o conftest.o > /dev/null 2> /dev/null
 105     ret=$?
 106     rm -f conftest.o
 107     return $ret
 108 }
 109
 110 # If using GCC specify some additional parameters
 111 if test "x$GCC" = "xyes" ; then
 112
 113     # We use gnu99 instead of c99 because many have interpreted the standard
 114     # in a way that int64_t isn't defined on non-64 bit platforms.
 115     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter -ffast-math"
 116
 117     for flag in $DESIRED_FLAGS ; do
 118         AC_MSG_CHECKING([whether $CC accepts $flag])
 119         if test_gcc_flag $flag ; then
 120            CFLAGS="$CFLAGS $flag"
 121            AC_MSG_RESULT([yes])
 122         else
 123            AC_MSG_RESULT([no])
 124         fi
 125     done
 126 fi
 127
 128 # Native atomic operation support
 129 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 130     AC_HELP_STRING([--disable-atomic-arm-linux-helpers], [use inline asm or libatomic_ops instead]),
 131         [
 132             case "${enableval}" in
 133                 yes) atomic_arm_linux_helpers=yes ;;
 134                 no) atomic_arm_linux_helpers=no ;;
 135                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 136             esac
 137         ],
 138         [atomic_arm_linux_helpers=auto])
 139
 140 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 141     AC_HELP_STRING([--enable-atomic-arm-memory-barrier], [only really needed in SMP arm systems]),
 142         [
 143             case "${enableval}" in
 144                 yes) AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers]) ;;
 145                 no) ;;
 146                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 147             esac
 148         ],)
 149
 150 AC_MSG_CHECKING([target operating system])
 151 case $host in
 152         *-*-linux*)
 153             AC_MSG_RESULT([linux])
 154             pulse_target_os=linux
 155         ;;
 156         *)
 157             AC_MSG_RESULT([unknown])
 158             pulse_target_os=unknown
 159         ;;
 160 esac
 161
 162 # If everything else fails use libatomic_ops
 163 need_libatomic_ops=yes
 164
 165 AC_MSG_CHECKING([whether $CC knows __sync_bool_compare_and_swap()])
 166 AC_LANG_CONFTEST([int main() { int a = 4; __sync_bool_compare_and_swap(&a, 4, 5); }])
 167 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 168 ret=$?
 169 rm -f conftest.o conftest
 170 if test $ret -eq 0 ; then
 171     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 172     AC_MSG_RESULT([yes])
 173     need_libatomic_ops=no
 174 else
 175     AC_MSG_RESULT([no])
 176     # HW specific atomic ops stuff
 177     AC_MSG_CHECKING([architecture for native atomic operations])
 178     case $host_cpu in
 179         arm*)
 180             AC_MSG_RESULT([arm])
 181             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 182             # The Linux kernel helper functions have been there since 2.6.16. However
 183             # compile time checking for kernel version in cross compile environment
 184             # (which is usually the case for arm cpu) is tricky (or impossible).
 185             if test "x$pulse_target_os" = "xlinux" && test "x$atomic_arm_linux_helpers" != "xno"; then
 186                 AC_MSG_RESULT([yes])
 187                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 188                 need_libatomic_ops=no
 189             else
 190                AC_MSG_RESULT([no])
 191                AC_MSG_CHECKING([compiler support for arm inline asm atomic operations])
 192                AC_LANG_CONFTEST([[int main()
 193                {
 194                    volatile int a=0;
 195                    int o=0, n=1, r;
 196                    asm volatile ("ldrex %0, [%1]\n"
 197                                  "subs  %0, %0, %2\n"
 198                                  "strexeq %0, %3, [%1]\n"
 199                                  : "=&r" (r)
 200                                  : "r" (&a), "Ir" (o), "r" (n)
 201                                  : "cc");
 202                    return (a==1 ? 0 : -1);
 203                }]])
 204                $CC conftest.c $CFLAGS -o conftest > /dev/null 2>&1
 205                ret=$?
 206                rm -f conftest.o conftest
 207                if test $ret -eq 0 ; then
 208                    AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARMv6 instructions.])
 209                    AC_MSG_RESULT([yes])
 210                    need_libatomic_ops=no
 211                else
 212                    AC_MSG_RESULT([no])
 213                fi
 214            fi
 215         ;;
 216         *)
 217             AC_MSG_RESULT([unknown])
 218         ;;
 219     esac
 220 fi
 221
 222 AC_MSG_CHECKING([whether $CC knows __thread])
 223 AC_LANG_CONFTEST([static __thread int a = 6; int main() { a = 5; }])
 224 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 225 ret=$?
 226 rm -f conftest.o conftest
 227 if test $ret -eq 0 ; then
 228     AC_DEFINE([HAVE_TLS_BUILTIN], 1, [Have __thread().])
 229     AC_MSG_RESULT([yes])
 230 else
 231     AC_MSG_RESULT([no])
 232 fi
 233
 234 AC_MSG_CHECKING([whether $CC knows _Bool])
 235 AC_LANG_CONFTEST([int main() { _Bool b; }])
 236 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 237 ret=$?
 238 rm -f conftest.o conftest
 239 if test $ret -eq 0 ; then
 240     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 241     AC_MSG_RESULT([yes])
 242 else
 243     AC_MSG_RESULT([no])
 244 fi
 245
 246 #### libtool stuff ####
 247
 248 AC_LTDL_ENABLE_INSTALL
 249 AC_LIBLTDL_INSTALLABLE
 250 AC_LIBTOOL_DLOPEN
 251 AC_LIBTOOL_WIN32_DLL
 252 AC_PROG_LIBTOOL
 253 AC_SUBST(LTDLINCL)
 254 AC_SUBST(LIBLTDL)
 255 AC_CONFIG_SUBDIRS(libltdl)
 256
 257 old_LIBS=$LIBS
 258 LIBS="$LIBS $LIBLTDL"
 259 AC_CHECK_FUNCS([lt_dlmutex_register])
 260 LIBS=$old_LIBS
 261 AC_CHECK_TYPES([struct lt_user_dlloader, lt_dladvise], , , [#include <ltdl.h>])
 262
 263 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 264     AC_MSG_ERROR([[
 265
 266         *** Cannot find the libltdl development files.
 267         *** Maybe you need to install the libltdl-dev package.
 268         ]])
 269 fi
 270
 271 #### Determine build environment ####
 272
 273 os_is_win32=0
 274
 275 case "$host_os" in
 276         mingw*)
 277         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 278         os_is_win32=1
 279                 ;;
 280         esac
 281
 282 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 283
 284 ###################################
 285 #   Basic environment checks      #
 286 ###################################
 287
 288 #### Checks for header files. ####
 289
 290 # ISO
 291 AC_HEADER_STDC
 292
 293 # POSIX
 294 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 295     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 296     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 297     syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 298 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 299                  [#include <sys/types.h>
 300                   #if HAVE_NETINET_IN_H
 301                   # include <netinet/in.h>
 302                   #endif
 303                   #if HAVE_NETINET_IN_SYSTM_H
 304                   # include <netinet/in_systm.h>
 305                   #endif
 306                  ])
 307 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 308 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 309
 310 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 311 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 312
 313 # Linux
 314 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 315
 316 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 317
 318 AC_CHECK_HEADERS([sys/prctl.h])
 319
 320 # Solaris
 321 AC_CHECK_HEADERS([sys/filio.h])
 322
 323 # Windows
 324 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 325
 326 # Other
 327 AC_CHECK_HEADERS([sys/ioctl.h])
 328 AC_CHECK_HEADERS([byteswap.h])
 329 AC_CHECK_HEADERS([sys/syscall.h])
 330
 331 #### Typdefs, structures, etc. ####
 332
 333 AC_C_CONST
 334 AC_C_BIGENDIAN
 335 AC_TYPE_PID_T
 336 AC_TYPE_SIZE_T
 337 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 338     [Define ssize_t if it is not done by the standard libs.])])
 339 AC_TYPE_OFF_T
 340 AC_TYPE_SIGNAL
 341 AC_TYPE_UID_T
 342 AC_CHECK_DECLS(environ)
 343
 344 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 345 HAVE_SIGXCPU=1
 346 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 347 ], [HAVE_SIGXCPU=0])
 348 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 349
 350 # Solaris lacks this
 351 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 352     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 353         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 354
 355 #### POSIX threads ####
 356
 357 ACX_PTHREAD
 358
 359 #### Check for libs ####
 360
 361 # ISO
 362 AC_SEARCH_LIBS([pow], [m])
 363
 364 # POSIX
 365 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 366 AC_SEARCH_LIBS([dlopen], [dl])
 367 AC_SEARCH_LIBS([shm_open], [rt])
 368 AC_SEARCH_LIBS([inet_ntop], [nsl])
 369 AC_SEARCH_LIBS([timer_create], [rt])
 370
 371 # BSD
 372 AC_SEARCH_LIBS([connect], [socket])
 373
 374 # Non-standard
 375
 376 # This magic is needed so we do not needlessly add static libs to the win32
 377 # build, disabling its ability to make dlls.
 378 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 379
 380 AC_CHECK_LIB(gdbm, gdbm_open)
 381 AC_CHECK_HEADERS(gdbm.h, [], [AC_MSG_ERROR([gdbm.h not found])])
 382
 383 #### Check for functions ####
 384
 385 # ISO
 386 AC_CHECK_FUNCS([lrintf strtof])
 387
 388 # POSIX
 389 AC_FUNC_FORK
 390 AC_FUNC_GETGROUPS
 391 AC_FUNC_SELECT_ARGTYPES
 392 AC_CHECK_FUNCS([chmod chown clock_gettime getaddrinfo getgrgid_r \
 393     getpwuid_r gettimeofday getuid inet_ntop inet_pton mlock nanosleep \
 394     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 395     sigaction sleep sysconf])
 396 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 397
 398 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 399
 400 # X/OPEN
 401 AC_CHECK_FUNCS([readlink])
 402
 403 # SUSv2
 404 AC_CHECK_FUNCS([ctime_r usleep])
 405
 406 # SUSv3
 407 AC_CHECK_FUNCS([strerror_r])
 408
 409 # BSD
 410 AC_CHECK_FUNCS([lstat])
 411
 412 # Non-standard
 413
 414 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 415
 416 AC_FUNC_ALLOCA
 417
 418 AC_MSG_CHECKING([for PTHREAD_PRIO_INHERIT])
 419 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
 420 #include <pthread.h>
 421 int main() { int i = PTHREAD_PRIO_INHERIT; }]])])
 422 $PTHREAD_CC conftest.c $PTHREAD_CFLAGS $CFLAGS $PTHREAD_LIBS -o conftest > /dev/null 2> /dev/null
 423 ret=$?
 424 rm -f conftest.o conftest
 425
 426 if test $ret -eq 0 ; then
 427     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 428     AC_MSG_RESULT([yes])
 429 else
 430     AC_MSG_RESULT([no])
 431 fi
 432
 433 #### Large File-Support (LFS) ####
 434
 435 AC_SYS_LARGEFILE
 436
 437 # Check for open64 to know if the current system does have open64() and similar functions
 438 AC_CHECK_FUNCS([open64])
 439
 440 #### [lib]iconv ####
 441
 442 AM_ICONV
 443
 444 IT_PROG_INTLTOOL([0.35.0])
 445 GETTEXT_PACKAGE=pulseaudio
 446 AC_SUBST([GETTEXT_PACKAGE])
 447 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 448 AM_GLIB_GNU_GETTEXT
 449
 450 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 451 AC_SUBST(pulselocaledir)
 452
 453 ###################################
 454 #      External libraries         #
 455 ###################################
 456
 457 #### X11 (optional) ####
 458
 459 HAVE_X11=0
 460
 461 # The macro tests the host, not the build target
 462 if test "x$os_is_win32" != "x1" ; then
 463     AC_PATH_XTRA
 464     test "x$no_x" != "xyes" && HAVE_X11=1
 465 fi
 466
 467 AC_SUBST(HAVE_X11)
 468 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 469 if test "x$HAVE_X11" = "x1" ; then
 470     AC_DEFINE([HAVE_X11], 1, [Have X11])
 471 fi
 472
 473 #### Capabilities (optional) ####
 474
 475 CAP_LIBS=''
 476
 477 AC_ARG_WITH(
 478         [caps],
 479         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 480
 481 if test "x${with_caps}" != "xno"; then
 482     AC_SEARCH_LIBS([cap_init], [cap], [], [
 483                     if test "x${with_caps}" = "xyes" ; then
 484                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 485                     fi])
 486     AC_CHECK_HEADERS([sys/capability.h], [], [
 487                     if test "x${with_caps}" = "xyes" ; then
 488                         AC_MSG_ERROR([*** POSIX caps headers not found])
 489                     fi])
 490 fi
 491
 492 #### pkg-config ####
 493
 494 # Check for pkg-config manually first, as if its not installed the
 495 # PKG_PROG_PKG_CONFIG macro won't be defined.
 496 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 497
 498 if test x"$have_pkg_config" = "xno"; then
 499     AC_MSG_ERROR(pkg-config is required to install this program)
 500 fi
 501
 502 PKG_PROG_PKG_CONFIG
 503
 504 #### Sound file ####
 505
 506 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 507 AC_SUBST(LIBSNDFILE_CFLAGS)
 508 AC_SUBST(LIBSNDFILE_LIBS)
 509
 510 PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ])
 511 AC_SUBST(LIBSPEEX_CFLAGS)
 512 AC_SUBST(LIBSPEEX_LIBS)
 513
 514 #### atomic-ops ###
 515
 516 AC_MSG_CHECKING([whether we need libatomic_ops])
 517 if test "x$need_libatomic_ops" = "xyes"; then
 518    AC_MSG_RESULT([yes])
 519    AC_CHECK_HEADERS([atomic_ops.h], [], [
 520    AC_MSG_ERROR([*** libatomic-ops headers not found])
 521    ])
 522
 523    # Win32 does not need the lib and breaks horribly if we try to include it
 524    if test "x$os_is_win32" != "x1" ; then
 525        LIBS="$LIBS -latomic_ops"
 526    fi
 527 else
 528    AC_MSG_RESULT([no])
 529 fi
 530
 531 #### Libsamplerate support (optional) ####
 532
 533 AC_ARG_ENABLE([samplerate],
 534     AC_HELP_STRING([--disable-samplerate], [Disable optional libsamplerate support]),
 535         [
 536             case "${enableval}" in
 537                 yes) samplerate=yes ;;
 538                 no) samplerate=no ;;
 539                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 540             esac
 541         ],
 542         [samplerate=auto])
 543
 544 if test "x${samplerate}" != xno ; then
 545     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 546         HAVE_LIBSAMPLERATE=1,
 547         [
 548             HAVE_LIBSAMPLERATE=0
 549             if test "x$samplerate" = xyes ; then
 550                 AC_MSG_ERROR([*** Libsamplerate not found])
 551             fi
 552         ])
 553 else
 554     HAVE_LIBSAMPLERATE=0
 555 fi
 556
 557 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 558    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 559 fi
 560
 561 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 562 AC_SUBST(LIBSAMPLERATE_LIBS)
 563 AC_SUBST(HAVE_LIBSAMPLERATE)
 564 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 565
 566 #### OSS support (optional) ####
 567
 568 AC_ARG_ENABLE([oss],
 569     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 570         [
 571             case "${enableval}" in
 572                 yes) oss=yes ;;
 573                 no) oss=no ;;
 574                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 575             esac
 576         ],
 577         [oss=auto])
 578
 579 if test "x${oss}" != xno ; then
 580     AC_CHECK_HEADERS([sys/soundcard.h],
 581         [
 582             HAVE_OSS=1
 583             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 584         ],
 585         [
 586             HAVE_OSS=0
 587             if test "x$oss" = xyes ; then
 588                 AC_MSG_ERROR([*** OSS support not found])
 589             fi
 590         ])
 591 else
 592     HAVE_OSS=0
 593 fi
 594
 595 AC_SUBST(HAVE_OSS)
 596 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 597
 598
 599 #### ALSA support (optional) ####
 600
 601 AC_ARG_ENABLE([alsa],
 602     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 603         [
 604             case "${enableval}" in
 605                 yes) alsa=yes ;;
 606                 no) alsa=no ;;
 607                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 608             esac
 609         ],
 610         [alsa=auto])
 611
 612 if test "x${alsa}" != xno ; then
 613     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.17 ],
 614         [
 615             HAVE_ALSA=1
 616             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 617         ],
 618         [
 619             HAVE_ALSA=0
 620             if test "x$alsa" = xyes ; then
 621                 AC_MSG_ERROR([*** Needed alsa >= 1.0.17 support not found])
 622             fi
 623         ])
 624 else
 625     HAVE_ALSA=0
 626 fi
 627
 628 AC_SUBST(ASOUNDLIB_CFLAGS)
 629 AC_SUBST(ASOUNDLIB_LIBS)
 630 AC_SUBST(HAVE_ALSA)
 631 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 632
 633 #### Solaris audio support (optional) ####
 634
 635 AC_ARG_ENABLE([solaris],
 636     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 637         [
 638             case "${enableval}" in
 639                 yes) solaris=yes ;;
 640                 no) solaris=no ;;
 641                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 642             esac
 643         ],
 644         [solaris=auto])
 645
 646 if test "x${solaris}" != xno ; then
 647     AC_CHECK_HEADERS([sys/audio.h],
 648         [
 649             HAVE_SOLARIS=1
 650             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 651         ],
 652         [
 653             HAVE_SOLARIS=0
 654             if test "x$solaris" = xyes ; then
 655                 AC_MSG_ERROR([*** Solaris audio support not found])
 656             fi
 657         ])
 658 else
 659     HAVE_SOLARIS=0
 660 fi
 661
 662 AC_SUBST(HAVE_SOLARIS)
 663 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 664
 665 #### GLib 2 support (optional) ####
 666
 667 AC_ARG_ENABLE([glib2],
 668     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 669         [
 670             case "${enableval}" in
 671                 yes) glib2=yes ;;
 672                 no) glib2=no ;;
 673                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 674             esac
 675         ],
 676         [glib2=auto])
 677
 678 if test "x${glib2}" != xno ; then
 679     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 680         HAVE_GLIB20=1,
 681         [
 682             HAVE_GLIB20=0
 683             if test "x$glib2" = xyes ; then
 684                 AC_MSG_ERROR([*** GLib 2 support not found])
 685             fi
 686         ])
 687 else
 688     HAVE_GLIB20=0
 689 fi
 690
 691 AC_SUBST(GLIB20_CFLAGS)
 692 AC_SUBST(GLIB20_LIBS)
 693 AC_SUBST(HAVE_GLIB20)
 694 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 695
 696 #### GConf support (optional) ####
 697
 698 AC_ARG_ENABLE([gconf],
 699     AC_HELP_STRING([--disable-gconf], [Disable optional GConf support]),
 700         [
 701             case "${enableval}" in
 702                 yes) gconf=yes ;;
 703                 no) gconf=no ;;
 704                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 705             esac
 706         ],
 707         [gconf=auto])
 708
 709 if test "x${gconf}" != xno ; then
 710     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 711         HAVE_GCONF=1,
 712         [
 713             HAVE_GCONF=0
 714             if test "x$gconf" = xyes ; then
 715                 AC_MSG_ERROR([*** GConf support not found])
 716             fi
 717         ])
 718 else
 719     HAVE_GCONF=0
 720 fi
 721
 722 AC_SUBST(GCONF_CFLAGS)
 723 AC_SUBST(GCONF_LIBS)
 724 AC_SUBST(HAVE_GCONF)
 725 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 726
 727 #### Avahi support (optional) ####
 728
 729 AC_ARG_ENABLE([avahi],
 730     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 731         [
 732             case "${enableval}" in
 733                 yes) avahi=yes ;;
 734                 no) avahi=no ;;
 735                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 736             esac
 737         ],
 738         [avahi=auto])
 739
 740 if test "x${avahi}" != xno ; then
 741     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 742         HAVE_AVAHI=1,
 743         [
 744                 HAVE_AVAHI=0
 745                 if test "x$avahi" = xyes ; then
 746                         AC_MSG_ERROR([*** Avahi support not found])
 747                 fi
 748         ])
 749 else
 750     HAVE_AVAHI=0
 751 fi
 752
 753 AC_SUBST(AVAHI_CFLAGS)
 754 AC_SUBST(AVAHI_LIBS)
 755 AC_SUBST(HAVE_AVAHI)
 756 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 757
 758 ### LIBOIL ####
 759
 760 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 761 AC_SUBST(LIBOIL_CFLAGS)
 762 AC_SUBST(LIBOIL_LIBS)
 763
 764 ### JACK (optional) ####
 765
 766 AC_ARG_ENABLE([jack],
 767     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 768         [
 769             case "${enableval}" in
 770                 yes) jack=yes ;;
 771                 no) jack=no ;;
 772                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 773             esac
 774         ],
 775         [jack=auto])
 776
 777 if test "x${jack}" != xno ; then
 778     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 779         HAVE_JACK=1,
 780         [
 781             HAVE_JACK=0
 782             if test "x$jack" = xyes ; then
 783                 AC_MSG_ERROR([*** JACK support not found])
 784             fi
 785         ])
 786 else
 787     HAVE_JACK=0
 788 fi
 789
 790 AC_SUBST(JACK_CFLAGS)
 791 AC_SUBST(JACK_LIBS)
 792 AC_SUBST(HAVE_JACK)
 793 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 794
 795 #### Async DNS support (optional) ####
 796
 797 AC_ARG_ENABLE([asyncns],
 798     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 799         [
 800             case "${enableval}" in
 801                 yes) asyncns=yes ;;
 802                 no) asyncns=no ;;
 803                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 804             esac
 805         ],
 806         [asyncns=auto])
 807
 808 if test "x${asyncns}" != xno ; then
 809     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 810         HAVE_LIBASYNCNS=1,
 811         [
 812             HAVE_LIBASYNCNS=0
 813             if test "x$asyncns" = xyes ; then
 814                 AC_MSG_ERROR([*** Async DNS support not found])
 815             fi
 816         ])
 817 else
 818     HAVE_LIBASYNCNS=0
 819 fi
 820
 821 AC_SUBST(LIBASYNCNS_CFLAGS)
 822 AC_SUBST(LIBASYNCNS_LIBS)
 823 AC_SUBST(HAVE_LIBASYNCNS)
 824 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 825
 826 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 827    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 828 fi
 829
 830 #### TCP wrappers (optional) ####
 831
 832 AC_ARG_ENABLE([tcpwrap],
 833     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 834         [
 835             case "${enableval}" in
 836                 yes) tcpwrap=yes ;;
 837                 no) tcpwrap=no ;;
 838                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 839             esac
 840         ],
 841         [tcpwrap=auto])
 842
 843 if test "x${tcpwrap}" != xno ; then
 844     ACX_LIBWRAP
 845     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 846         AC_MSG_ERROR([*** TCP wrappers support not found])
 847     fi
 848 else
 849     LIBWRAP_LIBS=
 850 fi
 851
 852 AC_SUBST(LIBWRAP_LIBS)
 853
 854 #### LIRC support (optional) ####
 855
 856 AC_ARG_ENABLE([lirc],
 857     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 858         [
 859             case "${enableval}" in
 860                 yes) lirc=yes ;;
 861                 no) lirc=no ;;
 862                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 863             esac
 864         ],
 865         [lirc=auto])
 866
 867 if test "x${lirc}" != xno ; then
 868     ACX_LIRC
 869     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 870         AC_MSG_ERROR([*** LIRC support not found])
 871     fi
 872 else
 873     HAVE_LIRC=0
 874 fi
 875
 876 AC_SUBST(LIRC_CFLAGS)
 877 AC_SUBST(LIRC_LIBS)
 878 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 879
 880 #### HAL support (optional) ####
 881
 882 AC_ARG_ENABLE([hal],
 883     AC_HELP_STRING([--disable-hal], [Disable optional HAL support]),
 884         [
 885             case "${enableval}" in
 886                 yes) hal=yes ;;
 887                 no) hal=no ;;
 888                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 889             esac
 890         ],
 891         [hal=auto])
 892 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 893     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 894         HAVE_HAL=1,
 895         [
 896             HAVE_HAL=0
 897             if test "x$hal" = xyes ; then
 898                 AC_MSG_ERROR([*** HAL support not found])
 899             fi
 900         ])
 901 else
 902     HAVE_HAL=0
 903 fi
 904
 905 AC_SUBST(HAL_CFLAGS)
 906 AC_SUBST(HAL_LIBS)
 907 AC_SUBST(HAVE_HAL)
 908 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 909
 910 #### BlueZ support (optional) ####
 911
 912 AC_ARG_ENABLE([bluez],
 913     AC_HELP_STRING([--disable-bluez], [Disable optional BlueZ support]),
 914         [
 915             case "${enableval}" in
 916                 yes) bluez=yes ;;
 917                 no) bluez=no ;;
 918                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-bluez) ;;
 919             esac
 920         ],
 921         [bluez=auto])
 922 if test "x${bluez}" != xno ; then
 923     PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ],
 924         HAVE_BLUEZ=1,
 925         [
 926             HAVE_BLUEZ=0
 927             if test "x$bluez" = xyes ; then
 928                 AC_MSG_ERROR([*** BLUEZ support not found])
 929             fi
 930         ])
 931 else
 932     HAVE_BLUEZ=0
 933 fi
 934
 935 AC_SUBST(BLUEZ_CFLAGS)
 936 AC_SUBST(BLUEZ_LIBS)
 937 AC_SUBST(HAVE_BLUEZ)
 938 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 939
 940 #### D-Bus support (optional) ####
 941
 942 AC_ARG_ENABLE([dbus],
 943     AC_HELP_STRING([--disable-dbus], [Disable optional D-Bus support]),
 944         [
 945             case "${enableval}" in
 946                 yes) dbus=yes ;;
 947                 no) dbus=no ;;
 948                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 949             esac
 950         ],
 951         [dbus=auto])
 952
 953 if test "x$HAVE_HAL" = x1 ; then
 954    dbus=yes
 955 fi
 956
 957 if test "x${dbus}" != xno || test "x${bluez}" != xno || "x${hal}" != xno ; then
 958
 959     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 960         [
 961             HAVE_DBUS=1
 962             saved_LIBS="$LIBS"
 963             LIBS="$LIBS $DBUS_LIBS"
 964             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 965             LIBS="$saved_LIBS"
 966             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 967         ],
 968         [
 969             HAVE_DBUS=0
 970             if test "x$dbus" = xyes ; then
 971                 AC_MSG_ERROR([*** D-Bus support not found])
 972             fi
 973         ])
 974 else
 975     HAVE_DBUS=0
 976 fi
 977
 978 AC_SUBST(DBUS_CFLAGS)
 979 AC_SUBST(DBUS_LIBS)
 980 AC_SUBST(HAVE_DBUS)
 981 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 982
 983 #### PolicyKit support (optional) ####
 984
 985 AC_ARG_ENABLE([polkit],
 986     AC_HELP_STRING([--disable-polkit], [Disable optional PolicyKit support]),
 987         [
 988             case "${enableval}" in
 989                 yes) polkit=yes ;;
 990                 no) polkit=no ;;
 991                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-polkit) ;;
 992             esac
 993         ],
 994         [polkit=auto])
 995
 996 if test "x${polkit}" != xno ; then
 997
 998     PKG_CHECK_MODULES(POLKIT, [ polkit-dbus >= 0.7 ],
 999         [
1000             HAVE_POLKIT=1
1001             AC_DEFINE([HAVE_POLKIT], 1, [Have PolicyKit])
1002             policydir=`pkg-config polkit-dbus --variable prefix`/share/PolicyKit/policy/
1003             AC_SUBST(policydir)
1004         ],
1005         [
1006             HAVE_POLKIT=0
1007             if test "x$polkit" = xyes ; then
1008                 AC_MSG_ERROR([*** PolicyKit support not found])
1009             fi
1010         ])
1011 else
1012     HAVE_POLKIT=0
1013 fi
1014
1015 AC_SUBST(POLKIT_CFLAGS)
1016 AC_SUBST(POLKIT_LIBS)
1017 AC_SUBST(HAVE_POLKIT)
1018 AM_CONDITIONAL([HAVE_POLKIT], [test "x$HAVE_POLKIT" = x1])
1019
1020 ### Build and Install man pages ###
1021 AC_ARG_ENABLE(manpages,
1022         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
1023 [case "${enableval}" in
1024   yes) manpages=yes ;;
1025   no)  manpages=no ;;
1026   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
1027 esac],[manpages=yes])
1028
1029 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
1030
1031 #### PulseAudio system group & user  #####
1032
1033 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1034 if test -z "$with_system_user" ; then
1035     PA_SYSTEM_USER=pulse
1036 else
1037     PA_SYSTEM_USER=$with_system_user
1038 fi
1039 AC_SUBST(PA_SYSTEM_USER)
1040 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1041
1042 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1043 if test -z "$with_system_group" ; then
1044     PA_SYSTEM_GROUP=pulse
1045 else
1046     PA_SYSTEM_GROUP=$with_system_group
1047 fi
1048 AC_SUBST(PA_SYSTEM_GROUP)
1049 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1050
1051 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
1052 if test -z "$with_realtime_group" ; then
1053     PA_REALTIME_GROUP=pulse-rt
1054 else
1055     PA_REALTIME_GROUP=$with_realtime_group
1056 fi
1057 AC_SUBST(PA_REALTIME_GROUP)
1058 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
1059
1060 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1061 if test -z "$with_access_group" ; then
1062     PA_ACCESS_GROUP=pulse-access
1063 else
1064     PA_ACCESS_GROUP=$with_access_group
1065 fi
1066 AC_SUBST(PA_ACCESS_GROUP)
1067 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1068
1069 AC_ARG_ENABLE(
1070         per_user_esound_socket,
1071         AS_HELP_STRING([--disable-per-user-esound-socket], [Use global esound socket directory /tmp/.esd/socket.]),
1072         [
1073             case "${enableval}" in
1074                 yes) per_user_esound_socket=1 ;;
1075                 no) per_user_esound_socket=0 ;;
1076                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-per-user-esound-socket) ;;
1077             esac
1078         ],
1079         [per_user_esound_socket=1])
1080
1081 if test "x$per_user_esound_socket" = "x1"; then
1082    AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1083 fi
1084
1085 #### PulseAudio system runtime dir ####
1086 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1087 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1088 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1089 AC_SUBST(PA_SYSTEM_CONFIG_PATH)
1090 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1091 AC_SUBST(PA_SYSTEM_STATE_PATH)
1092
1093 ###################################
1094 #            Output               #
1095 ###################################
1096
1097 AC_ARG_ENABLE(
1098         [static-bins],
1099         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
1100         [STATIC_BINS=1], [STATIC_BINS=0])
1101 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1102
1103 AC_ARG_WITH(
1104         [preopen-mods],
1105         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1106         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1107 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1108 if test "x$PREOPEN_MODS" != "xall" ; then
1109     tmpLIBS=""
1110     for mod in $PREOPEN_MODS; do
1111         tmpLIBS="$tmpLIBS module-$mod.la"
1112     done
1113     PREOPEN_MODS="$tmpLIBS"
1114     AC_SUBST(PREOPEN_MODS)
1115 fi
1116
1117 AC_ARG_WITH(
1118         [module-dir],
1119         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
1120         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
1121
1122 AC_SUBST(modlibexecdir)
1123
1124 AC_ARG_ENABLE(
1125         [force-preopen],
1126         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
1127         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
1128 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
1129
1130 AC_CONFIG_FILES([
1131 Makefile
1132 src/Makefile
1133 man/Makefile
1134 libpulse.pc
1135 libpulse-simple.pc
1136 libpulse-browse.pc
1137 libpulse-mainloop-glib.pc
1138 doxygen/Makefile
1139 doxygen/doxygen.conf
1140 src/pulse/version.h
1141 po/Makefile.in
1142 ])
1143 AC_OUTPUT
1144
1145 # ==========================================================================
1146 ENABLE_X11=no
1147 if test "x$HAVE_X11" = "x1" ; then
1148    ENABLE_X11=yes
1149 fi
1150
1151 ENABLE_OSS=no
1152 if test "x$HAVE_OSS" = "x1" ; then
1153    ENABLE_OSS=yes
1154 fi
1155
1156 ENABLE_ALSA=no
1157 if test "x$HAVE_ALSA" = "x1" ; then
1158    ENABLE_ALSA=yes
1159 fi
1160
1161 ENABLE_SOLARIS=no
1162 if test "x$HAVE_SOLARIS" = "x1" ; then
1163    ENABLE_SOLARIS=yes
1164 fi
1165
1166 ENABLE_GLIB20=no
1167 if test "x$HAVE_GLIB20" = "x1" ; then
1168    ENABLE_GLIB20=yes
1169 fi
1170
1171 ENABLE_GCONF=no
1172 if test "x$HAVE_GCONF" = "x1" ; then
1173    ENABLE_GCONF=yes
1174 fi
1175
1176 ENABLE_AVAHI=no
1177 if test "x$HAVE_AVAHI" = "x1" ; then
1178    ENABLE_AVAHI=yes
1179 fi
1180
1181 ENABLE_JACK=no
1182 if test "x$HAVE_JACK" = "x1" ; then
1183    ENABLE_JACK=yes
1184 fi
1185
1186 ENABLE_LIBASYNCNS=no
1187 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
1188    ENABLE_LIBASYNCNS=yes
1189 fi
1190
1191 ENABLE_LIRC=no
1192 if test "x$HAVE_LIRC" = "x1" ; then
1193    ENABLE_LIRC=yes
1194 fi
1195
1196 ENABLE_HAL=no
1197 if test "x$HAVE_HAL" = "x1" ; then
1198    ENABLE_HAL=yes
1199 fi
1200
1201 ENABLE_TCPWRAP=no
1202 if test "x${LIBWRAP_LIBS}" != x ; then
1203    ENABLE_TCPWRAP=yes
1204 fi
1205
1206 ENABLE_LIBSAMPLERATE=no
1207 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
1208    ENABLE_LIBSAMPLERATE=yes
1209 fi
1210
1211 ENABLE_BLUEZ=no
1212 if test "x${HAVE_BLUEZ}" = "x1" ; then
1213    ENABLE_BLUEZ=yes
1214 fi
1215
1216 ENABLE_POLKIT=no
1217 if test "x${HAVE_POLKIT}" = "x1" ; then
1218    ENABLE_POLKIT=yes
1219 fi
1220
1221 ENABLE_PER_USER_ESOUND_SOCKET=no
1222 if test "x$per_user_esound_socket" = "x1" ; then
1223    ENABLE_PER_USER_ESOUND_SOCKET=yes
1224 fi
1225
1226 echo "
1227  ---{ $PACKAGE_NAME $VERSION }---
1228
1229     prefix:                        ${prefix}
1230     sysconfdir:                    ${sysconfdir}
1231     localstatedir:                 ${localstatedir}
1232     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1233     System State Path:             ${PA_SYSTEM_STATE_PATH}
1234     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1235     Compiler:                      ${CC}
1236     CFLAGS:                        ${CFLAGS}
1237     Have X11:                      ${ENABLE_X11}
1238     Enable OSS:                    ${ENABLE_OSS}
1239     Enable Alsa:                   ${ENABLE_ALSA}
1240     Enable Solaris:                ${ENABLE_SOLARIS}
1241     Enable GLib 2.0:               ${ENABLE_GLIB20}
1242     Enable GConf:                  ${ENABLE_GCONF}
1243     Enable Avahi:                  ${ENABLE_AVAHI}
1244     Enable Jack:                   ${ENABLE_JACK}
1245     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1246     Enable LIRC:                   ${ENABLE_LIRC}
1247     Enable HAL:                    ${ENABLE_HAL}
1248     Enable BlueZ:                  ${ENABLE_BLUEZ}
1249     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1250     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1251     Enable PolicyKit:              ${ENABLE_POLKIT}
1252     System User:                   ${PA_SYSTEM_USER}
1253     System Group:                  ${PA_SYSTEM_GROUP}
1254     Realtime Group:                ${PA_REALTIME_GROUP}
1255     Access Group:                  ${PA_ACCESS_GROUP}
1256     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1257 "