code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of PulseAudio.
   7 #
   8 # PulseAudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # PulseAudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with PulseAudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23
  24 m4_define(PA_MAJOR, [0])
  25 m4_define(PA_MINOR, [9])
  26 m4_define(PA_MICRO, [4])
  27
  28 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  29 AC_CONFIG_SRCDIR([src/daemon/main.c])
  30 AC_CONFIG_HEADERS([config.h])
  31 AM_INIT_AUTOMAKE([foreign -Wall])
  32
  33 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  34 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/pulseaudio/])
  35
  36 AC_SUBST(PA_API_VERSION, 10)
  37 AC_SUBST(PA_PROTOCOL_VERSION, 10)
  38
  39 AC_SUBST(LIBPULSE_VERSION_INFO, [0:2:0])
  40 AC_SUBST(LIBPULSECORE_VERSION_INFO, [1:1:0])
  41 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:0:0])
  42 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:0:1])
  43 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:1:0])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 #### Platform hacks ####
  51
  52 case $host in
  53    *-*-solaris* )
  54       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  55       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  56       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  57       ;;
  58 esac
  59
  60 #### Checks for programs. ####
  61
  62 # CC
  63
  64 AC_PROG_CC
  65 AC_PROG_GCC_TRADITIONAL
  66 AC_GNU_SOURCE
  67
  68 # M4
  69
  70 AC_PATH_PROG([M4], [m4 gm4], [no])
  71 if test "x$M4" = xno ; then
  72    AC_MSG_ERROR([m4 missing])
  73 fi
  74
  75 # GCC flags
  76
  77 test_gcc_flag() {
  78     AC_LANG_CONFTEST([int main() {}])
  79     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  80     ret=$?
  81     rm -f conftest.o
  82     return $ret
  83 }
  84
  85 # If using GCC specify some additional parameters
  86 if test "x$GCC" = "xyes" ; then
  87
  88     # We use gnu99 instead of c99 because many have interpreted the standard
  89     # in a way that int64_t isn't defined on non-64 bit platforms.
  90     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  91
  92     for flag in $DESIRED_FLAGS ; do
  93         AC_MSG_CHECKING([whether $CC accepts $flag])
  94         if test_gcc_flag $flag ; then
  95            CFLAGS="$CFLAGS $flag"
  96            AC_MSG_RESULT([yes])
  97         else
  98            AC_MSG_RESULT([no])
  99         fi
 100     done
 101 fi
 102
 103 #### libtool stuff ####
 104
 105 AC_LTDL_ENABLE_INSTALL
 106 AC_LIBLTDL_INSTALLABLE
 107 AC_SUBST(LTDLINCL)
 108 AC_SUBST(LIBLTDL)
 109 AC_LIBTOOL_DLOPEN
 110 AC_LIBTOOL_WIN32_DLL
 111 AC_PROG_LIBTOOL
 112 AC_CONFIG_SUBDIRS(libltdl)
 113
 114 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 115     AC_MSG_ERROR([[
 116
 117         *** Cannot find the libltdl development files.
 118         *** Maybe you need to install the libltdl-dev package.
 119         ]])
 120 fi
 121
 122 #### Determine build environment ####
 123
 124 os_is_win32=0
 125
 126 case "$host_os" in
 127         mingw*)
 128         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 129         os_is_win32=1
 130                 ;;
 131         esac
 132
 133 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 134
 135 ###################################
 136 #   Basic environment checks      #
 137 ###################################
 138
 139 #### Checks for header files. ####
 140
 141 # ISO
 142 AC_HEADER_STDC
 143
 144 # POSIX
 145 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 146     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 147     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 148     syslog.h])
 149 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 150 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 151
 152 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 153 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 154
 155 # XPG4-UNIX
 156 AC_CHECK_HEADERS([sys/poll.h])
 157
 158 # Linux
 159 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 160
 161 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 162
 163 AC_CHECK_HEADERS([sys/prctl.h])
 164
 165 # Solaris
 166 AC_CHECK_HEADERS([sys/filio.h])
 167
 168 # Windows
 169 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 170
 171 # Other
 172 AC_CHECK_HEADERS([sys/ioctl.h])
 173
 174 #### Typdefs, structures, etc. ####
 175
 176 AC_C_CONST
 177 AC_C_BIGENDIAN
 178 AC_TYPE_PID_T
 179 AC_TYPE_SIZE_T
 180 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 181     [Define ssize_t if it is not done by the standard libs.])])
 182 AC_TYPE_OFF_T
 183 AC_TYPE_SIGNAL
 184 AC_TYPE_UID_T
 185
 186 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 187 HAVE_SIGXCPU=1
 188 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 189 ], [HAVE_SIGXCPU=0])
 190 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 191
 192 # Solaris lacks this
 193 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 194     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 195         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 196
 197 #### Check for libs ####
 198
 199 # ISO
 200 AC_SEARCH_LIBS([pow], [m])
 201
 202 # POSIX
 203 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 204 AC_SEARCH_LIBS([dlopen], [dl])
 205
 206 # BSD
 207 AC_SEARCH_LIBS([connect], [socket])
 208
 209 AC_SEARCH_LIBS([shm_open], [rt])
 210
 211 # Non-standard
 212
 213 # This magic is needed so we do not needlessly add static libs to the win32
 214 # build, disabling its ability to make dlls.
 215 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 216
 217 #### Check for functions ####
 218
 219 # POSIX
 220 AC_FUNC_FORK
 221 AC_FUNC_GETGROUPS
 222 AC_FUNC_SELECT_ARGTYPES
 223 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 224     getuid inet_ntop inet_pton nanosleep pipe setpgid setsid sigaction sleep])
 225 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 226
 227 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 228
 229 # X/OPEN
 230 AC_CHECK_FUNCS([readlink])
 231
 232 # SUSv2
 233 AC_CHECK_FUNCS([ctime_r usleep])
 234
 235 # SUSv3
 236 AC_CHECK_FUNCS([strerror_r])
 237
 238 # BSD
 239 AC_CHECK_FUNCS([lstat])
 240
 241 # Non-standard
 242
 243 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid])
 244
 245 # Memory mangement
 246
 247 AC_CHECK_FUNCS([mmap posix_memalign madvise])
 248
 249 #### POSIX threads ####
 250
 251 ACX_PTHREAD
 252
 253 #### Large File-Support (LFS) ####
 254
 255 AC_SYS_LARGEFILE
 256
 257 # Check for open64 to know if the current system does have open64() and similar functions
 258 AC_CHECK_FUNCS([open64])
 259
 260 #### [lib]iconv ####
 261
 262 AM_ICONV
 263
 264 ###################################
 265 #      External libraries         #
 266 ###################################
 267
 268 #### X11 (optional) ####
 269
 270 HAVE_X11=0
 271
 272 # The macro tests the host, not the build target
 273 if test "x$os_is_win32" != "x1" ; then
 274     AC_PATH_XTRA
 275     test "x$no_x" != "xyes" && HAVE_X11=1
 276 fi
 277
 278 AC_SUBST(HAVE_X11)
 279 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 280 if test "x$HAVE_X11" = "x1" ; then
 281     AC_DEFINE([HAVE_X11], 1, [Have X11])
 282 fi
 283
 284 #### Capabilities (optional) ####
 285
 286 CAP_LIBS=''
 287
 288 AC_ARG_WITH(
 289         [caps],
 290         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 291
 292 if test "x${with_caps}" != "xno"; then
 293     AC_SEARCH_LIBS([cap_init], [cap], [], [
 294                     if test "x${with_caps}" = "xyes" ; then
 295                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 296                     fi])
 297     AC_CHECK_HEADERS([sys/capability.h], [], [
 298                     if test "x${with_caps}" = "xyes" ; then
 299                         AC_MSG_ERROR([*** POSIX caps headers not found])
 300                     fi])
 301 fi
 302
 303 #### pkg-config ####
 304
 305 # Check for pkg-config manually first, as if its not installed the
 306 # PKG_PROG_PKG_CONFIG macro won't be defined.
 307 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 308
 309 if test x"$have_pkg_config" = "xno"; then
 310     AC_MSG_ERROR(pkg-config is required to install this program)
 311 fi
 312
 313 PKG_PROG_PKG_CONFIG
 314
 315 #### Sample rate conversion ####
 316
 317 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 318 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 319 AC_SUBST(LIBSAMPLERATE_LIBS)
 320
 321 #### Sound file ####
 322
 323 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 324 AC_SUBST(LIBSNDFILE_CFLAGS)
 325 AC_SUBST(LIBSNDFILE_LIBS)
 326
 327 #### OSS support (optional) ####
 328
 329 AC_ARG_ENABLE([oss],
 330     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 331         [
 332             case "${enableval}" in
 333                 yes) oss=yes ;;
 334                 no) oss=no ;;
 335                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 336             esac
 337         ],
 338         [oss=auto])
 339
 340 if test "x${oss}" != xno ; then
 341     AC_CHECK_HEADERS([sys/soundcard.h],
 342         [
 343             HAVE_OSS=1
 344             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 345         ],
 346         [
 347             HAVE_OSS=0
 348             if test "x$oss" = xyes ; then
 349                 AC_MSG_ERROR([*** OSS support not found])
 350             fi
 351         ])
 352 else
 353     HAVE_OSS=0
 354 fi
 355
 356 AC_SUBST(HAVE_OSS)
 357 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 358
 359
 360 #### ALSA support (optional) ####
 361
 362 AC_ARG_ENABLE([alsa],
 363     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 364         [
 365             case "${enableval}" in
 366                 yes) alsa=yes ;;
 367                 no) alsa=no ;;
 368                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 369             esac
 370         ],
 371         [alsa=auto])
 372
 373 if test "x${alsa}" != xno ; then
 374     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ],
 375         [
 376             HAVE_ALSA=1
 377             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 378         ],
 379         [
 380             HAVE_ALSA=0
 381             if test "x$alsa" = xyes ; then
 382                 AC_MSG_ERROR([*** ALSA support not found])
 383             fi
 384         ])
 385 else
 386     HAVE_ALSA=0
 387 fi
 388
 389 AC_SUBST(ASOUNDLIB_CFLAGS)
 390 AC_SUBST(ASOUNDLIB_LIBS)
 391 AC_SUBST(HAVE_ALSA)
 392 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 393
 394 #### Solaris audio support (optional) ####
 395
 396 AC_ARG_ENABLE([solaris],
 397     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 398         [
 399             case "${enableval}" in
 400                 yes) solaris=yes ;;
 401                 no) solaris=no ;;
 402                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 403             esac
 404         ],
 405         [solaris=auto])
 406
 407 if test "x${solaris}" != xno ; then
 408     AC_CHECK_HEADERS([sys/audio.h],
 409         [
 410             HAVE_SOLARIS=1
 411             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 412         ],
 413         [
 414             HAVE_SOLARIS=0
 415             if test "x$solaris" = xyes ; then
 416                 AC_MSG_ERROR([*** Solaris audio support not found])
 417             fi
 418         ])
 419 else
 420     HAVE_SOLARIS=0
 421 fi
 422
 423 AC_SUBST(HAVE_SOLARIS)
 424 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 425
 426 #### GLib 2 support (optional) ####
 427
 428 AC_ARG_ENABLE([glib2],
 429     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 430         [
 431             case "${enableval}" in
 432                 yes) glib2=yes ;;
 433                 no) glib2=no ;;
 434                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 435             esac
 436         ],
 437         [glib2=auto])
 438
 439 if test "x${glib2}" != xno ; then
 440     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 441         HAVE_GLIB20=1,
 442         [
 443             HAVE_GLIB20=0
 444             if test "x$glib2" = xyes ; then
 445                 AC_MSG_ERROR([*** GLib 2 support not found])
 446             fi
 447         ])
 448 else
 449     HAVE_GLIB20=0
 450 fi
 451
 452 AC_SUBST(GLIB20_CFLAGS)
 453 AC_SUBST(GLIB20_LIBS)
 454 AC_SUBST(HAVE_GLIB20)
 455 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 456
 457 #### GConf support (optional) ####
 458
 459 AC_ARG_ENABLE([gconf],
 460     AC_HELP_STRING([--disable-gconf], [Disable optional GConf support]),
 461         [
 462             case "${enableval}" in
 463                 yes) gconf=yes ;;
 464                 no) gconf=no ;;
 465                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 466             esac
 467         ],
 468         [glib=auto])
 469
 470 if test "x${gconf}" != xno ; then
 471     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 472         HAVE_GCONF=1,
 473         [
 474             HAVE_GCONF=0
 475             if test "x$gconf" = xyes ; then
 476                 AC_MSG_ERROR([*** GConf support not found])
 477             fi
 478         ])
 479 else
 480     HAVE_GCONF=0
 481 fi
 482
 483 AC_SUBST(GCONF_CFLAGS)
 484 AC_SUBST(GCONF_LIBS)
 485 AC_SUBST(HAVE_GCONF)
 486 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 487
 488 #### Avahi support (optional) ####
 489
 490 AC_ARG_ENABLE([avahi],
 491     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 492         [
 493             case "${enableval}" in
 494                 yes) avahi=yes ;;
 495                 no) avahi=no ;;
 496                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 497             esac
 498         ],
 499         [avahi=auto])
 500
 501 if test "x${avahi}" != xno ; then
 502     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 503         HAVE_AVAHI=1,
 504         [
 505                 HAVE_AVAHI=0
 506                 if test "x$avahi" = xyes ; then
 507                         AC_MSG_ERROR([*** Avahi support not found])
 508                 fi
 509         ])
 510 else
 511     HAVE_AVAHI=0
 512 fi
 513
 514 AC_SUBST(AVAHI_CFLAGS)
 515 AC_SUBST(AVAHI_LIBS)
 516 AC_SUBST(HAVE_AVAHI)
 517 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 518
 519 ### LIBOIL ####
 520
 521 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 522 AC_SUBST(LIBOIL_CFLAGS)
 523 AC_SUBST(LIBOIL_LIBS)
 524
 525 ### JACK (optional) ####
 526
 527 AC_ARG_ENABLE([jack],
 528     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 529         [
 530             case "${enableval}" in
 531                 yes) jack=yes ;;
 532                 no) jack=no ;;
 533                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 534             esac
 535         ],
 536         [jack=auto])
 537
 538 if test "x${jack}" != xno ; then
 539     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 540         HAVE_JACK=1,
 541         [
 542             HAVE_JACK=0
 543             if test "x$jack" = xyes ; then
 544                 AC_MSG_ERROR([*** JACK support not found])
 545             fi
 546         ])
 547 else
 548     HAVE_JACK=0
 549 fi
 550
 551 AC_SUBST(JACK_CFLAGS)
 552 AC_SUBST(JACK_LIBS)
 553 AC_SUBST(HAVE_JACK)
 554 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 555
 556 #### Async DNS support (optional) ####
 557
 558 AC_ARG_ENABLE([asyncns],
 559     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 560         [
 561             case "${enableval}" in
 562                 yes) asyncns=yes ;;
 563                 no) asyncns=no ;;
 564                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 565             esac
 566         ],
 567         [asyncns=auto])
 568
 569 if test "x${asyncns}" != xno ; then
 570     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 571         HAVE_LIBASYNCNS=1,
 572         [
 573             HAVE_LIBASYNCNS=0
 574             if test "x$asyncns" = xyes ; then
 575                 AC_MSG_ERROR([*** Async DNS support not found])
 576             fi
 577         ])
 578 else
 579     HAVE_LIBASYNCNS=0
 580 fi
 581
 582 AC_SUBST(LIBASYNCNS_CFLAGS)
 583 AC_SUBST(LIBASYNCNS_LIBS)
 584 AC_SUBST(HAVE_LIBASYNCNS)
 585 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 586
 587 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 588    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 589 fi
 590
 591 #### TCP wrappers (optional) ####
 592
 593 AC_ARG_ENABLE([tcpwrap],
 594     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 595         [
 596             case "${enableval}" in
 597                 yes) tcpwrap=yes ;;
 598                 no) tcpwrap=no ;;
 599                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 600             esac
 601         ],
 602         [tcpwrap=auto])
 603
 604 if test "x${tcpwrap}" != xno ; then
 605     ACX_LIBWRAP
 606     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 607         AC_MSG_ERROR([*** TCP wrappers support not found])
 608     fi
 609 else
 610     LIBWRAP_LIBS=
 611 fi
 612
 613 AC_SUBST(LIBWRAP_LIBS)
 614
 615 #### LIRC support (optional) ####
 616
 617 AC_ARG_ENABLE([lirc],
 618     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 619         [
 620             case "${enableval}" in
 621                 yes) lirc=yes ;;
 622                 no) lirc=no ;;
 623                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 624             esac
 625         ],
 626         [lirc=auto])
 627
 628 if test "x${lirc}" != xno ; then
 629     ACX_LIRC
 630     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 631         AC_MSG_ERROR([*** LIRC support not found])
 632     fi
 633 else
 634     HAVE_LIRC=0
 635 fi
 636
 637 AC_SUBST(LIRC_CFLAGS)
 638 AC_SUBST(LIRC_LIBS)
 639 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 640
 641 #### HAL support (optional) ####
 642
 643 AC_ARG_ENABLE([hal],
 644     AC_HELP_STRING([--disable-hal], [Disable optional HAL support]),
 645         [
 646             case "${enableval}" in
 647                 yes) hal=yes ;;
 648                 no) hal=no ;;
 649                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 650             esac
 651         ],
 652         [hal=auto])
 653
 654 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 655     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 656         HAVE_HAL=1,
 657         [
 658             HAVE_HAL=0
 659             if test "x$hal" = xyes ; then
 660                 AC_MSG_ERROR([*** HAL support not found])
 661             fi
 662         ])
 663 else
 664     HAVE_HAL=0
 665 fi
 666
 667 AC_SUBST(HAL_CFLAGS)
 668 AC_SUBST(HAL_LIBS)
 669 AC_SUBST(HAVE_HAL)
 670 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 671
 672 #### PulseAudio system group & user  #####
 673
 674 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
 675 if test -z "$with_system_user" ; then
 676     PA_SYSTEM_USER=pulse
 677 else
 678     PA_SYSTEM_USER=$with_system_user
 679 fi
 680 AC_SUBST(PA_SYSTEM_USER)
 681 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
 682
 683 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
 684 if test -z "$with_system_group" ; then
 685     PA_SYSTEM_GROUP=pulse
 686 else
 687     PA_SYSTEM_GROUP=$with_system_group
 688 fi
 689 AC_SUBST(PA_SYSTEM_GROUP)
 690 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
 691
 692 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
 693 if test -z "$with_realtime_group" ; then
 694     PA_REALTIME_GROUP=realtime
 695 else
 696     PA_REALTIME_GROUP=$with_realtime_group
 697 fi
 698 AC_SUBST(PA_REALTIME_GROUP)
 699 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
 700
 701 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
 702 if test -z "$with_access_group" ; then
 703     PA_ACCESS_GROUP=pulse-access
 704 else
 705     PA_ACCESS_GROUP=$with_access_group
 706 fi
 707 AC_SUBST(PA_ACCESS_GROUP)
 708 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
 709
 710 #### PulseAudio system runtime dir ####
 711 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
 712 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
 713
 714 ###################################
 715 #            Output               #
 716 ###################################
 717
 718 AC_ARG_ENABLE(
 719         [static-bins],
 720         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 721         [STATIC_BINS=1], [STATIC_BINS=0])
 722 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 723
 724 AC_ARG_WITH(
 725         [preopen-mods],
 726         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 727         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 728 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 729 if test "x$PREOPEN_MODS" != "xall" ; then
 730     tmpLIBS=""
 731     for mod in $PREOPEN_MODS; do
 732         tmpLIBS="$tmpLIBS module-$mod.la"
 733     done
 734     PREOPEN_MODS="$tmpLIBS"
 735     AC_SUBST(PREOPEN_MODS)
 736 fi
 737
 738 AC_ARG_WITH(
 739         [module-dir],
 740         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
 741         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
 742
 743 AC_SUBST(modlibexecdir)
 744
 745 AC_ARG_ENABLE(
 746         [force-preopen],
 747         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 748         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 749 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 750
 751 AC_CONFIG_FILES([
 752 Makefile
 753 src/Makefile
 754 libpulse.pc
 755 libpulse-simple.pc
 756 libpulse-browse.pc
 757 libpulse-mainloop-glib.pc
 758 doxygen/Makefile
 759 doxygen/doxygen.conf
 760 src/pulse/version.h
 761 ])
 762 AC_OUTPUT
 763
 764 # ==========================================================================
 765 ENABLE_X11=no
 766 if test "x$HAVE_X11" = "x1" ; then
 767    ENABLE_X11=yes
 768 fi
 769
 770 ENABLE_OSS=no
 771 if test "x$HAVE_OSS" = "x1" ; then
 772    ENABLE_OSS=yes
 773 fi
 774
 775 ENABLE_ALSA=no
 776 if test "x$HAVE_ALSA" = "x1" ; then
 777    ENABLE_ALSA=yes
 778 fi
 779
 780 ENABLE_SOLARIS=no
 781 if test "x$HAVE_SOLARIS" = "x1" ; then
 782    ENABLE_SOLARIS=yes
 783 fi
 784
 785 ENABLE_GLIB20=no
 786 if test "x$HAVE_GLIB20" = "x1" ; then
 787    ENABLE_GLIB20=yes
 788 fi
 789
 790 ENABLE_GCONF=no
 791 if test "x$HAVE_GCONF" = "x1" ; then
 792    ENABLE_GCONF=yes
 793 fi
 794
 795 ENABLE_AVAHI=no
 796 if test "x$HAVE_AVAHI" = "x1" ; then
 797    ENABLE_AVAHI=yes
 798 fi
 799
 800 ENABLE_JACK=no
 801 if test "x$HAVE_JACK" = "x1" ; then
 802    ENABLE_JACK=yes
 803 fi
 804
 805 ENABLE_LIBASYNCNS=no
 806 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
 807    ENABLE_LIBASYNCNS=yes
 808 fi
 809
 810 ENABLE_LIRC=no
 811 if test "x$HAVE_LIRC" = "x1" ; then
 812    ENABLE_LIRC=yes
 813 fi
 814
 815 ENABLE_HAL=no
 816 if test "x$HAVE_HAL" = "x1" ; then
 817    ENABLE_HAL=yes
 818 fi
 819
 820 ENABLE_TCPWRAP=no
 821 if test "x${LIBWRAP_LIBS}" != x ; then
 822    ENABLE_TCPWRAP=yes
 823 fi
 824
 825 echo "
 826  ---{ $PACKAGE_NAME $VERSION }---
 827
 828     prefix:                 ${prefix}
 829     sysconfdir:             ${sysconfdir}
 830     localstatedir:          ${localstatedir}
 831     System Runtime Path:    ${PA_SYSTEM_RUNTIME_PATH}
 832     Compiler:               ${CC}
 833     CFLAGS:                 ${CFLAGS}
 834     Have X11:               ${ENABLE_X11}
 835     Enable OSS:             ${ENABLE_OSS}
 836     Enable Alsa:            ${ENABLE_ALSA}
 837     Enable Solaris:         ${ENABLE_SOLARIS}
 838     Enable GLib 2.0:        ${ENABLE_GLIB20}
 839     Enable GConf:           ${ENABLE_GCONF}
 840     Enable Avahi:           ${ENABLE_AVAHI}
 841     Enable Jack:            ${ENABLE_JACK}
 842     Enable Async DNS:       ${ENABLE_LIBASYNCNS}
 843     Enable LIRC:            ${ENABLE_LIRC}
 844     Enable HAL:             ${ENABLE_HAL}
 845     Enable TCP Wrappers:    ${ENABLE_TCPWRAP}
 846     System User:            ${PA_SYSTEM_USER}
 847     System Group:           ${PA_SYSTEM_GROUP}
 848     Realtime Group:         ${PA_REALTIME_GROUP}
 849     Access Group:           ${PA_ACCESS_GROUP}
 850 "