code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23 AC_INIT([polypaudio],[0.8],[mzcbylcnhqvb (at) 0pointer (dot) de])
  24 AC_CONFIG_SRCDIR([src/daemon/main.c])
  25 AC_CONFIG_HEADERS([config.h])
  26 AM_INIT_AUTOMAKE([foreign -Wall])
  27
  28 AC_SUBST(PA_MAJORMINOR, "$PACKAGE_VERSION")
  29 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  30
  31 AC_SUBST(PA_API_VERSION, 8)
  32 AC_SUBST(PA_PROTOCOL_VERSION, 8)
  33
  34 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  35    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  36    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  37 fi
  38
  39 #### Checks for programs. ####
  40
  41 # CC
  42
  43 AC_PROG_CC
  44 AC_PROG_GCC_TRADITIONAL
  45 AC_GNU_SOURCE
  46
  47 # M4
  48
  49 AC_PATH_PROG([M4], [m4 gm4], [no])
  50 if test "x$M4" = xno ; then
  51    AC_MSG_ERROR([m4 missing])
  52 fi
  53
  54 # GCC flags
  55
  56 test_gcc_flag() {
  57     AC_LANG_CONFTEST([int main() {}])
  58     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  59     ret=$?
  60     rm -f conftest.o
  61     return $ret
  62 }
  63
  64 # If using GCC specify some additional parameters
  65 if test "x$GCC" = "xyes" ; then
  66
  67     # We use gnu99 instead of c99 because many have interpreted the standard
  68     # in a way that int64_t isn't defined on non-64 bit platforms.
  69     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  70
  71     for flag in $DESIRED_FLAGS ; do
  72         AC_MSG_CHECKING([whether $CC accepts $flag])
  73         if test_gcc_flag $flag ; then
  74            CFLAGS="$CFLAGS $flag"
  75            AC_MSG_RESULT([yes])
  76         else
  77            AC_MSG_RESULT([no])
  78         fi
  79     done
  80 fi
  81
  82 # LYNX documentation generation
  83 AC_ARG_ENABLE(lynx,
  84         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
  85 [case "${enableval}" in
  86   yes) lynx=yes ;;
  87   no)  lynx=no ;;
  88   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
  89 esac],[lynx=yes])
  90
  91 if test x$lynx = xyes ; then
  92    AC_CHECK_PROG(have_lynx, lynx, yes, no)
  93
  94    if test x$have_lynx = xno ; then
  95      AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
  96    fi
  97 fi
  98
  99 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
 100
 101 #### libtool stuff ####
 102
 103 AC_LTDL_ENABLE_INSTALL
 104 AC_LIBLTDL_INSTALLABLE
 105 AC_SUBST(LTDLINCL)
 106 AC_SUBST(LIBLTDL)
 107 AC_LIBTOOL_DLOPEN
 108 AC_LIBTOOL_WIN32_DLL
 109 AC_PROG_LIBTOOL
 110 AC_CONFIG_SUBDIRS(libltdl)
 111
 112 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 113     AC_MSG_ERROR([[
 114
 115         *** Cannot find the libltdl development files.
 116         *** Maybe you need to install the libltdl-dev package.
 117         ]])
 118 fi
 119
 120 #### Determine build environment ####
 121
 122 os_is_win32=0
 123
 124 case "$host_os" in
 125         mingw*)
 126         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 127         os_is_win32=1
 128                 ;;
 129         esac
 130
 131 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 132
 133 ###################################
 134 #   Basic environment checks      #
 135 ###################################
 136
 137 #### Checks for header files. ####
 138
 139 # ISO
 140 AC_HEADER_STDC
 141
 142 # POSIX
 143 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 144     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 145     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 146     syslog.h])
 147 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 148 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 149
 150 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 151 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 152
 153 # XPG4-UNIX
 154 AC_CHECK_HEADERS([sys/poll.h])
 155
 156 # Linux
 157 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 158
 159 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 160
 161 # Windows
 162 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 163
 164 # Other
 165 AC_CHECK_HEADERS([sys/ioctl.h])
 166
 167 #### Typdefs, structures, etc. ####
 168
 169 AC_C_CONST
 170 AC_C_BIGENDIAN
 171 AC_TYPE_PID_T
 172 AC_TYPE_SIZE_T
 173 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 174     [Define ssize_t if it is not done by the standard libs.])])
 175 AC_TYPE_OFF_T
 176 AC_TYPE_SIGNAL
 177 AC_TYPE_UID_T
 178
 179 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 180 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 181
 182 # Solaris lacks this
 183 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 184     [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])
 185
 186 #### Check for libs ####
 187
 188 # ISO
 189 AC_SEARCH_LIBS([pow], [m])
 190
 191 # POSIX
 192 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 193
 194 # BSD
 195 AC_SEARCH_LIBS([connect], [socket])
 196
 197 # Non-standard
 198
 199 # This magic is needed so we do not needlessly add static libs to the win32
 200 # build, disabling its ability to make dlls.
 201 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 202
 203 #### Check for functions ####
 204
 205 # POSIX
 206 AC_FUNC_FORK
 207 AC_FUNC_GETGROUPS
 208 AC_FUNC_SELECT_ARGTYPES
 209 AC_CHECK_FUNCS([getaddrinfo getgrgid_r getpwuid_r gettimeofday getuid \
 210     inet_ntop inet_pton nanosleep setpgid setsid sigaction sleep])
 211 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 212
 213 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 214
 215 # X/OPEN
 216 AC_CHECK_FUNCS([readlink])
 217
 218 # SUSv2
 219 AC_CHECK_FUNCS([ctime_r usleep])
 220
 221 # BSD
 222 AC_CHECK_FUNCS([lstat])
 223
 224 # Non-standard
 225
 226 AC_CHECK_FUNCS(setresuid)
 227 AC_CHECK_FUNCS(setreuid)
 228
 229 #### POSIX threads ####
 230
 231 ACX_PTHREAD
 232
 233 #### Large File-Support (LFS) ####
 234
 235 AC_SYS_LARGEFILE
 236
 237 ###################################
 238 #      External libraries         #
 239 ###################################
 240
 241 #### X11 (optional) ####
 242
 243 HAVE_X11=0
 244
 245 # The macro tests the host, not the build target
 246 if test "x$os_is_win32" != "x1" ; then
 247     AC_PATH_XTRA
 248     test "x$no_x" != "xyes" && HAVE_X11=1
 249 fi
 250
 251 AC_SUBST(HAVE_X11)
 252 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 253 if test "x$HAVE_X11" = "x1" ; then
 254     AC_DEFINE([HAVE_X11], 1, [Have X11])
 255 fi
 256
 257 #### Capabilities (optional) ####
 258
 259 CAP_LIBS=''
 260
 261 AC_ARG_WITH(
 262         [caps],
 263         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 264
 265 if test "x${with_caps}" != "xno"; then
 266     AC_SEARCH_LIBS([cap_init], [cap])
 267     AC_CHECK_HEADERS([sys/capability.h])
 268 fi
 269
 270 #### pkg-config ####
 271
 272 # Check for pkg-config manually first, as if its not installed the
 273 # PKG_PROG_PKG_CONFIG macro won't be defined.
 274 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 275
 276 if test x"$have_pkg_config" = "xno"; then
 277     AC_MSG_ERROR(pkg-config is required to install this program)
 278 fi
 279
 280 PKG_PROG_PKG_CONFIG
 281
 282 #### Sample rate conversion ####
 283
 284 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 285 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 286 AC_SUBST(LIBSAMPLERATE_LIBS)
 287
 288 #### Sound file ####
 289
 290 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 291 AC_SUBST(LIBSNDFILE_CFLAGS)
 292 AC_SUBST(LIBSNDFILE_LIBS)
 293
 294 #### OSS support (optional) ####
 295
 296 AC_CHECK_HEADERS([sys/soundcard.h], [
 297 HAVE_OSS=1
 298 AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 299 ], [HAVE_OSS=0])
 300 AC_SUBST(HAVE_OSS)
 301 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 302
 303
 304 #### ALSA support (optional) ####
 305
 306 PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [
 307 HAVE_ALSA=1
 308 AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 309 ], [HAVE_ALSA=0])
 310 AC_SUBST(ASOUNDLIB_CFLAGS)
 311 AC_SUBST(ASOUNDLIB_LIBS)
 312 AC_SUBST(HAVE_ALSA)
 313 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 314
 315 #### Solaris audio support (optional) ####
 316
 317 AC_CHECK_HEADERS([sys/audio.h], [
 318 HAVE_SOLARIS=1
 319 AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 320 ], [HAVE_SOLARIS=0])
 321 AC_SUBST(HAVE_SOLARIS)
 322 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 323
 324 #### GLib 2 support (optional) ####
 325
 326 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)
 327 AC_SUBST(GLIB20_CFLAGS)
 328 AC_SUBST(GLIB20_LIBS)
 329 AC_SUBST(HAVE_GLIB20)
 330 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 331
 332 #### GLib 1 support (optional) ####
 333
 334 PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, HAVE_GLIB12=0)
 335 AC_SUBST(GLIB12_CFLAGS)
 336 AC_SUBST(GLIB12_LIBS)
 337 AC_SUBST(HAVE_GLIB12)
 338 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 339
 340 #### Howl support (optional) ####
 341
 342 PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, HAVE_HOWL=0)
 343 AC_SUBST(HOWL_CFLAGS)
 344 AC_SUBST(HOWL_LIBS)
 345 AC_SUBST(HAVE_HOWL)
 346 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 347
 348
 349 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 350 AC_SUBST(LIBOIL_CFLAGS)
 351 AC_SUBST(LIBOIL_LIBS)
 352
 353 #### Async DNS support (optional) ####
 354
 355 PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)
 356 AC_SUBST(LIBASYNCNS_CFLAGS)
 357 AC_SUBST(LIBASYNCNS_LIBS)
 358 AC_SUBST(HAVE_LIBASYNCNS)
 359 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 360
 361 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 362    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 363 fi
 364
 365 #### TCP wrappers (optional) ####
 366
 367 ACX_LIBWRAP
 368 AC_SUBST(LIBWRAP_LIBS)
 369
 370 #### LIRC support (optional) ####
 371
 372 ACX_LIRC
 373 AC_SUBST(LIRC_CFLAGS)
 374 AC_SUBST(LIRC_LIBS)
 375 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 376
 377 ### /dev/random ###
 378
 379 AC_MSG_CHECKING([whether a random device is available])
 380
 381 rnd="no"
 382
 383 if test -e /dev/urandom ; then
 384    rnd=/dev/urandom
 385 else
 386    if test -e /dev/random ; then
 387       rnd=/dev/random
 388    fi
 389 fi
 390
 391 if test "x$rnd" != "no" ; then
 392    AC_DEFINE_UNQUOTED([RANDOM_DEVICE], ["$rnd"], [Random device])
 393 fi
 394
 395 AC_MSG_RESULT([$rnd])
 396
 397 ###################################
 398 #            Output               #
 399 ###################################
 400
 401 AC_ARG_ENABLE(
 402         [static-bins],
 403         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 404         [STATIC_BINS=1], [STATIC_BINS=0])
 405 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 406
 407 AC_ARG_WITH(
 408         [preopen-mods],
 409         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 410         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 411 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 412 if test "x$PREOPEN_MODS" != "xall" ; then
 413     tmpLIBS=""
 414     for mod in $PREOPEN_MODS; do
 415         tmpLIBS="$tmpLIBS module-$mod.la"
 416     done
 417     PREOPEN_MODS="$tmpLIBS"
 418     AC_SUBST(PREOPEN_MODS)
 419 fi
 420
 421 AC_ARG_ENABLE(
 422         [force-preopen],
 423         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 424         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 425 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 426
 427 AC_CONFIG_FILES([
 428 Makefile
 429 src/Makefile
 430 polyplib.pc
 431 polyplib-simple.pc
 432 polyplib-browse.pc
 433 polyplib-glib-mainloop.pc
 434 polyplib-glib12-mainloop.pc
 435 doc/Makefile
 436 doc/README.html
 437 doc/cli.html
 438 doc/daemon.html
 439 doc/modules.html
 440 doxygen/Makefile
 441 doxygen/doxygen.conf
 442 src/polyp/version.h
 443 doc/FAQ.html
 444 ])
 445 AC_OUTPUT