code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23 AC_INIT([polypaudio],[0.8.1],[mzcbylcnhqvb (at) 0pointer (dot) de])
  24 AC_CONFIG_SRCDIR([src/daemon/main.c])
  25 AC_CONFIG_HEADERS([config.h])
  26 AM_INIT_AUTOMAKE([foreign -Wall])
  27
  28 AC_SUBST(PA_MAJORMINOR, "$PACKAGE_VERSION")
  29 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  30
  31 AC_SUBST(PA_API_VERSION, 8)
  32 AC_SUBST(PA_PROTOCOL_VERSION, 8)
  33
  34 AC_SUBST(LIBPOLYP_VERSION_INFO, [0:0:0])
  35 AC_SUBST(LIBPOLYPCORE_VERSION_INFO, [0:0:0])
  36 AC_SUBST(LIBPOLYP_SIMPLE_VERSION_INFO, [0:0:0])
  37 AC_SUBST(LIBPOLYP_BROWSE_VERSION_INFO, [0:0:0])
  38 AC_SUBST(LIBPOLYP_MAINLOOP_GLIB_VERSION_INFO, [0:0:0])
  39
  40 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  41    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  42    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  43 fi
  44
  45 #### Platform hacks ####
  46
  47 case $host in
  48    *-*-solaris* )
  49       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  50       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  51       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  52       ;;
  53 esac
  54
  55 #### Checks for programs. ####
  56
  57 # CC
  58
  59 AC_PROG_CC
  60 AC_PROG_GCC_TRADITIONAL
  61 AC_GNU_SOURCE
  62
  63 # M4
  64
  65 AC_PATH_PROG([M4], [m4 gm4], [no])
  66 if test "x$M4" = xno ; then
  67    AC_MSG_ERROR([m4 missing])
  68 fi
  69
  70 # GCC flags
  71
  72 test_gcc_flag() {
  73     AC_LANG_CONFTEST([int main() {}])
  74     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  75     ret=$?
  76     rm -f conftest.o
  77     return $ret
  78 }
  79
  80 # If using GCC specify some additional parameters
  81 if test "x$GCC" = "xyes" ; then
  82
  83     # We use gnu99 instead of c99 because many have interpreted the standard
  84     # in a way that int64_t isn't defined on non-64 bit platforms.
  85     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  86
  87     for flag in $DESIRED_FLAGS ; do
  88         AC_MSG_CHECKING([whether $CC accepts $flag])
  89         if test_gcc_flag $flag ; then
  90            CFLAGS="$CFLAGS $flag"
  91            AC_MSG_RESULT([yes])
  92         else
  93            AC_MSG_RESULT([no])
  94         fi
  95     done
  96 fi
  97
  98 # LYNX documentation generation
  99 AC_ARG_ENABLE(lynx,
 100         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
 101 [case "${enableval}" in
 102   yes) lynx=yes ;;
 103   no)  lynx=no ;;
 104   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
 105 esac],[lynx=yes])
 106
 107 if test x$lynx = xyes ; then
 108    AC_CHECK_PROG(have_lynx, lynx, yes, no)
 109
 110    if test x$have_lynx = xno ; then
 111      AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
 112    fi
 113 fi
 114
 115 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
 116
 117 #### libtool stuff ####
 118
 119 AC_LTDL_ENABLE_INSTALL
 120 AC_LIBLTDL_INSTALLABLE
 121 AC_SUBST(LTDLINCL)
 122 AC_SUBST(LIBLTDL)
 123 AC_LIBTOOL_DLOPEN
 124 AC_LIBTOOL_WIN32_DLL
 125 AC_PROG_LIBTOOL
 126 AC_CONFIG_SUBDIRS(libltdl)
 127
 128 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 129     AC_MSG_ERROR([[
 130
 131         *** Cannot find the libltdl development files.
 132         *** Maybe you need to install the libltdl-dev package.
 133         ]])
 134 fi
 135
 136 #### Determine build environment ####
 137
 138 os_is_win32=0
 139
 140 case "$host_os" in
 141         mingw*)
 142         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 143         os_is_win32=1
 144                 ;;
 145         esac
 146
 147 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 148
 149 ###################################
 150 #   Basic environment checks      #
 151 ###################################
 152
 153 #### Checks for header files. ####
 154
 155 # ISO
 156 AC_HEADER_STDC
 157
 158 # POSIX
 159 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 160     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 161     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 162     syslog.h])
 163 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 164 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 165
 166 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 167 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 168
 169 # XPG4-UNIX
 170 AC_CHECK_HEADERS([sys/poll.h])
 171
 172 # Linux
 173 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 174
 175 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 176
 177 # Solaris
 178 AC_CHECK_HEADERS([sys/filio.h])
 179
 180 # Windows
 181 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 182
 183 # Other
 184 AC_CHECK_HEADERS([sys/ioctl.h])
 185
 186 #### Typdefs, structures, etc. ####
 187
 188 AC_C_CONST
 189 AC_C_BIGENDIAN
 190 AC_TYPE_PID_T
 191 AC_TYPE_SIZE_T
 192 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 193     [Define ssize_t if it is not done by the standard libs.])])
 194 AC_TYPE_OFF_T
 195 AC_TYPE_SIGNAL
 196 AC_TYPE_UID_T
 197
 198 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 199 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 200
 201 # Solaris lacks this
 202 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 203     [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])
 204
 205 #### Check for libs ####
 206
 207 # ISO
 208 AC_SEARCH_LIBS([pow], [m])
 209
 210 # POSIX
 211 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 212
 213 # BSD
 214 AC_SEARCH_LIBS([connect], [socket])
 215
 216 # Non-standard
 217
 218 # This magic is needed so we do not needlessly add static libs to the win32
 219 # build, disabling its ability to make dlls.
 220 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 221
 222 #### Check for functions ####
 223
 224 # POSIX
 225 AC_FUNC_FORK
 226 AC_FUNC_GETGROUPS
 227 AC_FUNC_SELECT_ARGTYPES
 228 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 229     getuid inet_ntop inet_pton nanosleep pipe setpgid setsid sigaction sleep])
 230 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 231
 232 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 233
 234 # X/OPEN
 235 AC_CHECK_FUNCS([readlink])
 236
 237 # SUSv2
 238 AC_CHECK_FUNCS([ctime_r usleep])
 239
 240 # BSD
 241 AC_CHECK_FUNCS([lstat])
 242
 243 # Non-standard
 244
 245 AC_CHECK_FUNCS(setresuid)
 246 AC_CHECK_FUNCS(setreuid)
 247
 248 #### POSIX threads ####
 249
 250 ACX_PTHREAD
 251
 252 #### Large File-Support (LFS) ####
 253
 254 AC_SYS_LARGEFILE
 255
 256 ###################################
 257 #      External libraries         #
 258 ###################################
 259
 260 #### X11 (optional) ####
 261
 262 HAVE_X11=0
 263
 264 # The macro tests the host, not the build target
 265 if test "x$os_is_win32" != "x1" ; then
 266     AC_PATH_XTRA
 267     test "x$no_x" != "xyes" && HAVE_X11=1
 268 fi
 269
 270 AC_SUBST(HAVE_X11)
 271 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 272 if test "x$HAVE_X11" = "x1" ; then
 273     AC_DEFINE([HAVE_X11], 1, [Have X11])
 274 fi
 275
 276 #### Capabilities (optional) ####
 277
 278 CAP_LIBS=''
 279
 280 AC_ARG_WITH(
 281         [caps],
 282         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 283
 284 if test "x${with_caps}" != "xno"; then
 285     AC_SEARCH_LIBS([cap_init], [cap])
 286     AC_CHECK_HEADERS([sys/capability.h])
 287 fi
 288
 289 #### pkg-config ####
 290
 291 # Check for pkg-config manually first, as if its not installed the
 292 # PKG_PROG_PKG_CONFIG macro won't be defined.
 293 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 294
 295 if test x"$have_pkg_config" = "xno"; then
 296     AC_MSG_ERROR(pkg-config is required to install this program)
 297 fi
 298
 299 PKG_PROG_PKG_CONFIG
 300
 301 #### Sample rate conversion ####
 302
 303 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 304 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 305 AC_SUBST(LIBSAMPLERATE_LIBS)
 306
 307 #### Sound file ####
 308
 309 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 310 AC_SUBST(LIBSNDFILE_CFLAGS)
 311 AC_SUBST(LIBSNDFILE_LIBS)
 312
 313 #### OSS support (optional) ####
 314
 315 AC_CHECK_HEADERS([sys/soundcard.h], [
 316 HAVE_OSS=1
 317 AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 318 ], [HAVE_OSS=0])
 319 AC_SUBST(HAVE_OSS)
 320 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 321
 322
 323 #### ALSA support (optional) ####
 324
 325 PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [
 326 HAVE_ALSA=1
 327 AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 328 ], [HAVE_ALSA=0])
 329 AC_SUBST(ASOUNDLIB_CFLAGS)
 330 AC_SUBST(ASOUNDLIB_LIBS)
 331 AC_SUBST(HAVE_ALSA)
 332 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 333
 334 #### Solaris audio support (optional) ####
 335
 336 AC_CHECK_HEADERS([sys/audio.h], [
 337 HAVE_SOLARIS=1
 338 AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 339 ], [HAVE_SOLARIS=0])
 340 AC_SUBST(HAVE_SOLARIS)
 341 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 342
 343 #### GLib 2 support (optional) ####
 344
 345 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)
 346 AC_SUBST(GLIB20_CFLAGS)
 347 AC_SUBST(GLIB20_LIBS)
 348 AC_SUBST(HAVE_GLIB20)
 349 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 350
 351 #### GLib 1 support (optional) ####
 352
 353 PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, HAVE_GLIB12=0)
 354 AC_SUBST(GLIB12_CFLAGS)
 355 AC_SUBST(GLIB12_LIBS)
 356 AC_SUBST(HAVE_GLIB12)
 357 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 358
 359 #### Howl support (optional) ####
 360
 361 PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, HAVE_HOWL=0)
 362 AC_SUBST(HOWL_CFLAGS)
 363 AC_SUBST(HOWL_LIBS)
 364 AC_SUBST(HAVE_HOWL)
 365 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 366
 367 ### LIBOIL ####
 368
 369 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 370 AC_SUBST(LIBOIL_CFLAGS)
 371 AC_SUBST(LIBOIL_LIBS)
 372
 373 ### JACK (optional) ####
 374
 375 PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ], HAVE_JACK=1, HAVE_JACK=0)
 376 AC_SUBST(JACK_CFLAGS)
 377 AC_SUBST(JACK_LIBS)
 378 AC_SUBST(HAVE_JACK)
 379 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 380
 381 #### Async DNS support (optional) ####
 382
 383 PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)
 384 AC_SUBST(LIBASYNCNS_CFLAGS)
 385 AC_SUBST(LIBASYNCNS_LIBS)
 386 AC_SUBST(HAVE_LIBASYNCNS)
 387 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 388
 389 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 390    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 391 fi
 392
 393 #### TCP wrappers (optional) ####
 394
 395 ACX_LIBWRAP
 396 AC_SUBST(LIBWRAP_LIBS)
 397
 398 #### LIRC support (optional) ####
 399
 400 ACX_LIRC
 401 AC_SUBST(LIRC_CFLAGS)
 402 AC_SUBST(LIRC_LIBS)
 403 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 404
 405 ###################################
 406 #            Output               #
 407 ###################################
 408
 409 AC_ARG_ENABLE(
 410         [static-bins],
 411         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 412         [STATIC_BINS=1], [STATIC_BINS=0])
 413 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 414
 415 AC_ARG_WITH(
 416         [preopen-mods],
 417         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 418         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 419 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 420 if test "x$PREOPEN_MODS" != "xall" ; then
 421     tmpLIBS=""
 422     for mod in $PREOPEN_MODS; do
 423         tmpLIBS="$tmpLIBS module-$mod.la"
 424     done
 425     PREOPEN_MODS="$tmpLIBS"
 426     AC_SUBST(PREOPEN_MODS)
 427 fi
 428
 429 AC_ARG_WITH(
 430         [module-dir],
 431         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/polypaudio-${PA_MAJORMINOR}]),
 432         [modlibexecdir=$withval], [modlibexecdir="${libdir}/polypaudio-${PA_MAJORMINOR}"])
 433
 434 AC_SUBST(modlibexecdir)
 435
 436 AC_ARG_ENABLE(
 437         [force-preopen],
 438         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 439         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 440 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 441
 442 AC_CONFIG_FILES([
 443 Makefile
 444 src/Makefile
 445 polyplib.pc
 446 polyplib-simple.pc
 447 polyplib-browse.pc
 448 polyplib-glib-mainloop.pc
 449 polyplib-glib12-mainloop.pc
 450 doc/Makefile
 451 doc/README.html
 452 doc/cli.html
 453 doc/daemon.html
 454 doc/modules.html
 455 doxygen/Makefile
 456 doxygen/doxygen.conf
 457 src/polyp/version.h
 458 doc/FAQ.html
 459 ])
 460 AC_OUTPUT