code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.63)
  24
  25 AC_INIT([pulseaudio],[m4_esyscmd(./git-version-gen .tarball-version)],[pulseaudio-discuss (at) lists (dot) freedesktop (dot) org],[pulseaudio],[http://pulseaudio.org/])
  26 AC_CONFIG_SRCDIR([src/daemon/main.c])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_HEADERS([config.h])
  29 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules color-tests dist-xz tar-ustar])
  30
  31 m4_define(pa_major, `echo $VERSION | cut -d. -f1 | cut -d- -f1`)
  32 m4_define(pa_minor, `echo $VERSION | cut -d. -f2 | cut -d- -f1`)
  33
  34 AC_SUBST(PA_MAJOR, pa_major)
  35 AC_SUBST(PA_MINOR, pa_minor)
  36 AC_SUBST(PA_MAJORMINOR, pa_major.pa_minor)
  37
  38 AC_SUBST(PA_API_VERSION, 12)
  39 AC_SUBST(PA_PROTOCOL_VERSION, 25)
  40
  41 # The stable ABI for client applications, for the version info x:y:z
  42 # always will hold y=z
  43 AC_SUBST(LIBPULSE_VERSION_INFO, [13:4:13])
  44
  45 # A simplified, synchronous, ABI-stable interface for client
  46 # applications, for the version info x:y:z always will hold y=z
  47 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:3:0])
  48
  49 # The ABI-stable network browsing interface for client applications,
  50 # for the version info x:y:z always will hold y=z
  51 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  52
  53 # The ABI-stable GLib adapter for client applications, for the version
  54 # info x:y:z always will hold y=z
  55 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:4:0])
  56
  57 AC_CANONICAL_HOST
  58 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  59
  60 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  61
  62 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  63     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  64     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  65 ])
  66
  67 AM_SILENT_RULES([yes])
  68
  69
  70 #### Checks for programs. ####
  71
  72 # mkdir -p
  73
  74 AC_PROG_MKDIR_P
  75
  76 # CC
  77
  78 AC_PROG_CC
  79 AC_PROG_CC_C99
  80 AM_PROG_CC_C_O
  81 # Only required if you want the WebRTC canceller -- no runtime dep on
  82 # libstdc++ otherwise
  83 AC_PROG_CXX
  84 AC_PROG_GCC_TRADITIONAL
  85 AC_USE_SYSTEM_EXTENSIONS
  86
  87 # M4
  88
  89 AC_CHECK_PROGS([M4], gm4 m4, no)
  90 AS_IF([test "x$M4" = "xno"], AC_MSG_ERROR([m4 missing]))
  91
  92 # pkg-config
  93
  94 PKG_PROG_PKG_CONFIG
  95
  96 # gettext
  97
  98 if test "x$enable_nls" != "xno"; then
  99 IT_PROG_INTLTOOL([0.35.0])
 100 GETTEXT_PACKAGE=pulseaudio
 101 AC_SUBST([GETTEXT_PACKAGE])
 102 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 103 AM_GLIB_GNU_GETTEXT
 104
 105 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 106 AX_DEFINE_DIR(PULSE_LOCALEDIR, pulselocaledir, [Gettext locale dir])
 107 fi
 108
 109
 110 #### Determine host OS ####
 111
 112 os_is_linux=0
 113 os_is_win32=0
 114 os_is_darwin=0
 115
 116 AC_MSG_CHECKING([host operating system])
 117 case "$host_os" in
 118     linux*)
 119         AC_MSG_RESULT([linux])
 120         os_is_linux=1
 121     ;;
 122     darwin*)
 123         AC_MSG_RESULT([darwin])
 124         os_is_darwin=1
 125         AC_DEFINE([OS_IS_DARWIN], 1, [Build target is Darwin.])
 126     ;;
 127     mingw*)
 128         AC_MSG_RESULT([win32])
 129         os_is_win32=1
 130         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 131     ;;
 132     *)
 133         AC_MSG_RESULT([unknown])
 134     ;;
 135 esac
 136
 137 AM_CONDITIONAL(OS_IS_DARWIN, test "x$os_is_darwin" = "x1")
 138 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 139 AC_SUBST([OS_IS_WIN32], [$os_is_win32])
 140
 141 # Platform specific hacks
 142 case "$host_os" in
 143     darwin* )
 144         AC_DEFINE([_DARWIN_C_SOURCE], [200112L], [Needed to get NSIG on Mac OS X])
 145     ;;
 146     mingw* )
 147         AC_DEFINE([WIN32_LEAN_AND_MEAN], 1, [Needed to avoid including unnecessary headers on Windows])
 148     ;;
 149     solaris* )
 150         AC_DEFINE(_XOPEN_SOURCE,       600, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 151         AC_DEFINE(__EXTENSIONS__,        1, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 152     ;;
 153 esac
 154
 155
 156 #### Compiler flags ####
 157
 158 AX_APPEND_COMPILE_FLAGS(
 159     [-Wall -W -Wextra -pipe -Wno-long-long -Wvla -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing -Wwrite-strings -Wno-unused-parameter -ffast-math -Wp,-D_FORTIFY_SOURCE=2 -fno-common -fdiagnostics-show-option],
 160     [], [-pedantic -Werror])
 161
 162 # Only enable fastpath asserts when doing a debug build, e.g. from bootstrap.sh.
 163 AS_CASE([" $CFLAGS "], [*" -O0 "*], [], [AX_APPEND_FLAG(["-DFASTPATH"], [CPPFLAGS])])
 164
 165
 166 #### Linker flags ####
 167
 168 # Check whether the linker supports the -version-script option.
 169 # The Make variable $(srcdir) needs to be in the LDFLAGS in that form,
 170 # so that it is expanded the right way in every subdir.
 171 AX_CHECK_LINK_FLAG(["-Wl,-version-script=${abs_top_srcdir}/src/map-file"],
 172     [VERSIONING_LDFLAGS='-Wl,-version-script=$(abs_top_srcdir)/map-file'])
 173 AC_SUBST([VERSIONING_LDFLAGS])
 174
 175 # Use immediate (now) bindings; avoids the funky re-call in itself.
 176 # The -z now syntax is lifted from Sun's linker and works with GNU's too, other linkers might be added later.
 177 AX_APPEND_LINK_FLAGS([-Wl,-z,now], [IMMEDIATE_LDFLAGS])
 178 AC_SUBST([IMMEDIATE_LDFLAGS])
 179
 180 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 181 # so we request the nodelete flag to be enabled.
 182 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 183 AX_APPEND_LINK_FLAGS([-Wl,-z,nodelete], [NODELETE_LDFLAGS])
 184 AC_SUBST([NODELETE_LDFLAGS])
 185
 186 # Check for the proper way to build libraries that have no undefined symbols
 187 case $host in
 188     # FreeBSD (et al.) does not complete linking for shared objects when pthreads
 189     # are requested, as different implementations are present.
 190     *-freebsd* | *-openbsd*) ;;
 191     *)
 192         for possible_flag in "-Wl,--no-undefined" "-Wl,-z,defs"; do
 193             AX_CHECK_LINK_FLAG([$possible_flag], [NOUNDEFINED_LDFLAGS="$possible_flag"; break])
 194         done
 195     ;;
 196 esac
 197 AC_SUBST([NOUNDEFINED_LDFLAGS])
 198
 199
 200 #### Atomic operations ####
 201
 202 # Native atomic operation support
 203 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 204     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]))
 205
 206 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 207     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]))
 208
 209 if test "x$enable_atomic_arm_memory_barrier" = "xyes"; then
 210     AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers])
 211 fi
 212
 213 # If everything else fails use libatomic_ops
 214 need_libatomic_ops=yes
 215
 216 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 217     pulseaudio_cv_sync_bool_compare_and_swap, [
 218     AC_LINK_IFELSE(
 219         AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
 220         [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 221         [pulseaudio_cv_sync_bool_compare_and_swap=no])
 222     ])
 223
 224 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 225     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 226     need_libatomic_ops=no
 227 else
 228     # HW specific atomic ops stuff
 229     AC_MSG_CHECKING([architecture for native atomic operations])
 230     case $host in
 231         arm*)
 232             AC_MSG_RESULT([arm])
 233             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 234             # The Linux kernel helper functions have been there since 2.6.16. However
 235             # compile time checking for kernel version in cross compile environment
 236             # (which is usually the case for arm cpu) is tricky (or impossible).
 237             if test "x$os_is_linux" = "x1" && test "x$enable_atomic_arm_linux_helpers" != "xno"; then
 238                 AC_MSG_RESULT([yes])
 239                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 240                 need_libatomic_ops=no
 241             else
 242                 AC_MSG_RESULT([no])
 243                 AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 244                     pulseaudio_cv_support_arm_atomic_ops, [
 245                     AC_COMPILE_IFELSE(
 246                         AC_LANG_PROGRAM([], [[
 247                             volatile int a=0;
 248                             int o=0, n=1, r;
 249                             asm volatile ("ldrex    %0, [%1]\n"
 250                                           "subs  %0, %0, %2\n"
 251                                           "strexeq %0, %3, [%1]\n"
 252                                           : "=&r" (r)
 253                                           : "r" (&a), "Ir" (o), "r" (n)
 254                                           : "cc");
 255                             return (a==1 ? 0 : -1);
 256                         ]]),
 257                         [pulseaudio_cv_support_arm_atomic_ops=yes],
 258                         [pulseaudio_cv_support_arm_atomic_ops=no])
 259                 ])
 260                 AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 261                     AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARM atomic instructions.])
 262                     need_libatomic_ops=no
 263                 ])
 264             fi
 265         ;;
 266         *-netbsdelf5*)
 267             AC_MSG_RESULT([yes])
 268             need_libatomic_ops=no
 269         ;;
 270         *-freebsd*)
 271             AC_MSG_RESULT([yes])
 272             need_libatomic_ops=no
 273         ;;
 274         *)
 275             AC_MSG_RESULT([unknown])
 276         ;;
 277     esac
 278 fi
 279
 280 # If we're on ARM, check for the ARMV6 instructions we need */
 281 case $host in
 282   arm*)
 283     AC_CACHE_CHECK([support for required armv6 instructions],
 284       pulseaudio_cv_support_armv6,
 285       [AC_COMPILE_IFELSE(
 286          AC_LANG_PROGRAM([],
 287            [[volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 288              asm volatile ("ldr r0, %2 \n"
 289                            "ldr r2, %3 \n"
 290                            "ldr r3, %4 \n"
 291                            "ssat r1, #8, r0 \n"
 292                            "str r1, %0 \n"
 293                            "pkhbt r1, r3, r2, LSL #8 \n"
 294                            "str r1, %1 \n"
 295                            : "=m" (a), "=m" (b)
 296                            : "m" (a), "m" (b), "m" (c)
 297                            : "r0", "r1", "r2", "r3", "cc");
 298              return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 299            ]]),
 300          [pulseaudio_cv_support_armv6=yes],
 301          [pulseaudio_cv_support_armv6=no])
 302       ])
 303     AS_IF([test "$pulseaudio_cv_support_armv6" = "yes"], [
 304         AC_DEFINE([HAVE_ARMV6], 1, [Have ARMv6 instructions.])
 305       ])
 306   ;;
 307   *)
 308   ;;
 309 esac
 310
 311
 312 #### libtool stuff ####
 313
 314 LT_PREREQ(2.2)
 315 LT_INIT([dlopen win32-dll disable-static])
 316
 317 dnl Unfortunately, even up to libtool 2.2.6a there is no way to know
 318 dnl exactly which version of libltdl is present in the system, so we
 319 dnl just assume that it's a working version as long as we have the
 320 dnl library and the header files.
 321 dnl
 322 dnl As an extra safety device, check for lt_dladvise_init() which is
 323 dnl only implemented in libtool 2.x, and refine as we go if we have
 324 dnl refined requirements.
 325 dnl
 326 dnl Check the header files first since the system may have a
 327 dnl libltdl.so for runtime, but no headers, and we want to bail out as
 328 dnl soon as possible.
 329 dnl
 330 dnl We don't need any special variable for this though, since the user
 331 dnl can give the proper place to find libltdl through the standard
 332 dnl variables like LDFLAGS and CPPFLAGS.
 333
 334 AC_CHECK_HEADER([ltdl.h],
 335     [AC_CHECK_LIB([ltdl], [lt_dladvise_init], [LIBLTDL=-lltdl], [LIBLTDL=])],
 336     [LIBLTDL=])
 337
 338 AS_IF([test "x$LIBLTDL" = "x"],
 339     [AC_MSG_ERROR([Unable to find libltdl version 2. Makes sure you have libtool 2.2 or later installed.])])
 340 AC_SUBST([LIBLTDL])
 341
 342
 343 ###################################
 344 #   Basic environment checks      #
 345 ###################################
 346
 347 #### Checks for header files. ####
 348
 349 # ISO
 350 AC_HEADER_STDC
 351
 352 # POSIX
 353 AC_CHECK_HEADERS_ONCE([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 354     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 355     sys/mman.h sys/select.h sys/socket.h sys/wait.h \
 356     sys/uio.h syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 357 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 358                  [#include <sys/types.h>
 359                   #if HAVE_NETINET_IN_H
 360                   # include <netinet/in.h>
 361                   #endif
 362                   #if HAVE_NETINET_IN_SYSTM_H
 363                   # include <netinet/in_systm.h>
 364                   #endif
 365                  ])
 366 AC_CHECK_HEADERS([sys/resource.h], [HAVE_SYS_RESOURCE_H=1], [HAVE_SYS_RESOURCE_H=0])
 367 AC_SUBST(HAVE_SYS_RESOURCE_H)
 368 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 369 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 370 AC_SUBST(HAVE_AF_UNIX)
 371
 372 # Linux
 373 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 374 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 375
 376 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 377
 378 # Solaris
 379 AC_CHECK_HEADERS_ONCE([sys/filio.h])
 380
 381 # Windows
 382 AC_CHECK_HEADERS_ONCE([windows.h winsock2.h ws2tcpip.h])
 383
 384 # NetBSD
 385 AC_CHECK_HEADERS_ONCE([sys/atomic.h])
 386
 387 # Other
 388 AC_CHECK_HEADERS_ONCE([sys/ioctl.h])
 389 AC_CHECK_HEADERS_ONCE([byteswap.h])
 390 AC_CHECK_HEADERS_ONCE([sys/syscall.h])
 391 AC_CHECK_HEADERS_ONCE([sys/eventfd.h])
 392 AC_CHECK_HEADERS_ONCE([execinfo.h])
 393 AC_CHECK_HEADERS_ONCE([langinfo.h])
 394 AC_CHECK_HEADERS_ONCE([regex.h pcreposix.h])
 395
 396
 397 #### Typdefs, structures, etc. ####
 398
 399 AC_C_CONST
 400 AC_C_BIGENDIAN
 401 AC_TYPE_PID_T
 402 AC_TYPE_SIZE_T
 403 AC_CHECK_TYPES(ssize_t, , AC_DEFINE([ssize_t], [signed long], [Define ssize_t if it is not done by the standard libs.]))
 404 AC_TYPE_OFF_T
 405
 406 AC_TYPE_UID_T
 407 AC_CHECK_DECLS(environ)
 408
 409 # SIGXCPU
 410 AX_CHECK_DEFINE([signal.h], [SIGXCPU], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 411 AS_IF([test "x$HAVE_SIGXCPU" = "x1"], AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?]))
 412 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 413
 414 # INADDR_NONE, Solaris lacks this
 415 AX_CHECK_DEFINE([netinet/in.h], [INADDR_NONE], [],
 416     [AX_CHECK_DEFINE([winsock2.h], [INADDR_NONE], [],
 417         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 418
 419
 420 # _Bool
 421 AC_CACHE_CHECK([whether $CC knows _Bool],
 422     pulseaudio_cv__Bool,
 423     [AC_COMPILE_IFELSE(
 424         AC_LANG_PROGRAM([], [[_Bool b;]]),
 425         [pulseaudio_cv__Bool=yes],
 426         [pulseaudio_cv__Bool=no])
 427     ])
 428
 429 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.]))
 430
 431
 432 #### Thread support ####
 433
 434 AX_TLS
 435 AS_IF([test "$ac_cv_tls" == "__thread"],
 436     AC_DEFINE([SUPPORT_TLS___THREAD], 1, [Define this if the compiler supports __thread for Thread-Local Storage]))
 437
 438 # Win32 build breaks with win32 pthread installed
 439 AS_IF([test "x$os_is_win32" != "x1"],
 440   [AX_PTHREAD])
 441
 442 AS_IF([test "x$ax_pthread_ok" == "xyes"],
 443     AC_DEFINE([_POSIX_PTHREAD_SEMANTICS], 1, [Needed on Solaris]))
 444
 445
 446 #### Check for libs ####
 447
 448 # ISO
 449 AC_SEARCH_LIBS([pow], [m])
 450
 451 # POSIX
 452 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 453 AC_SEARCH_LIBS([dlopen], [dl])
 454 AC_SEARCH_LIBS([shm_open], [rt])
 455 AC_SEARCH_LIBS([inet_ntop], [nsl])
 456 AC_SEARCH_LIBS([timer_create], [rt])
 457 AC_SEARCH_LIBS([pthread_setaffinity_np], [pthread])
 458 AC_SEARCH_LIBS([pthread_getname_np], [pthread])
 459 AC_SEARCH_LIBS([pthread_setname_np], [pthread])
 460
 461 # BSD
 462 AC_SEARCH_LIBS([connect], [socket])
 463 AC_SEARCH_LIBS([backtrace], [execinfo ubacktrace])
 464
 465 # Darwin/OS X
 466 if test "x$os_is_darwin" = "x1" ; then
 467     AC_MSG_CHECKING([looking for Apple CoreService Framework])
 468     # How do I check a framework "library" - AC_CHECK_LIB prob. won't work??, just assign LIBS & hope
 469     AC_CHECK_HEADER([/Developer/Headers/FlatCarbon/CoreServices.h],
 470         [LIBS="$LIBS -framework CoreServices"],
 471         [AC_MSG_ERROR([CoreServices.h header file not found])]
 472     )
 473
 474     AC_MSG_RESULT([ok])
 475     AC_DEFINE([HAVE_CLOCK_GETTIME], 1, [Using clock_gettime() replacement])
 476     HAVE_BONJOUR=1
 477 fi
 478
 479 AM_CONDITIONAL([HAVE_BONJOUR], [test "x$HAVE_BONJOUR" = x1])
 480
 481 # Windows
 482 AC_SEARCH_LIBS([regexec], [pcreposix])
 483 # This magic is needed so we do not needlessly add static libs to the win32  build, disabling its ability to make dlls.
 484 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 485
 486
 487 #### Check for functions ####
 488
 489 # ISO
 490 AC_CHECK_FUNCS_ONCE([lrintf strtof])
 491
 492 # POSIX
 493 AC_FUNC_FORK
 494 AC_FUNC_GETGROUPS
 495 AC_CHECK_FUNCS_ONCE([chmod chown fstat fchown fchmod clock_gettime getaddrinfo getgrgid_r getgrnam_r \
 496     getpwnam_r getpwuid_r gettimeofday getuid mlock nanosleep \
 497     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 498     sigaction sleep symlink sysconf uname pthread_setaffinity_np pthread_getname_np pthread_setname_np])
 499 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 500 AC_SUBST(HAVE_MKFIFO)
 501 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 502
 503 # X/OPEN
 504 AC_CHECK_FUNCS_ONCE([readlink])
 505
 506 # SUSv2
 507 AC_CHECK_FUNCS_ONCE([ctime_r usleep])
 508
 509 # SUSv3
 510 AC_CHECK_FUNCS_ONCE([strerror_r])
 511
 512 # BSD
 513 AC_CHECK_FUNCS_ONCE([lstat])
 514
 515 # Non-standard
 516 AC_CHECK_FUNCS_ONCE([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l pipe2 accept4])
 517
 518 AC_FUNC_ALLOCA
 519
 520 AC_CHECK_FUNCS([regexec], [HAVE_REGEX=1], [HAVE_REGEX=0])
 521 AM_CONDITIONAL(HAVE_REGEX, [test "x$HAVE_REGEX" = "x1"])
 522
 523 # Large File-Support (LFS)
 524 AC_SYS_LARGEFILE
 525 # Check for open64 to know if the current system does have open64() and similar functions
 526 AC_CHECK_FUNCS_ONCE([open64])
 527
 528
 529 ###################################
 530 #      External libraries         #
 531 ###################################
 532
 533 #### [lib]iconv ####
 534
 535 AM_ICONV
 536
 537 #### X11 (optional) ####
 538
 539 AC_ARG_ENABLE([x11],
 540     AS_HELP_STRING([--disable-x11],[Disable optional X11 support]))
 541
 542 AS_IF([test "x$enable_x11" != "xno"],
 543     [PKG_CHECK_MODULES(X11, [ x11-xcb xcb >= 1.6 ice sm xtst ], HAVE_X11=1, HAVE_X11=0)],
 544     HAVE_X11=0)
 545
 546 AS_IF([test "x$enable_x11" = "xyes" && test "x$HAVE_X11" = "x0"],
 547     [AC_MSG_ERROR([*** X11 not found])])
 548
 549 AC_SUBST(X11_CFLAGS)
 550 AC_SUBST(X11_LIBS)
 551 AC_SUBST(HAVE_X11)
 552 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
 553 AS_IF([test "x$HAVE_X11" = "x1"], AC_DEFINE([HAVE_X11], 1, [Have X11?]))
 554
 555 #### Capabilities (optional) ####
 556
 557 CAP_LIBS=''
 558
 559 AC_ARG_WITH([caps],
 560     AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 561
 562 if test "x${with_caps}" != "xno"; then
 563     AC_SEARCH_LIBS([cap_init], [cap], [], [
 564                     if test "x${with_caps}" = "xyes" ; then
 565                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 566                     fi])
 567     AC_CHECK_HEADERS([sys/capability.h], [], [
 568                     if test "x${with_caps}" = "xyes" ; then
 569                         AC_MSG_ERROR([*** POSIX caps headers not found])
 570                     fi])
 571 fi
 572
 573 #### Valgrind (optional) ####
 574
 575 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 576
 577 #### json parsing ####
 578
 579 PKG_CHECK_MODULES(LIBJSON, [ json >= 0.9 ])
 580 AC_SUBST(LIBJSON_CFLAGS)
 581 AC_SUBST(LIBJSON_LIBS)
 582
 583 #### Sound file ####
 584
 585 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.20 ])
 586 AC_SUBST(LIBSNDFILE_CFLAGS)
 587 AC_SUBST(LIBSNDFILE_LIBS)
 588
 589 #### atomic-ops ####
 590
 591 AC_MSG_CHECKING([whether we need libatomic_ops])
 592 if test "x$need_libatomic_ops" = "xyes"; then
 593     AC_MSG_RESULT([yes])
 594     AC_CHECK_HEADERS([atomic_ops.h],
 595         [CFLAGS="$CFLAGS -DAO_REQUIRE_CAS"],
 596         [AC_MSG_ERROR([*** libatomic-ops headers not found])])
 597
 598     # Win32 does not need the lib and breaks horribly if we try to include it
 599     AS_IF([test "x$os_is_win32" != "x1"], [LIBS="$LIBS -latomic_ops"])
 600 else
 601     AC_MSG_RESULT([no])
 602 fi
 603
 604 #### Libsamplerate support (optional) ####
 605
 606 AC_ARG_ENABLE([samplerate],
 607     AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]))
 608
 609 AS_IF([test "x$enable_samplerate" != "xno"],
 610     [PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ], HAVE_LIBSAMPLERATE=1, HAVE_LIBSAMPLERATE=0)],
 611     HAVE_LIBSAMPLERATE=0)
 612
 613 AS_IF([test "x$enable_samplerate" = "xyes" && test "x$HAVE_LIBSAMPLERATE" = "x0"],
 614     [AC_MSG_ERROR([*** Libsamplerate not found])])
 615
 616 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 617 AC_SUBST(LIBSAMPLERATE_LIBS)
 618 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 619 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?]))
 620
 621 #### Database support ####
 622
 623 AC_ARG_WITH([database],
 624     AS_HELP_STRING([--with-database=auto|tdb|gdbm|simple],[Choose database backend.]),[],[with_database=auto])
 625
 626
 627 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xtdb"],
 628     [PKG_CHECK_MODULES(TDB, [ tdb ], HAVE_TDB=1, HAVE_TDB=0)],
 629     HAVE_TDB=0)
 630 AS_IF([test "x$HAVE_TDB" = "x1"], with_database=tdb)
 631
 632 AS_IF([test "x$with_database" = "xtdb" && test "x$HAVE_TDB" = "x0"],
 633     [AC_MSG_ERROR([*** tdb not found])])
 634
 635
 636 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xgdbm"],
 637     [
 638         HAVE_GDBM=1
 639         AC_CHECK_LIB(gdbm, gdbm_open, [], HAVE_GDBM=0)
 640         AC_CHECK_HEADERS(gdbm.h, [], HAVE_GDBM=0)
 641     ],
 642     HAVE_GDBM=0)
 643 AS_IF([test "x$HAVE_GDBM" = "x1"],
 644     [
 645         with_database=gdbm
 646         GDBM_CFLAGS=
 647         GDBM_LIBS=-lgdbm
 648     ])
 649
 650 AS_IF([test "x$with_database" = "xgdbm" && test "x$HAVE_GDBM" = "x0"],
 651     [AC_MSG_ERROR([*** gdbm not found])])
 652
 653
 654 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xsimple"],
 655     HAVE_SIMPLEDB=1,
 656     HAVE_SIMPLEDB=0)
 657 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], with_database=simple)
 658
 659 AS_IF([test "x$HAVE_TDB" != x1 -a "x$HAVE_GDBM" != x1 -a "x$HAVE_SIMPLEDB" != x1],
 660     AC_MSG_ERROR([*** missing database backend]))
 661
 662
 663 AC_SUBST(TDB_CFLAGS)
 664 AC_SUBST(TDB_LIBS)
 665 AM_CONDITIONAL([HAVE_TDB], [test "x$HAVE_TDB" = x1])
 666 AS_IF([test "x$HAVE_TDB" = "x1"], AC_DEFINE([HAVE_TDB], 1, [Have tdb?]))
 667
 668 AC_SUBST(GDBM_CFLAGS)
 669 AC_SUBST(GDBM_LIBS)
 670 AM_CONDITIONAL([HAVE_GDBM], [test "x$HAVE_GDBM" = x1])
 671 AS_IF([test "x$HAVE_GDBM" = "x1"], AC_DEFINE([HAVE_GDBM], 1, [Have gdbm?]))
 672
 673 AM_CONDITIONAL([HAVE_SIMPLEDB], [test "x$HAVE_SIMPLEDB" = x1])
 674 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], AC_DEFINE([HAVE_SIMPLEDB], 1, [Have simple?]))
 675
 676 #### OSS support (optional) ####
 677
 678 AC_ARG_ENABLE([oss-output],
 679     AS_HELP_STRING([--disable-oss-output],[Disable optional OSS output support]))
 680
 681 AC_ARG_ENABLE([oss-wrapper],
 682     AS_HELP_STRING([--disable-oss-wrapper],[Disable optional OSS wrapper support]))
 683
 684 AS_IF([test "x$enable_oss_output" != "xno" -o "x$enable_oss_wrapper" != "xno"],
 685     [AC_CHECK_HEADERS([sys/soundcard.h], HAVE_OSS=1, HAVE_OSS=0)],
 686     HAVE_OSS=0)
 687
 688 AS_IF([test "x$enable_oss_output" = "xyes" -o "x$enable_oss_wrapper" = "xyes" && test "x$HAVE_OSS" = "x0"],
 689     [AC_MSG_ERROR([*** OSS support not found])])
 690
 691 AS_IF([test "x$enable_oss_output" != "xno"],
 692     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_OUTPUT=1, HAVE_OSS_OUTPUT=0)],
 693     HAVE_OSS_OUTPUT=0)
 694
 695 AS_IF([test "x$enable_oss_wrapper" != "xno"],
 696     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_WRAPPER=1, HAVE_OSS_WRAPPER=0)],
 697     HAVE_OSS_WRAPPER=0)
 698
 699 AC_SUBST(HAVE_OSS_OUTPUT)
 700 AM_CONDITIONAL([HAVE_OSS_OUTPUT], [test "x$HAVE_OSS_OUTPUT" = "x1"])
 701 AM_CONDITIONAL([HAVE_OSS_WRAPPER], [test "x$HAVE_OSS_WRAPPER" = "x1"])
 702 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], AC_DEFINE([HAVE_OSS_OUTPUT], 1, [Have OSS output?]))
 703 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], AC_DEFINE([HAVE_OSS_WRAPPER], 1, [Have OSS wrapper (padsp)?]))
 704
 705 #### CoreAudio support (optional) ####
 706
 707 AC_ARG_ENABLE([coreaudio-output],
 708     AS_HELP_STRING([--disable-coreaudio-output],[Disable optional CoreAudio output support]))
 709
 710 AS_IF([test "x$enable_coreaudio_output" != "xno"],
 711     [AC_CHECK_HEADERS([CoreAudio/CoreAudio.h], HAVE_COREAUDIO=1, HAVE_COREAUDIO=0)],
 712     HAVE_COREAUDIO=0)
 713
 714 AS_IF([test "x$enable_coreaudio_output" = "xyes" && test "x$HAVE_COREAUDIO" = "x0"],
 715     [AC_MSG_ERROR([*** CoreAudio output support not found])])
 716
 717 AM_CONDITIONAL([HAVE_COREAUDIO], [test "x$HAVE_COREAUDIO" = "x1" && test "x$enable_coreaudio_output" != "xno"])
 718
 719 #### ALSA support (optional) ####
 720
 721 AC_ARG_ENABLE([alsa],
 722     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]))
 723
 724 AS_IF([test "x$enable_alsa" != "xno"],
 725     [PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.19 ], HAVE_ALSA=1, HAVE_ALSA=0)],
 726     HAVE_ALSA=0)
 727
 728 AS_IF([test "x$enable_alsa" = "xyes" && test "x$HAVE_ALSA" = "x0"],
 729     [AC_MSG_ERROR([*** Needed alsa >= 1.0.19 support not found])])
 730
 731 AC_SUBST(ASOUNDLIB_CFLAGS)
 732 AC_SUBST(ASOUNDLIB_LIBS)
 733 AC_SUBST(HAVE_ALSA)
 734 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 735 AS_IF([test "x$HAVE_ALSA" = "x1"], AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?]))
 736
 737 #### Solaris audio support (optional) ####
 738
 739 AC_ARG_ENABLE([solaris],
 740     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]))
 741
 742 AS_IF([test "x$enable_solaris" != "xno"],
 743     [AC_CHECK_HEADERS([sys/audio.h], HAVE_SOLARIS=1, HAVE_SOLARIS=0)],
 744     HAVE_SOLARIS=0)
 745
 746 AS_IF([test "x$enable_solaris" = "xyes" && test "x$HAVE_SOLARIS" = "x0"],
 747     [AC_MSG_ERROR([*** Solaris audio support not found])])
 748
 749 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 750 AS_IF([test "x$HAVE_SOLARIS" = "x1"], AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?]))
 751
 752 #### WaveOut audio support (optional) ####
 753
 754 AC_ARG_ENABLE([waveout],
 755     AS_HELP_STRING([--disable-waveout],[Disable optional WaveOut audio support]))
 756
 757 AS_IF([test "x$enable_waveout" != "xno"],
 758     [AC_CHECK_HEADERS([mmsystem.h], HAVE_WAVEOUT=1, HAVE_WAVEOUT=0, [#include <windows.h>])],
 759     HAVE_WAVEOUT=0)
 760
 761 AS_IF([test "x$enable_waveout" = "xyes" && test "x$HAVE_WAVEOUT" = "x0"],
 762     [AC_MSG_ERROR([*** WaveOut audio support not found])])
 763
 764 AC_SUBST(HAVE_WAVEOUT)
 765 AM_CONDITIONAL([HAVE_WAVEOUT], [test "x$HAVE_WAVEOUT" = x1])
 766 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], AC_DEFINE([HAVE_WAVEOUT], 1, [Have WaveOut audio?]))
 767
 768 #### GLib 2 support (optional) ####
 769
 770 AC_ARG_ENABLE([glib2],
 771     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]))
 772
 773 AS_IF([test "x$enable_glib2" != "xno"],
 774     [PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)],
 775     HAVE_GLIB20=0)
 776
 777 AS_IF([test "x$enable_glib2" = "xyes" && test "x$HAVE_GLIB20" = "x0"],
 778     [AC_MSG_ERROR([*** GLib 2 support not found])])
 779
 780 AC_SUBST(GLIB20_CFLAGS)
 781 AC_SUBST(GLIB20_LIBS)
 782 AC_SUBST(HAVE_GLIB20)
 783 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 784 AS_IF([test "x$HAVE_GLIB20" = "x1"], AC_DEFINE([HAVE_GLIB], 1, [Have GLIB?]))
 785
 786 #### GTK2 support (optional) ####
 787
 788 AC_ARG_ENABLE([gtk2],
 789     AS_HELP_STRING([--disable-gtk2],[Disable optional Gtk+ 2 support]))
 790
 791 AS_IF([test "x$enable_gtk2" != "xno"],
 792     [PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ], HAVE_GTK20=1, HAVE_GTK20=0)],
 793     HAVE_GTK20=0)
 794
 795 AS_IF([test "x$enable_gtk2" = "xyes" && test "x$HAVE_GTK20" = "x0"],
 796     [AC_MSG_ERROR([*** Gtk+ 2 support not found])])
 797
 798 AC_SUBST(GTK20_CFLAGS)
 799 AC_SUBST(GTK20_LIBS)
 800 AM_CONDITIONAL([HAVE_GTK20], [test "x$HAVE_GTK20" = x1])
 801 AS_IF([test "x$HAVE_GTK20" = "x1"], AC_DEFINE([HAVE_GTK], 1, [Have GTK?]))
 802
 803 #### GConf support (optional) ####
 804
 805 AC_ARG_ENABLE([gconf],
 806     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]))
 807
 808 AS_IF([test "x$enable_gconf" != "xno"],
 809     [PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 gobject-2.0 ], HAVE_GCONF=1, HAVE_GCONF=0)],
 810     HAVE_GCONF=0)
 811
 812 AS_IF([test "x$enable_gconf" = "xyes" && test "x$HAVE_GCONF" = "x0"],
 813     [AC_MSG_ERROR([*** GConf support not found])])
 814
 815 AC_SUBST(GCONF_CFLAGS)
 816 AC_SUBST(GCONF_LIBS)
 817 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 818
 819 #### Avahi support (optional) ####
 820
 821 AC_ARG_ENABLE([avahi],
 822     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]))
 823
 824 AS_IF([test "x$enable_avahi" != "xno"],
 825     [PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ], HAVE_AVAHI=1, HAVE_AVAHI=0)],
 826     HAVE_AVAHI=0)
 827
 828 AS_IF([test "x$enable_avahi" = "xyes" && test "x$HAVE_AVAHI" = "x0"],
 829     [AC_MSG_ERROR([*** Avahi support not found])])
 830
 831 AC_SUBST(AVAHI_CFLAGS)
 832 AC_SUBST(AVAHI_LIBS)
 833 AC_SUBST(HAVE_AVAHI)
 834 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 835
 836 #### JACK (optional) ####
 837
 838 AC_ARG_ENABLE([jack],
 839     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]))
 840
 841 AS_IF([test "x$enable_jack" != "xno"],
 842     [PKG_CHECK_MODULES(JACK, [ jack >= 0.117.0 ], HAVE_JACK=1, HAVE_JACK=0)],
 843     HAVE_JACK=0)
 844
 845 AS_IF([test "x$enable_jack" = "xyes" && test "x$HAVE_JACK" = "x0"],
 846     [AC_MSG_ERROR([*** JACK support not found])])
 847
 848 AC_SUBST(JACK_CFLAGS)
 849 AC_SUBST(JACK_LIBS)
 850 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 851
 852 #### Async DNS support (optional) ####
 853
 854 AC_ARG_ENABLE([asyncns],
 855     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]))
 856
 857 AS_IF([test "x$enable_asyncns" != "xno"],
 858     [PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)],
 859     HAVE_LIBASYNCNS=0)
 860
 861 AS_IF([test "x$enable_asyncns" = "xyes" && test "x$HAVE_LIBASYNCNS" = "x0"],
 862     [AC_MSG_ERROR([*** Async DNS support not found])])
 863
 864 AC_SUBST(LIBASYNCNS_CFLAGS)
 865 AC_SUBST(LIBASYNCNS_LIBS)
 866 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 867 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?]))
 868
 869 #### TCP wrappers (optional) ####
 870
 871 AC_ARG_ENABLE([tcpwrap],
 872     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]))
 873
 874 AS_IF([test "x$enable_tcpwrap" != "xno"],
 875     [
 876         ACX_LIBWRAP
 877         AS_IF([test "x$LIBWRAP_LIBS" != "x"], HAVE_TCPWRAP=1, HAVE_TCPWRAP=0)
 878     ],
 879     HAVE_TCPWRAP=0)
 880
 881 AS_IF([test "x$enable_tcpwrap" = "xyes" && test "x$HAVE_TCPWRAP" = "x0"],
 882     [AC_MSG_ERROR([*** TCP wrappers support not found])])
 883
 884 AC_SUBST(LIBWRAP_LIBS)
 885
 886 #### LIRC support (optional) ####
 887
 888 AC_ARG_ENABLE([lirc],
 889     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]))
 890
 891 LIRC_CFLAGS=
 892 LIRC_LIBS=
 893
 894 AS_IF([test "x$enable_lirc" != "xno"],
 895     [
 896         HAVE_LIRC=1
 897         AC_CHECK_HEADER(lirc/lirc_client.h, [], [HAVE_LIRC=0])
 898         AC_CHECK_LIB(lirc_client, lirc_init, [LIRC_LIBS=-llirc_client], [HAVE_LIRC=0])
 899     ],
 900     HAVE_LIRC=0)
 901
 902 AS_IF([test "x$enable_lirc" = "xyes" && test "x$HAVE_LIRC" = "x0"],
 903     [AC_MSG_ERROR([*** LIRC support not found])])
 904
 905 AC_SUBST(LIRC_CFLAGS)
 906 AC_SUBST(LIRC_LIBS)
 907 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 908
 909 #### D-Bus support (optional) ####
 910
 911 AC_ARG_ENABLE([dbus],
 912     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]))
 913
 914 AS_IF([test "x$enable_dbus" != "xno"],
 915     [PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.0 ], HAVE_DBUS=1, HAVE_DBUS=0)],
 916     HAVE_DBUS=0)
 917
 918 AS_IF([test "x$enable_dbus" = "xyes" && test "x$HAVE_DBUS" = "x0"],
 919     [AC_MSG_ERROR([*** D-Bus (1.3.0+) support not found])])
 920
 921 AS_IF([test "x$HAVE_DBUS" = "x1"],
 922     [
 923         save_CFLAGS="$CFLAGS"; CFLAGS="$CFLAGS $DBUS_CFLAGS"
 924         save_LIBS="$LIBS"; LIBS="$LIBS $DBUS_LIBS"
 925         AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 926         CFLAGS="$save_CFLAGS"
 927         LIBS="$save_LIBS"
 928     ])
 929
 930 AC_SUBST(DBUS_CFLAGS)
 931 AC_SUBST(DBUS_LIBS)
 932 AC_SUBST(HAVE_DBUS)
 933 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 934 AS_IF([test "x$HAVE_DBUS" = "x1"], AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.]))
 935
 936 PA_MACHINE_ID="${localstatedir}/lib/dbus/machine-id"
 937 AX_DEFINE_DIR(PA_MACHINE_ID, PA_MACHINE_ID, [D-Bus machine-id file])
 938 PA_MACHINE_ID_FALLBACK="${sysconfdir}/machine-id"
 939 AX_DEFINE_DIR(PA_MACHINE_ID_FALLBACK, PA_MACHINE_ID_FALLBACK,
 940               [Fallback machine-id file])
 941
 942 #### HAL support (optional), dependant on D-Bus ####
 943
 944 AC_ARG_ENABLE([hal],
 945     AS_HELP_STRING([--disable-hal],[Disable optional HAL support]))
 946
 947 AS_IF([test "x$enable_hal" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
 948     [PKG_CHECK_MODULES(HAL, [ hal >= 0.5.11 ], HAVE_HAL=1, HAVE_HAL=0)],
 949     HAVE_HAL=0)
 950 AS_IF([test "x$HAVE_DBUS" != "x1"], HAVE_HAL=0)
 951
 952 AS_IF([test "x$enable_hal" = "xyes" && test "x$HAVE_HAL" = "x0"],
 953     [AC_MSG_ERROR([*** HAL support not found (requires D-Bus)])])
 954
 955 AC_SUBST(HAL_CFLAGS)
 956 AC_SUBST(HAL_LIBS)
 957 AC_SUBST(HAVE_HAL)
 958 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 959 AS_IF([test "x$HAVE_HAL" = "x1"], AC_DEFINE([HAVE_HAL], 1, [Have HAL.]))
 960
 961 #### BlueZ support (optional, dependant on D-Bus) ####
 962
 963 AC_ARG_ENABLE([bluez],
 964     AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]))
 965
 966 AS_IF([test "x$enable_bluez" != "xno"],
 967     [PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ], HAVE_BLUEZ=1, HAVE_BLUEZ=0)],
 968     HAVE_BLUEZ=0)
 969 AS_IF([test "x$HAVE_DBUS" != "x1"], HAVE_BLUEZ=0)
 970
 971 AS_IF([test "x$enable_bluez" = "xyes" && test "x$HAVE_BLUEZ" = "x0"],
 972     [AC_MSG_ERROR([*** BLUEZ support not found (requires D-Bus)])])
 973
 974 AC_SUBST(BLUEZ_CFLAGS)
 975 AC_SUBST(BLUEZ_LIBS)
 976 AC_SUBST(HAVE_BLUEZ)
 977 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 978
 979 #### UDEV support (optional) ####
 980
 981 AC_ARG_ENABLE([udev],
 982     AS_HELP_STRING([--disable-udev],[Disable optional UDEV support]))
 983
 984 AS_IF([test "x$enable_udev" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
 985     [PKG_CHECK_MODULES(UDEV, [ libudev >= 143 ], HAVE_UDEV=1, HAVE_UDEV=0)],
 986     HAVE_UDEV=0)
 987
 988 AS_IF([test "x$enable_udev" = "xyes" && test "x$HAVE_UDEV" = "x0"],
 989     [AC_MSG_ERROR([*** UDEV support not found])])
 990
 991 AC_SUBST(UDEV_CFLAGS)
 992 AC_SUBST(UDEV_LIBS)
 993 AC_SUBST(HAVE_UDEV)
 994 AM_CONDITIONAL([HAVE_UDEV], [test "x$HAVE_UDEV" = x1])
 995 AS_IF([test "x$HAVE_UDEV" = "x1"], AC_DEFINE([HAVE_UDEV], 1, [Have UDEV.]))
 996
 997 #### HAL compat support (optional, dependant on UDEV) ####
 998
 999 AC_ARG_ENABLE([hal-compat],
1000     AS_HELP_STRING([--disable-hal-compat],[Disable optional HAL->udev transition compatibility support]))
1001
1002 AS_IF([test "x$enable_hal_compat" != "xno"],
1003     [AS_IF([test "x$HAVE_HAL" = "x0" -a "x$HAVE_UDEV" = "x1"], HAVE_HAL_COMPAT=1, HAVE_HAL_COMPAT=0)],
1004     HAVE_HAL_COMPAT=0)
1005
1006 AS_IF([test "x$enable_hal_compat" = "xyes" && test "x$HAVE_HAL_COMPAT" = "x0"],
1007     [AC_MSG_ERROR([*** HAL-compat support requires UDEV and no HAL])])
1008
1009 AM_CONDITIONAL([HAVE_HAL_COMPAT], [test "x$HAVE_HAL_COMPAT" = x1])
1010 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], AC_DEFINE([HAVE_HAL_COMPAT], 1, [Have HAL compatibility.]))
1011
1012 #### IPv6 connection support (optional) ####
1013
1014 AC_ARG_ENABLE([ipv6],
1015     AS_HELP_STRING([--disable-ipv6],[Disable optional IPv6 support]))
1016
1017 AS_IF([test "x$enable_ipv6" != "xno"], [HAVE_IPV6=1], [HAVE_IPV6=0])
1018
1019 AS_IF([test "x$HAVE_IPV6" = "x1"], AC_DEFINE([HAVE_IPV6], 1, [Define this to enable IPv6 connection support]))
1020
1021 #### OpenSSL support (optional) ####
1022
1023 AC_ARG_ENABLE([openssl],
1024     AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]))
1025
1026 AS_IF([test "x$enable_openssl" != "xno"],
1027     [PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ], HAVE_OPENSSL=1, HAVE_OPENSSL=0)],
1028     HAVE_OPENSSL=0)
1029
1030 AS_IF([test "x$enable_openssl" = "xyes" && test "x$HAVE_OPENSSL" = "x0"],
1031     [AC_MSG_ERROR([*** OpenSSL support not found])])
1032
1033 AC_SUBST(OPENSSL_CFLAGS)
1034 AC_SUBST(OPENSSL_LIBS)
1035 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1036 AS_IF([test "x$HAVE_OPENSSL" = "x1"], AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL]))
1037
1038 #### FFTW (optional) ####
1039
1040 AC_ARG_WITH([fftw],
1041     AS_HELP_STRING([--without-fftw],[Omit FFTW-using modules (equalizer)]))
1042
1043 AS_IF([test "x$with_fftw" != "xno"],
1044     [PKG_CHECK_MODULES(FFTW, [ fftw3f ], HAVE_FFTW=1, HAVE_FFTW=0)],
1045     HAVE_FFTW=0)
1046
1047 AS_IF([test "x$with_fftw" = "xyes" && test "x$HAVE_FFTW" = "x0"],
1048     [AC_MSG_ERROR([*** FFTW support not found])])
1049
1050 AM_CONDITIONAL([HAVE_FFTW], [test "x$HAVE_FFTW" = "x1"])
1051
1052 #### speex (optional) ####
1053
1054 AC_ARG_WITH([speex],
1055     AS_HELP_STRING([--without-speex],[Omit speex (resampling, AEC)]))
1056
1057 AS_IF([test "x$with_speex" != "xno"],
1058     [PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ], HAVE_SPEEX=1, HAVE_SPEEX=0)],
1059     HAVE_SPEEX=0)
1060
1061 AS_IF([test "x$with_speex" = "xyes" && test "x$HAVE_SPEEX" = "x0"],
1062     [AC_MSG_ERROR([*** speex support not found])])
1063
1064 AM_CONDITIONAL([HAVE_SPEEX], [test "x$HAVE_SPEEX" = "x1"])
1065 AS_IF([test "x$HAVE_SPEEX" = "x1"], AC_DEFINE([HAVE_SPEEX], 1, [Have speex]))
1066
1067 AC_SUBST(LIBSPEEX_CFLAGS)
1068 AC_SUBST(LIBSPEEX_LIBS)
1069
1070 #### ORC (optional) ####
1071
1072 ORC_CHECK([0.4.11])
1073
1074 #### Build and Install man pages ####
1075
1076 AC_ARG_ENABLE([manpages],
1077     AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]))
1078
1079 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" != "xno"])
1080
1081 #### PulseAudio system group & user  #####
1082
1083 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1084 if test -z "$with_system_user" ; then
1085     PA_SYSTEM_USER=pulse
1086 else
1087     PA_SYSTEM_USER=$with_system_user
1088 fi
1089 AC_SUBST(PA_SYSTEM_USER)
1090 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1091
1092 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1093 if test -z "$with_system_group" ; then
1094     PA_SYSTEM_GROUP=pulse
1095 else
1096     PA_SYSTEM_GROUP=$with_system_group
1097 fi
1098 AC_SUBST(PA_SYSTEM_GROUP)
1099 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1100
1101 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1102 if test -z "$with_access_group" ; then
1103     PA_ACCESS_GROUP=pulse-access
1104 else
1105     PA_ACCESS_GROUP=$with_access_group
1106 fi
1107 AC_SUBST(PA_ACCESS_GROUP)
1108 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1109
1110 AC_ARG_ENABLE([per-user-esound-socket],
1111     AS_HELP_STRING([--disable-per-user-esound-socket],[Use global esound socket directory /tmp/.esd/socket.]))
1112
1113 if test "x$enable_per_user_esound_socket" != "xno"; then
1114     USE_PER_USER_ESOUND_SOCKET=1
1115     AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1116 else
1117     USE_PER_USER_ESOUND_SOCKET=0
1118 fi
1119
1120 #### PulseAudio system runtime dir ####
1121
1122 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1123 AX_DEFINE_DIR(PA_SYSTEM_RUNTIME_PATH, PA_SYSTEM_RUNTIME_PATH, [System runtime dir])
1124 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1125 AX_DEFINE_DIR(PA_SYSTEM_CONFIG_PATH, PA_SYSTEM_CONFIG_PATH, [System config dir])
1126 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1127 AX_DEFINE_DIR(PA_SYSTEM_STATE_PATH, PA_SYSTEM_STATE_PATH, [System state dir])
1128
1129 PA_BINARY=${bindir}/pulseaudio${EXEEXT}
1130 AX_DEFINE_DIR(PA_BINARY, PA_BINARY, [Location of pulseaudio binary])
1131
1132 PACTL_BINARY=${bindir}/pactl${EXEEXT}
1133 AX_DEFINE_DIR(PACTL_BINARY, PACTL_BINARY, [Location of pactl binary])
1134
1135 AC_SUBST(PA_SOEXT, [.so])
1136
1137 AC_SUBST(pulseconfdir, ["${sysconfdir}/pulse"])
1138 AX_DEFINE_DIR(PA_DEFAULT_CONFIG_DIR, pulseconfdir, [Location of configuration files])
1139
1140 AC_DEFINE_UNQUOTED(PA_BUILDDIR, "${ac_pwd}/src", [Location of uninstalled binaries])
1141
1142 #### Mac OSX specific stuff #####
1143
1144 AC_ARG_ENABLE(mac-universal,
1145     AS_HELP_STRING([--enable-mac-universal], [Build Mac universal binaries]),
1146     enable_mac_universal=$enableval, enable_mac_universal="no")
1147
1148 AC_ARG_WITH(mac-version-min,
1149     AS_HELP_STRING([--with-mac-version-min=<version>], [Defines the earliest version of MacOS X that the executables will run on.]),
1150     mac_version_min=$withval, mac_version_min="10.5")
1151
1152 AC_ARG_WITH(mac-sysroot,
1153     AS_HELP_STRING([--with-mac-sysroot=<path>], [SDK basedir to use as the logical root directory for headers and libraries.]),
1154     mac_sysroot=$withval, mac_sysroot="/Developer/SDKs/MacOSX10.5.sdk")
1155
1156 if test "x$os_is_darwin" = "x1" ; then
1157     LDFLAGS="$LDFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1158     CFLAGS="$CFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1159
1160     if test "x$enable_mac_universal" = "xyes" ; then
1161         mac_arches="-arch i386 -arch x86_64"
1162         LDFLAGS="$LDFLAGS $mac_arches"
1163         CFLAGS="$CFLAGS $mac_arches"
1164     fi
1165 fi
1166
1167 AC_ARG_ENABLE([webrtc-aec],
1168     AS_HELP_STRING([--enable-webrtc-aec], [Enable the optional WebRTC-based echo canceller]))
1169
1170 AS_IF([test "x$enable_webrtc_aec" != "xno"],
1171     [PKG_CHECK_MODULES(WEBRTC, [ webrtc-audio-processing ], [HAVE_WEBRTC=1], [HAVE_WEBRTC=0])],
1172     [HAVE_WEBRTC=0])
1173
1174 AS_IF([test "x$enable_webrtc_aec" = "xyes" && test "x$HAVE_WEBRTC" = "x0"],
1175     [AC_MSG_ERROR([*** webrtc-audio-processing library not found])])
1176
1177 AC_SUBST(WEBRTC_CFLAGS)
1178 AC_SUBST(WEBRTC_LIBS)
1179 AM_CONDITIONAL([HAVE_WEBRTC], [test "x$HAVE_WEBRTC" = "x1"])
1180
1181
1182 ###################################
1183 #            Output               #
1184 ###################################
1185
1186 AC_DEFINE_UNQUOTED(PA_CFLAGS, "$CFLAGS", [The CFLAGS used during compilation])
1187
1188 # Check whether to build tests by default (as compile-test) or not
1189 AC_ARG_ENABLE([default-build-tests],
1190     AS_HELP_STRING([--disable-default-build-tests], [Build test programs only during make check]))
1191 AM_CONDITIONAL([BUILD_TESTS_DEFAULT], [test "x$enable_default_build_tests" != "xno"])
1192
1193 AC_ARG_ENABLE([legacy-runtime-dir],
1194         AS_HELP_STRING([--disable-legacy-runtime-dir], [Try to connect on legacy (< 0.9.12) socket paths.]))
1195 if test "x$enable_legacy_runtime_dir" != "xno" ; then
1196         AC_DEFINE(ENABLE_LEGACY_RUNTIME_DIR, [1], [Legacy runtime dir])
1197 fi
1198
1199 AC_ARG_ENABLE([legacy-database-entry-format],
1200         AS_HELP_STRING([--disable-legacy-database-entry-format], [Try to load legacy (< 1.0) database files (card, device and volume restore).]))
1201 if test "x$enable_legacy_database_entry_format" != "xno" ; then
1202         AC_DEFINE(ENABLE_LEGACY_DATABASE_ENTRY_FORMAT, [1], [Legacy database entry format])
1203 fi
1204 AC_DEFINE([WIBBLE], 1, [Just a test.])
1205
1206 AC_ARG_ENABLE([static-bins],
1207     AS_HELP_STRING([--enable-static-bins],[Statically link executables.]))
1208 AM_CONDITIONAL([STATIC_BINS], [test "x$enable_static_bins" = "xyes"])
1209
1210 AC_ARG_WITH(
1211         [preopen-mods],
1212         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1213         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1214 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1215 if test "x$PREOPEN_MODS" != "xall" ; then
1216     tmpLIBS=""
1217     for mod in $PREOPEN_MODS; do
1218         tmpLIBS="$tmpLIBS module-$mod.la"
1219     done
1220     PREOPEN_MODS="$tmpLIBS"
1221     AC_SUBST(PREOPEN_MODS)
1222 fi
1223
1224 AC_ARG_WITH(
1225         [module-dir],
1226         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules]),
1227         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules"])
1228
1229 AC_SUBST(modlibexecdir)
1230 AX_DEFINE_DIR(PA_DLSEARCHPATH, modlibexecdir, [Modules dir])
1231
1232 AC_ARG_WITH(
1233         [udev-rules-dir],
1234         AS_HELP_STRING([--with-udev-rules-dir],[Directory where to install udev rules to (defaults to /lib/udev/rules.d)]),
1235         [udevrulesdir=$withval], [udevrulesdir="/lib/udev/rules.d"])
1236
1237 AC_SUBST(udevrulesdir)
1238
1239 AC_ARG_ENABLE([force-preopen],
1240     AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]))
1241
1242 if test "x$enable_force_preopen" = "xyes"; then
1243     FORCE_PREOPEN=yes
1244 else
1245     FORCE_PREOPEN=no
1246 fi
1247
1248 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1249
1250 AC_CONFIG_FILES([
1251 Makefile
1252 src/Makefile
1253 man/Makefile
1254 libpulse.pc
1255 libpulse-simple.pc
1256 libpulse-mainloop-glib.pc
1257 doxygen/Makefile
1258 doxygen/doxygen.conf
1259 src/pulse/version.h
1260 po/Makefile.in
1261 man/pulseaudio.1.xml
1262 man/esdcompat.1.xml
1263 man/pax11publish.1.xml
1264 man/paplay.1.xml
1265 man/pacat.1.xml
1266 man/pacmd.1.xml
1267 man/pactl.1.xml
1268 man/pasuspender.1.xml
1269 man/padsp.1.xml
1270 man/pulse-daemon.conf.5.xml
1271 man/pulse-client.conf.5.xml
1272 man/default.pa.5.xml
1273 man/start-pulseaudio-kde.1.xml
1274 man/start-pulseaudio-x11.1.xml
1275 ])
1276
1277 AC_CONFIG_FILES([src/esdcompat:src/daemon/esdcompat.in], [chmod +x src/esdcompat])
1278 AC_CONFIG_FILES([src/start-pulseaudio-x11:src/daemon/start-pulseaudio-x11.in], [chmod +x src/start-pulseaudio-x11])
1279 AC_CONFIG_FILES([src/start-pulseaudio-kde:src/daemon/start-pulseaudio-kde.in], [chmod +x src/start-pulseaudio-kde])
1280 AC_CONFIG_FILES([src/client.conf:src/pulse/client.conf.in])
1281 AC_CONFIG_FILES([src/daemon.conf:src/daemon/daemon.conf.in],
1282     [m4 src/daemon.conf > src/daemon.conf.gen && mv src/daemon.conf.gen src/daemon.conf])
1283 AC_CONFIG_FILES([src/default.pa:src/daemon/default.pa.in],
1284     [m4 src/default.pa > src/default.pa.gen && mv src/default.pa.gen src/default.pa])
1285 AC_CONFIG_FILES([src/system.pa:src/daemon/system.pa.in],
1286     [m4 src/system.pa > src/system.pa.gen && mv src/system.pa.gen src/system.pa])
1287
1288 # CMake related ProjectConfig files
1289 PA_LIBDIR="$libdir"
1290 AX_DEFINE_DIR(PA_LIBDIR, PA_LIBDIR, [PulseAudio library dir])
1291 PA_INCDIR="$includedir"
1292 AX_DEFINE_DIR(PA_INCDIR, PA_INCDIR, [PulseAudio include dir])
1293
1294 AC_CONFIG_FILES([PulseAudioConfig.cmake:PulseAudioConfig.cmake.in],
1295     [m4 PulseAudioConfig.cmake > PulseAudioConfig.cmake.gen && mv PulseAudioConfig.cmake.gen PulseAudioConfig.cmake])
1296 AC_CONFIG_FILES([PulseAudioConfigVersion.cmake])
1297
1298 AC_OUTPUT
1299
1300 # ==========================================================================
1301
1302 AS_IF([test "x$HAVE_X11" = "x1"], ENABLE_X11=yes, ENABLE_X11=no)
1303 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], ENABLE_OSS_OUTPUT=yes, ENABLE_OSS_OUTPUT=no)
1304 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], ENABLE_OSS_WRAPPER=yes, ENABLE_OSS_WRAPPER=no)
1305 AS_IF([test "x$HAVE_ALSA" = "x1"], ENABLE_ALSA=yes, ENABLE_ALSA=no)
1306 AS_IF([test "x$HAVE_COREAUDIO" = "x1"], ENABLE_COREAUDIO=yes, ENABLE_COREAUDIO=no)
1307 AS_IF([test "x$HAVE_SOLARIS" = "x1"], ENABLE_SOLARIS=yes, ENABLE_SOLARIS=no)
1308 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], ENABLE_WAVEOUT=yes, ENABLE_WAVEOUT=no)
1309 AS_IF([test "x$HAVE_GLIB20" = "x1"], ENABLE_GLIB20=yes, ENABLE_GLIB20=no)
1310 AS_IF([test "x$HAVE_GTK20" = "x1"], ENABLE_GTK20=yes, ENABLE_GTK20=no)
1311 AS_IF([test "x$HAVE_GCONF" = "x1"], ENABLE_GCONF=yes, ENABLE_GCONF=no)
1312 AS_IF([test "x$HAVE_AVAHI" = "x1"], ENABLE_AVAHI=yes, ENABLE_AVAHI=no)
1313 AS_IF([test "x$HAVE_JACK" = "x1"], ENABLE_JACK=yes, ENABLE_JACK=no)
1314 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], ENABLE_LIBASYNCNS=yes, ENABLE_LIBASYNCNS=no)
1315 AS_IF([test "x$HAVE_LIRC" = "x1"], ENABLE_LIRC=yes, ENABLE_LIRC=no)
1316 AS_IF([test "x$HAVE_DBUS" = "x1"], ENABLE_DBUS=yes, ENABLE_DBUS=no)
1317 AS_IF([test "x$HAVE_HAL" = "x1"], ENABLE_HAL=yes, ENABLE_HAL=no)
1318 AS_IF([test "x$HAVE_UDEV" = "x1"], ENABLE_UDEV=yes, ENABLE_UDEV=no)
1319 AS_IF([test "x$HAVE_BLUEZ" = "x1"], ENABLE_BLUEZ=yes, ENABLE_BLUEZ=no)
1320 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], ENABLE_HAL_COMPAT=yes, ENABLE_HAL_COMPAT=no)
1321 AS_IF([test "x$HAVE_TCPWRAP" = "x1"], ENABLE_TCPWRAP=yes, ENABLE_TCPWRAP=no)
1322 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], ENABLE_LIBSAMPLERATE=yes, ENABLE_LIBSAMPLERATE=no)
1323 AS_IF([test "x$HAVE_IPV6" = "x1"], ENABLE_IPV6=yes, ENABLE_IPV6=no)
1324 AS_IF([test "x$HAVE_OPENSSL" = "x1"], ENABLE_OPENSSL=yes, ENABLE_OPENSSL=no)
1325 AS_IF([test "x$HAVE_FFTW" = "x1"], ENABLE_FFTW=yes, ENABLE_FFTW=no)
1326 AS_IF([test "x$HAVE_ORC" = "xyes"], ENABLE_ORC=yes, ENABLE_ORC=no)
1327 AS_IF([test "x$HAVE_SPEEX" = "x1"], ENABLE_SPEEX=yes, ENABLE_SPEEX=no)
1328 AS_IF([test "x$HAVE_WEBRTC" = "x1"], ENABLE_WEBRTC=yes, ENABLE_WEBRTC=no)
1329 AS_IF([test "x$HAVE_TDB" = "x1"], ENABLE_TDB=yes, ENABLE_TDB=no)
1330 AS_IF([test "x$HAVE_GDBM" = "x1"], ENABLE_GDBM=yes, ENABLE_GDBM=no)
1331 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], ENABLE_SIMPLEDB=yes, ENABLE_SIMPLEDB=no)
1332 AS_IF([test "x$USE_PER_USER_ESOUND_SOCKET" = "x1"], ENABLE_PER_USER_ESOUND_SOCKET=yes, ENABLE_PER_USER_ESOUND_SOCKET=no)
1333 AS_IF([test "x$enable_legacy_runtime_dir" != "xno"], ENABLE_LEGACY_RUNTIME_DIR=yes, ENABLE_LEGACY_RUNTIME_DIR=no)
1334 AS_IF([test "x$enable_legacy_database_entry_format" != "xno"], ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=yes, ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=no)
1335
1336 echo "
1337  ---{ $PACKAGE_NAME $VERSION }---
1338
1339     prefix:                        ${prefix}
1340     sysconfdir:                    ${sysconfdir}
1341     localstatedir:                 ${localstatedir}
1342     modlibexecdir:                 ${modlibexecdir}
1343     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1344     System State Path:             ${PA_SYSTEM_STATE_PATH}
1345     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1346     Compiler:                      ${CC}
1347     CFLAGS:                        ${CFLAGS}
1348     LIBS:                          ${LIBS}
1349
1350     Enable X11:                    ${ENABLE_X11}
1351     Enable OSS Output:             ${ENABLE_OSS_OUTPUT}
1352     Enable OSS Wrapper:            ${ENABLE_OSS_WRAPPER}
1353     Enable Alsa:                   ${ENABLE_ALSA}
1354     Enable CoreAudio:              ${ENABLE_COREAUDIO}
1355     Enable Solaris:                ${ENABLE_SOLARIS}
1356     Enable WaveOut:                ${ENABLE_WAVEOUT}
1357     Enable GLib 2.0:               ${ENABLE_GLIB20}
1358     Enable Gtk+ 2.0:               ${ENABLE_GTK20}
1359     Enable GConf:                  ${ENABLE_GCONF}
1360     Enable Avahi:                  ${ENABLE_AVAHI}
1361     Enable Jack:                   ${ENABLE_JACK}
1362     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1363     Enable LIRC:                   ${ENABLE_LIRC}
1364     Enable D-Bus:                  ${ENABLE_DBUS}
1365       Enable HAL:                  ${ENABLE_HAL}
1366       Enable BlueZ:                ${ENABLE_BLUEZ}
1367     Enable udev:                   ${ENABLE_UDEV}
1368       Enable HAL->udev compat:     ${ENABLE_HAL_COMPAT}
1369     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1370     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1371     Enable IPv6:                   ${ENABLE_IPV6}
1372     Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1373     Enable fftw:                   ${ENABLE_FFTW}
1374     Enable orc:                    ${ENABLE_ORC}
1375     Enable speex:                  ${ENABLE_SPEEX}
1376     Enable WebRTC echo canceller:  ${ENABLE_WEBRTC}
1377     Database
1378       tdb:                         ${ENABLE_TDB}
1379       gdbm:                        ${ENABLE_GDBM}
1380       simple database:             ${ENABLE_SIMPLEDB}
1381
1382     System User:                   ${PA_SYSTEM_USER}
1383     System Group:                  ${PA_SYSTEM_GROUP}
1384     Access Group:                  ${PA_ACCESS_GROUP}
1385     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1386     Force preopen:                 ${FORCE_PREOPEN}
1387     Preopened modules:             ${PREOPEN_MODS}
1388
1389     Legacy Runtime Dir Support:    ${ENABLE_LEGACY_RUNTIME_DIR}
1390     Legacy Database Entry Support: ${ENABLE_LEGACY_DATABASE_ENTRY_FORMAT}
1391 "
1392
1393 if test "${ENABLE_DBUS}" = "no" && test "x$os_is_win32" != "x1" ; then
1394    echo "
1395 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1396 You do not have D-Bus support enabled. It is strongly recommended
1397 that you enable D-Bus support if your platform supports it.
1398 Many parts of PulseAudio use D-Bus, from ConsoleKit interaction
1399 to the Device Reservation Protocol to speak to JACK, Bluetooth
1400 support and even a native control protocol for communicating and
1401 controling the PulseAudio daemon itself.
1402 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1403 "
1404 fi
1405
1406 if test "${ENABLE_UDEV}" = "no" && test "x$os_is_win32" != "x1" ; then
1407    echo "
1408 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1409 You do not have udev support enabled. It is strongly recommended
1410 that you enable udev support if your platform supports it as it is
1411 the primary method used to detect hardware audio devices (on Linux)
1412 and is thus a critical part of PulseAudio on that platform.
1413 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1414 "
1415 fi
1416
1417 if test "${ENABLE_SPEEX}" = "no" && test "x$os_is_win32" != "x1" ; then
1418    echo "
1419 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1420 You do not have speex support enabled. It is strongly recommended
1421 that you enable speex support if your platform supports it as it is
1422 the primary method used for audio resampling and is thus a critical
1423 part of PulseAudio on that platform.
1424 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1425 "
1426 fi