code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23 AC_INIT([polypaudio],[0.8],[mzcbylcnhqvb (at) 0pointer (dot) de])
  24 AC_CONFIG_SRCDIR([src/daemon/main.c])
  25 AC_CONFIG_HEADERS([config.h])
  26 AM_INIT_AUTOMAKE([foreign -Wall])
  27
  28 AC_SUBST(PA_MAJORMINOR, "$PACKAGE_VERSION")
  29 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  30
  31 AC_SUBST(PA_API_VERSION, 8)
  32 AC_SUBST(PA_PROTOCOL_VERSION, 8)
  33
  34 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  35    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  36    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  37 fi
  38
  39 #### Large File-Support (LFS) ####
  40
  41 AC_SYS_LARGEFILE
  42
  43 #### Checks for programs. ####
  44
  45 # CC
  46
  47 AC_PROG_CC
  48 AC_PROG_GCC_TRADITIONAL
  49 AC_GNU_SOURCE
  50
  51 # M4
  52
  53 AC_PATH_PROG([M4], [m4 gm4], [no])
  54 if test "x$M4" = xno ; then
  55    AC_MSG_ERROR([m4 missing])
  56 fi
  57
  58 # GCC flags
  59
  60 test_gcc_flag() {
  61     AC_LANG_CONFTEST([int main() {}])
  62     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  63     ret=$?
  64     rm -f conftest.o
  65     return $ret
  66 }
  67
  68 # If using GCC specify some additional parameters
  69 if test "x$GCC" = "xyes" ; then
  70
  71     # We use gnu99 instead of c99 because many have interpreted the standard
  72     # in a way that int64_t isn't defined on non-64 bit platforms.
  73     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  74
  75     for flag in $DESIRED_FLAGS ; do
  76         AC_MSG_CHECKING([whether $CC accepts $flag])
  77         if test_gcc_flag $flag ; then
  78            CFLAGS="$CFLAGS $flag"
  79            AC_MSG_RESULT([yes])
  80         else
  81            AC_MSG_RESULT([no])
  82         fi
  83     done
  84 fi
  85
  86 # LYNX documentation generation
  87 AC_ARG_ENABLE(lynx,
  88         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
  89 [case "${enableval}" in
  90   yes) lynx=yes ;;
  91   no)  lynx=no ;;
  92   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
  93 esac],[lynx=yes])
  94
  95 if test x$lynx = xyes ; then
  96    AC_CHECK_PROG(have_lynx, lynx, yes, no)
  97
  98    if test x$have_lynx = xno ; then
  99      AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
 100    fi
 101 fi
 102
 103 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
 104
 105 #### libtool stuff ####
 106
 107 AC_LTDL_ENABLE_INSTALL
 108 AC_LIBLTDL_INSTALLABLE
 109 AC_SUBST(LTDLINCL)
 110 AC_SUBST(LIBLTDL)
 111 AC_LIBTOOL_DLOPEN
 112 AC_LIBTOOL_WIN32_DLL
 113 AC_PROG_LIBTOOL
 114 AC_CONFIG_SUBDIRS(libltdl)
 115
 116 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 117     AC_MSG_ERROR([[
 118
 119         *** Cannot find the libltdl development files.
 120         *** Maybe you need to install the libltdl-dev package.
 121         ]])
 122 fi
 123
 124 #### Determine build environment ####
 125
 126 os_is_win32=0
 127
 128 case "$host_os" in
 129         mingw*)
 130         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 131         os_is_win32=1
 132                 ;;
 133         esac
 134
 135 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 136
 137 ###################################
 138 #   Basic environment checks      #
 139 ###################################
 140
 141 #### Checks for header files. ####
 142
 143 # ISO
 144 AC_HEADER_STDC
 145
 146 # POSIX
 147 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 148     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 149     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 150     syslog.h])
 151 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 152 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 153
 154 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 155 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 156
 157 # XPG4-UNIX
 158 AC_CHECK_HEADERS([sys/poll.h])
 159
 160 # Linux
 161 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 162
 163 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 164
 165 # Windows
 166 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 167
 168 # Other
 169 AC_CHECK_HEADERS([sys/ioctl.h])
 170
 171 #### Typdefs, structures, etc. ####
 172
 173 AC_C_CONST
 174 AC_C_BIGENDIAN
 175 AC_TYPE_PID_T
 176 AC_TYPE_SIZE_T
 177 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 178     [Define ssize_t if it is not done by the standard libs.])])
 179 AC_TYPE_OFF_T
 180 AC_TYPE_SIGNAL
 181 AC_TYPE_UID_T
 182
 183 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 184 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 185
 186 # Solaris lacks this
 187 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 188     [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])
 189
 190 #### Check for libs ####
 191
 192 # ISO
 193 AC_SEARCH_LIBS([pow], [m])
 194
 195 # POSIX
 196 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 197
 198 # BSD
 199 AC_SEARCH_LIBS([connect], [socket])
 200
 201 # Non-standard
 202
 203 # This magic is needed so we do not needlessly add static libs to the win32
 204 # build, disabling its ability to make dlls.
 205 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 206
 207 #### Check for functions ####
 208
 209 # POSIX
 210 AC_FUNC_FORK
 211 AC_FUNC_GETGROUPS
 212 AC_FUNC_SELECT_ARGTYPES
 213 AC_CHECK_FUNCS([getaddrinfo getgrgid_r getpwuid_r gettimeofday getuid \
 214     inet_ntop inet_pton nanosleep setpgid setsid sigaction sleep])
 215 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 216
 217 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 218
 219 # X/OPEN
 220 AC_CHECK_FUNCS([readlink])
 221
 222 # SUSv2
 223 AC_CHECK_FUNCS([ctime_r usleep])
 224
 225 # BSD
 226 AC_CHECK_FUNCS([lstat])
 227
 228 # Non-standard
 229
 230 AC_CHECK_FUNCS(setresuid)
 231 AC_CHECK_FUNCS(setreuid)
 232
 233 #### POSIX threads ####
 234
 235 ACX_PTHREAD
 236
 237 ###################################
 238 #      External libraries         #
 239 ###################################
 240
 241 #### X11 (optional) ####
 242
 243 HAVE_X11=0
 244
 245 # The macro tests the host, not the build target
 246 if test "x$os_is_win32" != "x1" ; then
 247     AC_PATH_XTRA
 248     test "x$no_x" != "xyes" && HAVE_X11=1
 249 fi
 250
 251 AC_SUBST(HAVE_X11)
 252 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 253 if test "x$HAVE_X11" = "x1" ; then
 254     AC_DEFINE([HAVE_X11], 1, [Have X11])
 255 fi
 256
 257 #### Capabilities (optional) ####
 258
 259 CAP_LIBS=''
 260
 261 AC_ARG_WITH(
 262         [caps],
 263         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 264
 265 if test "x${with_caps}" != "xno"; then
 266     AC_SEARCH_LIBS([cap_init], [cap])
 267     AC_CHECK_HEADERS([sys/capability.h])
 268 fi
 269
 270 #### pkg-config ####
 271
 272 # Check for pkg-config manually first, as if its not installed the
 273 # PKG_PROG_PKG_CONFIG macro won't be defined.
 274 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 275
 276 if test x"$have_pkg_config" = "xno"; then
 277     AC_MSG_ERROR(pkg-config is required to install this program)
 278 fi
 279
 280 PKG_PROG_PKG_CONFIG
 281
 282 #### Sample rate conversion ####
 283
 284 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 285 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 286 AC_SUBST(LIBSAMPLERATE_LIBS)
 287
 288 #### Sound file ####
 289
 290 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 291 AC_SUBST(LIBSNDFILE_CFLAGS)
 292 AC_SUBST(LIBSNDFILE_LIBS)
 293
 294 #### OSS support (optional) ####
 295
 296 AC_CHECK_HEADERS([sys/soundcard.h], [
 297 HAVE_OSS=1
 298 AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 299 ], [HAVE_OSS=0])
 300 AC_SUBST(HAVE_OSS)
 301 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 302
 303
 304 #### ALSA support (optional) ####
 305
 306 PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [
 307 HAVE_ALSA=1
 308 AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 309 ], [HAVE_ALSA=0])
 310 AC_SUBST(ASOUNDLIB_CFLAGS)
 311 AC_SUBST(ASOUNDLIB_LIBS)
 312 AC_SUBST(HAVE_ALSA)
 313 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 314
 315 #### Solaris audio support (optional) ####
 316
 317 AC_CHECK_HEADERS([sys/audio.h], [
 318 HAVE_SOLARIS=1
 319 AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 320 ], [HAVE_SOLARIS=0])
 321 AC_SUBST(HAVE_SOLARIS)
 322 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 323
 324 #### GLib 2 support (optional) ####
 325
 326 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)
 327 AC_SUBST(GLIB20_CFLAGS)
 328 AC_SUBST(GLIB20_LIBS)
 329 AC_SUBST(HAVE_GLIB20)
 330 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 331
 332 #### GLib 1 support (optional) ####
 333
 334 PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, HAVE_GLIB12=0)
 335 AC_SUBST(GLIB12_CFLAGS)
 336 AC_SUBST(GLIB12_LIBS)
 337 AC_SUBST(HAVE_GLIB12)
 338 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 339
 340 #### Howl support (optional) ####
 341
 342 PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, HAVE_HOWL=0)
 343 AC_SUBST(HOWL_CFLAGS)
 344 AC_SUBST(HOWL_LIBS)
 345 AC_SUBST(HAVE_HOWL)
 346 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 347
 348
 349 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 350 AC_SUBST(LIBOIL_CFLAGS)
 351 AC_SUBST(LIBOIL_LIBS)
 352
 353 #### Async DNS support (optional) ####
 354
 355 PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)
 356 AC_SUBST(LIBASYNCNS_CFLAGS)
 357 AC_SUBST(LIBASYNCNS_LIBS)
 358 AC_SUBST(HAVE_LIBASYNCNS)
 359 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 360
 361 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 362    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 363 fi
 364
 365 #### TCP wrappers (optional) ####
 366
 367 ACX_LIBWRAP
 368 AC_SUBST(LIBWRAP_LIBS)
 369
 370 #### LIRC support (optional) ####
 371
 372 ACX_LIRC
 373 AC_SUBST(LIRC_CFLAGS)
 374 AC_SUBST(LIRC_LIBS)
 375 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 376
 377 ###################################
 378 #            Output               #
 379 ###################################
 380
 381 AC_ARG_ENABLE(
 382         [static-bins],
 383         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 384         [STATIC_BINS=1], [STATIC_BINS=0])
 385 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 386
 387 AC_ARG_WITH(
 388         [preopen-mods],
 389         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 390         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 391 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 392 if test "x$PREOPEN_MODS" != "xall" ; then
 393     tmpLIBS=""
 394     for mod in $PREOPEN_MODS; do
 395         tmpLIBS="$tmpLIBS module-$mod.la"
 396     done
 397     PREOPEN_MODS="$tmpLIBS"
 398     AC_SUBST(PREOPEN_MODS)
 399 fi
 400
 401 AC_CONFIG_FILES([
 402 Makefile
 403 src/Makefile
 404 polyplib.pc
 405 polyplib-simple.pc
 406 polyplib-browse.pc
 407 polyplib-glib-mainloop.pc
 408 polyplib-glib12-mainloop.pc
 409 doc/Makefile
 410 doc/README.html
 411 doc/cli.html
 412 doc/daemon.html
 413 doc/modules.html
 414 doxygen/Makefile
 415 doxygen/doxygen.conf
 416 src/polyp/version.h
 417 doc/FAQ.html
 418 ])
 419 AC_OUTPUT