code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.63)
  24
  25 m4_define(PA_MAJOR, [0])
  26 m4_define(PA_MINOR, [9])
  27 m4_define(PA_MICRO, [15])
  28
  29 AC_INIT([pulseaudio],[PA_MAJOR.PA_MINOR.PA_MICRO],[mzchyfrnhqvb (at) 0pointer (dot) net])
  30 AC_CONFIG_SRCDIR([src/daemon/main.c])
  31 AC_CONFIG_MACRO_DIR([m4])
  32 AC_CONFIG_HEADERS([config.h])
  33 AM_INIT_AUTOMAKE([foreign 1.10 -Wall])
  34
  35 AC_SUBST(PA_MAJORMINOR, PA_MAJOR.PA_MINOR)
  36 AC_SUBST(PA_MAJORMINORMICRO, PA_MAJOR.PA_MINOR.PA_MICRO)
  37 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
  38
  39 AC_SUBST(PA_API_VERSION, 12)
  40 AC_SUBST(PA_PROTOCOL_VERSION, 15)
  41
  42 # The stable ABI for client applications, for the version info x:y:z
  43 # always will hold y=z
  44 AC_SUBST(LIBPULSE_VERSION_INFO, [7:1:7])
  45
  46 # A simplified, synchronous, ABI-stable interface for client
  47 # applications, for the version info x:y:z always will hold y=z
  48 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:2:0])
  49
  50 # The ABI-stable network browsing interface for client applications,
  51 # for the version info x:y:z always will hold y=z
  52 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  53
  54 # The ABI-stable GLib adapter for client applications, for the version
  55 # info x:y:z always will hold y=z
  56 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:4:0])
  57
  58 AC_CANONICAL_HOST
  59 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  60
  61 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  62    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  63    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  64 fi
  65
  66 #### Platform hacks ####
  67
  68 case $host in
  69    *-*-solaris* )
  70       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  71       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  72       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  73       ;;
  74 esac
  75
  76 #### Checks for programs. ####
  77
  78 # mkdir -p
  79
  80 AC_PROG_MKDIR_P
  81
  82 # CC
  83
  84 AC_PROG_CC
  85 AC_PROG_CC_C99
  86 AM_PROG_CC_C_O
  87 AC_PROG_GCC_TRADITIONAL
  88 AC_USE_SYSTEM_EXTENSIONS
  89
  90 # M4
  91
  92 AC_PATH_PROG([M4], [m4 gm4], [no])
  93 if test "x$M4" = xno ; then
  94    AC_MSG_ERROR([m4 missing])
  95 fi
  96
  97 dnl Compiler flags
  98 DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wno-long-long -Winline -Wvla -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wpacked -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing=2 -Wwrite-strings -Wno-unused-parameter -ffast-math -Wp,-D_FORTIFY_SOURCE=2 -fno-common -fdiagnostics-show-option"
  99
 100 for flag in $DESIRED_FLAGS ; do
 101   CC_CHECK_CFLAGS([$flag], [CFLAGS="$CFLAGS $flag"])
 102 done
 103
 104 dnl Check whether to build tests by default (as compile-test) or not
 105 AC_ARG_ENABLE([default-build-tests],
 106     AS_HELP_STRING([--disable-default-build-tests], [Build test programs only during make check]))
 107
 108 AM_CONDITIONAL([BUILD_TESTS_DEFAULT], [test "x$enable_default_build_tests" = "xno"])
 109
 110 # Native atomic operation support
 111 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 112     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]),
 113         [
 114             case "${enableval}" in
 115                 yes) atomic_arm_linux_helpers=yes ;;
 116                 no) atomic_arm_linux_helpers=no ;;
 117                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 118             esac
 119         ],
 120         [atomic_arm_linux_helpers=auto])
 121
 122 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 123     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]),
 124         [
 125             case "${enableval}" in
 126                 yes) AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers]) ;;
 127                 no) ;;
 128                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 129             esac
 130         ],)
 131
 132 AC_ARG_ENABLE([netbsd-atomic-ops],
 133     AS_HELP_STRING([--enable-netbsd-atomic-ops],[Use the native NetBSD atomic_ops implementation]),
 134         [
 135             case "${enableval}" in
 136                 yes) atomic_netbsd_helpers=yes ;;
 137                 no) atomic_netbsd_helpers=no ;;
 138                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-netbsd-atomic-ops) ;;
 139             esac
 140         ],
 141         [atomic_netbsd_helpers=auto])
 142
 143 AC_MSG_CHECKING([target operating system])
 144 case $host in
 145         *-*-linux*)
 146             AC_MSG_RESULT([linux])
 147             pulse_target_os=linux
 148         ;;
 149         *-*-netbsd*)
 150             AC_MSG_RESULT([netbsd])
 151             pulse_target_os=netbsd
 152         ;;
 153         *)
 154             AC_MSG_RESULT([unknown])
 155             pulse_target_os=unknown
 156         ;;
 157 esac
 158
 159 # If everything else fails use libatomic_ops
 160 need_libatomic_ops=yes
 161
 162 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 163   pulseaudio_cv_sync_bool_compare_and_swap,
 164   [AC_LINK_IFELSE(
 165      AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
 166      [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 167      [pulseaudio_cv_sync_bool_compare_and_swap=no])
 168   ])
 169
 170 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 171     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 172     need_libatomic_ops=no
 173 else
 174     # HW specific atomic ops stuff
 175     AC_MSG_CHECKING([architecture for native atomic operations])
 176     case $host_cpu in
 177         arm*)
 178             AC_MSG_RESULT([arm])
 179             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 180             # The Linux kernel helper functions have been there since 2.6.16. However
 181             # compile time checking for kernel version in cross compile environment
 182             # (which is usually the case for arm cpu) is tricky (or impossible).
 183             if test "x$pulse_target_os" = "xlinux" && test "x$atomic_arm_linux_helpers" != "xno"; then
 184                 AC_MSG_RESULT([yes])
 185                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 186                 need_libatomic_ops=no
 187             else
 188                AC_MSG_RESULT([no])
 189                AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 190                  pulseaudio_cv_support_arm_atomic_ops,
 191                  [AC_COMPILE_IFELSE(
 192                     AC_LANG_PROGRAM([],
 193                       [[volatile int a=0;
 194                         int o=0, n=1, r;
 195                         asm volatile ("ldrex    %0, [%1]\n"
 196                                          "subs  %0, %0, %2\n"
 197                                          "strexeq %0, %3, [%1]\n"
 198                                          : "=&r" (r)
 199                                          : "r" (&a), "Ir" (o), "r" (n)
 200                                          : "cc");
 201                         return (a==1 ? 0 : -1);
 202                       ]]),
 203                     [pulseaudio_cv_support_arm_atomic_ops=yes],
 204                     [pulseaudio_cv_support_arm_atomic_ops=no])
 205                  ])
 206                AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 207                    AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARMv6 instructions.])
 208                    need_libatomic_ops=no
 209                  ])
 210            fi
 211         ;;
 212         *)
 213             if test "x$pulse_target_os" = "xnetbsd" && test "x$atomic_netbsd_helpers" = "xyes"; then
 214                 AC_MSG_RESULT([yes])
 215                 AC_DEFINE_UNQUOTED(NETBSD_ATOMIC_OPS, 1, [netbsd implementation])
 216                 need_libatomic_ops=no
 217             else
 218                 AC_MSG_RESULT([unknown])
 219             fi
 220         ;;
 221     esac
 222 fi
 223
 224 CC_CHECK_TLS
 225
 226 AC_CACHE_CHECK([whether $CC knows _Bool],
 227   pulseaudio_cv__Bool,
 228   [AC_COMPILE_IFELSE(
 229      AC_LANG_PROGRAM([], [[_Bool b;]]),
 230      [pulseaudio_cv__Bool=yes],
 231      [pulseaudio_cv__Bool=no])
 232   ])
 233
 234 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], [
 235     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 236   ])
 237
 238 #### libtool stuff ####
 239 LT_PREREQ(2.2)
 240 LT_CONFIG_LTDL_DIR([libltdl])
 241 LT_INIT([dlopen win32-dll disable-static])
 242 LTDL_INIT([convenience recursive])
 243
 244 #### Determine build environment ####
 245
 246 os_is_win32=0
 247
 248 case "$host_os" in
 249         mingw*)
 250         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 251         os_is_win32=1
 252                 ;;
 253         esac
 254
 255 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 256
 257 ###################################
 258 #   Basic environment checks      #
 259 ###################################
 260
 261 #### Checks for header files. ####
 262
 263 # ISO
 264 AC_HEADER_STDC
 265
 266 # POSIX
 267 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 268     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 269     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 270     sys/uio.h syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 271 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 272                  [#include <sys/types.h>
 273                   #if HAVE_NETINET_IN_H
 274                   # include <netinet/in.h>
 275                   #endif
 276                   #if HAVE_NETINET_IN_SYSTM_H
 277                   # include <netinet/in_systm.h>
 278                   #endif
 279                  ])
 280 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 281 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 282
 283 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 284 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 285
 286 # Linux
 287 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 288
 289 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 290
 291 AC_CHECK_HEADERS([sys/prctl.h])
 292
 293 # Solaris
 294 AC_CHECK_HEADERS([sys/filio.h])
 295
 296 # Windows
 297 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 298
 299 # NetBSD
 300 AC_CHECK_HEADERS([sys/atomic.h])
 301
 302 # Other
 303 AC_CHECK_HEADERS([sys/ioctl.h])
 304 AC_CHECK_HEADERS([byteswap.h])
 305 AC_CHECK_HEADERS([sys/syscall.h])
 306 AC_CHECK_HEADERS([sys/eventfd.h])
 307 AC_CHECK_HEADERS([execinfo.h])
 308
 309 #### Typdefs, structures, etc. ####
 310
 311 AC_C_CONST
 312 AC_C_BIGENDIAN
 313 AC_TYPE_PID_T
 314 AC_TYPE_SIZE_T
 315 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 316     [Define ssize_t if it is not done by the standard libs.])])
 317 AC_TYPE_OFF_T
 318
 319 AC_TYPE_UID_T
 320 AC_CHECK_DECLS(environ)
 321
 322 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 323 HAVE_SIGXCPU=1
 324 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 325 ], [HAVE_SIGXCPU=0])
 326 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 327
 328 # Solaris lacks this
 329 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 330     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 331         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 332
 333 #### POSIX threads ####
 334
 335 ACX_PTHREAD
 336
 337 #### Check for libs ####
 338
 339 # ISO
 340 AC_SEARCH_LIBS([pow], [m])
 341
 342 # POSIX
 343 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 344 AC_SEARCH_LIBS([dlopen], [dl])
 345 AC_SEARCH_LIBS([shm_open], [rt])
 346 AC_SEARCH_LIBS([inet_ntop], [nsl])
 347 AC_SEARCH_LIBS([timer_create], [rt])
 348
 349 # BSD
 350 AC_SEARCH_LIBS([connect], [socket])
 351
 352 # Non-standard
 353
 354 # This magic is needed so we do not needlessly add static libs to the win32
 355 # build, disabling its ability to make dlls.
 356 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 357
 358 AC_CHECK_LIB(gdbm, gdbm_open)
 359 AC_CHECK_HEADERS(gdbm.h, [], [AC_MSG_ERROR([gdbm.h not found])])
 360
 361 #### Check for functions ####
 362
 363 # ISO
 364 AC_CHECK_FUNCS([lrintf strtof])
 365
 366 # POSIX
 367 AC_FUNC_FORK
 368 AC_FUNC_GETGROUPS
 369 AC_FUNC_SELECT_ARGTYPES
 370 AC_CHECK_FUNCS([chmod chown clock_gettime getaddrinfo getgrgid_r getgrnam_r \
 371     getpwnam_r getpwuid_r gettimeofday getuid inet_ntop inet_pton mlock nanosleep \
 372     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 373     sigaction sleep sysconf])
 374 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 375
 376 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 377
 378 # X/OPEN
 379 AC_CHECK_FUNCS([readlink])
 380
 381 # SUSv2
 382 AC_CHECK_FUNCS([ctime_r usleep])
 383
 384 # SUSv3
 385 AC_CHECK_FUNCS([strerror_r])
 386
 387 # BSD
 388 AC_CHECK_FUNCS([lstat])
 389
 390 # Non-standard
 391
 392 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 393
 394 AC_FUNC_ALLOCA
 395
 396 AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
 397   pulseaudio_cv_PTHREAD_PRIO_INHERIT,
 398   [save_CC=$CC; CC=$PTHREAD_CC
 399    save_CFLAGS=$CFLAGS; CFLAGS=$PTHREAD_CFLAGS
 400    save_LIBS=$LIBS; LIBS=$PTHREAD_LIBS
 401    AC_LINK_IFELSE(
 402      AC_LANG_PROGRAM(
 403        [[
 404          #include <pthread.h>
 405        ]],
 406        [[int i = PTHREAD_PRIO_INHERIT;]]),
 407      [pulseaudio_cv_PTHREAD_PRIO_INHERIT=yes],
 408      [pulseaudio_cv_PTHREAD_PRIO_INHERIT=no])
 409    CC=$save_CC
 410    CFLAGS=$save_CFLAGS
 411    LIBS=$save_LIBS
 412   ])
 413
 414 AS_IF([test "$pulseaudio_cv_PTHREAD_PRIO_INHERIT" = "yes"], [
 415     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 416   ])
 417
 418 AC_DEFINE_UNQUOTED(PA_CFLAGS,"$CFLAGS", [The CFLAGS used during compilation])
 419
 420 #### Large File-Support (LFS) ####
 421
 422 AC_SYS_LARGEFILE
 423
 424 # Check for open64 to know if the current system does have open64() and similar functions
 425 AC_CHECK_FUNCS([open64])
 426
 427 #### [lib]iconv ####
 428
 429 AM_ICONV
 430
 431 IT_PROG_INTLTOOL([0.35.0])
 432 GETTEXT_PACKAGE=pulseaudio
 433 AC_SUBST([GETTEXT_PACKAGE])
 434 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 435 AM_GLIB_GNU_GETTEXT
 436
 437 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 438 AC_SUBST(pulselocaledir)
 439
 440 ###################################
 441 #      External libraries         #
 442 ###################################
 443
 444 #### pkg-config ####
 445
 446 # Check for pkg-config manually first, as if its not installed the
 447 # PKG_PROG_PKG_CONFIG macro won't be defined.
 448 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 449
 450 if test x"$have_pkg_config" = "xno"; then
 451     AC_MSG_ERROR(pkg-config is required to install this program)
 452 fi
 453
 454 PKG_PROG_PKG_CONFIG
 455
 456 #### X11 (optional) ####
 457
 458 AC_ARG_ENABLE([x11],
 459     AS_HELP_STRING([--disable-x11],[Disable optional X11 support]),
 460         [
 461             case "${enableval}" in
 462                 yes) x11=yes ;;
 463                 no) x11=no ;;
 464                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 465             esac
 466         ],
 467         [x11=auto])
 468
 469 if test "x${x11}" != xno ; then
 470     PKG_CHECK_MODULES(X11, [ x11 ice sm ],
 471         HAVE_X11=1,
 472         [
 473             HAVE_X11=0
 474             if test "x$x11" = xyes ; then
 475                 AC_MSG_ERROR([*** X11 not found])
 476             fi
 477         ])
 478 else
 479     HAVE_X11=0
 480 fi
 481
 482 if test "x${HAVE_X11}" = x1 ; then
 483    AC_DEFINE([HAVE_X11], 1, [Have X11?])
 484 fi
 485
 486 AC_SUBST(X11_CFLAGS)
 487 AC_SUBST(X11_LIBS)
 488 AC_SUBST(HAVE_X11)
 489 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
 490
 491 #### Capabilities (optional) ####
 492
 493 CAP_LIBS=''
 494
 495 AC_ARG_WITH(
 496         [caps],
 497         AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 498
 499 if test "x${with_caps}" != "xno"; then
 500     AC_SEARCH_LIBS([cap_init], [cap], [], [
 501                     if test "x${with_caps}" = "xyes" ; then
 502                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 503                     fi])
 504     AC_CHECK_HEADERS([sys/capability.h], [], [
 505                     if test "x${with_caps}" = "xyes" ; then
 506                         AC_MSG_ERROR([*** POSIX caps headers not found])
 507                     fi])
 508 fi
 509
 510 #### Valgrind (optional) ####
 511
 512 AC_CHECK_HEADERS([valgrind/memcheck.h])
 513
 514 #### Sound file ####
 515
 516 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 517 AC_SUBST(LIBSNDFILE_CFLAGS)
 518 AC_SUBST(LIBSNDFILE_LIBS)
 519
 520 PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ])
 521 AC_SUBST(LIBSPEEX_CFLAGS)
 522 AC_SUBST(LIBSPEEX_LIBS)
 523
 524 #### atomic-ops ###
 525
 526 AC_MSG_CHECKING([whether we need libatomic_ops])
 527 if test "x$need_libatomic_ops" = "xyes"; then
 528    AC_MSG_RESULT([yes])
 529    AC_CHECK_HEADERS([atomic_ops.h], [], [
 530    AC_MSG_ERROR([*** libatomic-ops headers not found])
 531    ])
 532
 533    # Win32 does not need the lib and breaks horribly if we try to include it
 534    if test "x$os_is_win32" != "x1" ; then
 535        LIBS="$LIBS -latomic_ops"
 536    fi
 537 else
 538    AC_MSG_RESULT([no])
 539 fi
 540
 541 #### Libsamplerate support (optional) ####
 542
 543 AC_ARG_ENABLE([samplerate],
 544     AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]),
 545         [
 546             case "${enableval}" in
 547                 yes) samplerate=yes ;;
 548                 no) samplerate=no ;;
 549                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 550             esac
 551         ],
 552         [samplerate=auto])
 553
 554 if test "x${samplerate}" != xno ; then
 555     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 556         HAVE_LIBSAMPLERATE=1,
 557         [
 558             HAVE_LIBSAMPLERATE=0
 559             if test "x$samplerate" = xyes ; then
 560                 AC_MSG_ERROR([*** Libsamplerate not found])
 561             fi
 562         ])
 563 else
 564     HAVE_LIBSAMPLERATE=0
 565 fi
 566
 567 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 568    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 569 fi
 570
 571 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 572 AC_SUBST(LIBSAMPLERATE_LIBS)
 573 AC_SUBST(HAVE_LIBSAMPLERATE)
 574 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 575
 576 #### OSS support (optional) ####
 577
 578 AC_ARG_ENABLE([oss],
 579     AS_HELP_STRING([--disable-oss],[Disable optional OSS support]),
 580         [
 581             case "${enableval}" in
 582                 yes) oss=yes ;;
 583                 no) oss=no ;;
 584                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 585             esac
 586         ],
 587         [oss=auto])
 588
 589 if test "x${oss}" != xno ; then
 590     AC_CHECK_HEADERS([sys/soundcard.h],
 591         [
 592             HAVE_OSS=1
 593             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 594         ],
 595         [
 596             HAVE_OSS=0
 597             if test "x$oss" = xyes ; then
 598                 AC_MSG_ERROR([*** OSS support not found])
 599             fi
 600         ])
 601 else
 602     HAVE_OSS=0
 603 fi
 604
 605 AC_SUBST(HAVE_OSS)
 606 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 607
 608
 609 #### ALSA support (optional) ####
 610
 611 AC_ARG_ENABLE([alsa],
 612     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]),
 613         [
 614             case "${enableval}" in
 615                 yes) alsa=yes ;;
 616                 no) alsa=no ;;
 617                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 618             esac
 619         ],
 620         [alsa=auto])
 621
 622 if test "x${alsa}" != xno ; then
 623     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.17 ],
 624         [
 625             HAVE_ALSA=1
 626             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 627         ],
 628         [
 629             HAVE_ALSA=0
 630             if test "x$alsa" = xyes ; then
 631                 AC_MSG_ERROR([*** Needed alsa >= 1.0.17 support not found])
 632             fi
 633         ])
 634 else
 635     HAVE_ALSA=0
 636 fi
 637
 638 AC_SUBST(ASOUNDLIB_CFLAGS)
 639 AC_SUBST(ASOUNDLIB_LIBS)
 640 AC_SUBST(HAVE_ALSA)
 641 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 642
 643 #### Solaris audio support (optional) ####
 644
 645 AC_ARG_ENABLE([solaris],
 646     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]),
 647         [
 648             case "${enableval}" in
 649                 yes) solaris=yes ;;
 650                 no) solaris=no ;;
 651                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 652             esac
 653         ],
 654         [solaris=auto])
 655
 656 if test "x${solaris}" != xno ; then
 657     AC_CHECK_HEADERS([sys/audio.h],
 658         [
 659             HAVE_SOLARIS=1
 660             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 661         ],
 662         [
 663             HAVE_SOLARIS=0
 664             if test "x$solaris" = xyes ; then
 665                 AC_MSG_ERROR([*** Solaris audio support not found])
 666             fi
 667         ])
 668 else
 669     HAVE_SOLARIS=0
 670 fi
 671
 672 AC_SUBST(HAVE_SOLARIS)
 673 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 674
 675 #### GLib 2 support (optional) ####
 676
 677 AC_ARG_ENABLE([glib2],
 678     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]),
 679         [
 680             case "${enableval}" in
 681                 yes) glib2=yes ;;
 682                 no) glib2=no ;;
 683                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 684             esac
 685         ],
 686         [glib2=auto])
 687
 688 if test "x${glib2}" != xno ; then
 689     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 690         HAVE_GLIB20=1,
 691         [
 692             HAVE_GLIB20=0
 693             if test "x$glib2" = xyes ; then
 694                 AC_MSG_ERROR([*** GLib 2 support not found])
 695             fi
 696         ])
 697 else
 698     HAVE_GLIB20=0
 699 fi
 700
 701 AC_SUBST(GLIB20_CFLAGS)
 702 AC_SUBST(GLIB20_LIBS)
 703 AC_SUBST(HAVE_GLIB20)
 704 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 705
 706 #### GConf support (optional) ####
 707
 708 AC_ARG_ENABLE([gconf],
 709     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]),
 710         [
 711             case "${enableval}" in
 712                 yes) gconf=yes ;;
 713                 no) gconf=no ;;
 714                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 715             esac
 716         ],
 717         [gconf=auto])
 718
 719 if test "x${gconf}" != xno ; then
 720     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 721         HAVE_GCONF=1,
 722         [
 723             HAVE_GCONF=0
 724             if test "x$gconf" = xyes ; then
 725                 AC_MSG_ERROR([*** GConf support not found])
 726             fi
 727         ])
 728 else
 729     HAVE_GCONF=0
 730 fi
 731
 732 AC_SUBST(GCONF_CFLAGS)
 733 AC_SUBST(GCONF_LIBS)
 734 AC_SUBST(HAVE_GCONF)
 735 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 736
 737 #### Avahi support (optional) ####
 738
 739 AC_ARG_ENABLE([avahi],
 740     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]),
 741         [
 742             case "${enableval}" in
 743                 yes) avahi=yes ;;
 744                 no) avahi=no ;;
 745                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 746             esac
 747         ],
 748         [avahi=auto])
 749
 750 if test "x${avahi}" != xno ; then
 751     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 752         HAVE_AVAHI=1,
 753         [
 754                 HAVE_AVAHI=0
 755                 if test "x$avahi" = xyes ; then
 756                         AC_MSG_ERROR([*** Avahi support not found])
 757                 fi
 758         ])
 759 else
 760     HAVE_AVAHI=0
 761 fi
 762
 763 AC_SUBST(AVAHI_CFLAGS)
 764 AC_SUBST(AVAHI_LIBS)
 765 AC_SUBST(HAVE_AVAHI)
 766 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 767
 768 ### LIBOIL ####
 769
 770 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 771 AC_SUBST(LIBOIL_CFLAGS)
 772 AC_SUBST(LIBOIL_LIBS)
 773
 774 ### JACK (optional) ####
 775
 776 AC_ARG_ENABLE([jack],
 777     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]),
 778         [
 779             case "${enableval}" in
 780                 yes) jack=yes ;;
 781                 no) jack=no ;;
 782                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 783             esac
 784         ],
 785         [jack=auto])
 786
 787 if test "x${jack}" != xno ; then
 788     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 789         HAVE_JACK=1,
 790         [
 791             HAVE_JACK=0
 792             if test "x$jack" = xyes ; then
 793                 AC_MSG_ERROR([*** JACK support not found])
 794             fi
 795         ])
 796 else
 797     HAVE_JACK=0
 798 fi
 799
 800 AC_SUBST(JACK_CFLAGS)
 801 AC_SUBST(JACK_LIBS)
 802 AC_SUBST(HAVE_JACK)
 803 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 804
 805 #### Async DNS support (optional) ####
 806
 807 AC_ARG_ENABLE([asyncns],
 808     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]),
 809         [
 810             case "${enableval}" in
 811                 yes) asyncns=yes ;;
 812                 no) asyncns=no ;;
 813                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 814             esac
 815         ],
 816         [asyncns=auto])
 817
 818 if test "x${asyncns}" != xno ; then
 819     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 820         HAVE_LIBASYNCNS=1,
 821         [
 822             HAVE_LIBASYNCNS=0
 823             if test "x$asyncns" = xyes ; then
 824                 AC_MSG_ERROR([*** Async DNS support not found])
 825             fi
 826         ])
 827 else
 828     HAVE_LIBASYNCNS=0
 829 fi
 830
 831 AC_SUBST(LIBASYNCNS_CFLAGS)
 832 AC_SUBST(LIBASYNCNS_LIBS)
 833 AC_SUBST(HAVE_LIBASYNCNS)
 834 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 835
 836 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 837    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 838 fi
 839
 840 #### TCP wrappers (optional) ####
 841
 842 AC_ARG_ENABLE([tcpwrap],
 843     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 844         [
 845             case "${enableval}" in
 846                 yes) tcpwrap=yes ;;
 847                 no) tcpwrap=no ;;
 848                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 849             esac
 850         ],
 851         [tcpwrap=auto])
 852
 853 if test "x${tcpwrap}" != xno ; then
 854     ACX_LIBWRAP
 855     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 856         AC_MSG_ERROR([*** TCP wrappers support not found])
 857     fi
 858 else
 859     LIBWRAP_LIBS=
 860 fi
 861
 862 AC_SUBST(LIBWRAP_LIBS)
 863
 864 #### LIRC support (optional) ####
 865
 866 AC_ARG_ENABLE([lirc],
 867     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]),
 868         [
 869             case "${enableval}" in
 870                 yes) lirc=yes ;;
 871                 no) lirc=no ;;
 872                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 873             esac
 874         ],
 875         [lirc=auto])
 876
 877 if test "x${lirc}" != xno ; then
 878     ACX_LIRC
 879     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 880         AC_MSG_ERROR([*** LIRC support not found])
 881     fi
 882 else
 883     HAVE_LIRC=0
 884 fi
 885
 886 AC_SUBST(LIRC_CFLAGS)
 887 AC_SUBST(LIRC_LIBS)
 888 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 889
 890 #### HAL support (optional) ####
 891
 892 AC_ARG_ENABLE([hal],
 893     AS_HELP_STRING([--disable-hal],[Disable optional HAL support]),
 894         [
 895             case "${enableval}" in
 896                 yes) hal=yes ;;
 897                 no) hal=no ;;
 898                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 899             esac
 900         ],
 901         [hal=auto])
 902 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 903     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.11 ],
 904         HAVE_HAL=1,
 905         [
 906             HAVE_HAL=0
 907             if test "x$hal" = xyes ; then
 908                 AC_MSG_ERROR([*** HAL support not found])
 909             fi
 910         ])
 911 else
 912     HAVE_HAL=0
 913 fi
 914
 915 AC_SUBST(HAL_CFLAGS)
 916 AC_SUBST(HAL_LIBS)
 917 AC_SUBST(HAVE_HAL)
 918 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 919
 920 #### BlueZ support (optional) ####
 921
 922 AC_ARG_ENABLE([bluez],
 923     AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]),
 924         [
 925             case "${enableval}" in
 926                 yes) bluez=yes ;;
 927                 no) bluez=no ;;
 928                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-bluez) ;;
 929             esac
 930         ],
 931         [bluez=auto])
 932 if test "x${bluez}" != xno ; then
 933     PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ],
 934         HAVE_BLUEZ=1,
 935         [
 936             HAVE_BLUEZ=0
 937             if test "x$bluez" = xyes ; then
 938                 AC_MSG_ERROR([*** BLUEZ support not found])
 939             fi
 940         ])
 941 else
 942     HAVE_BLUEZ=0
 943 fi
 944
 945 AC_SUBST(BLUEZ_CFLAGS)
 946 AC_SUBST(BLUEZ_LIBS)
 947 AC_SUBST(HAVE_BLUEZ)
 948 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 949
 950 #### D-Bus support (optional) ####
 951
 952 AC_ARG_ENABLE([dbus],
 953     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]),
 954         [
 955             case "${enableval}" in
 956                 yes) dbus=yes ;;
 957                 no) dbus=no ;;
 958                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 959             esac
 960         ],
 961         [dbus=auto])
 962
 963 if test "x$HAVE_HAL" = x1 ; then
 964    dbus=yes
 965 fi
 966
 967 if test "x${dbus}" != xno || test "x${bluez}" != xno || "x${hal}" != xno ; then
 968
 969     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 970         [
 971             HAVE_DBUS=1
 972             saved_LIBS="$LIBS"
 973             LIBS="$LIBS $DBUS_LIBS"
 974             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 975             LIBS="$saved_LIBS"
 976             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 977         ],
 978         [
 979             HAVE_DBUS=0
 980             if test "x$dbus" = xyes ; then
 981                 AC_MSG_ERROR([*** D-Bus support not found])
 982             fi
 983         ])
 984 else
 985     HAVE_DBUS=0
 986 fi
 987
 988 AC_SUBST(DBUS_CFLAGS)
 989 AC_SUBST(DBUS_LIBS)
 990 AC_SUBST(HAVE_DBUS)
 991 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 992
 993 #### PolicyKit support (optional) ####
 994
 995 AC_ARG_ENABLE([polkit],
 996     AS_HELP_STRING([--disable-polkit],[Disable optional PolicyKit support]),
 997         [
 998             case "${enableval}" in
 999                 yes) polkit=yes ;;
1000                 no) polkit=no ;;
1001                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-polkit) ;;
1002             esac
1003         ],
1004         [polkit=auto])
1005
1006 if test "x${polkit}" != xno ; then
1007
1008     PKG_CHECK_MODULES(POLKIT, [ polkit-dbus >= 0.7 ],
1009         [
1010             HAVE_POLKIT=1
1011             AC_DEFINE([HAVE_POLKIT], 1, [Have PolicyKit])
1012             policydir=`pkg-config polkit-dbus --variable prefix`/share/PolicyKit/policy/
1013             AC_SUBST(policydir)
1014         ],
1015         [
1016             HAVE_POLKIT=0
1017             if test "x$polkit" = xyes ; then
1018                 AC_MSG_ERROR([*** PolicyKit support not found])
1019             fi
1020         ])
1021 else
1022     HAVE_POLKIT=0
1023 fi
1024
1025 AC_SUBST(POLKIT_CFLAGS)
1026 AC_SUBST(POLKIT_LIBS)
1027 AC_SUBST(HAVE_POLKIT)
1028 AM_CONDITIONAL([HAVE_POLKIT], [test "x$HAVE_POLKIT" = x1])
1029
1030 #### OpenSSL support (optional) ####
1031
1032 AC_ARG_ENABLE([openssl],
1033     AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]),
1034         [
1035             case "${enableval}" in
1036                 yes) openssl=yes ;;
1037                 no) openssl=no ;;
1038                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-openssl) ;;
1039             esac
1040         ],
1041         [openssl=auto])
1042
1043 if test "x${openssl}" != xno ; then
1044
1045     PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ],
1046         [
1047             HAVE_OPENSSL=1
1048             AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL])
1049         ],
1050         [
1051             HAVE_OPENSSL=0
1052             if test "x$openssl" = xyes ; then
1053                 AC_MSG_ERROR([*** OpenSSL support not found])
1054             fi
1055         ])
1056 else
1057     HAVE_OPENSSL=0
1058 fi
1059
1060 AC_SUBST(OPENSSL_CFLAGS)
1061 AC_SUBST(OPENSSL_LIBS)
1062 AC_SUBST(HAVE_OPENSSL)
1063 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1064
1065 ### Build and Install man pages ###
1066 AC_ARG_ENABLE(manpages,
1067         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
1068 [case "${enableval}" in
1069   yes) manpages=yes ;;
1070   no)  manpages=no ;;
1071   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
1072 esac],[manpages=yes])
1073
1074 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
1075
1076 #### PulseAudio system group & user  #####
1077
1078 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1079 if test -z "$with_system_user" ; then
1080     PA_SYSTEM_USER=pulse
1081 else
1082     PA_SYSTEM_USER=$with_system_user
1083 fi
1084 AC_SUBST(PA_SYSTEM_USER)
1085 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1086
1087 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1088 if test -z "$with_system_group" ; then
1089     PA_SYSTEM_GROUP=pulse
1090 else
1091     PA_SYSTEM_GROUP=$with_system_group
1092 fi
1093 AC_SUBST(PA_SYSTEM_GROUP)
1094 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1095
1096 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
1097 if test -z "$with_realtime_group" ; then
1098     PA_REALTIME_GROUP=pulse-rt
1099 else
1100     PA_REALTIME_GROUP=$with_realtime_group
1101 fi
1102 AC_SUBST(PA_REALTIME_GROUP)
1103 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
1104
1105 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1106 if test -z "$with_access_group" ; then
1107     PA_ACCESS_GROUP=pulse-access
1108 else
1109     PA_ACCESS_GROUP=$with_access_group
1110 fi
1111 AC_SUBST(PA_ACCESS_GROUP)
1112 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1113
1114 AC_ARG_ENABLE(
1115         per_user_esound_socket,
1116         AS_HELP_STRING([--disable-per-user-esound-socket], [Use global esound socket directory /tmp/.esd/socket.]),
1117         [
1118             case "${enableval}" in
1119                 yes) per_user_esound_socket=1 ;;
1120                 no) per_user_esound_socket=0 ;;
1121                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-per-user-esound-socket) ;;
1122             esac
1123         ],
1124         [per_user_esound_socket=1])
1125
1126 if test "x$per_user_esound_socket" = "x1"; then
1127    AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1128 fi
1129
1130 #### PulseAudio system runtime dir ####
1131 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1132 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1133 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1134 AC_SUBST(PA_SYSTEM_CONFIG_PATH)
1135 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1136 AC_SUBST(PA_SYSTEM_STATE_PATH)
1137
1138 ###################################
1139 #            Output               #
1140 ###################################
1141
1142 AC_ARG_ENABLE(
1143         [static-bins],
1144         AS_HELP_STRING([--enable-static-bins],[Statically link executables.]),
1145         [STATIC_BINS=1], [STATIC_BINS=0])
1146 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1147
1148 AC_ARG_WITH(
1149         [preopen-mods],
1150         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1151         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1152 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1153 if test "x$PREOPEN_MODS" != "xall" ; then
1154     tmpLIBS=""
1155     for mod in $PREOPEN_MODS; do
1156         tmpLIBS="$tmpLIBS module-$mod.la"
1157     done
1158     PREOPEN_MODS="$tmpLIBS"
1159     AC_SUBST(PREOPEN_MODS)
1160 fi
1161
1162 AC_ARG_WITH(
1163         [module-dir],
1164         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINORMICRO}/modules/]),
1165         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINORMICRO}/modules/"])
1166
1167 AC_SUBST(modlibexecdir)
1168
1169 AC_ARG_ENABLE(
1170         [force-preopen],
1171         AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
1172         [FORCE_PREOPEN=$enableval], [FORCE_PREOPEN=no])
1173 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1174
1175 AC_CONFIG_FILES([
1176 Makefile
1177 libltdl/Makefile
1178 src/Makefile
1179 man/Makefile
1180 libpulse.pc
1181 libpulse-simple.pc
1182 libpulse-browse.pc
1183 libpulse-mainloop-glib.pc
1184 doxygen/Makefile
1185 doxygen/doxygen.conf
1186 src/pulse/version.h
1187 po/Makefile.in
1188 ])
1189 AC_OUTPUT
1190
1191 # ==========================================================================
1192 ENABLE_X11=no
1193 if test "x$HAVE_X11" = "x1" ; then
1194    ENABLE_X11=yes
1195 fi
1196
1197 ENABLE_OSS=no
1198 if test "x$HAVE_OSS" = "x1" ; then
1199    ENABLE_OSS=yes
1200 fi
1201
1202 ENABLE_ALSA=no
1203 if test "x$HAVE_ALSA" = "x1" ; then
1204    ENABLE_ALSA=yes
1205 fi
1206
1207 ENABLE_SOLARIS=no
1208 if test "x$HAVE_SOLARIS" = "x1" ; then
1209    ENABLE_SOLARIS=yes
1210 fi
1211
1212 ENABLE_GLIB20=no
1213 if test "x$HAVE_GLIB20" = "x1" ; then
1214    ENABLE_GLIB20=yes
1215 fi
1216
1217 ENABLE_GCONF=no
1218 if test "x$HAVE_GCONF" = "x1" ; then
1219    ENABLE_GCONF=yes
1220 fi
1221
1222 ENABLE_AVAHI=no
1223 if test "x$HAVE_AVAHI" = "x1" ; then
1224    ENABLE_AVAHI=yes
1225 fi
1226
1227 ENABLE_JACK=no
1228 if test "x$HAVE_JACK" = "x1" ; then
1229    ENABLE_JACK=yes
1230 fi
1231
1232 ENABLE_LIBASYNCNS=no
1233 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
1234    ENABLE_LIBASYNCNS=yes
1235 fi
1236
1237 ENABLE_LIRC=no
1238 if test "x$HAVE_LIRC" = "x1" ; then
1239    ENABLE_LIRC=yes
1240 fi
1241
1242 ENABLE_HAL=no
1243 if test "x$HAVE_HAL" = "x1" ; then
1244    ENABLE_HAL=yes
1245 fi
1246
1247 ENABLE_TCPWRAP=no
1248 if test "x${LIBWRAP_LIBS}" != x ; then
1249    ENABLE_TCPWRAP=yes
1250 fi
1251
1252 ENABLE_LIBSAMPLERATE=no
1253 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
1254    ENABLE_LIBSAMPLERATE=yes
1255 fi
1256
1257 ENABLE_BLUEZ=no
1258 if test "x${HAVE_BLUEZ}" = "x1" ; then
1259    ENABLE_BLUEZ=yes
1260 fi
1261
1262 ENABLE_POLKIT=no
1263 if test "x${HAVE_POLKIT}" = "x1" ; then
1264    ENABLE_POLKIT=yes
1265 fi
1266
1267 ENABLE_OPENSSL=no
1268 if test "x${HAVE_OPENSSL}" = "x1" ; then
1269    ENABLE_OPENSSL=yes
1270 fi
1271
1272 ENABLE_PER_USER_ESOUND_SOCKET=no
1273 if test "x$per_user_esound_socket" = "x1" ; then
1274    ENABLE_PER_USER_ESOUND_SOCKET=yes
1275 fi
1276
1277 echo "
1278  ---{ $PACKAGE_NAME $VERSION }---
1279
1280     prefix:                        ${prefix}
1281     sysconfdir:                    ${sysconfdir}
1282     localstatedir:                 ${localstatedir}
1283     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1284     System State Path:             ${PA_SYSTEM_STATE_PATH}
1285     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1286     Compiler:                      ${CC}
1287     CFLAGS:                        ${CFLAGS}
1288
1289     Have X11:                      ${ENABLE_X11}
1290     Enable OSS:                    ${ENABLE_OSS}
1291     Enable Alsa:                   ${ENABLE_ALSA}
1292     Enable Solaris:                ${ENABLE_SOLARIS}
1293     Enable GLib 2.0:               ${ENABLE_GLIB20}
1294     Enable GConf:                  ${ENABLE_GCONF}
1295     Enable Avahi:                  ${ENABLE_AVAHI}
1296     Enable Jack:                   ${ENABLE_JACK}
1297     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1298     Enable LIRC:                   ${ENABLE_LIRC}
1299     Enable HAL:                    ${ENABLE_HAL}
1300     Enable BlueZ:                  ${ENABLE_BLUEZ}
1301     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1302     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1303     Enable PolicyKit:              ${ENABLE_POLKIT}
1304     Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1305
1306     System User:                   ${PA_SYSTEM_USER}
1307     System Group:                  ${PA_SYSTEM_GROUP}
1308     Realtime Group:                ${PA_REALTIME_GROUP}
1309     Access Group:                  ${PA_ACCESS_GROUP}
1310     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1311     Force preopen:                 ${FORCE_PREOPEN}
1312     Preopened modules:             ${PREOPEN_MODS}
1313 "