code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23
  24 m4_define(PA_MAJOR, [0])
  25 m4_define(PA_MINOR, [9])
  26 m4_define(PA_MICRO, [0])
  27
  28 AC_INIT([polypaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  29 AC_CONFIG_SRCDIR([src/daemon/main.c])
  30 AC_CONFIG_HEADERS([config.h])
  31 AM_INIT_AUTOMAKE([foreign -Wall])
  32
  33 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  34 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  35
  36 AC_SUBST(PA_API_VERSION, 9)
  37 AC_SUBST(PA_PROTOCOL_VERSION, 9)
  38
  39 AC_SUBST(LIBPOLYP_VERSION_INFO, [0:0:0])
  40 AC_SUBST(LIBPOLYPCORE_VERSION_INFO, [0:0:0])
  41 AC_SUBST(LIBPOLYP_SIMPLE_VERSION_INFO, [0:0:0])
  42 AC_SUBST(LIBPOLYP_BROWSE_VERSION_INFO, [0:0:0])
  43 AC_SUBST(LIBPOLYP_MAINLOOP_GLIB_VERSION_INFO, [0:0:0])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 #### Platform hacks ####
  51
  52 case $host in
  53    *-*-solaris* )
  54       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  55       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  56       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  57       ;;
  58 esac
  59
  60 #### Checks for programs. ####
  61
  62 # CC
  63
  64 AC_PROG_CC
  65 AC_PROG_GCC_TRADITIONAL
  66 AC_GNU_SOURCE
  67
  68 # M4
  69
  70 AC_PATH_PROG([M4], [m4 gm4], [no])
  71 if test "x$M4" = xno ; then
  72    AC_MSG_ERROR([m4 missing])
  73 fi
  74
  75 # GCC flags
  76
  77 test_gcc_flag() {
  78     AC_LANG_CONFTEST([int main() {}])
  79     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  80     ret=$?
  81     rm -f conftest.o
  82     return $ret
  83 }
  84
  85 # If using GCC specify some additional parameters
  86 if test "x$GCC" = "xyes" ; then
  87
  88     # We use gnu99 instead of c99 because many have interpreted the standard
  89     # in a way that int64_t isn't defined on non-64 bit platforms.
  90     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  91
  92     for flag in $DESIRED_FLAGS ; do
  93         AC_MSG_CHECKING([whether $CC accepts $flag])
  94         if test_gcc_flag $flag ; then
  95            CFLAGS="$CFLAGS $flag"
  96            AC_MSG_RESULT([yes])
  97         else
  98            AC_MSG_RESULT([no])
  99         fi
 100     done
 101 fi
 102
 103 # LYNX documentation generation
 104 AC_ARG_ENABLE(lynx,
 105         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
 106 [case "${enableval}" in
 107   yes) lynx=yes ;;
 108   no)  lynx=no ;;
 109   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
 110 esac],[lynx=yes])
 111
 112 if test x$lynx = xyes ; then
 113    AC_CHECK_PROG(have_lynx, lynx, yes, no)
 114
 115    if test x$have_lynx = xno ; then
 116      AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
 117    fi
 118 fi
 119
 120 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
 121
 122 #### libtool stuff ####
 123
 124 AC_LTDL_ENABLE_INSTALL
 125 AC_LIBLTDL_INSTALLABLE
 126 AC_SUBST(LTDLINCL)
 127 AC_SUBST(LIBLTDL)
 128 AC_LIBTOOL_DLOPEN
 129 AC_LIBTOOL_WIN32_DLL
 130 AC_PROG_LIBTOOL
 131 AC_CONFIG_SUBDIRS(libltdl)
 132
 133 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 134     AC_MSG_ERROR([[
 135
 136         *** Cannot find the libltdl development files.
 137         *** Maybe you need to install the libltdl-dev package.
 138         ]])
 139 fi
 140
 141 #### Determine build environment ####
 142
 143 os_is_win32=0
 144
 145 case "$host_os" in
 146         mingw*)
 147         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 148         os_is_win32=1
 149                 ;;
 150         esac
 151
 152 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 153
 154 ###################################
 155 #   Basic environment checks      #
 156 ###################################
 157
 158 #### Checks for header files. ####
 159
 160 # ISO
 161 AC_HEADER_STDC
 162
 163 # POSIX
 164 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h iconv.h netdb.h netinet/in.h \
 165     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 166     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 167     syslog.h])
 168 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 169 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 170
 171 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 172 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 173
 174 # XPG4-UNIX
 175 AC_CHECK_HEADERS([sys/poll.h])
 176
 177 # Linux
 178 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 179
 180 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 181
 182 # Solaris
 183 AC_CHECK_HEADERS([sys/filio.h])
 184
 185 # Windows
 186 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 187
 188 # Other
 189 AC_CHECK_HEADERS([sys/ioctl.h])
 190
 191 #### Typdefs, structures, etc. ####
 192
 193 AC_C_CONST
 194 AC_C_BIGENDIAN
 195 AC_TYPE_PID_T
 196 AC_TYPE_SIZE_T
 197 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 198     [Define ssize_t if it is not done by the standard libs.])])
 199 AC_TYPE_OFF_T
 200 AC_TYPE_SIGNAL
 201 AC_TYPE_UID_T
 202
 203 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 204 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 205
 206 # Solaris lacks this
 207 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 208     [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])
 209
 210 #### Check for libs ####
 211
 212 # ISO
 213 AC_SEARCH_LIBS([pow], [m])
 214
 215 # POSIX
 216 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 217 AC_SEARCH_LIBS([dlopen], [dl])
 218
 219 # BSD
 220 AC_SEARCH_LIBS([connect], [socket])
 221
 222 # Non-standard
 223
 224 # This magic is needed so we do not needlessly add static libs to the win32
 225 # build, disabling its ability to make dlls.
 226 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 227
 228 #### Check for functions ####
 229
 230 # POSIX
 231 AC_FUNC_FORK
 232 AC_FUNC_GETGROUPS
 233 AC_FUNC_SELECT_ARGTYPES
 234 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 235     getuid inet_ntop inet_pton nanosleep pipe setpgid setsid sigaction sleep])
 236 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 237
 238 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 239
 240 # X/OPEN
 241 AC_CHECK_FUNCS([readlink])
 242
 243 # SUSv2
 244 AC_CHECK_FUNCS([ctime_r usleep])
 245
 246 # SUSv3
 247 AC_CHECK_FUNCS([strerror_r])
 248
 249 # BSD
 250 AC_CHECK_FUNCS([lstat])
 251
 252 # Non-standard
 253
 254 AC_CHECK_FUNCS(setresuid)
 255 AC_CHECK_FUNCS(setreuid)
 256
 257 #### POSIX threads ####
 258
 259 ACX_PTHREAD
 260
 261 #### Large File-Support (LFS) ####
 262
 263 AC_SYS_LARGEFILE
 264
 265 ###################################
 266 #      External libraries         #
 267 ###################################
 268
 269 #### X11 (optional) ####
 270
 271 HAVE_X11=0
 272
 273 # The macro tests the host, not the build target
 274 if test "x$os_is_win32" != "x1" ; then
 275     AC_PATH_XTRA
 276     test "x$no_x" != "xyes" && HAVE_X11=1
 277 fi
 278
 279 AC_SUBST(HAVE_X11)
 280 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 281 if test "x$HAVE_X11" = "x1" ; then
 282     AC_DEFINE([HAVE_X11], 1, [Have X11])
 283 fi
 284
 285 #### Capabilities (optional) ####
 286
 287 CAP_LIBS=''
 288
 289 AC_ARG_WITH(
 290         [caps],
 291         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 292
 293 if test "x${with_caps}" != "xno"; then
 294     AC_SEARCH_LIBS([cap_init], [cap])
 295     AC_CHECK_HEADERS([sys/capability.h])
 296 fi
 297
 298 #### pkg-config ####
 299
 300 # Check for pkg-config manually first, as if its not installed the
 301 # PKG_PROG_PKG_CONFIG macro won't be defined.
 302 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 303
 304 if test x"$have_pkg_config" = "xno"; then
 305     AC_MSG_ERROR(pkg-config is required to install this program)
 306 fi
 307
 308 PKG_PROG_PKG_CONFIG
 309
 310 #### Sample rate conversion ####
 311
 312 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 313 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 314 AC_SUBST(LIBSAMPLERATE_LIBS)
 315
 316 #### Sound file ####
 317
 318 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 319 AC_SUBST(LIBSNDFILE_CFLAGS)
 320 AC_SUBST(LIBSNDFILE_LIBS)
 321
 322 #### OSS support (optional) ####
 323
 324 AC_CHECK_HEADERS([sys/soundcard.h], [
 325 HAVE_OSS=1
 326 AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 327 ], [HAVE_OSS=0])
 328 AC_SUBST(HAVE_OSS)
 329 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 330
 331
 332 #### ALSA support (optional) ####
 333
 334 PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [
 335 HAVE_ALSA=1
 336 AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 337 ], [HAVE_ALSA=0])
 338 AC_SUBST(ASOUNDLIB_CFLAGS)
 339 AC_SUBST(ASOUNDLIB_LIBS)
 340 AC_SUBST(HAVE_ALSA)
 341 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 342
 343 #### Solaris audio support (optional) ####
 344
 345 AC_CHECK_HEADERS([sys/audio.h], [
 346 HAVE_SOLARIS=1
 347 AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 348 ], [HAVE_SOLARIS=0])
 349 AC_SUBST(HAVE_SOLARIS)
 350 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 351
 352 #### GLib 2 support (optional) ####
 353
 354 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)
 355 AC_SUBST(GLIB20_CFLAGS)
 356 AC_SUBST(GLIB20_LIBS)
 357 AC_SUBST(HAVE_GLIB20)
 358 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 359
 360 #### GLib 1 support (optional) ####
 361
 362 PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, HAVE_GLIB12=0)
 363 AC_SUBST(GLIB12_CFLAGS)
 364 AC_SUBST(GLIB12_LIBS)
 365 AC_SUBST(HAVE_GLIB12)
 366 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 367
 368 #### Howl support (optional) ####
 369
 370 PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, HAVE_HOWL=0)
 371 AC_SUBST(HOWL_CFLAGS)
 372 AC_SUBST(HOWL_LIBS)
 373 AC_SUBST(HAVE_HOWL)
 374 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 375
 376 ### LIBOIL ####
 377
 378 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 379 AC_SUBST(LIBOIL_CFLAGS)
 380 AC_SUBST(LIBOIL_LIBS)
 381
 382 ### JACK (optional) ####
 383
 384 PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ], HAVE_JACK=1, HAVE_JACK=0)
 385 AC_SUBST(JACK_CFLAGS)
 386 AC_SUBST(JACK_LIBS)
 387 AC_SUBST(HAVE_JACK)
 388 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 389
 390 #### Async DNS support (optional) ####
 391
 392 PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)
 393 AC_SUBST(LIBASYNCNS_CFLAGS)
 394 AC_SUBST(LIBASYNCNS_LIBS)
 395 AC_SUBST(HAVE_LIBASYNCNS)
 396 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 397
 398 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 399    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 400 fi
 401
 402 #### TCP wrappers (optional) ####
 403
 404 ACX_LIBWRAP
 405 AC_SUBST(LIBWRAP_LIBS)
 406
 407 #### LIRC support (optional) ####
 408
 409 ACX_LIRC
 410 AC_SUBST(LIRC_CFLAGS)
 411 AC_SUBST(LIRC_LIBS)
 412 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 413
 414 ###################################
 415 #            Output               #
 416 ###################################
 417
 418 AC_ARG_ENABLE(
 419         [static-bins],
 420         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 421         [STATIC_BINS=1], [STATIC_BINS=0])
 422 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 423
 424 AC_ARG_WITH(
 425         [preopen-mods],
 426         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 427         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 428 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 429 if test "x$PREOPEN_MODS" != "xall" ; then
 430     tmpLIBS=""
 431     for mod in $PREOPEN_MODS; do
 432         tmpLIBS="$tmpLIBS module-$mod.la"
 433     done
 434     PREOPEN_MODS="$tmpLIBS"
 435     AC_SUBST(PREOPEN_MODS)
 436 fi
 437
 438 AC_ARG_WITH(
 439         [module-dir],
 440         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/polypaudio-${PA_MAJORMINOR}/modules/]),
 441         [modlibexecdir=$withval], [modlibexecdir="${libdir}/polypaudio-${PA_MAJORMINOR}/modules/"])
 442
 443 AC_SUBST(modlibexecdir)
 444
 445 AC_ARG_ENABLE(
 446         [force-preopen],
 447         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 448         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 449 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 450
 451 AC_CONFIG_FILES([
 452 Makefile
 453 src/Makefile
 454 polyplib.pc
 455 polyplib-simple.pc
 456 polyplib-browse.pc
 457 polyplib-glib-mainloop.pc
 458 polyplib-glib12-mainloop.pc
 459 doc/Makefile
 460 doc/README.html
 461 doc/cli.html
 462 doc/daemon.html
 463 doc/modules.html
 464 doxygen/Makefile
 465 doxygen/doxygen.conf
 466 src/polyp/version.h
 467 doc/FAQ.html
 468 ])
 469 AC_OUTPUT