code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of PulseAudio.
   7 #
   8 # PulseAudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # PulseAudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with PulseAudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23
  24 m4_define(PA_MAJOR, [0])
  25 m4_define(PA_MINOR, [9])
  26 m4_define(PA_MICRO, [2])
  27
  28 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  29 AC_CONFIG_SRCDIR([src/daemon/main.c])
  30 AC_CONFIG_HEADERS([config.h])
  31 AM_INIT_AUTOMAKE([foreign -Wall])
  32
  33 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  34 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/pulseaudio/])
  35
  36 AC_SUBST(PA_API_VERSION, 9)
  37 AC_SUBST(PA_PROTOCOL_VERSION, 9)
  38
  39 AC_SUBST(LIBPULSE_VERSION_INFO, [0:0:0])
  40 AC_SUBST(LIBPULSECORE_VERSION_INFO, [0:1:0])
  41 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:0:0])
  42 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [0:0:0])
  43 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:0:0])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 #### Platform hacks ####
  51
  52 case $host in
  53    *-*-solaris* )
  54       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  55       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  56       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  57       ;;
  58 esac
  59
  60 #### Checks for programs. ####
  61
  62 # CC
  63
  64 AC_PROG_CC
  65 AC_PROG_GCC_TRADITIONAL
  66 AC_GNU_SOURCE
  67
  68 # M4
  69
  70 AC_PATH_PROG([M4], [m4 gm4], [no])
  71 if test "x$M4" = xno ; then
  72    AC_MSG_ERROR([m4 missing])
  73 fi
  74
  75 # GCC flags
  76
  77 test_gcc_flag() {
  78     AC_LANG_CONFTEST([int main() {}])
  79     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  80     ret=$?
  81     rm -f conftest.o
  82     return $ret
  83 }
  84
  85 # If using GCC specify some additional parameters
  86 if test "x$GCC" = "xyes" ; then
  87
  88     # We use gnu99 instead of c99 because many have interpreted the standard
  89     # in a way that int64_t isn't defined on non-64 bit platforms.
  90     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  91
  92     for flag in $DESIRED_FLAGS ; do
  93         AC_MSG_CHECKING([whether $CC accepts $flag])
  94         if test_gcc_flag $flag ; then
  95            CFLAGS="$CFLAGS $flag"
  96            AC_MSG_RESULT([yes])
  97         else
  98            AC_MSG_RESULT([no])
  99         fi
 100     done
 101 fi
 102
 103 #### libtool stuff ####
 104
 105 AC_LTDL_ENABLE_INSTALL
 106 AC_LIBLTDL_INSTALLABLE
 107 AC_SUBST(LTDLINCL)
 108 AC_SUBST(LIBLTDL)
 109 AC_LIBTOOL_DLOPEN
 110 AC_LIBTOOL_WIN32_DLL
 111 AC_PROG_LIBTOOL
 112 AC_CONFIG_SUBDIRS(libltdl)
 113
 114 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 115     AC_MSG_ERROR([[
 116
 117         *** Cannot find the libltdl development files.
 118         *** Maybe you need to install the libltdl-dev package.
 119         ]])
 120 fi
 121
 122 #### Determine build environment ####
 123
 124 os_is_win32=0
 125
 126 case "$host_os" in
 127         mingw*)
 128         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 129         os_is_win32=1
 130                 ;;
 131         esac
 132
 133 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 134
 135 ###################################
 136 #   Basic environment checks      #
 137 ###################################
 138
 139 #### Checks for header files. ####
 140
 141 # ISO
 142 AC_HEADER_STDC
 143
 144 # POSIX
 145 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 146     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 147     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 148     syslog.h])
 149 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 150 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 151
 152 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 153 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 154
 155 # XPG4-UNIX
 156 AC_CHECK_HEADERS([sys/poll.h])
 157
 158 # Linux
 159 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 160
 161 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 162
 163 AC_CHECK_HEADERS([sys/prctl.h])
 164
 165 # Solaris
 166 AC_CHECK_HEADERS([sys/filio.h])
 167
 168 # Windows
 169 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 170
 171 # Other
 172 AC_CHECK_HEADERS([sys/ioctl.h])
 173
 174 #### Typdefs, structures, etc. ####
 175
 176 AC_C_CONST
 177 AC_C_BIGENDIAN
 178 AC_TYPE_PID_T
 179 AC_TYPE_SIZE_T
 180 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 181     [Define ssize_t if it is not done by the standard libs.])])
 182 AC_TYPE_OFF_T
 183 AC_TYPE_SIGNAL
 184 AC_TYPE_UID_T
 185
 186 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 187 HAVE_SIGXCPU=1
 188 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 189 ], [HAVE_SIGXCPU=0])
 190 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 191
 192 # Solaris lacks this
 193 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 194     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 195         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 196
 197 #### Check for libs ####
 198
 199 # ISO
 200 AC_SEARCH_LIBS([pow], [m])
 201
 202 # POSIX
 203 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 204 AC_SEARCH_LIBS([dlopen], [dl])
 205
 206 # BSD
 207 AC_SEARCH_LIBS([connect], [socket])
 208
 209 # Non-standard
 210
 211 # This magic is needed so we do not needlessly add static libs to the win32
 212 # build, disabling its ability to make dlls.
 213 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 214
 215 #### Check for functions ####
 216
 217 # POSIX
 218 AC_FUNC_FORK
 219 AC_FUNC_GETGROUPS
 220 AC_FUNC_SELECT_ARGTYPES
 221 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 222     getuid inet_ntop inet_pton nanosleep pipe setpgid setsid sigaction sleep])
 223 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 224
 225 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 226
 227 # X/OPEN
 228 AC_CHECK_FUNCS([readlink])
 229
 230 # SUSv2
 231 AC_CHECK_FUNCS([ctime_r usleep])
 232
 233 # SUSv3
 234 AC_CHECK_FUNCS([strerror_r])
 235
 236 # BSD
 237 AC_CHECK_FUNCS([lstat])
 238
 239 # Non-standard
 240
 241 AC_CHECK_FUNCS(setresuid)
 242 AC_CHECK_FUNCS(setreuid)
 243
 244 #### POSIX threads ####
 245
 246 ACX_PTHREAD
 247
 248 #### Large File-Support (LFS) ####
 249
 250 AC_SYS_LARGEFILE
 251
 252 # Check for open64 to know if the current system does have open64() and similar functions
 253 AC_CHECK_FUNCS([open64])
 254
 255 #### [lib]iconv ####
 256
 257 AM_ICONV
 258
 259 ###################################
 260 #      External libraries         #
 261 ###################################
 262
 263 #### X11 (optional) ####
 264
 265 HAVE_X11=0
 266
 267 # The macro tests the host, not the build target
 268 if test "x$os_is_win32" != "x1" ; then
 269     AC_PATH_XTRA
 270     test "x$no_x" != "xyes" && HAVE_X11=1
 271 fi
 272
 273 AC_SUBST(HAVE_X11)
 274 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 275 if test "x$HAVE_X11" = "x1" ; then
 276     AC_DEFINE([HAVE_X11], 1, [Have X11])
 277 fi
 278
 279 #### Capabilities (optional) ####
 280
 281 CAP_LIBS=''
 282
 283 AC_ARG_WITH(
 284         [caps],
 285         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 286
 287 if test "x${with_caps}" != "xno"; then
 288     AC_SEARCH_LIBS([cap_init], [cap], [], [
 289                     if test "x${with_caps}" = "xyes" ; then
 290                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 291                     fi])
 292     AC_CHECK_HEADERS([sys/capability.h], [], [
 293                     if test "x${with_caps}" = "xyes" ; then
 294                         AC_MSG_ERROR([*** POSIX caps headers not found])
 295                     fi])
 296 fi
 297
 298 #### pkg-config ####
 299
 300 # Check for pkg-config manually first, as if its not installed the
 301 # PKG_PROG_PKG_CONFIG macro won't be defined.
 302 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 303
 304 if test x"$have_pkg_config" = "xno"; then
 305     AC_MSG_ERROR(pkg-config is required to install this program)
 306 fi
 307
 308 PKG_PROG_PKG_CONFIG
 309
 310 #### Sample rate conversion ####
 311
 312 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 313 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 314 AC_SUBST(LIBSAMPLERATE_LIBS)
 315
 316 #### Sound file ####
 317
 318 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 319 AC_SUBST(LIBSNDFILE_CFLAGS)
 320 AC_SUBST(LIBSNDFILE_LIBS)
 321
 322 #### OSS support (optional) ####
 323
 324 AC_ARG_ENABLE([oss],
 325     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 326         [
 327             case "${enableval}" in
 328                 yes) oss=yes ;;
 329                 no) oss=no ;;
 330                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 331             esac
 332         ],
 333         [oss=auto])
 334
 335 if test "x${oss}" != xno ; then
 336     AC_CHECK_HEADERS([sys/soundcard.h],
 337         [
 338             HAVE_OSS=1
 339             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 340         ],
 341         [
 342             HAVE_OSS=0
 343             if test "x$oss" = xyes ; then
 344                 AC_MSG_ERROR([*** OSS support not found])
 345             fi
 346         ])
 347 else
 348     HAVE_OSS=0
 349 fi
 350
 351 AC_SUBST(HAVE_OSS)
 352 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 353
 354
 355 #### ALSA support (optional) ####
 356
 357 AC_ARG_ENABLE([alsa],
 358     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 359         [
 360             case "${enableval}" in
 361                 yes) alsa=yes ;;
 362                 no) alsa=no ;;
 363                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 364             esac
 365         ],
 366         [alsa=auto])
 367
 368 if test "x${alsa}" != xno ; then
 369     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ],
 370         [
 371             HAVE_ALSA=1
 372             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 373         ],
 374         [
 375             HAVE_ALSA=0
 376             if test "x$alsa" = xyes ; then
 377                 AC_MSG_ERROR([*** ALSA support not found])
 378             fi
 379         ])
 380 else
 381     HAVE_ALSA=0
 382 fi
 383
 384 AC_SUBST(ASOUNDLIB_CFLAGS)
 385 AC_SUBST(ASOUNDLIB_LIBS)
 386 AC_SUBST(HAVE_ALSA)
 387 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 388
 389 #### Solaris audio support (optional) ####
 390
 391 AC_ARG_ENABLE([solaris],
 392     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 393         [
 394             case "${enableval}" in
 395                 yes) solaris=yes ;;
 396                 no) solaris=no ;;
 397                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 398             esac
 399         ],
 400         [solaris=auto])
 401
 402 if test "x${solaris}" != xno ; then
 403     AC_CHECK_HEADERS([sys/audio.h],
 404         [
 405             HAVE_SOLARIS=1
 406             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 407         ],
 408         [
 409             HAVE_SOLARIS=0
 410             if test "x$solaris" = xyes ; then
 411                 AC_MSG_ERROR([*** Solaris audio support not found])
 412             fi
 413         ])
 414 else
 415     HAVE_SOLARIS=0
 416 fi
 417
 418 AC_SUBST(HAVE_SOLARIS)
 419 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 420
 421 #### GLib 2 support (optional) ####
 422
 423 AC_ARG_ENABLE([glib2],
 424     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 425         [
 426             case "${enableval}" in
 427                 yes) glib2=yes ;;
 428                 no) glib2=no ;;
 429                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 430             esac
 431         ],
 432         [glib2=auto])
 433
 434 if test "x${glib2}" != xno ; then
 435     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 436         HAVE_GLIB20=1,
 437         [
 438             HAVE_GLIB20=0
 439             if test "x$glib2" = xyes ; then
 440                 AC_MSG_ERROR([*** GLib 2 support not found])
 441             fi
 442         ])
 443 else
 444     HAVE_GLIB20=0
 445 fi
 446
 447 AC_SUBST(GLIB20_CFLAGS)
 448 AC_SUBST(GLIB20_LIBS)
 449 AC_SUBST(HAVE_GLIB20)
 450 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 451
 452 #### GLib 1 support (optional) ####
 453
 454 AC_ARG_ENABLE([glib1],
 455     AC_HELP_STRING([--disable-glib1], [Disable optional GLib 1 support]),
 456         [
 457             case "${enableval}" in
 458                 yes) glib1=yes ;;
 459                 no) glib1=no ;;
 460                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib1) ;;
 461             esac
 462         ],
 463         [glib1=auto])
 464
 465 if test "x${glib1}" != xno ; then
 466     PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ],
 467         HAVE_GLIB12=1,
 468         [
 469             HAVE_GLIB12=0
 470             if test "x$glib1" = xyes ; then
 471                 AC_MSG_ERROR([*** GLib 1 support not found])
 472             fi
 473         ])
 474 else
 475     HAVE_GLIB12=0
 476 fi
 477
 478 AC_SUBST(GLIB12_CFLAGS)
 479 AC_SUBST(GLIB12_LIBS)
 480 AC_SUBST(HAVE_GLIB12)
 481 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 482
 483 #### Avahi support (optional) ####
 484
 485 AC_ARG_ENABLE([avahi],
 486     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 487         [
 488             case "${enableval}" in
 489                 yes) avahi=yes ;;
 490                 no) avahi=no ;;
 491                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 492             esac
 493         ],
 494         [avahi=auto])
 495
 496 if test "x${avahi}" != xno ; then
 497     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 498         HAVE_AVAHI=1,
 499         [
 500                 HAVE_AVAHI=0
 501                 if test "x$avahi" = xyes ; then
 502                         AC_MSG_ERROR([*** Avahi support not found])
 503                 fi
 504         ])
 505 else
 506     HAVE_AVAHI=0
 507 fi
 508
 509 AC_SUBST(AVAHI_CFLAGS)
 510 AC_SUBST(AVAHI_LIBS)
 511 AC_SUBST(HAVE_AVAHI)
 512 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 513
 514 ### LIBOIL ####
 515
 516 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 517 AC_SUBST(LIBOIL_CFLAGS)
 518 AC_SUBST(LIBOIL_LIBS)
 519
 520 ### JACK (optional) ####
 521
 522 AC_ARG_ENABLE([jack],
 523     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 524         [
 525             case "${enableval}" in
 526                 yes) jack=yes ;;
 527                 no) jack=no ;;
 528                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 529             esac
 530         ],
 531         [jack=auto])
 532
 533 if test "x${jack}" != xno ; then
 534     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 535         HAVE_JACK=1,
 536         [
 537             HAVE_JACK=0
 538             if test "x$jack" = xyes ; then
 539                 AC_MSG_ERROR([*** JACK support not found])
 540             fi
 541         ])
 542 else
 543     HAVE_JACK=0
 544 fi
 545
 546 AC_SUBST(JACK_CFLAGS)
 547 AC_SUBST(JACK_LIBS)
 548 AC_SUBST(HAVE_JACK)
 549 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 550
 551 #### Async DNS support (optional) ####
 552
 553 AC_ARG_ENABLE([asyncns],
 554     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 555         [
 556             case "${enableval}" in
 557                 yes) asyncns=yes ;;
 558                 no) asyncns=no ;;
 559                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 560             esac
 561         ],
 562         [asyncns=auto])
 563
 564 if test "x${asyncns}" != xno ; then
 565     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 566         HAVE_LIBASYNCNS=1,
 567         [
 568             HAVE_LIBASYNCNS=0
 569             if test "x$asyncns" = xyes ; then
 570                 AC_MSG_ERROR([*** Async DNS support not found])
 571             fi
 572         ])
 573 else
 574     HAVE_LIBASYNCNS=0
 575 fi
 576
 577 AC_SUBST(LIBASYNCNS_CFLAGS)
 578 AC_SUBST(LIBASYNCNS_LIBS)
 579 AC_SUBST(HAVE_LIBASYNCNS)
 580 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 581
 582 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 583    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 584 fi
 585
 586 #### TCP wrappers (optional) ####
 587
 588 AC_ARG_ENABLE([tcpwrap],
 589     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 590         [
 591             case "${enableval}" in
 592                 yes) tcpwrap=yes ;;
 593                 no) tcpwrap=no ;;
 594                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 595             esac
 596         ],
 597         [tcpwrap=auto])
 598
 599 if test "x${tcpwrap}" != xno ; then
 600     ACX_LIBWRAP
 601     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 602         AC_MSG_ERROR([*** TCP wrappers support not found])
 603     fi
 604 else
 605     LIBWRAP_LIBS=
 606 fi
 607
 608 AC_SUBST(LIBWRAP_LIBS)
 609
 610 #### LIRC support (optional) ####
 611
 612 AC_ARG_ENABLE([lirc],
 613     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 614         [
 615             case "${enableval}" in
 616                 yes) lirc=yes ;;
 617                 no) lirc=no ;;
 618                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 619             esac
 620         ],
 621         [lirc=auto])
 622
 623 if test "x${lirc}" != xno ; then
 624     ACX_LIRC
 625     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 626         AC_MSG_ERROR([*** LIRC support not found])
 627     fi
 628 else
 629     HAVE_LIRC=0
 630 fi
 631
 632 AC_SUBST(LIRC_CFLAGS)
 633 AC_SUBST(LIRC_LIBS)
 634 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 635
 636 ###################################
 637 #            Output               #
 638 ###################################
 639
 640 AC_ARG_ENABLE(
 641         [static-bins],
 642         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 643         [STATIC_BINS=1], [STATIC_BINS=0])
 644 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 645
 646 AC_ARG_WITH(
 647         [preopen-mods],
 648         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 649         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 650 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 651 if test "x$PREOPEN_MODS" != "xall" ; then
 652     tmpLIBS=""
 653     for mod in $PREOPEN_MODS; do
 654         tmpLIBS="$tmpLIBS module-$mod.la"
 655     done
 656     PREOPEN_MODS="$tmpLIBS"
 657     AC_SUBST(PREOPEN_MODS)
 658 fi
 659
 660 AC_ARG_WITH(
 661         [module-dir],
 662         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
 663         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
 664
 665 AC_SUBST(modlibexecdir)
 666
 667 AC_ARG_ENABLE(
 668         [force-preopen],
 669         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 670         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 671 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 672
 673 AC_CONFIG_FILES([
 674 Makefile
 675 src/Makefile
 676 libpulse.pc
 677 libpulse-simple.pc
 678 libpulse-browse.pc
 679 libpulse-mainloop-glib.pc
 680 libpulse-mainloop-glib12.pc
 681 doxygen/Makefile
 682 doxygen/doxygen.conf
 683 src/pulse/version.h
 684 ])
 685 AC_OUTPUT
 686
 687 # ==========================================================================
 688 ENABLE_X11=no
 689 if test "x$HAVE_X11" = "x1" ; then
 690    ENABLE_X11=yes
 691 fi
 692
 693 ENABLE_OSS=no
 694 if test "x$HAVE_OSS" = "x1" ; then
 695    ENABLE_OSS=yes
 696 fi
 697
 698 ENABLE_ALSA=no
 699 if test "x$HAVE_ALSA" = "x1" ; then
 700    ENABLE_ALSA=yes
 701 fi
 702
 703 ENABLE_SOLARIS=no
 704 if test "x$HAVE_SOLARIS" = "x1" ; then
 705    ENABLE_SOLARIS=yes
 706 fi
 707
 708 ENABLE_GLIB20=no
 709 if test "x$HAVE_GLIB20" = "x1" ; then
 710    ENABLE_GLIB20=yes
 711 fi
 712
 713 ENABLE_GLIB12=no
 714 if test "x$HAVE_GLIB12" = "x1" ; then
 715    ENABLE_GLIB12=yes
 716 fi
 717
 718 ENABLE_AVAHI=no
 719 if test "x$HAVE_AVAHI" = "x1" ; then
 720    ENABLE_AVAHI=yes
 721 fi
 722
 723 ENABLE_JACK=no
 724 if test "x$HAVE_JACK" = "x1" ; then
 725    ENABLE_JACK=yes
 726 fi
 727
 728 ENABLE_LIBASYNCNS=no
 729 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
 730    ENABLE_LIBASYNCNS=yes
 731 fi
 732
 733 ENABLE_LIRC=no
 734 if test "x$HAVE_LIRC" = "x1" ; then
 735    ENABLE_LIRC=yes
 736 fi
 737
 738 ENABLE_TCPWRAP=no
 739 if test "x${LIBWRAP_LIBS}" != x ; then
 740    ENABLE_TCPWRAP=yes
 741 fi
 742
 743 echo "
 744  ---{ $PACKAGE_NAME $VERSION }---
 745
 746     prefix:                 ${prefix}
 747     sysconfdir:             ${sysconfdir}
 748     localstatedir:          ${localstatedir}
 749     compiler:               ${CC}
 750     cflags:                 ${CFLAGS}
 751     Have X11:               ${ENABLE_X11}
 752     Enable OSS:             ${ENABLE_OSS}
 753     Enable Alsa:            ${ENABLE_ALSA}
 754     Enable Solaris:         ${ENABLE_SOLARIS}
 755     Enable Glib 2.0:        ${ENABLE_GLIB20}
 756     Enable Glib 1.2:        ${ENABLE_GLIB12}
 757     Enable Avahi:           ${ENABLE_AVAHI}
 758     Enable Jack:            ${ENABLE_JACK}
 759     Enable Async DNS:       ${ENABLE_LIBASYNCNS}
 760     Enable LIRC:            ${ENABLE_LIRC}
 761     Enable TCP Wrappers:    ${ENABLE_TCPWRAP}
 762 "