]> code.delx.au - pulseaudio/blob - configure.ac
delx.au / code / pulseaudio / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
build-sys: Remove unnecessary AC_SUBST calls
[pulseaudio] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4 # This file is part of PulseAudio.
5 #
6 # Copyright 2004-2008 Lennart Poettering
7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
8 #
9 # PulseAudio is free software; you can redistribute it and/or modify it
10 # under the terms of the GNU Lesser General Public License as published by
11 # the Free Software Foundation; either version 2 of the License, or
12 # (at your option) any later version.
13 #
14 # PulseAudio is distributed in the hope that it will be useful, but
15 # WITHOUT ANY WARRANTY; without even the implied warranty of
16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
17 # General Public License for more details.
18 #
19 # You should have received a copy of the GNU Lesser General Public License
20 # along with PulseAudio; if not, write to the Free Software Foundation,
21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
22
23 AC_PREREQ(2.63)
24
25 AC_INIT([pulseaudio],[m4_esyscmd(./git-version-gen .tarball-version)],[mzchyfrnhqvb (at) 0pointer (dot) net])
26 AC_CONFIG_SRCDIR([src/daemon/main.c])
27 AC_CONFIG_MACRO_DIR([m4])
28 AC_CONFIG_HEADERS([config.h])
29 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax])
30
31 m4_define(pa_major, `echo $VERSION | cut -d. -f1 | cut -d- -f1`)
32 m4_define(pa_minor, `echo $VERSION | cut -d. -f2 | cut -d- -f1`)
33
34 AC_SUBST(PA_MAJOR, pa_major)
35 AC_SUBST(PA_MINOR, pa_minor)
36 AC_SUBST(PA_MAJORMINOR, pa_major.pa_minor)
37 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
38
39 AC_SUBST(PA_API_VERSION, 12)
40 AC_SUBST(PA_PROTOCOL_VERSION, 21)
41
42 # The stable ABI for client applications, for the version info x:y:z
43 # always will hold y=z
44 AC_SUBST(LIBPULSE_VERSION_INFO, [12:3:12])
45
46 # A simplified, synchronous, ABI-stable interface for client
47 # applications, for the version info x:y:z always will hold y=z
48 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:3:0])
49
50 # The ABI-stable network browsing interface for client applications,
51 # for the version info x:y:z always will hold y=z
52 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
53
54 # The ABI-stable GLib adapter for client applications, for the version
55 # info x:y:z always will hold y=z
56 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:4:0])
57
58 AC_CANONICAL_HOST
59 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
60
61 AC_CHECK_PROG([STOW], [stow], [yes], [no])
62
63 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
64 AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
65 ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
66 ])
67
68 AM_SILENT_RULES([yes])
69
70 #### Checks for programs. ####
71
72 # mkdir -p
73
74 AC_PROG_MKDIR_P
75
76 # CC
77
78 AC_PROG_CC
79 AC_PROG_CC_C99
80 AM_PROG_CC_C_O
81 AC_PROG_GCC_TRADITIONAL
82 AC_USE_SYSTEM_EXTENSIONS
83
84 #### Platform hacks ####
85
86 case $host in
87 *-*-solaris* )
88 AC_DEFINE(_XOPEN_SOURCE, 600, Needed to get declarations for msg_control and msg_controllen on Solaris)
89 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
90 ;;
91 *-*-darwin* )
92 AC_DEFINE([_DARWIN_C_SOURCE], [200112L], [Needed to get NSIG on Mac OS X])
93 ;;
94 *-*-mingw* )
95 AC_DEFINE([WIN32_LEAN_AND_MEAN], 1, [Needed to avoid including unnecessary headers])
96 ;;
97 esac
98
99 # M4
100
101 AC_CHECK_PROGS([M4], gm4 m4, no)
102 if test "x$M4" = xno ; then
103 AC_MSG_ERROR([m4 missing])
104 fi
105
106 dnl Compiler flags
107
108 # Some compilers (e.g. clang) default to a warning on an unkown command line option.
109 # Change that temporarily to an error, for the CC_CHECK_CFLAGS_APPEND macro to work.
110 save_CC="$CC"
111 CC="$CC -Werror"
112 CC_CHECK_CFLAGS_APPEND([-Wall -W -Wextra -pipe -Wno-long-long -Wvla -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing -Wwrite-strings -Wno-unused-parameter -ffast-math -Wp,-D_FORTIFY_SOURCE=2 -fno-common -fdiagnostics-show-option])
113 CC="$save_CC"
114
115 dnl Linker flags.
116 dnl Check whether the linker supports the -version-script option.
117
118 dnl This variable is used to make sure ${srcdir} is expanded and not
119 dnl passed to the CC_CHECK_LDFLAGS macro as a name.
120 tmp_ldflag="-Wl,-version-script=${srcdir}/src/map-file"
121
122 CC_CHECK_LDFLAGS([${tmp_ldflag}],
123 [VERSIONING_LDFLAGS='-Wl,-version-script=$(srcdir)/map-file'])
124 AC_SUBST([VERSIONING_LDFLAGS])
125
126 dnl Use immediate (now) bindings; avoids the funky re-call in itself
127 dnl the -z now syntax is lifted from Sun's linker and works with GNU's too
128 dnl other linkes might be added later
129 CC_CHECK_LDFLAGS([-Wl,-z,now], [IMMEDIATE_LDFLAGS="-Wl,-z,now"])
130 AC_SUBST([IMMEDIATE_LDFLAGS])
131
132 dnl On ELF systems we don't want the libraries to be unloaded since we
133 dnl don't clean them up properly, so we request the nodelete flag to be
134 dnl enabled.
135 dnl
136 dnl On other systems, we don't really know how to do that, but it's
137 dnl welcome if somebody can tell.
138 CC_CHECK_LDFLAGS([-Wl,-z,nodelete], [NODELETE_LDFLAGS="-Wl,-z,nodelete"])
139 AC_SUBST([NODELETE_LDFLAGS])
140
141 dnl Check for the proper way to build libraries that have no undefined
142 dnl symbols; on some hosts this needs to be avoided but the macro
143 dnl takes care of it.
144 CC_NOUNDEFINED
145
146 dnl Check whether to build tests by default (as compile-test) or not
147 AC_ARG_ENABLE([default-build-tests],
148 AS_HELP_STRING([--disable-default-build-tests], [Build test programs only during make check]))
149
150 AM_CONDITIONAL([BUILD_TESTS_DEFAULT], [test "x$enable_default_build_tests" != "xno"])
151
152 # Native atomic operation support
153 AC_ARG_ENABLE([atomic-arm-linux-helpers],
154 AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]))
155
156 AC_ARG_ENABLE([atomic-arm-memory-barrier],
157 AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]))
158
159 if test "x$enable_atomic_arm_memory_barrier" = "xyes"; then
160 AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers])
161 fi
162
163 AC_ARG_ENABLE(mac-universal,
164 AS_HELP_STRING([--enable-mac-universal], [Build Mac universal binaries]),
165 enable_mac_universal=$enableval, enable_mac_universal="no")
166
167 AC_ARG_WITH(mac-version-min,
168 AS_HELP_STRING([--with-mac-version-min=<version>], [Defines the earliest version of MacOS X that the executables will run on.]),
169 mac_version_min=$withval, mac_version_min="10.5")
170
171 AC_ARG_WITH(mac-sysroot,
172 AS_HELP_STRING([--with-mac-sysroot=<path>], [SDK basedir to use as the logical root directory for headers and libraries.]),
173 mac_sysroot=$withval, mac_sysroot="/Developer/SDKs/MacOSX10.5.sdk")
174
175 AC_MSG_CHECKING([target operating system])
176 case $host in
177 *-*-linux*)
178 AC_MSG_RESULT([linux])
179 pulse_target_os=linux
180 ;;
181 *-*-darwin*)
182 AC_MSG_RESULT([darwin])
183 pulse_target_os=darwin
184
185 LDFLAGS="$LDFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
186 CFLAGS="$CFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
187
188 if test "x$enable_mac_universal" = "xyes" ; then
189 mac_arches="-arch i386 -arch x86_64"
190 LDFLAGS="$LDFLAGS $mac_arches"
191 CFLAGS="$CFLAGS $mac_arches"
192 fi
193 ;;
194 *)
195 AC_MSG_RESULT([unknown])
196 pulse_target_os=unknown
197 ;;
198 esac
199
200 # If everything else fails use libatomic_ops
201 need_libatomic_ops=yes
202
203 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
204 pulseaudio_cv_sync_bool_compare_and_swap,
205 [AC_LINK_IFELSE(
206 AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
207 [pulseaudio_cv_sync_bool_compare_and_swap=yes],
208 [pulseaudio_cv_sync_bool_compare_and_swap=no])
209 ])
210
211 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
212 AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
213 need_libatomic_ops=no
214 else
215 # HW specific atomic ops stuff
216 AC_MSG_CHECKING([architecture for native atomic operations])
217 case $host in
218 arm*)
219 AC_MSG_RESULT([arm])
220 AC_MSG_CHECKING([whether we can use Linux kernel helpers])
221 # The Linux kernel helper functions have been there since 2.6.16. However
222 # compile time checking for kernel version in cross compile environment
223 # (which is usually the case for arm cpu) is tricky (or impossible).
224 if test "x$pulse_target_os" = "xlinux" && test "x$enable_atomic_arm_linux_helpers" != "xno"; then
225 AC_MSG_RESULT([yes])
226 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
227 need_libatomic_ops=no
228 else
229 AC_MSG_RESULT([no])
230 AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
231 pulseaudio_cv_support_arm_atomic_ops,
232 [AC_COMPILE_IFELSE(
233 AC_LANG_PROGRAM([],
234 [[volatile int a=0;
235 int o=0, n=1, r;
236 asm volatile ("ldrex %0, [%1]\n"
237 "subs %0, %0, %2\n"
238 "strexeq %0, %3, [%1]\n"
239 : "=&r" (r)
240 : "r" (&a), "Ir" (o), "r" (n)
241 : "cc");
242 return (a==1 ? 0 : -1);
243 ]]),
244 [pulseaudio_cv_support_arm_atomic_ops=yes],
245 [pulseaudio_cv_support_arm_atomic_ops=no])
246 ])
247 AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
248 AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARM atomic instructions.])
249 need_libatomic_ops=no
250 ])
251 fi
252 ;;
253 *-netbsdelf5*)
254 AC_MSG_RESULT([yes])
255 need_libatomic_ops=no
256 ;;
257 *-freebsd*)
258 AC_MSG_RESULT([yes])
259 need_libatomic_ops=no
260 ;;
261 *)
262 AC_MSG_RESULT([unknown])
263 ;;
264 esac
265 fi
266
267 # If we're on ARM, check for the ARMV6 instructions we need */
268 case $host in
269 arm*)
270 AC_CACHE_CHECK([support for required armv6 instructions],
271 pulseaudio_cv_support_armv6,
272 [AC_COMPILE_IFELSE(
273 AC_LANG_PROGRAM([],
274 [[volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
275 asm volatile ("ldr r0, %2 \n"
276 "ldr r2, %3 \n"
277 "ldr r3, %4 \n"
278 "ssat r1, #8, r0 \n"
279 "str r1, %0 \n"
280 "pkhbt r1, r3, r2, LSL #8 \n"
281 "str r1, %1 \n"
282 : "=m" (a), "=m" (b)
283 : "m" (a), "m" (b), "m" (c)
284 : "r0", "r1", "r2", "r3", "cc");
285 return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
286 ]]),
287 [pulseaudio_cv_support_armv6=yes],
288 [pulseaudio_cv_support_armv6=no])
289 ])
290 AS_IF([test "$pulseaudio_cv_support_armv6" = "yes"], [
291 AC_DEFINE([HAVE_ARMV6], 1, [Have ARMv6 instructions.])
292 ])
293 ;;
294 *)
295 ;;
296 esac
297
298 CC_CHECK_TLS
299
300 AC_CACHE_CHECK([whether $CC knows _Bool],
301 pulseaudio_cv__Bool,
302 [AC_COMPILE_IFELSE(
303 AC_LANG_PROGRAM([], [[_Bool b;]]),
304 [pulseaudio_cv__Bool=yes],
305 [pulseaudio_cv__Bool=no])
306 ])
307
308 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], [
309 AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
310 ])
311
312 #### libtool stuff ####
313 LT_PREREQ(2.2)
314 LT_INIT([dlopen win32-dll disable-static])
315
316 dnl Unfortunately, even up to libtool 2.2.6a there is no way to know
317 dnl exactly which version of libltdl is present in the system, so we
318 dnl just assume that it's a working version as long as we have the
319 dnl library and the header files.
320 dnl
321 dnl As an extra safety device, check for lt_dladvise_init() which is
322 dnl only implemented in libtool 2.x, and refine as we go if we have
323 dnl refined requirements.
324 dnl
325 dnl Check the header files first since the system may have a
326 dnl libltdl.so for runtime, but no headers, and we want to bail out as
327 dnl soon as possible.
328 dnl
329 dnl We don't need any special variable for this though, since the user
330 dnl can give the proper place to find libltdl through the standard
331 dnl variables like LDFLAGS and CPPFLAGS.
332
333 AC_CHECK_HEADER([ltdl.h],
334 [AC_CHECK_LIB([ltdl], [lt_dladvise_init], [LIBLTDL=-lltdl], [LIBLTDL=])],
335 [LIBLTDL=])
336
337 AS_IF([test "x$LIBLTDL" = "x"],
338 [AC_MSG_ERROR([Unable to find libltdl version 2. Makes sure you have libtool 2.2 or later installed.])])
339 AC_SUBST([LIBLTDL])
340
341 #### Determine build environment ####
342
343 os_is_win32=0
344 os_is_darwin=0
345
346 case "$host_os" in
347 mingw*)
348 AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
349 os_is_win32=1
350 ;;
351 darwin*)
352 AC_DEFINE([OS_IS_DARWIN], 1, [Build target is Darwin.])
353 os_is_darwin=1
354 ;;
355 esac
356
357 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
358 AM_CONDITIONAL(OS_IS_DARWIN, test "x$os_is_darwin" = "x1")
359
360 ###################################
361 # Basic environment checks #
362 ###################################
363
364 #### Checks for header files. ####
365
366 # ISO
367 AC_HEADER_STDC
368
369 # POSIX
370 AC_CHECK_HEADERS_ONCE([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
371 netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
372 sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
373 sys/uio.h syslog.h sys/dl.h dlfcn.h linux/sockios.h])
374 AC_CHECK_HEADERS([netinet/ip.h], [], [],
375 [#include <sys/types.h>
376 #if HAVE_NETINET_IN_H
377 # include <netinet/in.h>
378 #endif
379 #if HAVE_NETINET_IN_SYSTM_H
380 # include <netinet/in_systm.h>
381 #endif
382 ])
383 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
384 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
385
386 # Linux
387 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
388 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
389
390 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
391
392 # Solaris
393 AC_CHECK_HEADERS_ONCE([sys/filio.h])
394
395 # Windows
396 AC_CHECK_HEADERS_ONCE([windows.h winsock2.h ws2tcpip.h])
397
398 # NetBSD
399 AC_CHECK_HEADERS_ONCE([sys/atomic.h])
400
401 # Other
402 AC_CHECK_HEADERS_ONCE([sys/ioctl.h])
403 AC_CHECK_HEADERS_ONCE([byteswap.h])
404 AC_CHECK_HEADERS_ONCE([sys/syscall.h])
405 AC_CHECK_HEADERS_ONCE([sys/eventfd.h])
406 AC_CHECK_HEADERS_ONCE([execinfo.h])
407 AC_CHECK_HEADERS_ONCE([langinfo.h])
408 AC_CHECK_HEADERS_ONCE([regex.h pcreposix.h])
409
410 #### Typdefs, structures, etc. ####
411
412 AC_C_CONST
413 AC_C_BIGENDIAN
414 AC_TYPE_PID_T
415 AC_TYPE_SIZE_T
416 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
417 [Define ssize_t if it is not done by the standard libs.])])
418 AC_TYPE_OFF_T
419
420 AC_TYPE_UID_T
421 AC_CHECK_DECLS(environ)
422
423 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
424 HAVE_SIGXCPU=1
425 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
426 ], [HAVE_SIGXCPU=0])
427 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
428
429 # Solaris lacks this
430 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
431 [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
432 [AC_DEFINE([INADDR_NONE], [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
433
434 #### POSIX threads ####
435
436 # Win32 build breaks with win32 pthread installed
437 AS_IF([test "x$os_is_win32" != "x1"],
438 [ACX_PTHREAD])
439
440 #### Check for libs ####
441
442 # ISO
443 AC_SEARCH_LIBS([pow], [m])
444
445 # POSIX
446 AC_SEARCH_LIBS([sched_setscheduler], [rt])
447 AC_SEARCH_LIBS([dlopen], [dl])
448 AC_SEARCH_LIBS([shm_open], [rt])
449 AC_SEARCH_LIBS([inet_ntop], [nsl])
450 AC_SEARCH_LIBS([timer_create], [rt])
451 AC_SEARCH_LIBS([pthread_setaffinity_np], [pthread])
452 AC_SEARCH_LIBS([pthread_getname_np], [pthread])
453 AC_SEARCH_LIBS([pthread_setname_np], [pthread])
454
455 # BSD
456 AC_SEARCH_LIBS([connect], [socket])
457 AC_SEARCH_LIBS([backtrace], [execinfo])
458
459 # Darwin/OS X
460 if test "x$os_is_darwin" = "x1" ; then
461 AC_MSG_CHECKING([looking for Apple CoreService Framework])
462 # How do I check a framework "library" - AC_CHECK_LIB prob. won't work??, just assign LIBS & hope
463 AC_CHECK_HEADER([/Developer/Headers/FlatCarbon/CoreServices.h],
464 [LIBS="$LIBS -framework CoreServices"],
465 [AC_MSG_ERROR([CoreServices.h header file not found]) ])
466
467 AC_MSG_RESULT([ok])
468 AC_DEFINE([HAVE_CLOCK_GETTIME], 1, [Using clock_gettime() replacement])
469 HAVE_BONJOUR=1
470 fi
471
472 AM_CONDITIONAL([HAVE_BONJOUR], [test "x$HAVE_BONJOUR" = x1])
473
474 # Windows
475 AC_SEARCH_LIBS([regexec], [pcreposix])
476 # This magic is needed so we do not needlessly add static libs to the win32 build, disabling its ability to make dlls.
477 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
478
479 #### Check for functions ####
480
481 # ISO
482 AC_CHECK_FUNCS_ONCE([lrintf strtof])
483
484 # POSIX
485 AC_FUNC_FORK
486 AC_FUNC_GETGROUPS
487 AC_FUNC_SELECT_ARGTYPES
488 AC_CHECK_FUNCS_ONCE([chmod chown fstat fchown fchmod clock_gettime getaddrinfo getgrgid_r getgrnam_r \
489 getpwnam_r getpwuid_r gettimeofday getuid mlock nanosleep \
490 pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
491 sigaction sleep symlink sysconf uname pthread_setaffinity_np pthread_getname_np pthread_setname_np])
492 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
493
494 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
495
496 # X/OPEN
497 AC_CHECK_FUNCS_ONCE([readlink])
498
499 # SUSv2
500 AC_CHECK_FUNCS_ONCE([ctime_r usleep])
501
502 # SUSv3
503 AC_CHECK_FUNCS_ONCE([strerror_r])
504
505 # BSD
506 AC_CHECK_FUNCS_ONCE([lstat])
507
508 # Non-standard
509
510 AC_CHECK_FUNCS_ONCE([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l pipe2 accept4])
511
512 AC_FUNC_ALLOCA
513
514 AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
515 pulseaudio_cv_PTHREAD_PRIO_INHERIT,
516 [save_CC=$CC; CC=$PTHREAD_CC
517 save_CFLAGS=$CFLAGS; CFLAGS=$PTHREAD_CFLAGS
518 save_LIBS=$LIBS; LIBS=$PTHREAD_LIBS
519 AC_LINK_IFELSE(
520 AC_LANG_PROGRAM(
521 [[
522 #include <pthread.h>
523 ]],
524 [[int i = PTHREAD_PRIO_INHERIT;]]),
525 [pulseaudio_cv_PTHREAD_PRIO_INHERIT=yes],
526 [pulseaudio_cv_PTHREAD_PRIO_INHERIT=no])
527 CC=$save_CC
528 CFLAGS=$save_CFLAGS
529 LIBS=$save_LIBS
530 ])
531
532 AS_IF([test "$pulseaudio_cv_PTHREAD_PRIO_INHERIT" = "yes"], [
533 AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
534 ])
535
536 AC_DEFINE_UNQUOTED(PA_CFLAGS,"$CFLAGS", [The CFLAGS used during compilation])
537
538 AC_CHECK_FUNCS([regexec], [HAVE_REGEX=1], [HAVE_REGEX=0])
539 AM_CONDITIONAL(HAVE_REGEX, [test "x$HAVE_REGEX" = "x1"])
540
541 #### Large File-Support (LFS) ####
542
543 AC_SYS_LARGEFILE
544
545 # Check for open64 to know if the current system does have open64() and similar functions
546 AC_CHECK_FUNCS_ONCE([open64])
547
548 #### [lib]iconv ####
549
550 AM_ICONV
551
552 IT_PROG_INTLTOOL([0.35.0])
553 GETTEXT_PACKAGE=pulseaudio
554 AC_SUBST([GETTEXT_PACKAGE])
555 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
556 AM_GLIB_GNU_GETTEXT
557
558 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
559 AC_SUBST(pulselocaledir)
560
561 ###################################
562 # External libraries #
563 ###################################
564
565 #### pkg-config ####
566
567 PKG_PROG_PKG_CONFIG
568
569 #### X11 (optional) ####
570
571 AC_ARG_ENABLE([x11],
572 AS_HELP_STRING([--disable-x11],[Disable optional X11 support]))
573
574 AS_IF([test "x$enable_x11" != "xno"],
575 [PKG_CHECK_MODULES(X11, [ x11-xcb xcb >= 1.6 ice sm xtst ], HAVE_X11=1, HAVE_X11=0)],
576 HAVE_X11=0)
577
578 AS_IF([test "x$enable_x11" = "xyes" && test "x$HAVE_X11" = "x0"],
579 [AC_MSG_ERROR([*** X11 not found])])
580
581 AC_SUBST(X11_CFLAGS)
582 AC_SUBST(X11_LIBS)
583 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
584 AS_IF([test "x$HAVE_X11" = "x1"], AC_DEFINE([HAVE_X11], 1, [Have X11?]))
585
586 #### Capabilities (optional) ####
587
588 CAP_LIBS=''
589
590 AC_ARG_WITH(
591 [caps],
592 AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
593
594 if test "x${with_caps}" != "xno"; then
595 AC_SEARCH_LIBS([cap_init], [cap], [], [
596 if test "x${with_caps}" = "xyes" ; then
597 AC_MSG_ERROR([*** POSIX caps libraries not found])
598 fi])
599 AC_CHECK_HEADERS([sys/capability.h], [], [
600 if test "x${with_caps}" = "xyes" ; then
601 AC_MSG_ERROR([*** POSIX caps headers not found])
602 fi])
603 fi
604
605 #### Valgrind (optional) ####
606
607 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
608
609 #### json parsing ####
610
611 PKG_CHECK_MODULES(LIBJSON, [ json >= 0.9 ])
612 AC_SUBST(LIBJSON_CFLAGS)
613 AC_SUBST(LIBJSON_LIBS)
614
615 #### Sound file ####
616
617 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.20 ])
618 AC_SUBST(LIBSNDFILE_CFLAGS)
619 AC_SUBST(LIBSNDFILE_LIBS)
620
621 PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ])
622 AC_SUBST(LIBSPEEX_CFLAGS)
623 AC_SUBST(LIBSPEEX_LIBS)
624
625 #### atomic-ops ###
626
627 AC_MSG_CHECKING([whether we need libatomic_ops])
628 if test "x$need_libatomic_ops" = "xyes"; then
629 AC_MSG_RESULT([yes])
630 AC_CHECK_HEADERS([atomic_ops.h], [], [
631 AC_MSG_ERROR([*** libatomic-ops headers not found])
632 ])
633
634 # Win32 does not need the lib and breaks horribly if we try to include it
635 if test "x$os_is_win32" != "x1" ; then
636 LIBS="$LIBS -latomic_ops"
637 fi
638 else
639 AC_MSG_RESULT([no])
640 fi
641
642 #### Libsamplerate support (optional) ####
643
644 AC_ARG_ENABLE([samplerate],
645 AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]))
646
647 AS_IF([test "x$enable_samplerate" != "xno"],
648 [PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ], HAVE_LIBSAMPLERATE=1, HAVE_LIBSAMPLERATE=0)],
649 HAVE_LIBSAMPLERATE=0)
650
651 AS_IF([test "x$enable_samplerate" = "xyes" && test "x$HAVE_LIBSAMPLERATE" = "x0"],
652 [AC_MSG_ERROR([*** Libsamplerate not found])])
653
654 AC_SUBST(LIBSAMPLERATE_CFLAGS)
655 AC_SUBST(LIBSAMPLERATE_LIBS)
656 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
657 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?]))
658
659 #### Database support ####
660
661 AC_ARG_WITH([database],
662 AS_HELP_STRING([--with-database=auto|tdb|gdbm|simple],[Choose database backend.]),[],[with_database=auto])
663
664
665 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xtdb"],
666 [PKG_CHECK_MODULES(TDB, [ tdb ], HAVE_TDB=1, HAVE_TDB=0)],
667 HAVE_TDB=0)
668 AS_IF([test "x$HAVE_TDB" = "x1"], with_database=tdb)
669
670 AS_IF([test "x$with_database" = "xtdb" && test "x$HAVE_TDB" = "x0"],
671 [AC_MSG_ERROR([*** tdb not found])])
672
673
674 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xgdbm"],
675 [
676 HAVE_GDBM=1
677 AC_CHECK_LIB(gdbm, gdbm_open, [], HAVE_GDBM=0)
678 AC_CHECK_HEADERS(gdbm.h, [], HAVE_GDBM=0)
679 ],
680 HAVE_GDBM=0)
681 AS_IF([test "x$HAVE_GDBM" = "x1"],
682 [
683 with_database=gdbm
684 GDBM_CFLAGS=
685 GDBM_LIBS=-lgdbm
686 ])
687
688 AS_IF([test "x$with_database" = "xgdbm" && test "x$HAVE_GDBM" = "x0"],
689 [AC_MSG_ERROR([*** gdbm not found])])
690
691
692 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xsimple"],
693 HAVE_SIMPLEDB=1,
694 HAVE_SIMPLEDB=0)
695 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], with_database=simple)
696
697 AS_IF([test "x$HAVE_TDB" != x1 -a "x$HAVE_GDBM" != x1 -a "x$HAVE_SIMPLEDB" != x1],
698 AC_MSG_ERROR([*** missing database backend]))
699
700
701 AC_SUBST(TDB_CFLAGS)
702 AC_SUBST(TDB_LIBS)
703 AM_CONDITIONAL([HAVE_TDB], [test "x$HAVE_TDB" = x1])
704 AS_IF([test "x$HAVE_TDB" = "x1"], AC_DEFINE([HAVE_TDB], 1, [Have tdb?]))
705
706 AC_SUBST(GDBM_CFLAGS)
707 AC_SUBST(GDBM_LIBS)
708 AM_CONDITIONAL([HAVE_GDBM], [test "x$HAVE_GDBM" = x1])
709 AS_IF([test "x$HAVE_GDBM" = "x1"], AC_DEFINE([HAVE_GDBM], 1, [Have gdbm?]))
710
711 AM_CONDITIONAL([HAVE_SIMPLEDB], [test "x$HAVE_SIMPLEDB" = x1])
712 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], AC_DEFINE([HAVE_SIMPLEDB], 1, [Have simple?]))
713
714 #### OSS support (optional) ####
715
716 AC_ARG_ENABLE([oss-output],
717 AS_HELP_STRING([--disable-oss-output],[Disable optional OSS output support]))
718
719 AC_ARG_ENABLE([oss-wrapper],
720 AS_HELP_STRING([--disable-oss-wrapper],[Disable optional OSS wrapper support]))
721
722 AS_IF([test "x$enable_oss_output" != "xno" -o "x$enable_oss_wrapper" != "xno"],
723 [AC_CHECK_HEADERS([sys/soundcard.h], HAVE_OSS=1, HAVE_OSS=0)],
724 HAVE_OSS=0)
725
726 AS_IF([test "x$enable_oss_output" = "xyes" -o "x$enable_oss_wrapper" = "xyes" && test "x$HAVE_OSS" = "x0"],
727 [AC_MSG_ERROR([*** OSS support not found])])
728
729 AS_IF([test "x$enable_oss_output" != "xno"],
730 [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_OUTPUT=1, HAVE_OSS_OUTPUT=0)],
731 HAVE_OSS_OUTPUT=0)
732
733 AS_IF([test "x$enable_oss_wrapper" != "xno"],
734 [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_WRAPPER=1, HAVE_OSS_WRAPPER=0)],
735 HAVE_OSS_WRAPPER=0)
736
737 AM_CONDITIONAL([HAVE_OSS_OUTPUT], [test "x$HAVE_OSS_OUTPUT" = "x1"])
738 AM_CONDITIONAL([HAVE_OSS_WRAPPER], [test "x$HAVE_OSS_WRAPPER" = "x1"])
739 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], AC_DEFINE([HAVE_OSS_OUTPUT], 1, [Have OSS output?]))
740 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], AC_DEFINE([HAVE_OSS_WRAPPER], 1, [Have OSS wrapper (padsp)?]))
741
742 #### CoreAudio support (optional) ####
743
744 AC_ARG_ENABLE([coreaudio-output],
745 AS_HELP_STRING([--disable-coreaudio-output],[Disable optional CoreAudio output support]))
746
747 AS_IF([test "x$enable_coreaudio_output" != "xno"],
748 [AC_CHECK_HEADERS([CoreAudio/CoreAudio.h], HAVE_COREAUDIO=1, HAVE_COREAUDIO=0)],
749 HAVE_COREAUDIO=0)
750
751 AS_IF([test "x$enable_coreaudio_output" = "xyes" && test "x$HAVE_COREAUDIO" = "x0"],
752 [AC_MSG_ERROR([*** CoreAudio output support not found])])
753
754 AM_CONDITIONAL([HAVE_COREAUDIO], [test "x$HAVE_COREAUDIO" = "x1" && test "x$enable_coreaudio_output" != "xno"])
755
756 #### ALSA support (optional) ####
757
758 AC_ARG_ENABLE([alsa],
759 AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]))
760
761 AS_IF([test "x$enable_alsa" != "xno"],
762 [PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.19 ], HAVE_ALSA=1, HAVE_ALSA=0)],
763 HAVE_ALSA=0)
764
765 AS_IF([test "x$enable_alsa" = "xyes" && test "x$HAVE_ALSA" = "x0"],
766 [AC_MSG_ERROR([*** Needed alsa >= 1.0.19 support not found])])
767
768 AC_SUBST(ASOUNDLIB_CFLAGS)
769 AC_SUBST(ASOUNDLIB_LIBS)
770 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
771 AS_IF([test "x$HAVE_ALSA" = "x1"], AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?]))
772
773 #### Solaris audio support (optional) ####
774
775 AC_ARG_ENABLE([solaris],
776 AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]))
777
778 AS_IF([test "x$enable_solaris" != "xno"],
779 [AC_CHECK_HEADERS([sys/audio.h], HAVE_SOLARIS=1, HAVE_SOLARIS=0)],
780 HAVE_SOLARIS=0)
781
782 AS_IF([test "x$enable_solaris" = "xyes" && test "x$HAVE_SOLARIS" = "x0"],
783 [AC_MSG_ERROR([*** Solaris audio support not found])])
784
785 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
786 AS_IF([test "x$HAVE_SOLARIS" = "x1"], AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?]))
787
788 #### WaveOut audio support (optional) ####
789
790 AC_ARG_ENABLE([waveout],
791 AS_HELP_STRING([--disable-waveout],[Disable optional WaveOut audio support]))
792
793 AS_IF([test "x$enable_waveout" != "xno"],
794 [AC_CHECK_HEADERS([mmsystem.h], HAVE_WAVEOUT=1, HAVE_WAVEOUT=0, [#include <windows.h>])],
795 HAVE_WAVEOUT=0)
796
797 AS_IF([test "x$enable_waveout" = "xyes" && test "x$HAVE_WAVEOUT" = "x0"],
798 [AC_MSG_ERROR([*** WaveOut audio support not found])])
799
800 AM_CONDITIONAL([HAVE_WAVEOUT], [test "x$HAVE_WAVEOUT" = x1])
801 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], AC_DEFINE([HAVE_WAVEOUT], 1, [Have WaveOut audio?]))
802
803 #### GLib 2 support (optional) ####
804
805 AC_ARG_ENABLE([glib2],
806 AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]))
807
808 AS_IF([test "x$enable_glib2" != "xno"],
809 [PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)],
810 HAVE_GLIB20=0)
811
812 AS_IF([test "x$enable_glib2" = "xyes" && test "x$HAVE_GLIB20" = "x0"],
813 [AC_MSG_ERROR([*** GLib 2 support not found])])
814
815 AC_SUBST(GLIB20_CFLAGS)
816 AC_SUBST(GLIB20_LIBS)
817 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
818 AS_IF([test "x$HAVE_GLIB20" = "x1"], AC_DEFINE([HAVE_GLIB], 1, [Have GLIB?]))
819
820 #### GTK2 support (optional) ####
821
822 AC_ARG_ENABLE([gtk2],
823 AS_HELP_STRING([--disable-gtk2],[Disable optional Gtk+ 2 support]))
824
825 AS_IF([test "x$enable_gtk2" != "xno"],
826 [PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ], HAVE_GTK20=1, HAVE_GTK20=0)],
827 HAVE_GTK20=0)
828
829 AS_IF([test "x$enable_gtk2" = "xyes" && test "x$HAVE_GTK20" = "x0"],
830 [AC_MSG_ERROR([*** Gtk+ 2 support not found])])
831
832 AC_SUBST(GTK20_CFLAGS)
833 AC_SUBST(GTK20_LIBS)
834 AM_CONDITIONAL([HAVE_GTK20], [test "x$HAVE_GTK20" = x1])
835 AS_IF([test "x$HAVE_GTK20" = "x1"], AC_DEFINE([HAVE_GTK], 1, [Have GTK?]))
836
837 #### GConf support (optional) ####
838
839 AC_ARG_ENABLE([gconf],
840 AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]))
841
842 AS_IF([test "x$enable_gconf" != "xno"],
843 [PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 gobject-2.0 ], HAVE_GCONF=1, HAVE_GCONF=0)],
844 HAVE_GCONF=0)
845
846 AS_IF([test "x$enable_gconf" = "xyes" && test "x$HAVE_GCONF" = "x0"],
847 [AC_MSG_ERROR([*** GConf support not found])])
848
849 AC_SUBST(GCONF_CFLAGS)
850 AC_SUBST(GCONF_LIBS)
851 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
852
853 #### Avahi support (optional) ####
854
855 AC_ARG_ENABLE([avahi],
856 AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]))
857
858 AS_IF([test "x$enable_avahi" != "xno"],
859 [PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ], HAVE_AVAHI=1, HAVE_AVAHI=0)],
860 HAVE_AVAHI=0)
861
862 AS_IF([test "x$enable_avahi" = "xyes" && test "x$HAVE_AVAHI" = "x0"],
863 [AC_MSG_ERROR([*** Avahi support not found])])
864
865 AC_SUBST(AVAHI_CFLAGS)
866 AC_SUBST(AVAHI_LIBS)
867 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
868
869 ### JACK (optional) ####
870
871 AC_ARG_ENABLE([jack],
872 AS_HELP_STRING([--disable-jack],[Disable optional JACK support]))
873
874 AS_IF([test "x$enable_jack" != "xno"],
875 [PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ], HAVE_JACK=1, HAVE_JACK=0)],
876 HAVE_JACK=0)
877
878 AS_IF([test "x$enable_jack" = "xyes" && test "x$HAVE_JACK" = "x0"],
879 [AC_MSG_ERROR([*** JACK support not found])])
880
881 AC_SUBST(JACK_CFLAGS)
882 AC_SUBST(JACK_LIBS)
883 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
884
885 #### Async DNS support (optional) ####
886
887 AC_ARG_ENABLE([asyncns],
888 AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]))
889
890 AS_IF([test "x$enable_asyncns" != "xno"],
891 [PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)],
892 HAVE_LIBASYNCNS=0)
893
894 AS_IF([test "x$enable_asyncns" = "xyes" && test "x$HAVE_LIBASYNCNS" = "x0"],
895 [AC_MSG_ERROR([*** Async DNS support not found])])
896
897 AC_SUBST(LIBASYNCNS_CFLAGS)
898 AC_SUBST(LIBASYNCNS_LIBS)
899 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
900 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?]))
901
902 #### TCP wrappers (optional) ####
903
904 AC_ARG_ENABLE([tcpwrap],
905 AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]))
906
907 AS_IF([test "x$enable_tcpwrap" != "xno"],
908 [
909 ACX_LIBWRAP
910 AS_IF([test "x$LIBWRAP_LIBS" != "x"], HAVE_TCPWRAP=1, HAVE_TCPWRAP=0)
911 ],
912 HAVE_TCPWRAP=0)
913
914 AS_IF([test "x$enable_tcpwrap" = "xyes" && test "x$HAVE_TCPWRAP" = "x0"],
915 [AC_MSG_ERROR([*** TCP wrappers support not found])])
916
917 AC_SUBST(LIBWRAP_LIBS)
918
919 #### LIRC support (optional) ####
920
921 AC_ARG_ENABLE([lirc],
922 AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]))
923
924 AS_IF([test "x$enable_lirc" != "xno"],
925 [ACX_LIRC],
926 HAVE_LIRC=0)
927
928 AS_IF([test "x$enable_lirc" = "xyes" && test "x$HAVE_LIRC" = "x0"],
929 [AC_MSG_ERROR([*** LIRC support not found])])
930
931 AC_SUBST(LIRC_CFLAGS)
932 AC_SUBST(LIRC_LIBS)
933 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
934
935 #### HAL support (optional) ####
936
937 AC_ARG_ENABLE([hal],
938 AS_HELP_STRING([--disable-hal],[Disable optional HAL support]))
939
940 AS_IF([test "x$enable_hal" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
941 [PKG_CHECK_MODULES(HAL, [ hal >= 0.5.11 ], HAVE_HAL=1, HAVE_HAL=0)],
942 HAVE_HAL=0)
943
944 AS_IF([test "x$enable_hal" = "xyes" && test "x$HAVE_HAL" = "x0"],
945 [AC_MSG_ERROR([*** HAL support not found])])
946
947 AC_SUBST(HAL_CFLAGS)
948 AC_SUBST(HAL_LIBS)
949 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
950 AS_IF([test "x$HAVE_HAL" = "x1"], AC_DEFINE([HAVE_HAL], 1, [Have HAL.]))
951
952 #### UDEV support (optional) ####
953
954 AC_ARG_ENABLE([udev],
955 AS_HELP_STRING([--disable-udev],[Disable optional UDEV support]))
956
957 AS_IF([test "x$enable_udev" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
958 [PKG_CHECK_MODULES(UDEV, [ libudev >= 143 ], HAVE_UDEV=1, HAVE_UDEV=0)],
959 HAVE_UDEV=0)
960
961 AS_IF([test "x$enable_udev" = "xyes" && test "x$HAVE_UDEV" = "x0"],
962 [AC_MSG_ERROR([*** UDEV support not found])])
963
964 AC_SUBST(UDEV_CFLAGS)
965 AC_SUBST(UDEV_LIBS)
966 AM_CONDITIONAL([HAVE_UDEV], [test "x$HAVE_UDEV" = x1])
967 AS_IF([test "x$HAVE_UDEV" = "x1"], AC_DEFINE([HAVE_UDEV], 1, [Have UDEV.]))
968
969 #### BlueZ support (optional) ####
970
971 AC_ARG_ENABLE([bluez],
972 AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]))
973
974 AS_IF([test "x$enable_bluez" != "xno"],
975 [PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ], HAVE_BLUEZ=1, HAVE_BLUEZ=0)],
976 HAVE_BLUEZ=0)
977
978 AS_IF([test "x$enable_bluez" = "xyes" && test "x$HAVE_BLUEZ" = "x0"],
979 [AC_MSG_ERROR([*** BLUEZ support not found])])
980
981 AC_SUBST(BLUEZ_CFLAGS)
982 AC_SUBST(BLUEZ_LIBS)
983 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
984
985 #### D-Bus support (optional) ####
986
987 AC_ARG_ENABLE([dbus],
988 AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]))
989
990 AS_IF([test "x$enable_dbus" != "xno"],
991 [PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ], HAVE_DBUS=1, HAVE_DBUS=0)],
992 HAVE_DBUS=0)
993
994 AS_IF([test "x$enable_dbus" = "xyes" && test "x$HAVE_DBUS" = "x0"],
995 [AC_MSG_ERROR([*** D-Bus support not found])])
996
997 AS_IF([test "x$HAVE_DBUS" = "x1"],
998 [
999 saved_LIBS="$LIBS"
1000 LIBS="$LIBS $DBUS_LIBS"
1001 CFLAGS="$CFLAGS $DBUS_CFLAGS"
1002 AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
1003 LIBS="$saved_LIBS"
1004 ])
1005
1006 AC_SUBST(DBUS_CFLAGS)
1007 AC_SUBST(DBUS_LIBS)
1008 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
1009 AS_IF([test "x$HAVE_DBUS" = "x1"], AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.]))
1010
1011 # HAL and BlueZ depend on D-Bus: So double check if they were explicitly enabled.
1012 if test "x$HAVE_DBUS" != "x1" ; then
1013 HAVE_HAL=0
1014 if test "x$enable_hal" = "xyes"; then
1015 AC_MSG_ERROR([*** D-Bus support is required by HAL])
1016 fi
1017
1018 HAVE_BLUEZ=0
1019 if test "x$enable_bluez" = "xyes"; then
1020 AC_MSG_ERROR([*** D-Bus support is required by BLUEZ])
1021 fi
1022 fi
1023
1024 #### HAL compat support (optional) ####
1025
1026 AC_ARG_ENABLE([hal-compat],
1027 AS_HELP_STRING([--disable-hal-compat],[Disable optional HAL->udev transition compatibility support]))
1028
1029 if test "x$enable_hal_compat" != "xno" -a "x$HAVE_HAL" = "x0" -a "x$HAVE_UDEV" = "x1"; then
1030 HAVE_HAL_COMPAT=1
1031 AC_DEFINE([HAVE_HAL_COMPAT], 1, [Have HAL compatibility.])
1032 else
1033 HAVE_HAL_COMPAT=0
1034 fi
1035
1036 AM_CONDITIONAL([HAVE_HAL_COMPAT], [test "x$HAVE_HAL_COMPAT" = x1])
1037
1038 ### IPv6 connection support (optional) ###
1039
1040 AC_ARG_ENABLE([ipv6],
1041 AS_HELP_STRING([--disable-ipv6],[Disable optional IPv6 support]))
1042
1043 if test "x$enable_ipv6" != "xno"; then
1044 AC_DEFINE([HAVE_IPV6], [1], [Define this to enable IPv6 connection support])
1045 HAVE_IPV6=1
1046 else
1047 HAVE_IPV6=0
1048 fi
1049
1050 #### OpenSSL support (optional) ####
1051
1052 AC_ARG_ENABLE([openssl],
1053 AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]))
1054
1055 AS_IF([test "x$enable_openssl" != "xno"],
1056 [PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ], HAVE_OPENSSL=1, HAVE_OPENSSL=0)],
1057 HAVE_OPENSSL=0)
1058
1059 AS_IF([test "x$enable_openssl" = "xyes" && test "x$HAVE_OPENSSL" = "x0"],
1060 [AC_MSG_ERROR([*** OpenSSL support not found])])
1061
1062 AC_SUBST(OPENSSL_CFLAGS)
1063 AC_SUBST(OPENSSL_LIBS)
1064 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1065 AS_IF([test "x$HAVE_OPENSSL" = "x1"], AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL]))
1066
1067 #### FFTW (optional) ####
1068 AC_ARG_WITH([fftw],
1069 AS_HELP_STRING([--without-fftw],[Omit FFTW-using modules (equalizer)]))
1070
1071 AS_IF([test "x$with_fftw" != "xno"],
1072 [PKG_CHECK_MODULES(FFTW, [ fftw3f ], HAVE_FFTW=1, HAVE_FFTW=0)],
1073 HAVE_FFTW=0)
1074
1075 AM_CONDITIONAL([HAVE_FFTW], [test "x$HAVE_FFTW" = "x1"])
1076
1077 ### ORC (optional) ###
1078 ORC_CHECK([0.4.11])
1079
1080 ### Build and Install man pages ###
1081 AC_ARG_ENABLE([manpages],
1082 AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]))
1083
1084 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" != "xno"])
1085
1086 #### PulseAudio system group & user #####
1087
1088 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1089 if test -z "$with_system_user" ; then
1090 PA_SYSTEM_USER=pulse
1091 else
1092 PA_SYSTEM_USER=$with_system_user
1093 fi
1094 AC_SUBST(PA_SYSTEM_USER)
1095 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1096
1097 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1098 if test -z "$with_system_group" ; then
1099 PA_SYSTEM_GROUP=pulse
1100 else
1101 PA_SYSTEM_GROUP=$with_system_group
1102 fi
1103 AC_SUBST(PA_SYSTEM_GROUP)
1104 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1105
1106 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1107 if test -z "$with_access_group" ; then
1108 PA_ACCESS_GROUP=pulse-access
1109 else
1110 PA_ACCESS_GROUP=$with_access_group
1111 fi
1112 AC_SUBST(PA_ACCESS_GROUP)
1113 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1114
1115 AC_ARG_ENABLE([per-user-esound-socket],
1116 AS_HELP_STRING([--disable-per-user-esound-socket],[Use global esound socket directory /tmp/.esd/socket.]))
1117
1118 if test "x$enable_per_user_esound_socket" != "xno"; then
1119 USE_PER_USER_ESOUND_SOCKET=1
1120 AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1121 else
1122 USE_PER_USER_ESOUND_SOCKET=0
1123 fi
1124
1125 #### PulseAudio system runtime dir ####
1126 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1127 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1128 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1129 AC_SUBST(PA_SYSTEM_CONFIG_PATH)
1130 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1131 AC_SUBST(PA_SYSTEM_STATE_PATH)
1132
1133 ###################################
1134 # Output #
1135 ###################################
1136
1137 AC_ARG_ENABLE([legacy-runtime-dir],
1138 AS_HELP_STRING([--disable-legacy-runtime-dir], [Try to connect on legacy (< 0.9.12) socket paths.]))
1139 if test "x$enable_legacy_runtime_dir" != "xno" ; then
1140 AC_DEFINE(ENABLE_LEGACY_RUNTIME_DIR, [1], [Legacy runtime dir])
1141 fi
1142
1143 AC_ARG_ENABLE([static-bins],
1144 AS_HELP_STRING([--enable-static-bins],[Statically link executables.]))
1145
1146 if test "x$enable_static_bins" = "xyes"; then
1147 STATIC_BINS=1
1148 else
1149 STATIC_BINS=0
1150 fi
1151
1152 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1153
1154 AC_ARG_WITH(
1155 [preopen-mods],
1156 AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1157 [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1158 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1159 if test "x$PREOPEN_MODS" != "xall" ; then
1160 tmpLIBS=""
1161 for mod in $PREOPEN_MODS; do
1162 tmpLIBS="$tmpLIBS module-$mod.la"
1163 done
1164 PREOPEN_MODS="$tmpLIBS"
1165 AC_SUBST(PREOPEN_MODS)
1166 fi
1167
1168 AC_ARG_WITH(
1169 [module-dir],
1170 AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules]),
1171 [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules"])
1172
1173 AC_SUBST(modlibexecdir)
1174
1175 AC_ARG_WITH(
1176 [udev-rules-dir],
1177 AS_HELP_STRING([--with-udev-rules-dir],[Directory where to install udev rules to (defaults to /lib/udev/rules.d)]),
1178 [udevrulesdir=$withval], [udevrulesdir="/lib/udev/rules.d"])
1179
1180 AC_SUBST(udevrulesdir)
1181
1182 AC_ARG_ENABLE([force-preopen],
1183 AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]))
1184
1185 if test "x$enable_force_preopen" = "xyes"; then
1186 FORCE_PREOPEN=yes
1187 else
1188 FORCE_PREOPEN=no
1189 fi
1190
1191 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1192
1193 AC_CONFIG_FILES([
1194 Makefile
1195 src/Makefile
1196 man/Makefile
1197 libpulse.pc
1198 libpulse-simple.pc
1199 libpulse-browse.pc
1200 libpulse-mainloop-glib.pc
1201 doxygen/Makefile
1202 doxygen/doxygen.conf
1203 src/pulse/version.h
1204 po/Makefile.in
1205 ])
1206
1207 AC_OUTPUT
1208
1209 # ==========================================================================
1210
1211 AS_IF([test "x$HAVE_X11" = "x1"], ENABLE_X11=yes, ENABLE_X11=no)
1212 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], ENABLE_OSS_OUTPUT=yes, ENABLE_OSS_OUTPUT=no)
1213 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], ENABLE_OSS_WRAPPER=yes, ENABLE_OSS_WRAPPER=no)
1214 AS_IF([test "x$HAVE_ALSA" = "x1"], ENABLE_ALSA=yes, ENABLE_ALSA=no)
1215 AS_IF([test "x$HAVE_COREAUDIO" = "x1"], ENABLE_COREAUDIO=yes, ENABLE_COREAUDIO=no)
1216 AS_IF([test "x$HAVE_SOLARIS" = "x1"], ENABLE_SOLARIS=yes, ENABLE_SOLARIS=no)
1217 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], ENABLE_WAVEOUT=yes, ENABLE_WAVEOUT=no)
1218 AS_IF([test "x$HAVE_GLIB20" = "x1"], ENABLE_GLIB20=yes, ENABLE_GLIB20=no)
1219 AS_IF([test "x$HAVE_GTK20" = "x1"], ENABLE_GTK20=yes, ENABLE_GTK20=no)
1220 AS_IF([test "x$HAVE_GCONF" = "x1"], ENABLE_GCONF=yes, ENABLE_GCONF=no)
1221 AS_IF([test "x$HAVE_AVAHI" = "x1"], ENABLE_AVAHI=yes, ENABLE_AVAHI=no)
1222 AS_IF([test "x$HAVE_JACK" = "x1"], ENABLE_JACK=yes, ENABLE_JACK=no)
1223 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], ENABLE_LIBASYNCNS=yes, ENABLE_LIBASYNCNS=no)
1224 AS_IF([test "x$HAVE_LIRC" = "x1"], ENABLE_LIRC=yes, ENABLE_LIRC=no)
1225 AS_IF([test "x$HAVE_DBUS" = "x1"], ENABLE_DBUS=yes, ENABLE_DBUS=no)
1226 AS_IF([test "x$HAVE_HAL" = "x1"], ENABLE_HAL=yes, ENABLE_HAL=no)
1227 AS_IF([test "x$HAVE_UDEV" = "x1"], ENABLE_UDEV=yes, ENABLE_UDEV=no)
1228 AS_IF([test "x$HAVE_BLUEZ" = "x1"], ENABLE_BLUEZ=yes, ENABLE_BLUEZ=no)
1229 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], ENABLE_HAL_COMPAT=yes, ENABLE_HAL_COMPAT=no)
1230 AS_IF([test "x$HAVE_TCPWRAP" = "x1"], ENABLE_TCPWRAP=yes, ENABLE_TCPWRAP=no)
1231 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], ENABLE_LIBSAMPLERATE=yes, ENABLE_LIBSAMPLERATE=no)
1232 AS_IF([test "x$HAVE_IPV6" = "x1"], ENABLE_IPV6=yes, ENABLE_IPV6=no)
1233 AS_IF([test "x$HAVE_OPENSSL" = "x1"], ENABLE_OPENSSL=yes, ENABLE_OPENSSL=no)
1234 AS_IF([test "x$HAVE_FFTW" = "x1"], ENABLE_FFTW=yes, ENABLE_FFTW=no)
1235 AS_IF([test "x$HAVE_ORC" = "xyes"], ENABLE_ORC=yes, ENABLE_ORC=no)
1236 AS_IF([test "x$HAVE_TDB" = "x1"], ENABLE_TDB=yes, ENABLE_TDB=no)
1237 AS_IF([test "x$HAVE_GDBM" = "x1"], ENABLE_GDBM=yes, ENABLE_GDBM=no)
1238 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], ENABLE_SIMPLEDB=yes, ENABLE_SIMPLEDB=no)
1239 AS_IF([test "x$USE_PER_USER_ESOUND_SOCKET" = "x1"], ENABLE_PER_USER_ESOUND_SOCKET=yes, ENABLE_PER_USER_ESOUND_SOCKET=no)
1240
1241 echo "
1242 ---{ $PACKAGE_NAME $VERSION }---
1243
1244 prefix: ${prefix}
1245 sysconfdir: ${sysconfdir}
1246 localstatedir: ${localstatedir}
1247 System Runtime Path: ${PA_SYSTEM_RUNTIME_PATH}
1248 System State Path: ${PA_SYSTEM_STATE_PATH}
1249 System Config Path: ${PA_SYSTEM_CONFIG_PATH}
1250 Compiler: ${CC}
1251 CFLAGS: ${CFLAGS}
1252 LIBS: ${LIBS}
1253
1254 Enable X11: ${ENABLE_X11}
1255 Enable OSS Output: ${ENABLE_OSS_OUTPUT}
1256 Enable OSS Wrapper: ${ENABLE_OSS_WRAPPER}
1257 Enable Alsa: ${ENABLE_ALSA}
1258 Enable CoreAudio: ${ENABLE_COREAUDIO}
1259 Enable Solaris: ${ENABLE_SOLARIS}
1260 Enable WaveOut: ${ENABLE_WAVEOUT}
1261 Enable GLib 2.0: ${ENABLE_GLIB20}
1262 Enable Gtk+ 2.0: ${ENABLE_GTK20}
1263 Enable GConf: ${ENABLE_GCONF}
1264 Enable Avahi: ${ENABLE_AVAHI}
1265 Enable Jack: ${ENABLE_JACK}
1266 Enable Async DNS: ${ENABLE_LIBASYNCNS}
1267 Enable LIRC: ${ENABLE_LIRC}
1268 Enable D-Bus: ${ENABLE_DBUS}
1269 Enable HAL: ${ENABLE_HAL}
1270 Enable BlueZ: ${ENABLE_BLUEZ}
1271 Enable udev: ${ENABLE_UDEV}
1272 Enable HAL->udev compat: ${ENABLE_HAL_COMPAT}
1273 Enable TCP Wrappers: ${ENABLE_TCPWRAP}
1274 Enable libsamplerate: ${ENABLE_LIBSAMPLERATE}
1275 Enable IPv6: ${ENABLE_IPV6}
1276 Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1277 Enable fftw: ${ENABLE_FFTW}
1278 Enable orc: ${ENABLE_ORC}
1279 Database
1280 tdb: ${ENABLE_TDB}
1281 gdbm: ${ENABLE_GDBM}
1282 simple database: ${ENABLE_SIMPLEDB}
1283
1284 System User: ${PA_SYSTEM_USER}
1285 System Group: ${PA_SYSTEM_GROUP}
1286 Access Group: ${PA_ACCESS_GROUP}
1287 Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1288 Force preopen: ${FORCE_PREOPEN}
1289 Preopened modules: ${PREOPEN_MODS}
1290 "
1291
1292 if test "${ENABLE_DBUS}" = "no" && test "x$os_is_win32" != "x1" ; then
1293 echo "
1294 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1295 You do not have D-Bus support enabled. It is strongly recommended
1296 that you enable D-Bus support if your platform supports it.
1297 Many parts of PulseAudio use D-Bus, from ConsoleKit interaction
1298 to the Device Reservation Protocol to speak to JACK, Bluetooth
1299 support and even a native control protocol for communicating and
1300 controling the PulseAudio daemon itself.
1301 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1302 "
1303 fi
1304
1305 if test "${ENABLE_UDEV}" = "no" && test "x$os_is_win32" != "x1" ; then
1306 echo "
1307 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1308 You do not have udev support enabled. It is strongly recommended
1309 that you enable udev support if your platform supports it as it is
1310 the primary method used to detect hardware audio devices (on Linux)
1311 and is thus a critical part of PulseAudio on that platform.
1312 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1313 "
1314 fi