code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23 AC_INIT([polypaudio],[0.8.1],[mzcbylcnhqvb (at) 0pointer (dot) de])
  24 AC_CONFIG_SRCDIR([src/daemon/main.c])
  25 AC_CONFIG_HEADERS([config.h])
  26 AM_INIT_AUTOMAKE([foreign -Wall])
  27
  28 AC_SUBST(PA_MAJORMINOR, "$PACKAGE_VERSION")
  29 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  30
  31 AC_SUBST(PA_API_VERSION, 8)
  32 AC_SUBST(PA_PROTOCOL_VERSION, 8)
  33
  34 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  35    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  36    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  37 fi
  38
  39 #### Platform hacks ####
  40
  41 case $host in
  42    *-*-solaris* )
  43       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  44       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  45       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  46       ;;
  47 esac
  48
  49 #### Checks for programs. ####
  50
  51 # CC
  52
  53 AC_PROG_CC
  54 AC_PROG_GCC_TRADITIONAL
  55 AC_GNU_SOURCE
  56
  57 # M4
  58
  59 AC_PATH_PROG([M4], [m4 gm4], [no])
  60 if test "x$M4" = xno ; then
  61    AC_MSG_ERROR([m4 missing])
  62 fi
  63
  64 # GCC flags
  65
  66 test_gcc_flag() {
  67     AC_LANG_CONFTEST([int main() {}])
  68     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  69     ret=$?
  70     rm -f conftest.o
  71     return $ret
  72 }
  73
  74 # If using GCC specify some additional parameters
  75 if test "x$GCC" = "xyes" ; then
  76
  77     # We use gnu99 instead of c99 because many have interpreted the standard
  78     # in a way that int64_t isn't defined on non-64 bit platforms.
  79     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  80
  81     for flag in $DESIRED_FLAGS ; do
  82         AC_MSG_CHECKING([whether $CC accepts $flag])
  83         if test_gcc_flag $flag ; then
  84            CFLAGS="$CFLAGS $flag"
  85            AC_MSG_RESULT([yes])
  86         else
  87            AC_MSG_RESULT([no])
  88         fi
  89     done
  90 fi
  91
  92 # LYNX documentation generation
  93 AC_ARG_ENABLE(lynx,
  94         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
  95 [case "${enableval}" in
  96   yes) lynx=yes ;;
  97   no)  lynx=no ;;
  98   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
  99 esac],[lynx=yes])
 100
 101 if test x$lynx = xyes ; then
 102    AC_CHECK_PROG(have_lynx, lynx, yes, no)
 103
 104    if test x$have_lynx = xno ; then
 105      AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
 106    fi
 107 fi
 108
 109 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
 110
 111 #### libtool stuff ####
 112
 113 AC_LTDL_ENABLE_INSTALL
 114 AC_LIBLTDL_INSTALLABLE
 115 AC_SUBST(LTDLINCL)
 116 AC_SUBST(LIBLTDL)
 117 AC_LIBTOOL_DLOPEN
 118 AC_LIBTOOL_WIN32_DLL
 119 AC_PROG_LIBTOOL
 120 AC_CONFIG_SUBDIRS(libltdl)
 121
 122 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 123     AC_MSG_ERROR([[
 124
 125         *** Cannot find the libltdl development files.
 126         *** Maybe you need to install the libltdl-dev package.
 127         ]])
 128 fi
 129
 130 #### Determine build environment ####
 131
 132 os_is_win32=0
 133
 134 case "$host_os" in
 135         mingw*)
 136         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 137         os_is_win32=1
 138                 ;;
 139         esac
 140
 141 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 142
 143 ###################################
 144 #   Basic environment checks      #
 145 ###################################
 146
 147 #### Checks for header files. ####
 148
 149 # ISO
 150 AC_HEADER_STDC
 151
 152 # POSIX
 153 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 154     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 155     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 156     syslog.h])
 157 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 158 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 159
 160 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 161 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 162
 163 # XPG4-UNIX
 164 AC_CHECK_HEADERS([sys/poll.h])
 165
 166 # Linux
 167 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 168
 169 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 170
 171 # Solaris
 172 AC_CHECK_HEADERS([sys/filio.h])
 173
 174 # Windows
 175 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 176
 177 # Other
 178 AC_CHECK_HEADERS([sys/ioctl.h])
 179
 180 #### Typdefs, structures, etc. ####
 181
 182 AC_C_CONST
 183 AC_C_BIGENDIAN
 184 AC_TYPE_PID_T
 185 AC_TYPE_SIZE_T
 186 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 187     [Define ssize_t if it is not done by the standard libs.])])
 188 AC_TYPE_OFF_T
 189 AC_TYPE_SIGNAL
 190 AC_TYPE_UID_T
 191
 192 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 193 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 194
 195 # Solaris lacks this
 196 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 197     [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])
 198
 199 #### Check for libs ####
 200
 201 # ISO
 202 AC_SEARCH_LIBS([pow], [m])
 203
 204 # POSIX
 205 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 206
 207 # BSD
 208 AC_SEARCH_LIBS([connect], [socket])
 209
 210 # Non-standard
 211
 212 # This magic is needed so we do not needlessly add static libs to the win32
 213 # build, disabling its ability to make dlls.
 214 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 215
 216 #### Check for functions ####
 217
 218 # POSIX
 219 AC_FUNC_FORK
 220 AC_FUNC_GETGROUPS
 221 AC_FUNC_SELECT_ARGTYPES
 222 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 223     getuid inet_ntop inet_pton nanosleep pipe setpgid setsid sigaction sleep])
 224 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 225
 226 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 227
 228 # X/OPEN
 229 AC_CHECK_FUNCS([readlink])
 230
 231 # SUSv2
 232 AC_CHECK_FUNCS([ctime_r usleep])
 233
 234 # BSD
 235 AC_CHECK_FUNCS([lstat])
 236
 237 # Non-standard
 238
 239 AC_CHECK_FUNCS(setresuid)
 240 AC_CHECK_FUNCS(setreuid)
 241
 242 #### POSIX threads ####
 243
 244 ACX_PTHREAD
 245
 246 #### Large File-Support (LFS) ####
 247
 248 AC_SYS_LARGEFILE
 249
 250 ###################################
 251 #      External libraries         #
 252 ###################################
 253
 254 #### X11 (optional) ####
 255
 256 HAVE_X11=0
 257
 258 # The macro tests the host, not the build target
 259 if test "x$os_is_win32" != "x1" ; then
 260     AC_PATH_XTRA
 261     test "x$no_x" != "xyes" && HAVE_X11=1
 262 fi
 263
 264 AC_SUBST(HAVE_X11)
 265 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 266 if test "x$HAVE_X11" = "x1" ; then
 267     AC_DEFINE([HAVE_X11], 1, [Have X11])
 268 fi
 269
 270 #### Capabilities (optional) ####
 271
 272 CAP_LIBS=''
 273
 274 AC_ARG_WITH(
 275         [caps],
 276         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 277
 278 if test "x${with_caps}" != "xno"; then
 279     AC_SEARCH_LIBS([cap_init], [cap])
 280     AC_CHECK_HEADERS([sys/capability.h])
 281 fi
 282
 283 #### pkg-config ####
 284
 285 # Check for pkg-config manually first, as if its not installed the
 286 # PKG_PROG_PKG_CONFIG macro won't be defined.
 287 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 288
 289 if test x"$have_pkg_config" = "xno"; then
 290     AC_MSG_ERROR(pkg-config is required to install this program)
 291 fi
 292
 293 PKG_PROG_PKG_CONFIG
 294
 295 #### Sample rate conversion ####
 296
 297 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 298 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 299 AC_SUBST(LIBSAMPLERATE_LIBS)
 300
 301 #### Sound file ####
 302
 303 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 304 AC_SUBST(LIBSNDFILE_CFLAGS)
 305 AC_SUBST(LIBSNDFILE_LIBS)
 306
 307 #### OSS support (optional) ####
 308
 309 AC_CHECK_HEADERS([sys/soundcard.h], [
 310 HAVE_OSS=1
 311 AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 312 ], [HAVE_OSS=0])
 313 AC_SUBST(HAVE_OSS)
 314 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 315
 316
 317 #### ALSA support (optional) ####
 318
 319 PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [
 320 HAVE_ALSA=1
 321 AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 322 ], [HAVE_ALSA=0])
 323 AC_SUBST(ASOUNDLIB_CFLAGS)
 324 AC_SUBST(ASOUNDLIB_LIBS)
 325 AC_SUBST(HAVE_ALSA)
 326 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 327
 328 #### Solaris audio support (optional) ####
 329
 330 AC_CHECK_HEADERS([sys/audio.h], [
 331 HAVE_SOLARIS=1
 332 AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 333 ], [HAVE_SOLARIS=0])
 334 AC_SUBST(HAVE_SOLARIS)
 335 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 336
 337 #### GLib 2 support (optional) ####
 338
 339 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)
 340 AC_SUBST(GLIB20_CFLAGS)
 341 AC_SUBST(GLIB20_LIBS)
 342 AC_SUBST(HAVE_GLIB20)
 343 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 344
 345 #### GLib 1 support (optional) ####
 346
 347 PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, HAVE_GLIB12=0)
 348 AC_SUBST(GLIB12_CFLAGS)
 349 AC_SUBST(GLIB12_LIBS)
 350 AC_SUBST(HAVE_GLIB12)
 351 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 352
 353 #### Howl support (optional) ####
 354
 355 PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, HAVE_HOWL=0)
 356 AC_SUBST(HOWL_CFLAGS)
 357 AC_SUBST(HOWL_LIBS)
 358 AC_SUBST(HAVE_HOWL)
 359 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 360
 361 ### LIBOIL ####
 362
 363 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 364 AC_SUBST(LIBOIL_CFLAGS)
 365 AC_SUBST(LIBOIL_LIBS)
 366
 367 ### JACK (optional) ####
 368
 369 PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ], HAVE_JACK=1, HAVE_JACK=0)
 370 AC_SUBST(JACK_CFLAGS)
 371 AC_SUBST(JACK_LIBS)
 372 AC_SUBST(HAVE_JACK)
 373 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 374
 375 #### Async DNS support (optional) ####
 376
 377 PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)
 378 AC_SUBST(LIBASYNCNS_CFLAGS)
 379 AC_SUBST(LIBASYNCNS_LIBS)
 380 AC_SUBST(HAVE_LIBASYNCNS)
 381 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 382
 383 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 384    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 385 fi
 386
 387 #### TCP wrappers (optional) ####
 388
 389 ACX_LIBWRAP
 390 AC_SUBST(LIBWRAP_LIBS)
 391
 392 #### LIRC support (optional) ####
 393
 394 ACX_LIRC
 395 AC_SUBST(LIRC_CFLAGS)
 396 AC_SUBST(LIRC_LIBS)
 397 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 398
 399 ###################################
 400 #            Output               #
 401 ###################################
 402
 403 AC_ARG_ENABLE(
 404         [static-bins],
 405         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 406         [STATIC_BINS=1], [STATIC_BINS=0])
 407 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 408
 409 AC_ARG_WITH(
 410         [preopen-mods],
 411         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 412         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 413 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 414 if test "x$PREOPEN_MODS" != "xall" ; then
 415     tmpLIBS=""
 416     for mod in $PREOPEN_MODS; do
 417         tmpLIBS="$tmpLIBS module-$mod.la"
 418     done
 419     PREOPEN_MODS="$tmpLIBS"
 420     AC_SUBST(PREOPEN_MODS)
 421 fi
 422
 423 AC_ARG_ENABLE(
 424         [force-preopen],
 425         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 426         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 427 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 428
 429 AC_CONFIG_FILES([
 430 Makefile
 431 src/Makefile
 432 polyplib.pc
 433 polyplib-simple.pc
 434 polyplib-browse.pc
 435 polyplib-glib-mainloop.pc
 436 polyplib-glib12-mainloop.pc
 437 doc/Makefile
 438 doc/README.html
 439 doc/cli.html
 440 doc/daemon.html
 441 doc/modules.html
 442 doxygen/Makefile
 443 doxygen/doxygen.conf
 444 src/polyp/version.h
 445 doc/FAQ.html
 446 ])
 447 AC_OUTPUT