code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of PulseAudio.
   7 #
   8 # PulseAudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # PulseAudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with PulseAudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23
  24 m4_define(PA_MAJOR, [0])
  25 m4_define(PA_MINOR, [9])
  26 m4_define(PA_MICRO, [2])
  27
  28 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  29 AC_CONFIG_SRCDIR([src/daemon/main.c])
  30 AC_CONFIG_HEADERS([config.h])
  31 AM_INIT_AUTOMAKE([foreign -Wall])
  32
  33 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  34 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/pulseaudio/])
  35
  36 AC_SUBST(PA_API_VERSION, 9)
  37 AC_SUBST(PA_PROTOCOL_VERSION, 9)
  38
  39 AC_SUBST(LIBPULSE_VERSION_INFO, [0:0:0])
  40 AC_SUBST(LIBPULSECORE_VERSION_INFO, [0:1:0])
  41 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:0:0])
  42 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [0:0:0])
  43 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:0:0])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 #### Platform hacks ####
  51
  52 case $host in
  53    *-*-solaris* )
  54       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  55       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  56       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  57       ;;
  58 esac
  59
  60 #### Checks for programs. ####
  61
  62 # CC
  63
  64 AC_PROG_CC
  65 AC_PROG_GCC_TRADITIONAL
  66 AC_GNU_SOURCE
  67
  68 # M4
  69
  70 AC_PATH_PROG([M4], [m4 gm4], [no])
  71 if test "x$M4" = xno ; then
  72    AC_MSG_ERROR([m4 missing])
  73 fi
  74
  75 # GCC flags
  76
  77 test_gcc_flag() {
  78     AC_LANG_CONFTEST([int main() {}])
  79     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  80     ret=$?
  81     rm -f conftest.o
  82     return $ret
  83 }
  84
  85 # If using GCC specify some additional parameters
  86 if test "x$GCC" = "xyes" ; then
  87
  88     # We use gnu99 instead of c99 because many have interpreted the standard
  89     # in a way that int64_t isn't defined on non-64 bit platforms.
  90     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  91
  92     for flag in $DESIRED_FLAGS ; do
  93         AC_MSG_CHECKING([whether $CC accepts $flag])
  94         if test_gcc_flag $flag ; then
  95            CFLAGS="$CFLAGS $flag"
  96            AC_MSG_RESULT([yes])
  97         else
  98            AC_MSG_RESULT([no])
  99         fi
 100     done
 101 fi
 102
 103 #### libtool stuff ####
 104
 105 AC_LTDL_ENABLE_INSTALL
 106 AC_LIBLTDL_INSTALLABLE
 107 AC_SUBST(LTDLINCL)
 108 AC_SUBST(LIBLTDL)
 109 AC_LIBTOOL_DLOPEN
 110 AC_LIBTOOL_WIN32_DLL
 111 AC_PROG_LIBTOOL
 112 AC_CONFIG_SUBDIRS(libltdl)
 113
 114 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 115     AC_MSG_ERROR([[
 116
 117         *** Cannot find the libltdl development files.
 118         *** Maybe you need to install the libltdl-dev package.
 119         ]])
 120 fi
 121
 122 #### Determine build environment ####
 123
 124 os_is_win32=0
 125
 126 case "$host_os" in
 127         mingw*)
 128         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 129         os_is_win32=1
 130                 ;;
 131         esac
 132
 133 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 134
 135 ###################################
 136 #   Basic environment checks      #
 137 ###################################
 138
 139 #### Checks for header files. ####
 140
 141 # ISO
 142 AC_HEADER_STDC
 143
 144 # POSIX
 145 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 146     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 147     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 148     syslog.h])
 149 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 150 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 151
 152 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 153 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 154
 155 # XPG4-UNIX
 156 AC_CHECK_HEADERS([sys/poll.h])
 157
 158 # Linux
 159 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 160
 161 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 162
 163 AC_CHECK_HEADERS([sys/prctl.h])
 164
 165 # Solaris
 166 AC_CHECK_HEADERS([sys/filio.h])
 167
 168 # Windows
 169 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 170
 171 # Other
 172 AC_CHECK_HEADERS([sys/ioctl.h])
 173
 174 #### Typdefs, structures, etc. ####
 175
 176 AC_C_CONST
 177 AC_C_BIGENDIAN
 178 AC_TYPE_PID_T
 179 AC_TYPE_SIZE_T
 180 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 181     [Define ssize_t if it is not done by the standard libs.])])
 182 AC_TYPE_OFF_T
 183 AC_TYPE_SIGNAL
 184 AC_TYPE_UID_T
 185
 186 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 187 HAVE_SIGXCPU=1
 188 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 189 ], [HAVE_SIGXCPU=0])
 190 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 191
 192 # Solaris lacks this
 193 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 194     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 195         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 196
 197 #### Check for libs ####
 198
 199 # ISO
 200 AC_SEARCH_LIBS([pow], [m])
 201
 202 # POSIX
 203 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 204 AC_SEARCH_LIBS([dlopen], [dl])
 205
 206 # BSD
 207 AC_SEARCH_LIBS([connect], [socket])
 208
 209 # Non-standard
 210
 211 # This magic is needed so we do not needlessly add static libs to the win32
 212 # build, disabling its ability to make dlls.
 213 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 214
 215 #### Check for functions ####
 216
 217 # POSIX
 218 AC_FUNC_FORK
 219 AC_FUNC_GETGROUPS
 220 AC_FUNC_SELECT_ARGTYPES
 221 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 222     getuid inet_ntop inet_pton nanosleep pipe setpgid setsid sigaction sleep])
 223 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 224
 225 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 226
 227 # X/OPEN
 228 AC_CHECK_FUNCS([readlink])
 229
 230 # SUSv2
 231 AC_CHECK_FUNCS([ctime_r usleep])
 232
 233 # SUSv3
 234 AC_CHECK_FUNCS([strerror_r])
 235
 236 # BSD
 237 AC_CHECK_FUNCS([lstat])
 238
 239 # Non-standard
 240
 241 AC_CHECK_FUNCS(setresuid)
 242 AC_CHECK_FUNCS(setreuid)
 243
 244 #### POSIX threads ####
 245
 246 ACX_PTHREAD
 247
 248 #### Large File-Support (LFS) ####
 249
 250 AC_SYS_LARGEFILE
 251
 252 #### [lib]iconv ####
 253
 254 AM_ICONV
 255
 256 ###################################
 257 #      External libraries         #
 258 ###################################
 259
 260 #### X11 (optional) ####
 261
 262 HAVE_X11=0
 263
 264 # The macro tests the host, not the build target
 265 if test "x$os_is_win32" != "x1" ; then
 266     AC_PATH_XTRA
 267     test "x$no_x" != "xyes" && HAVE_X11=1
 268 fi
 269
 270 AC_SUBST(HAVE_X11)
 271 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 272 if test "x$HAVE_X11" = "x1" ; then
 273     AC_DEFINE([HAVE_X11], 1, [Have X11])
 274 fi
 275
 276 #### Capabilities (optional) ####
 277
 278 CAP_LIBS=''
 279
 280 AC_ARG_WITH(
 281         [caps],
 282         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 283
 284 if test "x${with_caps}" != "xno"; then
 285     AC_SEARCH_LIBS([cap_init], [cap], [], [
 286                     if test "x${with_caps}" = "xyes" ; then
 287                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 288                     fi])
 289     AC_CHECK_HEADERS([sys/capability.h], [], [
 290                     if test "x${with_caps}" = "xyes" ; then
 291                         AC_MSG_ERROR([*** POSIX caps headers not found])
 292                     fi])
 293 fi
 294
 295 #### pkg-config ####
 296
 297 # Check for pkg-config manually first, as if its not installed the
 298 # PKG_PROG_PKG_CONFIG macro won't be defined.
 299 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 300
 301 if test x"$have_pkg_config" = "xno"; then
 302     AC_MSG_ERROR(pkg-config is required to install this program)
 303 fi
 304
 305 PKG_PROG_PKG_CONFIG
 306
 307 #### Sample rate conversion ####
 308
 309 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 310 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 311 AC_SUBST(LIBSAMPLERATE_LIBS)
 312
 313 #### Sound file ####
 314
 315 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 316 AC_SUBST(LIBSNDFILE_CFLAGS)
 317 AC_SUBST(LIBSNDFILE_LIBS)
 318
 319 #### OSS support (optional) ####
 320
 321 AC_ARG_ENABLE([oss],
 322     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 323         [
 324             case "${enableval}" in
 325                 yes) oss=yes ;;
 326                 no) oss=no ;;
 327                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 328             esac
 329         ],
 330         [oss=auto])
 331
 332 if test "x${oss}" != xno ; then
 333     AC_CHECK_HEADERS([sys/soundcard.h],
 334         [
 335             HAVE_OSS=1
 336             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 337         ],
 338         [
 339             HAVE_OSS=0
 340             if test "x$oss" = xyes ; then
 341                 AC_MSG_ERROR([*** OSS support not found])
 342             fi
 343         ])
 344 else
 345     HAVE_OSS=0
 346 fi
 347
 348 AC_SUBST(HAVE_OSS)
 349 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 350
 351
 352 #### ALSA support (optional) ####
 353
 354 AC_ARG_ENABLE([alsa],
 355     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 356         [
 357             case "${enableval}" in
 358                 yes) alsa=yes ;;
 359                 no) alsa=no ;;
 360                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 361             esac
 362         ],
 363         [alsa=auto])
 364
 365 if test "x${alsa}" != xno ; then
 366     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ],
 367         [
 368             HAVE_ALSA=1
 369             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 370         ],
 371         [
 372             HAVE_ALSA=0
 373             if test "x$alsa" = xyes ; then
 374                 AC_MSG_ERROR([*** ALSA support not found])
 375             fi
 376         ])
 377 else
 378     HAVE_ALSA=0
 379 fi
 380
 381 AC_SUBST(ASOUNDLIB_CFLAGS)
 382 AC_SUBST(ASOUNDLIB_LIBS)
 383 AC_SUBST(HAVE_ALSA)
 384 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 385
 386 #### Solaris audio support (optional) ####
 387
 388 AC_ARG_ENABLE([solaris],
 389     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 390         [
 391             case "${enableval}" in
 392                 yes) solaris=yes ;;
 393                 no) solaris=no ;;
 394                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 395             esac
 396         ],
 397         [solaris=auto])
 398
 399 if test "x${solaris}" != xno ; then
 400     AC_CHECK_HEADERS([sys/audio.h],
 401         [
 402             HAVE_SOLARIS=1
 403             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 404         ],
 405         [
 406             HAVE_SOLARIS=0
 407             if test "x$solaris" = xyes ; then
 408                 AC_MSG_ERROR([*** Solaris audio support not found])
 409             fi
 410         ])
 411 else
 412     HAVE_SOLARIS=0
 413 fi
 414
 415 AC_SUBST(HAVE_SOLARIS)
 416 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 417
 418 #### GLib 2 support (optional) ####
 419
 420 AC_ARG_ENABLE([glib2],
 421     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 422         [
 423             case "${enableval}" in
 424                 yes) glib2=yes ;;
 425                 no) glib2=no ;;
 426                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 427             esac
 428         ],
 429         [glib2=auto])
 430
 431 if test "x${glib2}" != xno ; then
 432     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 433         HAVE_GLIB20=1,
 434         [
 435             HAVE_GLIB20=0
 436             if test "x$glib2" = xyes ; then
 437                 AC_MSG_ERROR([*** GLib 2 support not found])
 438             fi
 439         ])
 440 else
 441     HAVE_GLIB20=0
 442 fi
 443
 444 AC_SUBST(GLIB20_CFLAGS)
 445 AC_SUBST(GLIB20_LIBS)
 446 AC_SUBST(HAVE_GLIB20)
 447 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 448
 449 #### GLib 1 support (optional) ####
 450
 451 AC_ARG_ENABLE([glib1],
 452     AC_HELP_STRING([--disable-glib1], [Disable optional GLib 1 support]),
 453         [
 454             case "${enableval}" in
 455                 yes) glib1=yes ;;
 456                 no) glib1=no ;;
 457                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib1) ;;
 458             esac
 459         ],
 460         [glib1=auto])
 461
 462 if test "x${glib1}" != xno ; then
 463     PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ],
 464         HAVE_GLIB12=1,
 465         [
 466             HAVE_GLIB12=0
 467             if test "x$glib1" = xyes ; then
 468                 AC_MSG_ERROR([*** GLib 1 support not found])
 469             fi
 470         ])
 471 else
 472     HAVE_GLIB12=0
 473 fi
 474
 475 AC_SUBST(GLIB12_CFLAGS)
 476 AC_SUBST(GLIB12_LIBS)
 477 AC_SUBST(HAVE_GLIB12)
 478 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 479
 480 #### Avahi support (optional) ####
 481
 482 AC_ARG_ENABLE([avahi],
 483     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 484         [
 485             case "${enableval}" in
 486                 yes) avahi=yes ;;
 487                 no) avahi=no ;;
 488                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 489             esac
 490         ],
 491         [avahi=auto])
 492
 493 if test "x${avahi}" != xno ; then
 494     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 495         HAVE_AVAHI=1,
 496         [
 497                 HAVE_AVAHI=0
 498                 if test "x$avahi" = xyes ; then
 499                         AC_MSG_ERROR([*** Avahi support not found])
 500                 fi
 501         ])
 502 else
 503     HAVE_AVAHI=0
 504 fi
 505
 506 AC_SUBST(AVAHI_CFLAGS)
 507 AC_SUBST(AVAHI_LIBS)
 508 AC_SUBST(HAVE_AVAHI)
 509 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 510
 511 ### LIBOIL ####
 512
 513 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 514 AC_SUBST(LIBOIL_CFLAGS)
 515 AC_SUBST(LIBOIL_LIBS)
 516
 517 ### JACK (optional) ####
 518
 519 AC_ARG_ENABLE([jack],
 520     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 521         [
 522             case "${enableval}" in
 523                 yes) jack=yes ;;
 524                 no) jack=no ;;
 525                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 526             esac
 527         ],
 528         [jack=auto])
 529
 530 if test "x${jack}" != xno ; then
 531     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 532         HAVE_JACK=1,
 533         [
 534             HAVE_JACK=0
 535             if test "x$jack" = xyes ; then
 536                 AC_MSG_ERROR([*** JACK support not found])
 537             fi
 538         ])
 539 else
 540     HAVE_JACK=0
 541 fi
 542
 543 AC_SUBST(JACK_CFLAGS)
 544 AC_SUBST(JACK_LIBS)
 545 AC_SUBST(HAVE_JACK)
 546 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 547
 548 #### Async DNS support (optional) ####
 549
 550 AC_ARG_ENABLE([asyncns],
 551     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 552         [
 553             case "${enableval}" in
 554                 yes) asyncns=yes ;;
 555                 no) asyncns=no ;;
 556                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 557             esac
 558         ],
 559         [asyncns=auto])
 560
 561 if test "x${asyncns}" != xno ; then
 562     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 563         HAVE_LIBASYNCNS=1,
 564         [
 565             HAVE_LIBASYNCNS=0
 566             if test "x$asyncns" = xyes ; then
 567                 AC_MSG_ERROR([*** Async DNS support not found])
 568             fi
 569         ])
 570 else
 571     HAVE_LIBASYNCNS=0
 572 fi
 573
 574 AC_SUBST(LIBASYNCNS_CFLAGS)
 575 AC_SUBST(LIBASYNCNS_LIBS)
 576 AC_SUBST(HAVE_LIBASYNCNS)
 577 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 578
 579 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 580    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 581 fi
 582
 583 #### TCP wrappers (optional) ####
 584
 585 AC_ARG_ENABLE([tcpwrap],
 586     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 587         [
 588             case "${enableval}" in
 589                 yes) tcpwrap=yes ;;
 590                 no) tcpwrap=no ;;
 591                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 592             esac
 593         ],
 594         [tcpwrap=auto])
 595
 596 if test "x${tcpwrap}" != xno ; then
 597     ACX_LIBWRAP
 598     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 599         AC_MSG_ERROR([*** TCP wrappers support not found])
 600     fi
 601 else
 602     LIBWRAP_LIBS=
 603 fi
 604
 605 AC_SUBST(LIBWRAP_LIBS)
 606
 607 #### LIRC support (optional) ####
 608
 609 AC_ARG_ENABLE([lirc],
 610     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 611         [
 612             case "${enableval}" in
 613                 yes) lirc=yes ;;
 614                 no) lirc=no ;;
 615                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 616             esac
 617         ],
 618         [lirc=auto])
 619
 620 if test "x${lirc}" != xno ; then
 621     ACX_LIRC
 622     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 623         AC_MSG_ERROR([*** LIRC support not found])
 624     fi
 625 else
 626     HAVE_LIRC=0
 627 fi
 628
 629 AC_SUBST(LIRC_CFLAGS)
 630 AC_SUBST(LIRC_LIBS)
 631 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 632
 633 ###################################
 634 #            Output               #
 635 ###################################
 636
 637 AC_ARG_ENABLE(
 638         [static-bins],
 639         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 640         [STATIC_BINS=1], [STATIC_BINS=0])
 641 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 642
 643 AC_ARG_WITH(
 644         [preopen-mods],
 645         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 646         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 647 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 648 if test "x$PREOPEN_MODS" != "xall" ; then
 649     tmpLIBS=""
 650     for mod in $PREOPEN_MODS; do
 651         tmpLIBS="$tmpLIBS module-$mod.la"
 652     done
 653     PREOPEN_MODS="$tmpLIBS"
 654     AC_SUBST(PREOPEN_MODS)
 655 fi
 656
 657 AC_ARG_WITH(
 658         [module-dir],
 659         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
 660         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
 661
 662 AC_SUBST(modlibexecdir)
 663
 664 AC_ARG_ENABLE(
 665         [force-preopen],
 666         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 667         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 668 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 669
 670 AC_CONFIG_FILES([
 671 Makefile
 672 src/Makefile
 673 libpulse.pc
 674 libpulse-simple.pc
 675 libpulse-browse.pc
 676 libpulse-mainloop-glib.pc
 677 libpulse-mainloop-glib12.pc
 678 doxygen/Makefile
 679 doxygen/doxygen.conf
 680 src/pulse/version.h
 681 ])
 682 AC_OUTPUT
 683
 684 # ==========================================================================
 685 ENABLE_X11=no
 686 if test "x$HAVE_X11" = "x1" ; then
 687    ENABLE_X11=yes
 688 fi
 689
 690 ENABLE_OSS=no
 691 if test "x$HAVE_OSS" = "x1" ; then
 692    ENABLE_OSS=yes
 693 fi
 694
 695 ENABLE_ALSA=no
 696 if test "x$HAVE_ALSA" = "x1" ; then
 697    ENABLE_ALSA=yes
 698 fi
 699
 700 ENABLE_SOLARIS=no
 701 if test "x$HAVE_SOLARIS" = "x1" ; then
 702    ENABLE_SOLARIS=yes
 703 fi
 704
 705 ENABLE_GLIB20=no
 706 if test "x$HAVE_GLIB20" = "x1" ; then
 707    ENABLE_GLIB20=yes
 708 fi
 709
 710 ENABLE_GLIB12=no
 711 if test "x$HAVE_GLIB12" = "x1" ; then
 712    ENABLE_GLIB12=yes
 713 fi
 714
 715 ENABLE_AVAHI=no
 716 if test "x$HAVE_AVAHI" = "x1" ; then
 717    ENABLE_AVAHI=yes
 718 fi
 719
 720 ENABLE_JACK=no
 721 if test "x$HAVE_JACK" = "x1" ; then
 722    ENABLE_JACK=yes
 723 fi
 724
 725 ENABLE_LIBASYNCNS=no
 726 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
 727    ENABLE_LIBASYNCNS=yes
 728 fi
 729
 730 ENABLE_LIRC=no
 731 if test "x$HAVE_LIRC" = "x1" ; then
 732    ENABLE_LIRC=yes
 733 fi
 734
 735 ENABLE_TCPWRAP=no
 736 if test "x${LIBWRAP_LIBS}" != x ; then
 737    ENABLE_TCPWRAP=yes
 738 fi
 739
 740 echo "
 741  ---{ $PACKAGE_NAME $VERSION }---
 742
 743     prefix:                 ${prefix}
 744     sysconfdir:             ${sysconfdir}
 745     localstatedir:          ${localstatedir}
 746     compiler:               ${CC}
 747     cflags:                 ${CFLAGS}
 748     Have X11:               ${ENABLE_X11}
 749     Enable OSS:             ${ENABLE_OSS}
 750     Enable Alsa:            ${ENABLE_ALSA}
 751     Enable Solaris:         ${ENABLE_SOLARIS}
 752     Enable Glib 2.0:        ${ENABLE_GLIB20}
 753     Enable Glib 1.2:        ${ENABLE_GLIB12}
 754     Enable Avahi:           ${ENABLE_AVAHI}
 755     Enable Jack:            ${ENABLE_JACK}
 756     Enable Async DNS:       ${ENABLE_LIBASYNCNS}
 757     Enable LIRC:            ${ENABLE_LIRC}
 758     Enable TCP Wrappers:    ${ENABLE_TCPWRAP}
 759 "