code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23
  24 m4_define(PA_MAJOR, [0])
  25 m4_define(PA_MINOR, [9])
  26 m4_define(PA_MICRO, [0])
  27
  28 AC_INIT([polypaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  29 AC_CONFIG_SRCDIR([src/daemon/main.c])
  30 AC_CONFIG_HEADERS([config.h])
  31 AM_INIT_AUTOMAKE([foreign -Wall])
  32
  33 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  34 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  35
  36 AC_SUBST(PA_API_VERSION, 9)
  37 AC_SUBST(PA_PROTOCOL_VERSION, 8)
  38
  39 AC_SUBST(LIBPOLYP_VERSION_INFO, [0:0:0])
  40 AC_SUBST(LIBPOLYPCORE_VERSION_INFO, [0:0:0])
  41 AC_SUBST(LIBPOLYP_SIMPLE_VERSION_INFO, [0:0:0])
  42 AC_SUBST(LIBPOLYP_BROWSE_VERSION_INFO, [0:0:0])
  43 AC_SUBST(LIBPOLYP_MAINLOOP_GLIB_VERSION_INFO, [0:0:0])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 #### Platform hacks ####
  51
  52 case $host in
  53    *-*-solaris* )
  54       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  55       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  56       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  57       ;;
  58 esac
  59
  60 #### Checks for programs. ####
  61
  62 # CC
  63
  64 AC_PROG_CC
  65 AC_PROG_GCC_TRADITIONAL
  66 AC_GNU_SOURCE
  67
  68 # M4
  69
  70 AC_PATH_PROG([M4], [m4 gm4], [no])
  71 if test "x$M4" = xno ; then
  72    AC_MSG_ERROR([m4 missing])
  73 fi
  74
  75 # GCC flags
  76
  77 test_gcc_flag() {
  78     AC_LANG_CONFTEST([int main() {}])
  79     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  80     ret=$?
  81     rm -f conftest.o
  82     return $ret
  83 }
  84
  85 # If using GCC specify some additional parameters
  86 if test "x$GCC" = "xyes" ; then
  87
  88     # We use gnu99 instead of c99 because many have interpreted the standard
  89     # in a way that int64_t isn't defined on non-64 bit platforms.
  90     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  91
  92     for flag in $DESIRED_FLAGS ; do
  93         AC_MSG_CHECKING([whether $CC accepts $flag])
  94         if test_gcc_flag $flag ; then
  95            CFLAGS="$CFLAGS $flag"
  96            AC_MSG_RESULT([yes])
  97         else
  98            AC_MSG_RESULT([no])
  99         fi
 100     done
 101 fi
 102
 103 # LYNX documentation generation
 104 AC_ARG_ENABLE(lynx,
 105         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
 106 [case "${enableval}" in
 107   yes) lynx=yes ;;
 108   no)  lynx=no ;;
 109   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
 110 esac],[lynx=yes])
 111
 112 if test x$lynx = xyes ; then
 113    AC_CHECK_PROG(have_lynx, lynx, yes, no)
 114
 115    if test x$have_lynx = xno ; then
 116      AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
 117    fi
 118 fi
 119
 120 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
 121
 122 #### libtool stuff ####
 123
 124 AC_LTDL_ENABLE_INSTALL
 125 AC_LIBLTDL_INSTALLABLE
 126 AC_SUBST(LTDLINCL)
 127 AC_SUBST(LIBLTDL)
 128 AC_LIBTOOL_DLOPEN
 129 AC_LIBTOOL_WIN32_DLL
 130 AC_PROG_LIBTOOL
 131 AC_CONFIG_SUBDIRS(libltdl)
 132
 133 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 134     AC_MSG_ERROR([[
 135
 136         *** Cannot find the libltdl development files.
 137         *** Maybe you need to install the libltdl-dev package.
 138         ]])
 139 fi
 140
 141 #### Determine build environment ####
 142
 143 os_is_win32=0
 144
 145 case "$host_os" in
 146         mingw*)
 147         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 148         os_is_win32=1
 149                 ;;
 150         esac
 151
 152 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 153
 154 ###################################
 155 #   Basic environment checks      #
 156 ###################################
 157
 158 #### Checks for header files. ####
 159
 160 # ISO
 161 AC_HEADER_STDC
 162
 163 # POSIX
 164 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h iconv.h netdb.h netinet/in.h \
 165     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 166     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 167     syslog.h])
 168 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 169 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 170
 171 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 172 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 173
 174 # XPG4-UNIX
 175 AC_CHECK_HEADERS([sys/poll.h])
 176
 177 # Linux
 178 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 179
 180 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 181
 182 # Solaris
 183 AC_CHECK_HEADERS([sys/filio.h])
 184
 185 # Windows
 186 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 187
 188 # Other
 189 AC_CHECK_HEADERS([sys/ioctl.h])
 190
 191 #### Typdefs, structures, etc. ####
 192
 193 AC_C_CONST
 194 AC_C_BIGENDIAN
 195 AC_TYPE_PID_T
 196 AC_TYPE_SIZE_T
 197 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 198     [Define ssize_t if it is not done by the standard libs.])])
 199 AC_TYPE_OFF_T
 200 AC_TYPE_SIGNAL
 201 AC_TYPE_UID_T
 202
 203 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 204 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 205
 206 # Solaris lacks this
 207 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 208     [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])
 209
 210 #### Check for libs ####
 211
 212 # ISO
 213 AC_SEARCH_LIBS([pow], [m])
 214
 215 # POSIX
 216 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 217
 218 # BSD
 219 AC_SEARCH_LIBS([connect], [socket])
 220
 221 # Non-standard
 222
 223 # This magic is needed so we do not needlessly add static libs to the win32
 224 # build, disabling its ability to make dlls.
 225 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 226
 227 #### Check for functions ####
 228
 229 # POSIX
 230 AC_FUNC_FORK
 231 AC_FUNC_GETGROUPS
 232 AC_FUNC_SELECT_ARGTYPES
 233 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 234     getuid inet_ntop inet_pton nanosleep pipe setpgid setsid sigaction sleep])
 235 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 236
 237 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 238
 239 # X/OPEN
 240 AC_CHECK_FUNCS([readlink])
 241
 242 # SUSv2
 243 AC_CHECK_FUNCS([ctime_r usleep])
 244
 245 # BSD
 246 AC_CHECK_FUNCS([lstat])
 247
 248 # Non-standard
 249
 250 AC_CHECK_FUNCS(setresuid)
 251 AC_CHECK_FUNCS(setreuid)
 252
 253 #### POSIX threads ####
 254
 255 ACX_PTHREAD
 256
 257 #### Large File-Support (LFS) ####
 258
 259 AC_SYS_LARGEFILE
 260
 261 ###################################
 262 #      External libraries         #
 263 ###################################
 264
 265 #### X11 (optional) ####
 266
 267 HAVE_X11=0
 268
 269 # The macro tests the host, not the build target
 270 if test "x$os_is_win32" != "x1" ; then
 271     AC_PATH_XTRA
 272     test "x$no_x" != "xyes" && HAVE_X11=1
 273 fi
 274
 275 AC_SUBST(HAVE_X11)
 276 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 277 if test "x$HAVE_X11" = "x1" ; then
 278     AC_DEFINE([HAVE_X11], 1, [Have X11])
 279 fi
 280
 281 #### Capabilities (optional) ####
 282
 283 CAP_LIBS=''
 284
 285 AC_ARG_WITH(
 286         [caps],
 287         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 288
 289 if test "x${with_caps}" != "xno"; then
 290     AC_SEARCH_LIBS([cap_init], [cap])
 291     AC_CHECK_HEADERS([sys/capability.h])
 292 fi
 293
 294 #### pkg-config ####
 295
 296 # Check for pkg-config manually first, as if its not installed the
 297 # PKG_PROG_PKG_CONFIG macro won't be defined.
 298 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 299
 300 if test x"$have_pkg_config" = "xno"; then
 301     AC_MSG_ERROR(pkg-config is required to install this program)
 302 fi
 303
 304 PKG_PROG_PKG_CONFIG
 305
 306 #### Sample rate conversion ####
 307
 308 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 309 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 310 AC_SUBST(LIBSAMPLERATE_LIBS)
 311
 312 #### Sound file ####
 313
 314 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 315 AC_SUBST(LIBSNDFILE_CFLAGS)
 316 AC_SUBST(LIBSNDFILE_LIBS)
 317
 318 #### OSS support (optional) ####
 319
 320 AC_CHECK_HEADERS([sys/soundcard.h], [
 321 HAVE_OSS=1
 322 AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 323 ], [HAVE_OSS=0])
 324 AC_SUBST(HAVE_OSS)
 325 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 326
 327
 328 #### ALSA support (optional) ####
 329
 330 PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [
 331 HAVE_ALSA=1
 332 AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 333 ], [HAVE_ALSA=0])
 334 AC_SUBST(ASOUNDLIB_CFLAGS)
 335 AC_SUBST(ASOUNDLIB_LIBS)
 336 AC_SUBST(HAVE_ALSA)
 337 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 338
 339 #### Solaris audio support (optional) ####
 340
 341 AC_CHECK_HEADERS([sys/audio.h], [
 342 HAVE_SOLARIS=1
 343 AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 344 ], [HAVE_SOLARIS=0])
 345 AC_SUBST(HAVE_SOLARIS)
 346 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 347
 348 #### GLib 2 support (optional) ####
 349
 350 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)
 351 AC_SUBST(GLIB20_CFLAGS)
 352 AC_SUBST(GLIB20_LIBS)
 353 AC_SUBST(HAVE_GLIB20)
 354 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 355
 356 #### GLib 1 support (optional) ####
 357
 358 PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, HAVE_GLIB12=0)
 359 AC_SUBST(GLIB12_CFLAGS)
 360 AC_SUBST(GLIB12_LIBS)
 361 AC_SUBST(HAVE_GLIB12)
 362 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 363
 364 #### Howl support (optional) ####
 365
 366 PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, HAVE_HOWL=0)
 367 AC_SUBST(HOWL_CFLAGS)
 368 AC_SUBST(HOWL_LIBS)
 369 AC_SUBST(HAVE_HOWL)
 370 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 371
 372 ### LIBOIL ####
 373
 374 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 375 AC_SUBST(LIBOIL_CFLAGS)
 376 AC_SUBST(LIBOIL_LIBS)
 377
 378 ### JACK (optional) ####
 379
 380 PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ], HAVE_JACK=1, HAVE_JACK=0)
 381 AC_SUBST(JACK_CFLAGS)
 382 AC_SUBST(JACK_LIBS)
 383 AC_SUBST(HAVE_JACK)
 384 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 385
 386 #### Async DNS support (optional) ####
 387
 388 PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)
 389 AC_SUBST(LIBASYNCNS_CFLAGS)
 390 AC_SUBST(LIBASYNCNS_LIBS)
 391 AC_SUBST(HAVE_LIBASYNCNS)
 392 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 393
 394 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 395    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 396 fi
 397
 398 #### TCP wrappers (optional) ####
 399
 400 ACX_LIBWRAP
 401 AC_SUBST(LIBWRAP_LIBS)
 402
 403 #### LIRC support (optional) ####
 404
 405 ACX_LIRC
 406 AC_SUBST(LIRC_CFLAGS)
 407 AC_SUBST(LIRC_LIBS)
 408 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 409
 410 ###################################
 411 #            Output               #
 412 ###################################
 413
 414 AC_ARG_ENABLE(
 415         [static-bins],
 416         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 417         [STATIC_BINS=1], [STATIC_BINS=0])
 418 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 419
 420 AC_ARG_WITH(
 421         [preopen-mods],
 422         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 423         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 424 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 425 if test "x$PREOPEN_MODS" != "xall" ; then
 426     tmpLIBS=""
 427     for mod in $PREOPEN_MODS; do
 428         tmpLIBS="$tmpLIBS module-$mod.la"
 429     done
 430     PREOPEN_MODS="$tmpLIBS"
 431     AC_SUBST(PREOPEN_MODS)
 432 fi
 433
 434 AC_ARG_WITH(
 435         [module-dir],
 436         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/polypaudio-${PA_MAJORMINOR}]),
 437         [modlibexecdir=$withval], [modlibexecdir="${libdir}/polypaudio-${PA_MAJORMINOR}"])
 438
 439 AC_SUBST(modlibexecdir)
 440
 441 AC_ARG_ENABLE(
 442         [force-preopen],
 443         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 444         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 445 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 446
 447 AC_CONFIG_FILES([
 448 Makefile
 449 src/Makefile
 450 polyplib.pc
 451 polyplib-simple.pc
 452 polyplib-browse.pc
 453 polyplib-glib-mainloop.pc
 454 polyplib-glib12-mainloop.pc
 455 doc/Makefile
 456 doc/README.html
 457 doc/cli.html
 458 doc/daemon.html
 459 doc/modules.html
 460 doxygen/Makefile
 461 doxygen/doxygen.conf
 462 src/polyp/version.h
 463 doc/FAQ.html
 464 ])
 465 AC_OUTPUT