code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23 AC_INIT([polypaudio],[0.8],[mzcbylcnhqvb (at) 0pointer (dot) de])
  24 AC_CONFIG_SRCDIR([polyp/main.c])
  25 AC_CONFIG_HEADERS([config.h])
  26 AM_INIT_AUTOMAKE([foreign -Wall])
  27
  28 AC_SUBST(PA_MAJORMINOR, "$PACKAGE_VERSION")
  29 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  30
  31 AC_SUBST(PA_API_VERSION, 8)
  32
  33 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  34    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  35    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  36 fi
  37
  38 #### Checks for programs. ####
  39
  40 # CC
  41
  42 AC_PROG_CC
  43 AC_PROG_GCC_TRADITIONAL
  44
  45 # If using GCC specify some additional parameters
  46 if test "x$GCC" = "xyes" ; then
  47    CFLAGS="$CFLAGS -pipe -W -Wall -pedantic"
  48
  49    AC_LANG_CONFTEST([int main() {}])
  50    $CC -c conftest.c -std=gnu9x -Wno-unused-parameter $CFLAGS > /dev/null 2> /dev/null && CFLAGS="$CFLAGS -std=gnu9x -Wno-unused-parameter"
  51    rm -f conftest.o
  52 fi
  53
  54 # M4
  55
  56 AC_PATH_PROG([M4], [m4 gm4], [no])
  57 if test "x$M4" = xno ; then
  58    AC_MSG_ERROR([m4 missing])
  59 fi
  60
  61 # LYNX documentation generation
  62 AC_ARG_ENABLE(lynx,
  63         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
  64 [case "${enableval}" in
  65   yes) lynx=yes ;;
  66   no)  lynx=no ;;
  67   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
  68 esac],[lynx=yes])
  69
  70 if test x$lynx = xyes ; then
  71    AC_CHECK_PROG(have_lynx, lynx, yes, no)
  72
  73    if test x$have_lynx = xno ; then
  74      AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
  75    fi
  76 fi
  77
  78 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
  79
  80 #### libtool stuff ####
  81
  82 AC_LTDL_ENABLE_INSTALL
  83 AC_LIBLTDL_INSTALLABLE
  84 AC_SUBST(LTDLINCL)
  85 AC_SUBST(LIBLTDL)
  86 AC_LIBTOOL_DLOPEN
  87 AC_LIBTOOL_WIN32_DLL
  88 AC_PROG_LIBTOOL
  89 AC_CONFIG_SUBDIRS(libltdl)
  90
  91 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
  92     AC_MSG_ERROR([[
  93
  94         *** Cannot find the libltdl development files.
  95         *** Maybe you need to install the libltdl-dev package.
  96         ]])
  97 fi
  98
  99 #### Determine build environment ####
 100
 101 os_is_win32=0
 102
 103 case "$host_os" in
 104         mingw*)
 105         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 106         os_is_win32=1
 107                 ;;
 108         esac
 109
 110 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 111
 112 ###################################
 113 #   Basic environment checks      #
 114 ###################################
 115
 116 #### Checks for header files. ####
 117
 118 # ISO
 119 AC_HEADER_STDC
 120
 121 # POSIX
 122 AC_CHECK_HEADERS([glob.h grp.h netdb.h netinet/in.h netinet/tcp.h pwd.h \
 123     sched.h sys/capability.h sys/resource.h sys/select.h sys/socket.h \
 124     syslog.h])
 125 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 126 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 127
 128 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 129 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 130
 131 # XPG4-UNIX
 132 AC_CHECK_HEADERS([sys/poll.h])
 133
 134 # Linux
 135 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 136
 137 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 138
 139 # Windows
 140 AC_CHECK_HEADERS([winsock2.h ws2tcpip.h])
 141
 142 # Other
 143 AC_CHECK_HEADERS([sys/ioctl.h])
 144
 145 #### Typdefs, structures, etc. ####
 146
 147 AC_C_CONST
 148 AC_C_BIGENDIAN
 149 AC_TYPE_PID_T
 150 AC_TYPE_SIZE_T
 151 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 152     [Define ssize_t if it is not done by the standard libs.])])
 153 AC_TYPE_OFF_T
 154 AC_TYPE_SIGNAL
 155 AC_TYPE_UID_T
 156
 157 AC_CHECK_DEFINE([SIGXCPU], [signal.h])
 158 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 159
 160 #### Check for functions ####
 161
 162 # ISO
 163 AC_CHECK_LIB([m], [pow])
 164
 165 # POSIX
 166 AC_FUNC_FORK
 167 AC_FUNC_GETGROUPS
 168 AC_FUNC_SELECT_ARGTYPES
 169 AC_CHECK_FUNCS([ftruncate getgrgid_r getpwuid_r gettimeofday getuid \
 170     inet_ntop mkfifo nanosleep sigaction sleep])
 171
 172 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 173
 174 # X/OPEN
 175 AC_CHECK_FUNCS([readlink])
 176
 177 # SUSv2
 178 AC_CHECK_FUNCS([ctime_r usleep])
 179
 180 # Non-standard
 181
 182 AC_CHECK_FUNCS(setresuid)
 183 AC_CHECK_FUNCS(setreuid)
 184
 185 #### POSIX threads ####
 186
 187 ACX_PTHREAD
 188
 189 ###################################
 190 #      External libraries         #
 191 ###################################
 192
 193 #### X11 (optional) ####
 194
 195 HAVE_X11=0
 196
 197 # The macro tests the host, not the build target
 198 if test "x$os_is_win32" != "x1" ; then
 199     AC_PATH_XTRA
 200     test "x$no_x" != "xyes" && HAVE_X11=1
 201 fi
 202
 203 AC_SUBST(HAVE_X11)
 204 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 205 if test "x$HAVE_X11" = "x1" ; then
 206     AC_DEFINE([HAVE_X11], 1, [Have X11])
 207 fi
 208
 209 #### Capabilities (optional) ####
 210
 211 AC_CHECK_LIB(cap, cap_init, [CAP_LIBS='-lcap'], [CAP_LIBS=''])
 212 AC_SUBST(CAP_LIBS)
 213
 214 #### Sample rate conversion ####
 215
 216 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 217 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 218 AC_SUBST(LIBSAMPLERATE_LIBS)
 219
 220 #### Sound file ####
 221
 222 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 223 AC_SUBST(LIBSNDFILE_CFLAGS)
 224 AC_SUBST(LIBSNDFILE_LIBS)
 225
 226 #### ALSA support (optional) ####
 227
 228 PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [HAVE_ALSA=1], [HAVE_ALSA=0])
 229 AC_SUBST(ASOUNDLIB_CFLAGS)
 230 AC_SUBST(ASOUNDLIB_LIBS)
 231 AC_SUBST(HAVE_ALSA)
 232 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 233
 234 #### GLib 2 support (optional) ####
 235
 236 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)
 237 AC_SUBST(GLIB20_CFLAGS)
 238 AC_SUBST(GLIB20_LIBS)
 239 AC_SUBST(HAVE_GLIB20)
 240 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 241
 242 #### GLib 1 support (optional) ####
 243
 244 PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, HAVE_GLIB12=0)
 245 AC_SUBST(GLIB12_CFLAGS)
 246 AC_SUBST(GLIB12_LIBS)
 247 AC_SUBST(HAVE_GLIB12)
 248 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 249
 250 #### Howl support (optional) ####
 251
 252 PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, HAVE_HOWL=0)
 253 AC_SUBST(HOWL_CFLAGS)
 254 AC_SUBST(HOWL_LIBS)
 255 AC_SUBST(HAVE_HOWL)
 256 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 257
 258 #### Async DNS support (optional) ####
 259
 260 PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)
 261 AC_SUBST(LIBASYNCNS_CFLAGS)
 262 AC_SUBST(LIBASYNCNS_LIBS)
 263 AC_SUBST(HAVE_LIBASYNCNS)
 264 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 265
 266 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 267    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 268 fi
 269
 270 #### TCP wrappers (optional) ####
 271
 272 ACX_LIBWRAP
 273 AC_SUBST(LIBWRAP_LIBS)
 274
 275 #### LIRC support (optional) ####
 276
 277 ACX_LIRC
 278 AC_SUBST(LIRC_CFLAGS)
 279 AC_SUBST(LIRC_LIBS)
 280 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 281
 282 ###################################
 283 #            Output               #
 284 ###################################
 285
 286 AM_CONDITIONAL(BUILD_LIBPOLYPCORE, false)
 287
 288 AC_CONFIG_FILES([
 289 Makefile
 290 polyp/Makefile
 291 polyplib.pc
 292 polyplib-simple.pc
 293 polyplib-mainloop.pc
 294 polyplib-browse.pc
 295 polyplib-error.pc
 296 polyplib-glib-mainloop.pc
 297 polyplib-glib12-mainloop.pc
 298 doc/Makefile
 299 doc/README.html
 300 doc/cli.html
 301 doc/daemon.html
 302 doc/modules.html
 303 doxygen/Makefile
 304 doxygen/doxygen.conf
 305 polyp/polyplib-version.h
 306 doc/FAQ.html
 307 ])
 308 AC_OUTPUT