code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.63)
  24
  25 AC_INIT([pulseaudio],[m4_esyscmd(./git-version-gen .tarball-version)],[pulseaudio-discuss (at) lists (dot) freedesktop (dot) org],[pulseaudio],[http://pulseaudio.org/])
  26 AC_CONFIG_SRCDIR([src/daemon/main.c])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_HEADERS([config.h])
  29 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules color-tests dist-xz tar-ustar])
  30
  31 AS_IF([! test -n "$VERSION"], [
  32    AC_MSG_ERROR([git-version-gen failed])
  33 ])
  34
  35 m4_define(pa_major, `echo $VERSION | cut -d. -f1 | cut -d- -f1`)
  36 m4_define(pa_minor, `echo $VERSION | cut -d. -f2 | cut -d- -f1`)
  37
  38 AC_SUBST(PA_MAJOR, pa_major)
  39 AC_SUBST(PA_MINOR, pa_minor)
  40 AC_SUBST(PA_MAJORMINOR, pa_major.pa_minor)
  41
  42 AC_SUBST(PA_API_VERSION, 12)
  43 AC_SUBST(PA_PROTOCOL_VERSION, 27)
  44
  45 # The stable ABI for client applications, for the version info x:y:z
  46 # always will hold y=z
  47 AC_SUBST(LIBPULSE_VERSION_INFO, [14:2:14])
  48
  49 # A simplified, synchronous, ABI-stable interface for client
  50 # applications, for the version info x:y:z always will hold y=z
  51 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:3:0])
  52
  53 # The ABI-stable network browsing interface for client applications,
  54 # for the version info x:y:z always will hold y=z
  55 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  56
  57 # The ABI-stable GLib adapter for client applications, for the version
  58 # info x:y:z always will hold y=z
  59 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:4:0])
  60
  61 AC_CANONICAL_HOST
  62 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  63
  64 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  65
  66 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  67     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  68     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  69 ])
  70
  71 AM_SILENT_RULES([yes])
  72
  73
  74 #### Checks for programs. ####
  75
  76 # mkdir -p
  77
  78 AC_PROG_MKDIR_P
  79
  80 # CC
  81
  82 AC_PROG_CC
  83 AC_PROG_CC_C99
  84 AM_PROG_CC_C_O
  85 # Only required if you want the WebRTC canceller -- no runtime dep on
  86 # libstdc++ otherwise
  87 AC_PROG_CXX
  88 AC_PROG_GCC_TRADITIONAL
  89 AC_USE_SYSTEM_EXTENSIONS
  90
  91 # M4
  92
  93 AC_CHECK_PROGS([M4], gm4 m4, no)
  94 AS_IF([test "x$M4" = "xno"], AC_MSG_ERROR([m4 missing]))
  95
  96 # pkg-config
  97
  98 PKG_PROG_PKG_CONFIG
  99
 100 # gettext
 101
 102 if test "x$enable_nls" != "xno"; then
 103 IT_PROG_INTLTOOL([0.35.0])
 104 GETTEXT_PACKAGE=pulseaudio
 105 AC_SUBST([GETTEXT_PACKAGE])
 106 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 107 AM_GLIB_GNU_GETTEXT
 108
 109 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 110 AX_DEFINE_DIR(PULSE_LOCALEDIR, pulselocaledir, [Gettext locale dir])
 111 else
 112 # workaround till an intltool m4 bug is fixed upstream
 113 # (https://bugs.launchpad.net/intltool/+bug/904647)
 114 USE_NLS=no
 115 AC_SUBST(USE_NLS)
 116 fi
 117
 118
 119 #### Determine host OS ####
 120
 121 os_is_linux=0
 122 os_is_win32=0
 123 os_is_darwin=0
 124
 125 AC_MSG_CHECKING([host operating system])
 126 case "$host_os" in
 127     linux*)
 128         AC_MSG_RESULT([linux])
 129         os_is_linux=1
 130     ;;
 131     darwin*)
 132         AC_MSG_RESULT([darwin])
 133         os_is_darwin=1
 134         AC_DEFINE([OS_IS_DARWIN], 1, [Build target is Darwin.])
 135     ;;
 136     mingw*)
 137         AC_MSG_RESULT([win32])
 138         os_is_win32=1
 139         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 140     ;;
 141     *)
 142         AC_MSG_RESULT([unknown])
 143     ;;
 144 esac
 145
 146 AM_CONDITIONAL(OS_IS_DARWIN, test "x$os_is_darwin" = "x1")
 147 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 148 AC_SUBST([OS_IS_WIN32], [$os_is_win32])
 149
 150 # Platform specific hacks
 151 case "$host_os" in
 152     darwin* )
 153         AC_DEFINE([_DARWIN_C_SOURCE], [200112L], [Needed to get NSIG on Mac OS X])
 154     ;;
 155     mingw* )
 156         AC_DEFINE([WIN32_LEAN_AND_MEAN], 1, [Needed to avoid including unnecessary headers on Windows])
 157     ;;
 158     solaris* )
 159         AC_DEFINE(_XOPEN_SOURCE,       600, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 160         AC_DEFINE(__EXTENSIONS__,        1, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 161     ;;
 162 esac
 163
 164
 165 #### Compiler flags ####
 166
 167 AX_APPEND_COMPILE_FLAGS(
 168     [-Wall -W -Wextra -pipe -Wno-long-long -Wvla -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing -Wwrite-strings -Wno-unused-parameter -ffast-math -Wp,-D_FORTIFY_SOURCE=2 -fno-common -fdiagnostics-show-option],
 169     [], [-pedantic -Werror])
 170
 171 # Only enable fastpath asserts when doing a debug build, e.g. from bootstrap.sh.
 172 AS_CASE([" $CFLAGS "], [*" -O0 "*], [], [AX_APPEND_FLAG(["-DFASTPATH"], [CPPFLAGS])])
 173
 174
 175 #### Linker flags ####
 176
 177 # Check whether the linker supports the -version-script option.
 178 # The Make variable $(srcdir) needs to be in the LDFLAGS in that form,
 179 # so that it is expanded the right way in every subdir.
 180 AX_CHECK_LINK_FLAG(["-Wl,-version-script=${srcdir}/src/map-file"],
 181     [VERSIONING_LDFLAGS='-Wl,-version-script=$(abs_top_srcdir)/src/map-file'])
 182 AC_SUBST([VERSIONING_LDFLAGS])
 183
 184 # Use immediate (now) bindings; avoids the funky re-call in itself.
 185 # The -z now syntax is lifted from Sun's linker and works with GNU's too, other linkers might be added later.
 186 AX_APPEND_LINK_FLAGS([-Wl,-z,now], [IMMEDIATE_LDFLAGS])
 187 AC_SUBST([IMMEDIATE_LDFLAGS])
 188
 189 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 190 # so we request the nodelete flag to be enabled.
 191 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 192 AX_APPEND_LINK_FLAGS([-Wl,-z,nodelete], [NODELETE_LDFLAGS])
 193 AC_SUBST([NODELETE_LDFLAGS])
 194
 195 # Check for the proper way to build libraries that have no undefined symbols
 196 case $host in
 197     # FreeBSD (et al.) does not complete linking for shared objects when pthreads
 198     # are requested, as different implementations are present.
 199     *-freebsd* | *-openbsd*) ;;
 200     *)
 201         for possible_flag in "-Wl,--no-undefined" "-Wl,-z,defs"; do
 202             AX_CHECK_LINK_FLAG([$possible_flag], [NOUNDEFINED_LDFLAGS="$possible_flag"; break])
 203         done
 204     ;;
 205 esac
 206 AC_SUBST([NOUNDEFINED_LDFLAGS])
 207
 208
 209 #### Atomic operations ####
 210
 211 # Native atomic operation support
 212 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 213     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]))
 214
 215 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 216     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]))
 217
 218 if test "x$enable_atomic_arm_memory_barrier" = "xyes"; then
 219     AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers])
 220 fi
 221
 222 # If everything else fails use libatomic_ops
 223 need_libatomic_ops=yes
 224
 225 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 226     pulseaudio_cv_sync_bool_compare_and_swap, [
 227     AC_LINK_IFELSE(
 228         AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
 229         [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 230         [pulseaudio_cv_sync_bool_compare_and_swap=no])
 231     ])
 232
 233 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 234     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 235     need_libatomic_ops=no
 236 else
 237     # HW specific atomic ops stuff
 238     AC_MSG_CHECKING([architecture for native atomic operations])
 239     case $host in
 240         arm*)
 241             AC_MSG_RESULT([arm])
 242             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 243             # The Linux kernel helper functions have been there since 2.6.16. However
 244             # compile time checking for kernel version in cross compile environment
 245             # (which is usually the case for arm cpu) is tricky (or impossible).
 246             if test "x$os_is_linux" = "x1" && test "x$enable_atomic_arm_linux_helpers" != "xno"; then
 247                 AC_MSG_RESULT([yes])
 248                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 249                 need_libatomic_ops=no
 250             else
 251                 AC_MSG_RESULT([no])
 252                 AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 253                     pulseaudio_cv_support_arm_atomic_ops, [
 254                     AC_COMPILE_IFELSE(
 255                         AC_LANG_PROGRAM([], [[
 256                             volatile int a=0;
 257                             int o=0, n=1, r;
 258                             asm volatile ("ldrex    %0, [%1]\n"
 259                                           "subs  %0, %0, %2\n"
 260                                           "strexeq %0, %3, [%1]\n"
 261                                           : "=&r" (r)
 262                                           : "r" (&a), "Ir" (o), "r" (n)
 263                                           : "cc");
 264                             return (a==1 ? 0 : -1);
 265                         ]]),
 266                         [pulseaudio_cv_support_arm_atomic_ops=yes],
 267                         [pulseaudio_cv_support_arm_atomic_ops=no])
 268                 ])
 269                 AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 270                     AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARM atomic instructions.])
 271                     need_libatomic_ops=no
 272                 ])
 273             fi
 274         ;;
 275         *-netbsdelf5*)
 276             AC_MSG_RESULT([yes])
 277             need_libatomic_ops=no
 278         ;;
 279         *-freebsd*)
 280             AC_MSG_RESULT([yes])
 281             need_libatomic_ops=no
 282         ;;
 283         *)
 284             AC_MSG_RESULT([unknown])
 285         ;;
 286     esac
 287 fi
 288
 289 # If we're on ARM, check for the ARMV6 instructions we need */
 290 case $host in
 291   arm*)
 292     AC_CACHE_CHECK([support for required armv6 instructions],
 293       pulseaudio_cv_support_armv6,
 294       [AC_COMPILE_IFELSE(
 295          AC_LANG_PROGRAM([],
 296            [[volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 297              asm volatile ("ldr r0, %2 \n"
 298                            "ldr r2, %3 \n"
 299                            "ldr r3, %4 \n"
 300                            "ssat r1, #8, r0 \n"
 301                            "str r1, %0 \n"
 302                            "pkhbt r1, r3, r2, LSL #8 \n"
 303                            "str r1, %1 \n"
 304                            : "=m" (a), "=m" (b)
 305                            : "m" (a), "m" (b), "m" (c)
 306                            : "r0", "r1", "r2", "r3", "cc");
 307              return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 308            ]]),
 309          [pulseaudio_cv_support_armv6=yes],
 310          [pulseaudio_cv_support_armv6=no])
 311       ])
 312     AS_IF([test "$pulseaudio_cv_support_armv6" = "yes"], [
 313         AC_DEFINE([HAVE_ARMV6], 1, [Have ARMv6 instructions.])
 314       ])
 315   ;;
 316   *)
 317   ;;
 318 esac
 319
 320
 321 #### libtool stuff ####
 322
 323 LT_PREREQ(2.2)
 324 LT_INIT([dlopen win32-dll disable-static])
 325
 326 dnl Unfortunately, even up to libtool 2.2.6a there is no way to know
 327 dnl exactly which version of libltdl is present in the system, so we
 328 dnl just assume that it's a working version as long as we have the
 329 dnl library and the header files.
 330 dnl
 331 dnl As an extra safety device, check for lt_dladvise_init() which is
 332 dnl only implemented in libtool 2.x, and refine as we go if we have
 333 dnl refined requirements.
 334 dnl
 335 dnl Check the header files first since the system may have a
 336 dnl libltdl.so for runtime, but no headers, and we want to bail out as
 337 dnl soon as possible.
 338 dnl
 339 dnl We don't need any special variable for this though, since the user
 340 dnl can give the proper place to find libltdl through the standard
 341 dnl variables like LDFLAGS and CPPFLAGS.
 342
 343 AC_CHECK_HEADER([ltdl.h],
 344     [AC_CHECK_LIB([ltdl], [lt_dladvise_init], [LIBLTDL=-lltdl], [LIBLTDL=])],
 345     [LIBLTDL=])
 346
 347 AS_IF([test "x$LIBLTDL" = "x"],
 348     [AC_MSG_ERROR([Unable to find libltdl version 2. Makes sure you have libtool 2.2 or later installed.])])
 349 AC_SUBST([LIBLTDL])
 350
 351
 352 ###################################
 353 #   Basic environment checks      #
 354 ###################################
 355
 356 #### Checks for header files. ####
 357
 358 # ISO
 359 AC_HEADER_STDC
 360
 361 # POSIX
 362 AC_CHECK_HEADERS_ONCE([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 363     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 364     sys/mman.h sys/select.h sys/socket.h sys/wait.h \
 365     sys/uio.h syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 366 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 367                  [#include <sys/types.h>
 368                   #if HAVE_NETINET_IN_H
 369                   # include <netinet/in.h>
 370                   #endif
 371                   #if HAVE_NETINET_IN_SYSTM_H
 372                   # include <netinet/in_systm.h>
 373                   #endif
 374                  ])
 375 AC_CHECK_HEADERS([sys/resource.h], [HAVE_SYS_RESOURCE_H=1], [HAVE_SYS_RESOURCE_H=0])
 376 AC_SUBST(HAVE_SYS_RESOURCE_H)
 377 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 378 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 379 AC_SUBST(HAVE_AF_UNIX)
 380
 381 # Linux
 382 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 383 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 384
 385 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 386
 387 # Solaris
 388 AC_CHECK_HEADERS_ONCE([sys/filio.h])
 389
 390 # Windows
 391 AC_CHECK_HEADERS_ONCE([windows.h winsock2.h ws2tcpip.h])
 392
 393 # NetBSD
 394 AC_CHECK_HEADERS_ONCE([sys/atomic.h])
 395
 396 # Other
 397 AC_CHECK_HEADERS_ONCE([sys/ioctl.h])
 398 AC_CHECK_HEADERS_ONCE([byteswap.h])
 399 AC_CHECK_HEADERS_ONCE([sys/syscall.h])
 400 AC_CHECK_HEADERS_ONCE([sys/eventfd.h])
 401 AC_CHECK_HEADERS_ONCE([execinfo.h])
 402 AC_CHECK_HEADERS_ONCE([langinfo.h])
 403 AC_CHECK_HEADERS_ONCE([regex.h pcreposix.h])
 404
 405
 406 #### Typdefs, structures, etc. ####
 407
 408 AC_C_CONST
 409 AC_C_BIGENDIAN
 410 AC_TYPE_PID_T
 411 AC_TYPE_SIZE_T
 412 AC_CHECK_TYPES(ssize_t, , AC_DEFINE([ssize_t], [signed long], [Define ssize_t if it is not done by the standard libs.]))
 413 AC_TYPE_OFF_T
 414
 415 AC_TYPE_UID_T
 416 AC_CHECK_DECLS(environ)
 417
 418 # SIGXCPU
 419 AX_CHECK_DEFINE([signal.h], [SIGXCPU], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 420 AS_IF([test "x$HAVE_SIGXCPU" = "x1"], AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?]))
 421 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 422
 423 # INADDR_NONE, Solaris lacks this
 424 AX_CHECK_DEFINE([netinet/in.h], [INADDR_NONE], [],
 425     [AX_CHECK_DEFINE([winsock2.h], [INADDR_NONE], [],
 426         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 427
 428
 429 # _Bool
 430 AC_CACHE_CHECK([whether $CC knows _Bool],
 431     pulseaudio_cv__Bool,
 432     [AC_COMPILE_IFELSE(
 433         AC_LANG_PROGRAM([], [[_Bool b;]]),
 434         [pulseaudio_cv__Bool=yes],
 435         [pulseaudio_cv__Bool=no])
 436     ])
 437
 438 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.]))
 439
 440
 441 #### Thread support ####
 442
 443 AX_TLS
 444 AS_IF([test "$ac_cv_tls" == "__thread"],
 445     AC_DEFINE([SUPPORT_TLS___THREAD], 1, [Define this if the compiler supports __thread for Thread-Local Storage]))
 446
 447 # Win32 build breaks with win32 pthread installed
 448 AS_IF([test "x$os_is_win32" != "x1"],
 449   [AX_PTHREAD])
 450
 451 AS_IF([test "x$ax_pthread_ok" == "xyes"],
 452     AC_DEFINE([_POSIX_PTHREAD_SEMANTICS], 1, [Needed on Solaris]))
 453
 454
 455 #### Check for libs ####
 456
 457 # ISO
 458 AC_SEARCH_LIBS([pow], [m])
 459
 460 # POSIX
 461 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 462 AC_SEARCH_LIBS([dlopen], [dl])
 463 AC_SEARCH_LIBS([shm_open], [rt])
 464 AC_SEARCH_LIBS([inet_ntop], [nsl])
 465 AC_SEARCH_LIBS([timer_create], [rt])
 466 AC_SEARCH_LIBS([pthread_setaffinity_np], [pthread])
 467 AC_SEARCH_LIBS([pthread_getname_np], [pthread])
 468 AC_SEARCH_LIBS([pthread_setname_np], [pthread])
 469
 470 # BSD
 471 AC_SEARCH_LIBS([connect], [socket])
 472 AC_SEARCH_LIBS([backtrace], [execinfo ubacktrace])
 473
 474 # Darwin/OS X
 475 if test "x$os_is_darwin" = "x1" ; then
 476     AC_MSG_CHECKING([looking for Apple CoreService Framework])
 477     # How do I check a framework "library" - AC_CHECK_LIB prob. won't work??, just assign LIBS & hope
 478     AC_CHECK_HEADER([/Developer/Headers/FlatCarbon/CoreServices.h],
 479         [LIBS="$LIBS -framework CoreServices"],
 480         [AC_MSG_ERROR([CoreServices.h header file not found])]
 481     )
 482
 483     AC_MSG_RESULT([ok])
 484     AC_DEFINE([HAVE_CLOCK_GETTIME], 1, [Using clock_gettime() replacement])
 485     HAVE_BONJOUR=1
 486 fi
 487
 488 AM_CONDITIONAL([HAVE_BONJOUR], [test "x$HAVE_BONJOUR" = x1])
 489
 490 # Windows
 491 AC_SEARCH_LIBS([regexec], [pcreposix])
 492 # This magic is needed so we do not needlessly add static libs to the win32  build, disabling its ability to make dlls.
 493 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 494
 495
 496 #### Check for functions ####
 497
 498 # ISO
 499 AC_CHECK_FUNCS_ONCE([lrintf strtof])
 500
 501 # POSIX
 502 AC_FUNC_FORK
 503 AC_FUNC_GETGROUPS
 504 AC_CHECK_FUNCS_ONCE([chmod chown fstat fchown fchmod clock_gettime getaddrinfo getgrgid_r getgrnam_r \
 505     getpwnam_r getpwuid_r gettimeofday getuid mlock nanosleep \
 506     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 507     sigaction sleep symlink sysconf uname pthread_setaffinity_np pthread_getname_np pthread_setname_np])
 508 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 509 AC_SUBST(HAVE_MKFIFO)
 510 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 511
 512 # X/OPEN
 513 AC_CHECK_FUNCS_ONCE([readlink])
 514
 515 # SUSv2
 516 AC_CHECK_FUNCS_ONCE([ctime_r usleep])
 517
 518 # SUSv3
 519 AC_CHECK_FUNCS_ONCE([strerror_r])
 520
 521 # BSD
 522 AC_CHECK_FUNCS_ONCE([lstat])
 523
 524 # Non-standard
 525 AC_CHECK_FUNCS_ONCE([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l pipe2 accept4])
 526
 527 AC_FUNC_ALLOCA
 528
 529 AC_CHECK_FUNCS([regexec], [HAVE_REGEX=1], [HAVE_REGEX=0])
 530 AM_CONDITIONAL(HAVE_REGEX, [test "x$HAVE_REGEX" = "x1"])
 531
 532 # Large File-Support (LFS)
 533 AC_SYS_LARGEFILE
 534 # Check for open64 to know if the current system does have open64() and similar functions
 535 AC_CHECK_FUNCS_ONCE([open64])
 536
 537
 538 ###################################
 539 #      External libraries         #
 540 ###################################
 541
 542 #### [lib]iconv ####
 543
 544 AM_ICONV
 545
 546 #### X11 (optional) ####
 547
 548 AC_ARG_ENABLE([x11],
 549     AS_HELP_STRING([--disable-x11],[Disable optional X11 support]))
 550
 551 AS_IF([test "x$enable_x11" != "xno"],
 552     [PKG_CHECK_MODULES(X11, [ x11-xcb xcb >= 1.6 ice sm xtst ], HAVE_X11=1, HAVE_X11=0)],
 553     HAVE_X11=0)
 554
 555 AS_IF([test "x$enable_x11" = "xyes" && test "x$HAVE_X11" = "x0"],
 556     [AC_MSG_ERROR([*** X11 not found])])
 557
 558 AC_SUBST(X11_CFLAGS)
 559 AC_SUBST(X11_LIBS)
 560 AC_SUBST(HAVE_X11)
 561 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
 562 AS_IF([test "x$HAVE_X11" = "x1"], AC_DEFINE([HAVE_X11], 1, [Have X11?]))
 563
 564 #### Capabilities (optional) ####
 565
 566 CAP_LIBS=''
 567
 568 AC_ARG_WITH([caps],
 569     AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 570
 571 if test "x${with_caps}" != "xno"; then
 572     AC_SEARCH_LIBS([cap_init], [cap], [], [
 573                     if test "x${with_caps}" = "xyes" ; then
 574                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 575                     fi])
 576     AC_CHECK_HEADERS([sys/capability.h], [], [
 577                     if test "x${with_caps}" = "xyes" ; then
 578                         AC_MSG_ERROR([*** POSIX caps headers not found])
 579                     fi])
 580 fi
 581
 582 #### Valgrind (optional) ####
 583
 584 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 585
 586 #### check test framework ####
 587
 588 PKG_CHECK_MODULES(LIBCHECK, [ check ])
 589 AC_SUBST(LIBCHECK_CFLAGS)
 590 AC_SUBST(LIBCHECK_LIBS)
 591
 592 #### json parsing ####
 593
 594 PKG_CHECK_MODULES(LIBJSON, [ json >= 0.9 ])
 595 AC_SUBST(LIBJSON_CFLAGS)
 596 AC_SUBST(LIBJSON_LIBS)
 597
 598 #### Sound file ####
 599
 600 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.20 ])
 601 AC_SUBST(LIBSNDFILE_CFLAGS)
 602 AC_SUBST(LIBSNDFILE_LIBS)
 603
 604 #### atomic-ops ####
 605
 606 AC_MSG_CHECKING([whether we need libatomic_ops])
 607 if test "x$need_libatomic_ops" = "xyes"; then
 608     AC_MSG_RESULT([yes])
 609     AC_CHECK_HEADERS([atomic_ops.h],
 610         [CFLAGS="$CFLAGS -DAO_REQUIRE_CAS"],
 611         [AC_MSG_ERROR([*** libatomic-ops headers not found])])
 612
 613     # Win32 does not need the lib and breaks horribly if we try to include it
 614     AS_IF([test "x$os_is_win32" != "x1"], [LIBS="$LIBS -latomic_ops"])
 615 else
 616     AC_MSG_RESULT([no])
 617 fi
 618
 619 #### Libsamplerate support (optional) ####
 620
 621 AC_ARG_ENABLE([samplerate],
 622     AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]))
 623
 624 AS_IF([test "x$enable_samplerate" != "xno"],
 625     [PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ], HAVE_LIBSAMPLERATE=1, HAVE_LIBSAMPLERATE=0)],
 626     HAVE_LIBSAMPLERATE=0)
 627
 628 AS_IF([test "x$enable_samplerate" = "xyes" && test "x$HAVE_LIBSAMPLERATE" = "x0"],
 629     [AC_MSG_ERROR([*** Libsamplerate not found])])
 630
 631 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 632 AC_SUBST(LIBSAMPLERATE_LIBS)
 633 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 634 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?]))
 635
 636 #### Database support ####
 637
 638 AC_ARG_WITH([database],
 639     AS_HELP_STRING([--with-database=auto|tdb|gdbm|simple],[Choose database backend.]),[],[with_database=auto])
 640
 641
 642 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xtdb"],
 643     [PKG_CHECK_MODULES(TDB, [ tdb ], HAVE_TDB=1, HAVE_TDB=0)],
 644     HAVE_TDB=0)
 645 AS_IF([test "x$HAVE_TDB" = "x1"], with_database=tdb)
 646
 647 AS_IF([test "x$with_database" = "xtdb" && test "x$HAVE_TDB" = "x0"],
 648     [AC_MSG_ERROR([*** tdb not found])])
 649
 650
 651 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xgdbm"],
 652     [
 653         HAVE_GDBM=1
 654         AC_CHECK_LIB(gdbm, gdbm_open, [], HAVE_GDBM=0)
 655         AC_CHECK_HEADERS(gdbm.h, [], HAVE_GDBM=0)
 656     ],
 657     HAVE_GDBM=0)
 658 AS_IF([test "x$HAVE_GDBM" = "x1"],
 659     [
 660         with_database=gdbm
 661         GDBM_CFLAGS=
 662         GDBM_LIBS=-lgdbm
 663     ])
 664
 665 AS_IF([test "x$with_database" = "xgdbm" && test "x$HAVE_GDBM" = "x0"],
 666     [AC_MSG_ERROR([*** gdbm not found])])
 667
 668
 669 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xsimple"],
 670     HAVE_SIMPLEDB=1,
 671     HAVE_SIMPLEDB=0)
 672 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], with_database=simple)
 673
 674 AS_IF([test "x$HAVE_TDB" != x1 -a "x$HAVE_GDBM" != x1 -a "x$HAVE_SIMPLEDB" != x1],
 675     AC_MSG_ERROR([*** missing database backend]))
 676
 677
 678 AC_SUBST(TDB_CFLAGS)
 679 AC_SUBST(TDB_LIBS)
 680 AM_CONDITIONAL([HAVE_TDB], [test "x$HAVE_TDB" = x1])
 681 AS_IF([test "x$HAVE_TDB" = "x1"], AC_DEFINE([HAVE_TDB], 1, [Have tdb?]))
 682
 683 AC_SUBST(GDBM_CFLAGS)
 684 AC_SUBST(GDBM_LIBS)
 685 AM_CONDITIONAL([HAVE_GDBM], [test "x$HAVE_GDBM" = x1])
 686 AS_IF([test "x$HAVE_GDBM" = "x1"], AC_DEFINE([HAVE_GDBM], 1, [Have gdbm?]))
 687
 688 AM_CONDITIONAL([HAVE_SIMPLEDB], [test "x$HAVE_SIMPLEDB" = x1])
 689 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], AC_DEFINE([HAVE_SIMPLEDB], 1, [Have simple?]))
 690
 691 #### OSS support (optional) ####
 692
 693 AC_ARG_ENABLE([oss-output],
 694     AS_HELP_STRING([--disable-oss-output],[Disable optional OSS output support]))
 695
 696 AC_ARG_ENABLE([oss-wrapper],
 697     AS_HELP_STRING([--disable-oss-wrapper],[Disable optional OSS wrapper support]))
 698
 699 AS_IF([test "x$enable_oss_output" != "xno" -o "x$enable_oss_wrapper" != "xno"],
 700     [AC_CHECK_HEADERS([sys/soundcard.h], HAVE_OSS=1, HAVE_OSS=0)],
 701     HAVE_OSS=0)
 702
 703 AS_IF([test "x$enable_oss_output" = "xyes" -o "x$enable_oss_wrapper" = "xyes" && test "x$HAVE_OSS" = "x0"],
 704     [AC_MSG_ERROR([*** OSS support not found])])
 705
 706 AS_IF([test "x$enable_oss_output" != "xno"],
 707     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_OUTPUT=1, HAVE_OSS_OUTPUT=0)],
 708     HAVE_OSS_OUTPUT=0)
 709
 710 AS_IF([test "x$enable_oss_wrapper" != "xno"],
 711     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_WRAPPER=1, HAVE_OSS_WRAPPER=0)],
 712     HAVE_OSS_WRAPPER=0)
 713
 714 AC_SUBST(HAVE_OSS_OUTPUT)
 715 AM_CONDITIONAL([HAVE_OSS_OUTPUT], [test "x$HAVE_OSS_OUTPUT" = "x1"])
 716 AM_CONDITIONAL([HAVE_OSS_WRAPPER], [test "x$HAVE_OSS_WRAPPER" = "x1"])
 717 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], AC_DEFINE([HAVE_OSS_OUTPUT], 1, [Have OSS output?]))
 718 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], AC_DEFINE([HAVE_OSS_WRAPPER], 1, [Have OSS wrapper (padsp)?]))
 719
 720 #### CoreAudio support (optional) ####
 721
 722 AC_ARG_ENABLE([coreaudio-output],
 723     AS_HELP_STRING([--disable-coreaudio-output],[Disable optional CoreAudio output support]))
 724
 725 AS_IF([test "x$enable_coreaudio_output" != "xno"],
 726     [AC_CHECK_HEADERS([CoreAudio/CoreAudio.h], HAVE_COREAUDIO=1, HAVE_COREAUDIO=0)],
 727     HAVE_COREAUDIO=0)
 728
 729 AS_IF([test "x$enable_coreaudio_output" = "xyes" && test "x$HAVE_COREAUDIO" = "x0"],
 730     [AC_MSG_ERROR([*** CoreAudio output support not found])])
 731
 732 AM_CONDITIONAL([HAVE_COREAUDIO], [test "x$HAVE_COREAUDIO" = "x1" && test "x$enable_coreaudio_output" != "xno"])
 733
 734 #### ALSA support (optional) ####
 735
 736 AC_ARG_ENABLE([alsa],
 737     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]))
 738
 739 AS_IF([test "x$enable_alsa" != "xno"],
 740     [PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.19 ], HAVE_ALSA=1, HAVE_ALSA=0)],
 741     HAVE_ALSA=0)
 742
 743 AS_IF([test "x$enable_alsa" = "xyes" && test "x$HAVE_ALSA" = "x0"],
 744     [AC_MSG_ERROR([*** Needed alsa >= 1.0.19 support not found])])
 745
 746 AC_SUBST(ASOUNDLIB_CFLAGS)
 747 AC_SUBST(ASOUNDLIB_LIBS)
 748 AC_SUBST(HAVE_ALSA)
 749 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 750 AS_IF([test "x$HAVE_ALSA" = "x1"], AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?]))
 751
 752 #### EsounD support (optional) ####
 753
 754 AC_ARG_ENABLE([esound],
 755     AS_HELP_STRING([--disable-esound],[Disable optional EsounD support]))
 756 AM_CONDITIONAL([HAVE_ESOUND], [test "x$enable_esound" != "xno"])
 757 AS_IF([test "x$enable_esound" != "xno"], [HAVE_ESOUND=1])
 758
 759 #### Solaris audio support (optional) ####
 760
 761 AC_ARG_ENABLE([solaris],
 762     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]))
 763
 764 AS_IF([test "x$enable_solaris" != "xno"],
 765     [AC_CHECK_HEADERS([sys/audio.h], HAVE_SOLARIS=1, HAVE_SOLARIS=0)],
 766     HAVE_SOLARIS=0)
 767
 768 AS_IF([test "x$enable_solaris" = "xyes" && test "x$HAVE_SOLARIS" = "x0"],
 769     [AC_MSG_ERROR([*** Solaris audio support not found])])
 770
 771 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 772 AS_IF([test "x$HAVE_SOLARIS" = "x1"], AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?]))
 773
 774 #### WaveOut audio support (optional) ####
 775
 776 AC_ARG_ENABLE([waveout],
 777     AS_HELP_STRING([--disable-waveout],[Disable optional WaveOut audio support]))
 778
 779 AS_IF([test "x$enable_waveout" != "xno"],
 780     [AC_CHECK_HEADERS([mmsystem.h], HAVE_WAVEOUT=1, HAVE_WAVEOUT=0, [#include <windows.h>])],
 781     HAVE_WAVEOUT=0)
 782
 783 AS_IF([test "x$enable_waveout" = "xyes" && test "x$HAVE_WAVEOUT" = "x0"],
 784     [AC_MSG_ERROR([*** WaveOut audio support not found])])
 785
 786 AC_SUBST(HAVE_WAVEOUT)
 787 AM_CONDITIONAL([HAVE_WAVEOUT], [test "x$HAVE_WAVEOUT" = x1])
 788 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], AC_DEFINE([HAVE_WAVEOUT], 1, [Have WaveOut audio?]))
 789
 790 #### GLib 2 support (optional) ####
 791
 792 AC_ARG_ENABLE([glib2],
 793     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]))
 794
 795 AS_IF([test "x$enable_glib2" != "xno"],
 796     [PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)],
 797     HAVE_GLIB20=0)
 798
 799 AS_IF([test "x$enable_glib2" = "xyes" && test "x$HAVE_GLIB20" = "x0"],
 800     [AC_MSG_ERROR([*** GLib 2 support not found])])
 801
 802 AC_SUBST(GLIB20_CFLAGS)
 803 AC_SUBST(GLIB20_LIBS)
 804 AC_SUBST(HAVE_GLIB20)
 805 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 806 AS_IF([test "x$HAVE_GLIB20" = "x1"], AC_DEFINE([HAVE_GLIB], 1, [Have GLIB?]))
 807
 808 #### GTK2 support (optional) ####
 809
 810 AC_ARG_ENABLE([gtk2],
 811     AS_HELP_STRING([--disable-gtk2],[Disable optional Gtk+ 2 support]))
 812
 813 AS_IF([test "x$enable_gtk2" != "xno"],
 814     [PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ], HAVE_GTK20=1, HAVE_GTK20=0)],
 815     HAVE_GTK20=0)
 816
 817 AS_IF([test "x$enable_gtk2" = "xyes" && test "x$HAVE_GTK20" = "x0"],
 818     [AC_MSG_ERROR([*** Gtk+ 2 support not found])])
 819
 820 AC_SUBST(GTK20_CFLAGS)
 821 AC_SUBST(GTK20_LIBS)
 822 AM_CONDITIONAL([HAVE_GTK20], [test "x$HAVE_GTK20" = x1])
 823 AS_IF([test "x$HAVE_GTK20" = "x1"], AC_DEFINE([HAVE_GTK], 1, [Have GTK?]))
 824
 825 #### GConf support (optional) ####
 826
 827 AC_ARG_ENABLE([gconf],
 828     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]))
 829
 830 AS_IF([test "x$enable_gconf" != "xno"],
 831     [PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 gobject-2.0 ], HAVE_GCONF=1, HAVE_GCONF=0)],
 832     HAVE_GCONF=0)
 833
 834 AS_IF([test "x$enable_gconf" = "xyes" && test "x$HAVE_GCONF" = "x0"],
 835     [AC_MSG_ERROR([*** GConf support not found])])
 836
 837 AC_SUBST(GCONF_CFLAGS)
 838 AC_SUBST(GCONF_LIBS)
 839 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 840
 841 #### Avahi support (optional) ####
 842
 843 AC_ARG_ENABLE([avahi],
 844     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]))
 845
 846 AS_IF([test "x$enable_avahi" != "xno"],
 847     [PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ], HAVE_AVAHI=1, HAVE_AVAHI=0)],
 848     HAVE_AVAHI=0)
 849
 850 AS_IF([test "x$enable_avahi" = "xyes" && test "x$HAVE_AVAHI" = "x0"],
 851     [AC_MSG_ERROR([*** Avahi support not found])])
 852
 853 AC_SUBST(AVAHI_CFLAGS)
 854 AC_SUBST(AVAHI_LIBS)
 855 AC_SUBST(HAVE_AVAHI)
 856 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 857
 858 #### JACK (optional) ####
 859
 860 AC_ARG_ENABLE([jack],
 861     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]))
 862
 863 AS_IF([test "x$enable_jack" != "xno"],
 864     [PKG_CHECK_MODULES(JACK, [ jack >= 0.117.0 ], HAVE_JACK=1, HAVE_JACK=0)],
 865     HAVE_JACK=0)
 866
 867 AS_IF([test "x$enable_jack" = "xyes" && test "x$HAVE_JACK" = "x0"],
 868     [AC_MSG_ERROR([*** JACK support not found])])
 869
 870 AC_SUBST(JACK_CFLAGS)
 871 AC_SUBST(JACK_LIBS)
 872 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 873
 874 #### Async DNS support (optional) ####
 875
 876 AC_ARG_ENABLE([asyncns],
 877     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]))
 878
 879 AS_IF([test "x$enable_asyncns" != "xno"],
 880     [PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)],
 881     HAVE_LIBASYNCNS=0)
 882
 883 AS_IF([test "x$enable_asyncns" = "xyes" && test "x$HAVE_LIBASYNCNS" = "x0"],
 884     [AC_MSG_ERROR([*** Async DNS support not found])])
 885
 886 AC_SUBST(LIBASYNCNS_CFLAGS)
 887 AC_SUBST(LIBASYNCNS_LIBS)
 888 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 889 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?]))
 890
 891 #### TCP wrappers (optional) ####
 892
 893 AC_ARG_ENABLE([tcpwrap],
 894     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]))
 895
 896 AS_IF([test "x$enable_tcpwrap" != "xno"],
 897     [
 898         ACX_LIBWRAP
 899         AS_IF([test "x$LIBWRAP_LIBS" != "x"], HAVE_TCPWRAP=1, HAVE_TCPWRAP=0)
 900     ],
 901     HAVE_TCPWRAP=0)
 902
 903 AS_IF([test "x$enable_tcpwrap" = "xyes" && test "x$HAVE_TCPWRAP" = "x0"],
 904     [AC_MSG_ERROR([*** TCP wrappers support not found])])
 905
 906 AC_SUBST(LIBWRAP_LIBS)
 907
 908 #### LIRC support (optional) ####
 909
 910 AC_ARG_ENABLE([lirc],
 911     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]))
 912
 913 LIRC_CFLAGS=
 914 LIRC_LIBS=
 915
 916 AS_IF([test "x$enable_lirc" != "xno"],
 917     [
 918         HAVE_LIRC=1
 919         AC_CHECK_HEADER(lirc/lirc_client.h, [], [HAVE_LIRC=0])
 920         AC_CHECK_LIB(lirc_client, lirc_init, [LIRC_LIBS=-llirc_client], [HAVE_LIRC=0])
 921     ],
 922     HAVE_LIRC=0)
 923
 924 AS_IF([test "x$enable_lirc" = "xyes" && test "x$HAVE_LIRC" = "x0"],
 925     [AC_MSG_ERROR([*** LIRC support not found])])
 926
 927 AC_SUBST(LIRC_CFLAGS)
 928 AC_SUBST(LIRC_LIBS)
 929 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 930
 931 #### D-Bus support (optional) ####
 932
 933 AC_ARG_ENABLE([dbus],
 934     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]))
 935
 936 AS_IF([test "x$enable_dbus" != "xno"],
 937     [PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.0 ], HAVE_DBUS=1, HAVE_DBUS=0)],
 938     HAVE_DBUS=0)
 939
 940 AS_IF([test "x$enable_dbus" = "xyes" && test "x$HAVE_DBUS" = "x0"],
 941     [AC_MSG_ERROR([*** D-Bus (1.3.0+) support not found])])
 942
 943 AS_IF([test "x$HAVE_DBUS" = "x1"],
 944     [
 945         save_CFLAGS="$CFLAGS"; CFLAGS="$CFLAGS $DBUS_CFLAGS"
 946         save_LIBS="$LIBS"; LIBS="$LIBS $DBUS_LIBS"
 947         AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 948         CFLAGS="$save_CFLAGS"
 949         LIBS="$save_LIBS"
 950     ])
 951
 952 AC_SUBST(DBUS_CFLAGS)
 953 AC_SUBST(DBUS_LIBS)
 954 AC_SUBST(HAVE_DBUS)
 955 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 956 AS_IF([test "x$HAVE_DBUS" = "x1"], AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.]))
 957
 958 PA_MACHINE_ID="${sysconfdir}/machine-id"
 959 AX_DEFINE_DIR(PA_MACHINE_ID, PA_MACHINE_ID, [D-Bus machine-id file])
 960 PA_MACHINE_ID_FALLBACK="${localstatedir}/lib/dbus/machine-id"
 961 AX_DEFINE_DIR(PA_MACHINE_ID_FALLBACK, PA_MACHINE_ID_FALLBACK,
 962               [Fallback machine-id file])
 963
 964 #### BlueZ support (optional, dependant on D-Bus) ####
 965
 966 AC_ARG_ENABLE([bluez],
 967     AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]))
 968
 969 AS_IF([test "x$enable_bluez" != "xno"],
 970     [PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ], HAVE_BLUEZ=1, HAVE_BLUEZ=0)],
 971     HAVE_BLUEZ=0)
 972 AS_IF([test "x$enable_bluez" != "xno"],
 973     [PKG_CHECK_MODULES(SBC, [ sbc >= 1.0 ], HAVE_BLUEZ=1, HAVE_BLUEZ=0)],
 974     HAVE_BLUEZ=0)
 975 AS_IF([test "x$HAVE_DBUS" != "x1"], HAVE_BLUEZ=0)
 976
 977 AS_IF([test "x$enable_bluez" = "xyes" && test "x$HAVE_BLUEZ" = "x0"],
 978     [AC_MSG_ERROR([*** BLUEZ support not found (requires D-Bus)])])
 979
 980 AC_SUBST(BLUEZ_CFLAGS)
 981 AC_SUBST(BLUEZ_LIBS)
 982 AC_SUBST(HAVE_BLUEZ)
 983 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 984
 985 #### UDEV support (optional) ####
 986
 987 AC_ARG_ENABLE([udev],
 988     AS_HELP_STRING([--disable-udev],[Disable optional UDEV support]))
 989
 990 AS_IF([test "x$enable_udev" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
 991     [PKG_CHECK_MODULES(UDEV, [ libudev >= 143 ], HAVE_UDEV=1, HAVE_UDEV=0)],
 992     HAVE_UDEV=0)
 993
 994 AS_IF([test "x$enable_udev" = "xyes" && test "x$HAVE_UDEV" = "x0"],
 995     [AC_MSG_ERROR([*** UDEV support not found])])
 996
 997 AC_SUBST(UDEV_CFLAGS)
 998 AC_SUBST(UDEV_LIBS)
 999 AC_SUBST(HAVE_UDEV)
1000 AM_CONDITIONAL([HAVE_UDEV], [test "x$HAVE_UDEV" = x1])
1001 AS_IF([test "x$HAVE_UDEV" = "x1"], AC_DEFINE([HAVE_UDEV], 1, [Have UDEV.]))
1002
1003 #### HAL compat support (optional, dependant on UDEV) ####
1004
1005 AC_ARG_ENABLE([hal-compat],
1006     AS_HELP_STRING([--disable-hal-compat],[Disable optional HAL->udev transition compatibility support]))
1007
1008 AS_IF([test "x$enable_hal_compat" != "xno"],
1009     [AS_IF([test "x$HAVE_UDEV" = "x1"], HAVE_HAL_COMPAT=1, HAVE_HAL_COMPAT=0)],
1010     HAVE_HAL_COMPAT=0)
1011
1012 AM_CONDITIONAL([HAVE_HAL_COMPAT], [test "x$HAVE_HAL_COMPAT" = x1])
1013 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], AC_DEFINE([HAVE_HAL_COMPAT], 1, [Have HAL compatibility.]))
1014
1015 #### IPv6 connection support (optional) ####
1016
1017 AC_ARG_ENABLE([ipv6],
1018     AS_HELP_STRING([--disable-ipv6],[Disable optional IPv6 support]))
1019
1020 AS_IF([test "x$enable_ipv6" != "xno"], [HAVE_IPV6=1], [HAVE_IPV6=0])
1021
1022 AS_IF([test "x$HAVE_IPV6" = "x1"], AC_DEFINE([HAVE_IPV6], 1, [Define this to enable IPv6 connection support]))
1023
1024 #### OpenSSL support (optional) ####
1025
1026 AC_ARG_ENABLE([openssl],
1027     AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]))
1028
1029 AS_IF([test "x$enable_openssl" != "xno"],
1030     [PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ], HAVE_OPENSSL=1, HAVE_OPENSSL=0)],
1031     HAVE_OPENSSL=0)
1032
1033 AS_IF([test "x$enable_openssl" = "xyes" && test "x$HAVE_OPENSSL" = "x0"],
1034     [AC_MSG_ERROR([*** OpenSSL support not found])])
1035
1036 AC_SUBST(OPENSSL_CFLAGS)
1037 AC_SUBST(OPENSSL_LIBS)
1038 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1039 AS_IF([test "x$HAVE_OPENSSL" = "x1"], AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL]))
1040
1041 #### FFTW (optional) ####
1042
1043 AC_ARG_WITH([fftw],
1044     AS_HELP_STRING([--without-fftw],[Omit FFTW-using modules (equalizer)]))
1045
1046 AS_IF([test "x$with_fftw" != "xno"],
1047     [PKG_CHECK_MODULES(FFTW, [ fftw3f ], HAVE_FFTW=1, HAVE_FFTW=0)],
1048     HAVE_FFTW=0)
1049
1050 AS_IF([test "x$with_fftw" = "xyes" && test "x$HAVE_FFTW" = "x0"],
1051     [AC_MSG_ERROR([*** FFTW support not found])])
1052
1053 AM_CONDITIONAL([HAVE_FFTW], [test "x$HAVE_FFTW" = "x1"])
1054
1055 #### speex (optional) ####
1056
1057 AC_ARG_WITH([speex],
1058     AS_HELP_STRING([--without-speex],[Omit speex (resampling, AEC)]))
1059
1060 AS_IF([test "x$with_speex" != "xno"],
1061     [PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ], HAVE_SPEEX=1, HAVE_SPEEX=0)],
1062     HAVE_SPEEX=0)
1063
1064 AS_IF([test "x$with_speex" = "xyes" && test "x$HAVE_SPEEX" = "x0"],
1065     [AC_MSG_ERROR([*** speex support not found])])
1066
1067 AM_CONDITIONAL([HAVE_SPEEX], [test "x$HAVE_SPEEX" = "x1"])
1068 AS_IF([test "x$HAVE_SPEEX" = "x1"], AC_DEFINE([HAVE_SPEEX], 1, [Have speex]))
1069
1070 AC_SUBST(LIBSPEEX_CFLAGS)
1071 AC_SUBST(LIBSPEEX_LIBS)
1072
1073 #### Xen support (optional) ####
1074
1075 AC_ARG_ENABLE([xen],
1076     AS_HELP_STRING([--disable-xen],[Disable optional Xen paravirtualized driver]))
1077
1078 XEN_CFLAGS=
1079 XEN_LIBS=
1080
1081 AS_IF([test "x$enable_xen" != "xno"],
1082     [
1083         HAVE_XEN=1
1084         AC_CHECK_HEADER(xenctrl.h, [], [HAVE_XEN=0])
1085         AC_CHECK_HEADER(xs.h, [], [HAVE_XEN=0])
1086         AC_CHECK_LIB(xenctrl, xc_interface_open, [XEN_LIBS="$XEN_LIBS -lxenctrl"], [HAVE_XEN=0])
1087         AC_CHECK_LIB(xenstore, xs_domain_open, [XEN_LIBS="$XEN_LIBS -lxenstore"], [HAVE_XEN=0])
1088     ],
1089     HAVE_XEN=0)
1090
1091 AS_IF([test "x$enable_xen" = "xyes" && test "x$HAVE_XEN" = "x0"],
1092     [AC_MSG_ERROR([*** Xen development headers or libraries not found])])
1093
1094 AC_SUBST(XEN_CFLAGS)
1095 AC_SUBST(XEN_LIBS)
1096 AM_CONDITIONAL([HAVE_XEN], [test "x$HAVE_XEN" = x1])
1097
1098 #### gcov support (optional) #####
1099
1100 AC_ARG_ENABLE([gcov],
1101     AS_HELP_STRING([--enable-gcov],[Enable optional gcov coverage analysis]))
1102
1103 GCOV_CFLAGS=
1104 GCOV_LIBS=" -lgcov"
1105
1106 AS_IF([test "x$enable_gcov" = "xyes"],
1107     [
1108         HAVE_GCOV=1
1109         GCOV_CFLAGS="$GCOV_CFLAGS -fprofile-arcs -ftest-coverage"
1110         GCOV_LIBS="$GCOV_LIBS -fprofile-arcs"
1111     ],
1112     HAVE_GCOV=0)
1113
1114 AC_SUBST(GCOV_CFLAGS)
1115 AC_SUBST(GCOV_LIBS)
1116 AM_CONDITIONAL([HAVE_GCOV], [test "x$HAVE_GCOV" = x1])
1117
1118 #### ORC (optional) ####
1119
1120 ORC_CHECK([0.4.11])
1121
1122 #### systemd support (optional) ####
1123
1124 AC_ARG_ENABLE([systemd],
1125     AS_HELP_STRING([--disable-systemd],[Disable optional systemd support]))
1126
1127 AS_IF([test "x$enable_systemd" != "xno"],
1128     [PKG_CHECK_MODULES(SYSTEMD, [ libsystemd-login libsystemd-daemon ], HAVE_SYSTEMD=1, HAVE_SYSTEMD=0)],
1129     HAVE_SYSTEMD=0)
1130
1131 AS_IF([test "x$enable_systemd" = "xyes" && test "x$HAVE_SYSTEMD" = "x0"],
1132     [AC_MSG_ERROR([*** Needed systemd support not found])])
1133
1134 AC_SUBST(HAVE_SYSTEMD)
1135 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$HAVE_SYSTEMD" = x1])
1136 AS_IF([test "x$HAVE_SYSTEMD" = "x1"], AC_DEFINE([HAVE_SYSTEMD], 1, [Have SYSTEMD?]))
1137
1138 #### Build and Install man pages ####
1139
1140 AC_ARG_ENABLE([manpages],
1141     AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]))
1142
1143 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" != "xno"])
1144
1145 #### PulseAudio system group & user  #####
1146
1147 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1148 if test -z "$with_system_user" ; then
1149     PA_SYSTEM_USER=pulse
1150 else
1151     PA_SYSTEM_USER=$with_system_user
1152 fi
1153 AC_SUBST(PA_SYSTEM_USER)
1154 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1155
1156 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1157 if test -z "$with_system_group" ; then
1158     PA_SYSTEM_GROUP=pulse
1159 else
1160     PA_SYSTEM_GROUP=$with_system_group
1161 fi
1162 AC_SUBST(PA_SYSTEM_GROUP)
1163 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1164
1165 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1166 if test -z "$with_access_group" ; then
1167     PA_ACCESS_GROUP=pulse-access
1168 else
1169     PA_ACCESS_GROUP=$with_access_group
1170 fi
1171 AC_SUBST(PA_ACCESS_GROUP)
1172 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1173
1174 AC_ARG_ENABLE([per-user-esound-socket],
1175     AS_HELP_STRING([--disable-per-user-esound-socket],[Use global esound socket directory /tmp/.esd/socket.]))
1176
1177 if test "x$enable_per_user_esound_socket" != "xno"; then
1178     USE_PER_USER_ESOUND_SOCKET=1
1179     AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1180 else
1181     USE_PER_USER_ESOUND_SOCKET=0
1182 fi
1183
1184 #### PulseAudio system runtime dir ####
1185
1186 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1187 AX_DEFINE_DIR(PA_SYSTEM_RUNTIME_PATH, PA_SYSTEM_RUNTIME_PATH, [System runtime dir])
1188 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1189 AX_DEFINE_DIR(PA_SYSTEM_CONFIG_PATH, PA_SYSTEM_CONFIG_PATH, [System config dir])
1190 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1191 AX_DEFINE_DIR(PA_SYSTEM_STATE_PATH, PA_SYSTEM_STATE_PATH, [System state dir])
1192
1193 PA_BINARY=${bindir}/pulseaudio${EXEEXT}
1194 AX_DEFINE_DIR(PA_BINARY, PA_BINARY, [Location of pulseaudio binary])
1195
1196 PACTL_BINARY=${bindir}/pactl${EXEEXT}
1197 AX_DEFINE_DIR(PACTL_BINARY, PACTL_BINARY, [Location of pactl binary])
1198
1199 AC_SUBST(PA_SOEXT, [.so])
1200
1201 AC_SUBST(pulseconfdir, ["${sysconfdir}/pulse"])
1202 AX_DEFINE_DIR(PA_DEFAULT_CONFIG_DIR, pulseconfdir, [Location of configuration files])
1203
1204 AC_DEFINE_UNQUOTED(PA_BUILDDIR, "${ac_pwd}/src", [Location of uninstalled binaries])
1205
1206 #### Mac OSX specific stuff #####
1207
1208 AC_ARG_ENABLE(mac-universal,
1209     AS_HELP_STRING([--enable-mac-universal], [Build Mac universal binaries]),
1210     enable_mac_universal=$enableval, enable_mac_universal="no")
1211
1212 AC_ARG_WITH(mac-version-min,
1213     AS_HELP_STRING([--with-mac-version-min=<version>], [Defines the earliest version of MacOS X that the executables will run on.]),
1214     mac_version_min=$withval, mac_version_min="10.5")
1215
1216 AC_ARG_WITH(mac-sysroot,
1217     AS_HELP_STRING([--with-mac-sysroot=<path>], [SDK basedir to use as the logical root directory for headers and libraries.]),
1218     mac_sysroot=$withval, mac_sysroot="/Developer/SDKs/MacOSX10.5.sdk")
1219
1220 if test "x$os_is_darwin" = "x1" ; then
1221     LDFLAGS="$LDFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1222     CFLAGS="$CFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1223
1224     if test "x$enable_mac_universal" = "xyes" ; then
1225         mac_arches="-arch i386 -arch x86_64"
1226         LDFLAGS="$LDFLAGS $mac_arches"
1227         CFLAGS="$CFLAGS $mac_arches"
1228     fi
1229 fi
1230
1231 AC_ARG_ENABLE([webrtc-aec],
1232     AS_HELP_STRING([--enable-webrtc-aec], [Enable the optional WebRTC-based echo canceller]))
1233
1234 AS_IF([test "x$enable_webrtc_aec" != "xno"],
1235     [PKG_CHECK_MODULES(WEBRTC, [ webrtc-audio-processing ], [HAVE_WEBRTC=1], [HAVE_WEBRTC=0])],
1236     [HAVE_WEBRTC=0])
1237
1238 AS_IF([test "x$enable_webrtc_aec" = "xyes" && test "x$HAVE_WEBRTC" = "x0"],
1239     [AC_MSG_ERROR([*** webrtc-audio-processing library not found])])
1240
1241 AC_SUBST(WEBRTC_CFLAGS)
1242 AC_SUBST(WEBRTC_LIBS)
1243 AM_CONDITIONAL([HAVE_WEBRTC], [test "x$HAVE_WEBRTC" = "x1"])
1244
1245 AC_ARG_ENABLE([adrian-aec],
1246     AS_HELP_STRING([--enable-adrian-aec], [Enable Adrian's optional echo canceller]))
1247 AS_IF([test "x$enable_adrian_aec" != "xno"],
1248     [HAVE_ADRIAN_EC=1])
1249 AM_CONDITIONAL([HAVE_ADRIAN_EC], [test "x$HAVE_ADRIAN_EC" = "x1"])
1250
1251
1252
1253 ###################################
1254 #            Output               #
1255 ###################################
1256
1257 AC_DEFINE_UNQUOTED(PA_CFLAGS, "$CFLAGS", [The CFLAGS used during compilation])
1258
1259 # Check whether to build tests by default (as compile-test) or not
1260 AC_ARG_ENABLE([default-build-tests],
1261     AS_HELP_STRING([--disable-default-build-tests], [Build test programs only during make check]))
1262 AM_CONDITIONAL([BUILD_TESTS_DEFAULT], [test "x$enable_default_build_tests" != "xno"])
1263
1264 AC_ARG_ENABLE([legacy-database-entry-format],
1265         AS_HELP_STRING([--disable-legacy-database-entry-format], [Try to load legacy (< 1.0) database files (card, device and volume restore).]))
1266 if test "x$enable_legacy_database_entry_format" != "xno" ; then
1267         AC_DEFINE(ENABLE_LEGACY_DATABASE_ENTRY_FORMAT, [1], [Legacy database entry format])
1268 fi
1269 AC_DEFINE([WIBBLE], 1, [Just a test.])
1270
1271 AC_ARG_ENABLE([static-bins],
1272     AS_HELP_STRING([--enable-static-bins],[Statically link executables.]))
1273 AM_CONDITIONAL([STATIC_BINS], [test "x$enable_static_bins" = "xyes"])
1274
1275 AC_ARG_WITH(
1276         [preopen-mods],
1277         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1278         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1279 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1280 if test "x$PREOPEN_MODS" != "xall" ; then
1281     tmpLIBS=""
1282     for mod in $PREOPEN_MODS; do
1283         tmpLIBS="$tmpLIBS module-$mod.la"
1284     done
1285     PREOPEN_MODS="$tmpLIBS"
1286     AC_SUBST(PREOPEN_MODS)
1287 fi
1288
1289 AC_ARG_WITH(
1290         [module-dir],
1291         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules]),
1292         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules"])
1293
1294 AC_SUBST(modlibexecdir)
1295 AX_DEFINE_DIR(PA_DLSEARCHPATH, modlibexecdir, [Modules dir])
1296
1297 AC_ARG_WITH(
1298         [udev-rules-dir],
1299         AS_HELP_STRING([--with-udev-rules-dir],[Directory where to install udev rules to (defaults to /lib/udev/rules.d)]),
1300         [udevrulesdir=$withval], [udevrulesdir="/lib/udev/rules.d"])
1301
1302 AC_SUBST(udevrulesdir)
1303
1304 AC_ARG_ENABLE([force-preopen],
1305     AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]))
1306
1307 if test "x$enable_force_preopen" = "xyes"; then
1308     FORCE_PREOPEN=yes
1309 else
1310     FORCE_PREOPEN=no
1311 fi
1312
1313 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1314
1315 AC_CONFIG_FILES([
1316 Makefile
1317 src/Makefile
1318 man/Makefile
1319 libpulse.pc
1320 libpulse-simple.pc
1321 libpulse-mainloop-glib.pc
1322 doxygen/Makefile
1323 doxygen/doxygen.conf
1324 src/pulse/version.h
1325 po/Makefile.in
1326 man/pulseaudio.1.xml
1327 man/esdcompat.1.xml
1328 man/pax11publish.1.xml
1329 man/paplay.1.xml
1330 man/pacat.1.xml
1331 man/pacmd.1.xml
1332 man/pactl.1.xml
1333 man/pasuspender.1.xml
1334 man/padsp.1.xml
1335 man/pulse-daemon.conf.5.xml
1336 man/pulse-client.conf.5.xml
1337 man/default.pa.5.xml
1338 man/pulse-cli-syntax.5.xml
1339 man/start-pulseaudio-kde.1.xml
1340 man/start-pulseaudio-x11.1.xml
1341 ])
1342
1343 AC_CONFIG_FILES([src/esdcompat:src/daemon/esdcompat.in], [chmod +x src/esdcompat])
1344 AC_CONFIG_FILES([src/start-pulseaudio-x11:src/daemon/start-pulseaudio-x11.in], [chmod +x src/start-pulseaudio-x11])
1345 AC_CONFIG_FILES([src/start-pulseaudio-kde:src/daemon/start-pulseaudio-kde.in], [chmod +x src/start-pulseaudio-kde])
1346 AC_CONFIG_FILES([src/client.conf:src/pulse/client.conf.in])
1347 AC_CONFIG_FILES([src/daemon.conf:src/daemon/daemon.conf.in],
1348     [m4 src/daemon.conf > src/daemon.conf.gen && mv src/daemon.conf.gen src/daemon.conf])
1349 AC_CONFIG_FILES([src/default.pa:src/daemon/default.pa.in],
1350     [m4 src/default.pa > src/default.pa.gen && mv src/default.pa.gen src/default.pa])
1351 AC_CONFIG_FILES([src/system.pa:src/daemon/system.pa.in],
1352     [m4 src/system.pa > src/system.pa.gen && mv src/system.pa.gen src/system.pa])
1353
1354 # CMake related ProjectConfig files
1355 PA_LIBDIR="$libdir"
1356 AX_DEFINE_DIR(PA_LIBDIR, PA_LIBDIR, [PulseAudio library dir])
1357 PA_INCDIR="$includedir"
1358 AX_DEFINE_DIR(PA_INCDIR, PA_INCDIR, [PulseAudio include dir])
1359
1360 AC_CONFIG_FILES([PulseAudioConfig.cmake:PulseAudioConfig.cmake.in],
1361     [m4 PulseAudioConfig.cmake > PulseAudioConfig.cmake.gen && mv PulseAudioConfig.cmake.gen PulseAudioConfig.cmake])
1362 AC_CONFIG_FILES([PulseAudioConfigVersion.cmake])
1363
1364 AC_OUTPUT
1365
1366 # ==========================================================================
1367
1368 AS_IF([test "x$HAVE_X11" = "x1"], ENABLE_X11=yes, ENABLE_X11=no)
1369 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], ENABLE_OSS_OUTPUT=yes, ENABLE_OSS_OUTPUT=no)
1370 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], ENABLE_OSS_WRAPPER=yes, ENABLE_OSS_WRAPPER=no)
1371 AS_IF([test "x$HAVE_ALSA" = "x1"], ENABLE_ALSA=yes, ENABLE_ALSA=no)
1372 AS_IF([test "x$HAVE_COREAUDIO" = "x1"], ENABLE_COREAUDIO=yes, ENABLE_COREAUDIO=no)
1373 AS_IF([test "x$HAVE_SOLARIS" = "x1"], ENABLE_SOLARIS=yes, ENABLE_SOLARIS=no)
1374 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], ENABLE_WAVEOUT=yes, ENABLE_WAVEOUT=no)
1375 AS_IF([test "x$HAVE_GLIB20" = "x1"], ENABLE_GLIB20=yes, ENABLE_GLIB20=no)
1376 AS_IF([test "x$HAVE_GTK20" = "x1"], ENABLE_GTK20=yes, ENABLE_GTK20=no)
1377 AS_IF([test "x$HAVE_GCONF" = "x1"], ENABLE_GCONF=yes, ENABLE_GCONF=no)
1378 AS_IF([test "x$HAVE_AVAHI" = "x1"], ENABLE_AVAHI=yes, ENABLE_AVAHI=no)
1379 AS_IF([test "x$HAVE_JACK" = "x1"], ENABLE_JACK=yes, ENABLE_JACK=no)
1380 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], ENABLE_LIBASYNCNS=yes, ENABLE_LIBASYNCNS=no)
1381 AS_IF([test "x$HAVE_LIRC" = "x1"], ENABLE_LIRC=yes, ENABLE_LIRC=no)
1382 AS_IF([test "x$HAVE_XEN" = "x1"], ENABLE_XEN=yes, ENABLE_XEN=no)
1383 AS_IF([test "x$HAVE_DBUS" = "x1"], ENABLE_DBUS=yes, ENABLE_DBUS=no)
1384 AS_IF([test "x$HAVE_UDEV" = "x1"], ENABLE_UDEV=yes, ENABLE_UDEV=no)
1385 AS_IF([test "x$HAVE_SYSTEMD" = "x1"], ENABLE_SYSTEMD=yes, ENABLE_SYSTEMD=no)
1386 AS_IF([test "x$HAVE_BLUEZ" = "x1"], ENABLE_BLUEZ=yes, ENABLE_BLUEZ=no)
1387 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], ENABLE_HAL_COMPAT=yes, ENABLE_HAL_COMPAT=no)
1388 AS_IF([test "x$HAVE_TCPWRAP" = "x1"], ENABLE_TCPWRAP=yes, ENABLE_TCPWRAP=no)
1389 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], ENABLE_LIBSAMPLERATE=yes, ENABLE_LIBSAMPLERATE=no)
1390 AS_IF([test "x$HAVE_IPV6" = "x1"], ENABLE_IPV6=yes, ENABLE_IPV6=no)
1391 AS_IF([test "x$HAVE_OPENSSL" = "x1"], ENABLE_OPENSSL=yes, ENABLE_OPENSSL=no)
1392 AS_IF([test "x$HAVE_FFTW" = "x1"], ENABLE_FFTW=yes, ENABLE_FFTW=no)
1393 AS_IF([test "x$HAVE_ORC" = "xyes"], ENABLE_ORC=yes, ENABLE_ORC=no)
1394 AS_IF([test "x$HAVE_ADRIAN_EC" = "x1"], ENABLE_ADRIAN_EC=yes, ENABLE_ADRIAN_EC=no)
1395 AS_IF([test "x$HAVE_SPEEX" = "x1"], ENABLE_SPEEX=yes, ENABLE_SPEEX=no)
1396 AS_IF([test "x$HAVE_WEBRTC" = "x1"], ENABLE_WEBRTC=yes, ENABLE_WEBRTC=no)
1397 AS_IF([test "x$HAVE_TDB" = "x1"], ENABLE_TDB=yes, ENABLE_TDB=no)
1398 AS_IF([test "x$HAVE_GDBM" = "x1"], ENABLE_GDBM=yes, ENABLE_GDBM=no)
1399 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], ENABLE_SIMPLEDB=yes, ENABLE_SIMPLEDB=no)
1400 AS_IF([test "x$HAVE_ESOUND" = "x1"], ENABLE_ESOUND=yes, ENABLE_ESOUND=no)
1401 AS_IF([test "x$HAVE_ESOUND" = "x1" -a "x$USE_PER_USER_ESOUND_SOCKET" = "x1"], ENABLE_PER_USER_ESOUND_SOCKET=yes, ENABLE_PER_USER_ESOUND_SOCKET=no)
1402 AS_IF([test "x$HAVE_GCOV" = "x1"], ENABLE_GCOV=yes, ENABLE_GCOV=no)
1403 AS_IF([test "x$enable_legacy_database_entry_format" != "xno"], ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=yes, ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=no)
1404
1405 echo "
1406  ---{ $PACKAGE_NAME $VERSION }---
1407
1408     prefix:                        ${prefix}
1409     sysconfdir:                    ${sysconfdir}
1410     localstatedir:                 ${localstatedir}
1411     modlibexecdir:                 ${modlibexecdir}
1412     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1413     System State Path:             ${PA_SYSTEM_STATE_PATH}
1414     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1415     Compiler:                      ${CC}
1416     CFLAGS:                        ${CFLAGS}
1417     LIBS:                          ${LIBS}
1418
1419     Enable X11:                    ${ENABLE_X11}
1420     Enable OSS Output:             ${ENABLE_OSS_OUTPUT}
1421     Enable OSS Wrapper:            ${ENABLE_OSS_WRAPPER}
1422     Enable EsounD:                 ${ENABLE_ESOUND}
1423     Enable Alsa:                   ${ENABLE_ALSA}
1424     Enable CoreAudio:              ${ENABLE_COREAUDIO}
1425     Enable Solaris:                ${ENABLE_SOLARIS}
1426     Enable WaveOut:                ${ENABLE_WAVEOUT}
1427     Enable GLib 2.0:               ${ENABLE_GLIB20}
1428     Enable Gtk+ 2.0:               ${ENABLE_GTK20}
1429     Enable GConf:                  ${ENABLE_GCONF}
1430     Enable Avahi:                  ${ENABLE_AVAHI}
1431     Enable Jack:                   ${ENABLE_JACK}
1432     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1433     Enable LIRC:                   ${ENABLE_LIRC}
1434     Enable Xen PV driver:          ${ENABLE_XEN}
1435     Enable D-Bus:                  ${ENABLE_DBUS}
1436       Enable BlueZ:                ${ENABLE_BLUEZ}
1437     Enable udev:                   ${ENABLE_UDEV}
1438       Enable HAL->udev compat:     ${ENABLE_HAL_COMPAT}
1439     Enable systemd login:          ${ENABLE_SYSTEMD}
1440     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1441     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1442     Enable IPv6:                   ${ENABLE_IPV6}
1443     Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1444     Enable fftw:                   ${ENABLE_FFTW}
1445     Enable orc:                    ${ENABLE_ORC}
1446     Enable Adrian echo canceller:  ${ENABLE_ADRIAN_EC}
1447     Enable speex (resampler, AEC): ${ENABLE_SPEEX}
1448     Enable WebRTC echo canceller:  ${ENABLE_WEBRTC}
1449     Enable gcov coverage:          ${ENABLE_GCOV}
1450     Database
1451       tdb:                         ${ENABLE_TDB}
1452       gdbm:                        ${ENABLE_GDBM}
1453       simple database:             ${ENABLE_SIMPLEDB}
1454
1455     System User:                   ${PA_SYSTEM_USER}
1456     System Group:                  ${PA_SYSTEM_GROUP}
1457     Access Group:                  ${PA_ACCESS_GROUP}
1458     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1459     Force preopen:                 ${FORCE_PREOPEN}
1460     Preopened modules:             ${PREOPEN_MODS}
1461
1462     Legacy Database Entry Support: ${ENABLE_LEGACY_DATABASE_ENTRY_FORMAT}
1463 "
1464
1465 if test "${ENABLE_SPEEX}" = "no" && test "${ENABLE_WEBRTC}" = "no" && test "${ENABLE_ADRIAN_EC}" = "no" ; then
1466 AC_MSG_ERROR([At least one echo canceller implementation must be available.])
1467 fi
1468
1469 if test "${ENABLE_DBUS}" = "no" && test "x$os_is_win32" != "x1" ; then
1470    echo "
1471 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1472 You do not have D-Bus support enabled. It is strongly recommended
1473 that you enable D-Bus support if your platform supports it.
1474 Many parts of PulseAudio use D-Bus, from ConsoleKit interaction
1475 to the Device Reservation Protocol to speak to JACK, Bluetooth
1476 support and even a native control protocol for communicating and
1477 controling the PulseAudio daemon itself.
1478 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1479 "
1480 fi
1481
1482 if test "${ENABLE_UDEV}" = "no" && test "x$os_is_win32" != "x1" ; then
1483    echo "
1484 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1485 You do not have udev support enabled. It is strongly recommended
1486 that you enable udev support if your platform supports it as it is
1487 the primary method used to detect hardware audio devices (on Linux)
1488 and is thus a critical part of PulseAudio on that platform.
1489 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1490 "
1491 fi
1492
1493 if test "${ENABLE_SPEEX}" = "no" && test "x$os_is_win32" != "x1" ; then
1494    echo "
1495 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1496 You do not have speex support enabled. It is strongly recommended
1497 that you enable speex support if your platform supports it as it is
1498 the primary method used for audio resampling and is thus a critical
1499 part of PulseAudio on that platform.
1500 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1501 "
1502 fi