code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23 AC_INIT([polypaudio],[0.8],[mzcbylcnhqvb (at) 0pointer (dot) de])
  24 AC_CONFIG_SRCDIR([polyp/main.c])
  25 AC_CONFIG_HEADERS([config.h])
  26 AM_INIT_AUTOMAKE([foreign -Wall])
  27
  28 AC_SUBST(PA_MAJORMINOR, "$PACKAGE_VERSION")
  29 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  30
  31 AC_SUBST(PA_API_VERSION, 8)
  32
  33 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  34    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  35    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  36 fi
  37
  38 #### Checks for programs. ####
  39
  40 # CC
  41
  42 AC_PROG_CC
  43 AC_PROG_GCC_TRADITIONAL
  44
  45 # If using GCC specify some additional parameters
  46 if test "x$GCC" = "xyes" ; then
  47    CFLAGS="$CFLAGS -pipe -W -Wall -pedantic"
  48
  49    AC_LANG_CONFTEST([int main() {}])
  50    $CC -c conftest.c -std=gnu9x -Wno-unused-parameter $CFLAGS > /dev/null 2> /dev/null && CFLAGS="$CFLAGS -std=gnu9x -Wno-unused-parameter"
  51    rm -f conftest.o
  52 fi
  53
  54 # M4
  55
  56 AC_PATH_PROG([M4], [m4 gm4], [no])
  57 if test "x$M4" = xno ; then
  58    AC_MSG_ERROR([m4 missing])
  59 fi
  60
  61 # LYNX documentation generation
  62 AC_ARG_ENABLE(lynx,
  63         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
  64 [case "${enableval}" in
  65   yes) lynx=yes ;;
  66   no)  lynx=no ;;
  67   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
  68 esac],[lynx=yes])
  69
  70 if test x$lynx = xyes ; then
  71    AC_CHECK_PROG(have_lynx, lynx, yes, no)
  72
  73    if test x$have_lynx = xno ; then
  74      AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
  75    fi
  76 fi
  77
  78 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
  79
  80 #### libtool stuff ####
  81
  82 AC_LTDL_ENABLE_INSTALL
  83 AC_LIBLTDL_INSTALLABLE
  84 AC_SUBST(LTDLINCL)
  85 AC_SUBST(LIBLTDL)
  86 AC_LIBTOOL_DLOPEN
  87 AC_LIBTOOL_WIN32_DLL
  88 AC_PROG_LIBTOOL
  89 AC_CONFIG_SUBDIRS(libltdl)
  90
  91 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
  92     AC_MSG_ERROR([[
  93
  94         *** Cannot find the libltdl development files.
  95         *** Maybe you need to install the libltdl-dev package.
  96         ]])
  97 fi
  98
  99 #### Determine build environment ####
 100
 101 os_is_win32=0
 102
 103 case "$host_os" in
 104         mingw*)
 105         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 106         os_is_win32=1
 107                 ;;
 108         esac
 109
 110 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 111
 112 ###################################
 113 #   Basic environment checks      #
 114 ###################################
 115
 116 #### Checks for header files. ####
 117
 118 # ISO
 119 AC_HEADER_STDC
 120
 121 # POSIX
 122 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 123     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 124     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 125     syslog.h])
 126 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 127 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 128
 129 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 130 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 131
 132 # XPG4-UNIX
 133 AC_CHECK_HEADERS([sys/poll.h])
 134
 135 # Linux
 136 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 137
 138 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 139
 140 # Windows
 141 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 142
 143 # Other
 144 AC_CHECK_HEADERS([sys/ioctl.h])
 145
 146 #### Typdefs, structures, etc. ####
 147
 148 AC_C_CONST
 149 AC_C_BIGENDIAN
 150 AC_TYPE_PID_T
 151 AC_TYPE_SIZE_T
 152 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 153     [Define ssize_t if it is not done by the standard libs.])])
 154 AC_TYPE_OFF_T
 155 AC_TYPE_SIGNAL
 156 AC_TYPE_UID_T
 157
 158 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 159 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 160
 161 # Solaris lacks this
 162 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 163     [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])
 164
 165 #### Check for libs ####
 166
 167 # ISO
 168 AC_CHECK_LIB([m], [pow])
 169
 170 # POSIX
 171 AC_CHECK_LIB([rt], [sched_setscheduler])
 172
 173 # BSD
 174 AC_CHECK_LIB([socket], [connect])
 175
 176 # Non-standard
 177
 178 # This magic is needed so we do not needlessly add static libs to the win32
 179 # build, disabling its ability to make dlls.
 180 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 181
 182 #### Check for functions ####
 183
 184 # POSIX
 185 AC_FUNC_FORK
 186 AC_FUNC_GETGROUPS
 187 AC_FUNC_SELECT_ARGTYPES
 188 AC_CHECK_FUNCS([getaddrinfo getgrgid_r getpwuid_r gettimeofday getuid \
 189     inet_ntop nanosleep setpgid setsid sigaction sleep])
 190 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 191
 192 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 193
 194 # X/OPEN
 195 AC_CHECK_FUNCS([readlink])
 196
 197 # SUSv2
 198 AC_CHECK_FUNCS([ctime_r usleep])
 199
 200 # BSD
 201 AC_CHECK_FUNCS([lstat])
 202
 203 # Non-standard
 204
 205 AC_CHECK_FUNCS(setresuid)
 206 AC_CHECK_FUNCS(setreuid)
 207
 208 #### POSIX threads ####
 209
 210 ACX_PTHREAD
 211
 212 ###################################
 213 #      External libraries         #
 214 ###################################
 215
 216 #### X11 (optional) ####
 217
 218 HAVE_X11=0
 219
 220 # The macro tests the host, not the build target
 221 if test "x$os_is_win32" != "x1" ; then
 222     AC_PATH_XTRA
 223     test "x$no_x" != "xyes" && HAVE_X11=1
 224 fi
 225
 226 AC_SUBST(HAVE_X11)
 227 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 228 if test "x$HAVE_X11" = "x1" ; then
 229     AC_DEFINE([HAVE_X11], 1, [Have X11])
 230 fi
 231
 232 #### Capabilities (optional) ####
 233
 234 CAP_LIBS=''
 235
 236 AC_ARG_WITH(
 237         [caps],
 238         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 239
 240 if test "x${with_caps}" != "xno"; then
 241     AC_CHECK_LIB(cap, cap_init, [CAP_LIBS='-lcap'], [CAP_LIBS=''])
 242     AC_CHECK_HEADERS([sys/capability.h])
 243 fi
 244 AC_SUBST(CAP_LIBS)
 245
 246 #### Sample rate conversion ####
 247
 248 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 249 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 250 AC_SUBST(LIBSAMPLERATE_LIBS)
 251
 252 #### Sound file ####
 253
 254 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 255 AC_SUBST(LIBSNDFILE_CFLAGS)
 256 AC_SUBST(LIBSNDFILE_LIBS)
 257
 258 #### OSS support (optional) ####
 259
 260 AC_CHECK_HEADERS([sys/soundcard.h], [HAVE_OSS=1], [HAVE_OSS=0])
 261 AC_SUBST(HAVE_OSS)
 262 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 263
 264 #### ALSA support (optional) ####
 265
 266 PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [HAVE_ALSA=1], [HAVE_ALSA=0])
 267 AC_SUBST(ASOUNDLIB_CFLAGS)
 268 AC_SUBST(ASOUNDLIB_LIBS)
 269 AC_SUBST(HAVE_ALSA)
 270 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 271
 272 #### Solaris audio support (optional) ####
 273
 274 AC_CHECK_HEADERS([sys/audio.h], [HAVE_SOLARIS=1], [HAVE_SOLARIS=0])
 275 AC_SUBST(HAVE_SOLARIS)
 276 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 277
 278 #### GLib 2 support (optional) ####
 279
 280 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)
 281 AC_SUBST(GLIB20_CFLAGS)
 282 AC_SUBST(GLIB20_LIBS)
 283 AC_SUBST(HAVE_GLIB20)
 284 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 285
 286 #### GLib 1 support (optional) ####
 287
 288 PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, HAVE_GLIB12=0)
 289 AC_SUBST(GLIB12_CFLAGS)
 290 AC_SUBST(GLIB12_LIBS)
 291 AC_SUBST(HAVE_GLIB12)
 292 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 293
 294 #### Howl support (optional) ####
 295
 296 PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, HAVE_HOWL=0)
 297 AC_SUBST(HOWL_CFLAGS)
 298 AC_SUBST(HOWL_LIBS)
 299 AC_SUBST(HAVE_HOWL)
 300 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 301
 302 #### Async DNS support (optional) ####
 303
 304 PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)
 305 AC_SUBST(LIBASYNCNS_CFLAGS)
 306 AC_SUBST(LIBASYNCNS_LIBS)
 307 AC_SUBST(HAVE_LIBASYNCNS)
 308 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 309
 310 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 311    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 312 fi
 313
 314 #### TCP wrappers (optional) ####
 315
 316 ACX_LIBWRAP
 317 AC_SUBST(LIBWRAP_LIBS)
 318
 319 #### LIRC support (optional) ####
 320
 321 ACX_LIRC
 322 AC_SUBST(LIRC_CFLAGS)
 323 AC_SUBST(LIRC_LIBS)
 324 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 325
 326 ###################################
 327 #            Output               #
 328 ###################################
 329
 330 AC_ARG_ENABLE(
 331         [static-bins],
 332         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 333         [STATIC_BINS=1], [STATIC_BINS=0])
 334 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 335
 336 AC_ARG_WITH(
 337         [preopen-mods],
 338         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 339         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 340 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 341 if test "x$PREOPEN_MODS" != "xall" ; then
 342     tmpLIBS=""
 343     for mod in $PREOPEN_MODS; do
 344         tmpLIBS="$tmpLIBS module-$mod.la"
 345     done
 346     PREOPEN_MODS="$tmpLIBS"
 347     AC_SUBST(PREOPEN_MODS)
 348 fi
 349
 350 AC_CONFIG_FILES([
 351 Makefile
 352 polyp/Makefile
 353 polyplib.pc
 354 polyplib-simple.pc
 355 polyplib-mainloop.pc
 356 polyplib-browse.pc
 357 polyplib-error.pc
 358 polyplib-glib-mainloop.pc
 359 polyplib-glib12-mainloop.pc
 360 doc/Makefile
 361 doc/README.html
 362 doc/cli.html
 363 doc/daemon.html
 364 doc/modules.html
 365 doxygen/Makefile
 366 doxygen/doxygen.conf
 367 polyp/polyplib-version.h
 368 doc/FAQ.html
 369 ])
 370 AC_OUTPUT