code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.62)
  24
  25 m4_define(PA_MAJOR, [0])
  26 m4_define(PA_MINOR, [9])
  27 m4_define(PA_MICRO, [13])
  28
  29 AC_INIT([pulseaudio],[PA_MAJOR.PA_MINOR.PA_MICRO],[mzchyfrnhqvb (at) 0pointer (dot) net])
  30 AC_CONFIG_SRCDIR([src/daemon/main.c])
  31 AC_CONFIG_MACRO_DIR([m4])
  32 AC_CONFIG_HEADERS([config.h])
  33 AM_INIT_AUTOMAKE([foreign 1.10 -Wall])
  34
  35 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  36 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
  37
  38 AC_SUBST(PA_API_VERSION, 12)
  39 AC_SUBST(PA_PROTOCOL_VERSION, 14)
  40
  41 # The stable ABI for client applications, for the version info x:y:z
  42 # always will hold y=z
  43 AC_SUBST(LIBPULSE_VERSION_INFO, [7:0:7])
  44
  45 # A simplified, synchronous, ABI-stable interface for client
  46 # applications, for the version info x:y:z always will hold y=z
  47 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:2:0])
  48
  49 # The ABI-stable network browsing interface for client applications,
  50 # for the version info x:y:z always will hold y=z
  51 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  52
  53 # The ABI-stable GLib adapter for client applications, for the version
  54 # info x:y:z always will hold y=z
  55 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:4:0])
  56
  57 # An internally used, ABI-unstable library that contains the
  58 # PulseAudio core, SONAMEs are bumped on every release, version info
  59 # suffix will always be 0:0
  60 AC_SUBST(LIBPULSECORE_VERSION_INFO, [8:0:0])
  61
  62 AC_CANONICAL_HOST
  63 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  64
  65 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  66    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  67    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  68 fi
  69
  70 #### Platform hacks ####
  71
  72 case $host in
  73    *-*-solaris* )
  74       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  75       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  76       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  77       ;;
  78 esac
  79
  80 #### Checks for programs. ####
  81
  82 # mkdir -p
  83
  84 AC_PROG_MKDIR_P
  85
  86 # CC
  87
  88 AC_PROG_CC
  89 AC_PROG_CC_C99
  90 AM_PROG_CC_C_O
  91 AC_PROG_GCC_TRADITIONAL
  92 AC_USE_SYSTEM_EXTENSIONS
  93
  94 # M4
  95
  96 AC_PATH_PROG([M4], [m4 gm4], [no])
  97 if test "x$M4" = xno ; then
  98    AC_MSG_ERROR([m4 missing])
  99 fi
 100
 101 dnl Compiler flags
 102 DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wno-long-long -Wvla -Wno-overlength-strings -Wconversion -Wundef -Wformat -Wlogical-op -Wpacked -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Wno-unused-parameter -ffast-math"
 103
 104 for flag in $DESIRED_FLAGS ; do
 105   CC_CHECK_CFLAGS([$flag], [CFLAGS="$CFLAGS $flag"])
 106 done
 107
 108 # Native atomic operation support
 109 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 110     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]),
 111         [
 112             case "${enableval}" in
 113                 yes) atomic_arm_linux_helpers=yes ;;
 114                 no) atomic_arm_linux_helpers=no ;;
 115                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 116             esac
 117         ],
 118         [atomic_arm_linux_helpers=auto])
 119
 120 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 121     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]),
 122         [
 123             case "${enableval}" in
 124                 yes) AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers]) ;;
 125                 no) ;;
 126                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 127             esac
 128         ],)
 129
 130 AC_MSG_CHECKING([target operating system])
 131 case $host in
 132         *-*-linux*)
 133             AC_MSG_RESULT([linux])
 134             pulse_target_os=linux
 135         ;;
 136         *)
 137             AC_MSG_RESULT([unknown])
 138             pulse_target_os=unknown
 139         ;;
 140 esac
 141
 142 # If everything else fails use libatomic_ops
 143 need_libatomic_ops=yes
 144
 145 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 146   pulseaudio_cv_sync_bool_compare_and_swap,
 147   [AC_LINK_IFELSE(
 148      AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
 149      [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 150      [pulseaudio_cv_sync_bool_compare_and_swap=no])
 151   ])
 152
 153 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 154     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 155     need_libatomic_ops=no
 156 else
 157     # HW specific atomic ops stuff
 158     AC_MSG_CHECKING([architecture for native atomic operations])
 159     case $host_cpu in
 160         arm*)
 161             AC_MSG_RESULT([arm])
 162             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 163             # The Linux kernel helper functions have been there since 2.6.16. However
 164             # compile time checking for kernel version in cross compile environment
 165             # (which is usually the case for arm cpu) is tricky (or impossible).
 166             if test "x$pulse_target_os" = "xlinux" && test "x$atomic_arm_linux_helpers" != "xno"; then
 167                 AC_MSG_RESULT([yes])
 168                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 169                 need_libatomic_ops=no
 170             else
 171                AC_MSG_RESULT([no])
 172                AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 173                  pulseaudio_cv_support_arm_atomic_ops,
 174                  [AC_COMPILE_IFELSE(
 175                     AC_LANG_PROGRAM([],
 176                       [[volatile int a=0;
 177                         int o=0, n=1, r;
 178                         asm volatile ("ldrex    %0, [%1]\n"
 179                                          "subs  %0, %0, %2\n"
 180                                          "strexeq %0, %3, [%1]\n"
 181                                          : "=&r" (r)
 182                                          : "r" (&a), "Ir" (o), "r" (n)
 183                                          : "cc");
 184                         return (a==1 ? 0 : -1);
 185                       ]]),
 186                     [pulseaudio_cv_support_arm_atomic_ops=yes],
 187                     [pulseaudio_cv_support_arm_atomic_ops=no])
 188                  ])
 189                AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 190                    AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARMv6 instructions.])
 191                    need_libatomic_ops=no
 192                  ])
 193            fi
 194         ;;
 195         *)
 196             AC_MSG_RESULT([unknown])
 197         ;;
 198     esac
 199 fi
 200
 201 CC_CHECK_TLS
 202
 203 AC_CACHE_CHECK([whether $CC knows _Bool],
 204   pulseaudio_cv__Bool,
 205   [AC_COMPILE_IFELSE(
 206      AC_LANG_PROGRAM([], [[_Bool b;]]),
 207      [pulseaudio_cv__Bool=yes],
 208      [pulseaudio_cv__Bool=no])
 209   ])
 210
 211 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], [
 212     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 213   ])
 214
 215 #### libtool stuff ####
 216
 217 AC_LTDL_ENABLE_INSTALL
 218 AC_LIBLTDL_INSTALLABLE
 219 AC_LIBTOOL_DLOPEN
 220 AC_LIBTOOL_WIN32_DLL
 221 AC_PROG_LIBTOOL
 222 AC_SUBST(LTDLINCL)
 223 AC_SUBST(LIBLTDL)
 224 AC_CONFIG_SUBDIRS(libltdl)
 225
 226 old_LIBS=$LIBS
 227 LIBS="$LIBS $LIBLTDL"
 228 AC_CHECK_FUNCS([lt_dlmutex_register])
 229 LIBS=$old_LIBS
 230 AC_CHECK_TYPES([struct lt_user_dlloader, lt_dladvise], , , [#include <ltdl.h>])
 231
 232 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 233     AC_MSG_ERROR([[
 234
 235         *** Cannot find the libltdl development files.
 236         *** Maybe you need to install the libltdl-dev package.
 237         ]])
 238 fi
 239
 240 #### Determine build environment ####
 241
 242 os_is_win32=0
 243
 244 case "$host_os" in
 245         mingw*)
 246         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 247         os_is_win32=1
 248                 ;;
 249         esac
 250
 251 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 252
 253 ###################################
 254 #   Basic environment checks      #
 255 ###################################
 256
 257 #### Checks for header files. ####
 258
 259 # ISO
 260 AC_HEADER_STDC
 261
 262 # POSIX
 263 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 264     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 265     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 266     syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 267 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 268                  [#include <sys/types.h>
 269                   #if HAVE_NETINET_IN_H
 270                   # include <netinet/in.h>
 271                   #endif
 272                   #if HAVE_NETINET_IN_SYSTM_H
 273                   # include <netinet/in_systm.h>
 274                   #endif
 275                  ])
 276 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 277 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 278
 279 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 280 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 281
 282 # Linux
 283 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 284
 285 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 286
 287 AC_CHECK_HEADERS([sys/prctl.h])
 288
 289 # Solaris
 290 AC_CHECK_HEADERS([sys/filio.h])
 291
 292 # Windows
 293 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 294
 295 # Other
 296 AC_CHECK_HEADERS([sys/ioctl.h])
 297 AC_CHECK_HEADERS([byteswap.h])
 298 AC_CHECK_HEADERS([sys/syscall.h])
 299 AC_CHECK_HEADERS([sys/eventfd.h])
 300
 301 #### Typdefs, structures, etc. ####
 302
 303 AC_C_CONST
 304 AC_C_BIGENDIAN
 305 AC_TYPE_PID_T
 306 AC_TYPE_SIZE_T
 307 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 308     [Define ssize_t if it is not done by the standard libs.])])
 309 AC_TYPE_OFF_T
 310 AC_TYPE_SIGNAL
 311 AC_TYPE_UID_T
 312 AC_CHECK_DECLS(environ)
 313
 314 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 315 HAVE_SIGXCPU=1
 316 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 317 ], [HAVE_SIGXCPU=0])
 318 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 319
 320 # Solaris lacks this
 321 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 322     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 323         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 324
 325 #### POSIX threads ####
 326
 327 ACX_PTHREAD
 328
 329 #### Check for libs ####
 330
 331 # ISO
 332 AC_SEARCH_LIBS([pow], [m])
 333
 334 # POSIX
 335 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 336 AC_SEARCH_LIBS([dlopen], [dl])
 337 AC_SEARCH_LIBS([shm_open], [rt])
 338 AC_SEARCH_LIBS([inet_ntop], [nsl])
 339 AC_SEARCH_LIBS([timer_create], [rt])
 340
 341 # BSD
 342 AC_SEARCH_LIBS([connect], [socket])
 343
 344 # Non-standard
 345
 346 # This magic is needed so we do not needlessly add static libs to the win32
 347 # build, disabling its ability to make dlls.
 348 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 349
 350 AC_CHECK_LIB(gdbm, gdbm_open)
 351 AC_CHECK_HEADERS(gdbm.h, [], [AC_MSG_ERROR([gdbm.h not found])])
 352
 353 #### Check for functions ####
 354
 355 # ISO
 356 AC_CHECK_FUNCS([lrintf strtof])
 357
 358 # POSIX
 359 AC_FUNC_FORK
 360 AC_FUNC_GETGROUPS
 361 AC_FUNC_SELECT_ARGTYPES
 362 AC_CHECK_FUNCS([chmod chown clock_gettime getaddrinfo getgrgid_r \
 363     getpwuid_r gettimeofday getuid inet_ntop inet_pton mlock nanosleep \
 364     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 365     sigaction sleep sysconf])
 366 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 367
 368 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 369
 370 # X/OPEN
 371 AC_CHECK_FUNCS([readlink])
 372
 373 # SUSv2
 374 AC_CHECK_FUNCS([ctime_r usleep])
 375
 376 # SUSv3
 377 AC_CHECK_FUNCS([strerror_r])
 378
 379 # BSD
 380 AC_CHECK_FUNCS([lstat])
 381
 382 # Non-standard
 383
 384 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 385
 386 AC_FUNC_ALLOCA
 387
 388 AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
 389   pulseaudio_cv_PTHREAD_PRIO_INHERIT,
 390   [save_CC=$CC; CC=$PTHREAD_CC
 391    save_CFLAGS=$CFLAGS; CFLAGS=$PTHREAD_CFLAGS
 392    save_LIBS=$LIBS; LIBS=$PTHREAD_LIBS
 393    AC_LINK_IFELSE(
 394      AC_LANG_PROGRAM(
 395        [[
 396          #include <pthread.h>
 397        ]],
 398        [[int i = PTHREAD_PRIO_INHERIT;]]),
 399      [pulseaudio_cv_PTHREAD_PRIO_INHERIT=yes],
 400      [pulseaudio_cv_PTHREAD_PRIO_INHERIT=no])
 401    CC=$save_CC
 402    CFLAGS=$save_CFLAGS
 403    LIBS=$save_LIBS
 404   ])
 405
 406 AS_IF([test "$pulseaudio_cv_PTHREAD_PRIO_INHERIT" = "yes"], [
 407     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 408   ])
 409
 410 AC_DEFINE_UNQUOTED(PA_CFLAGS,"$CFLAGS", [The CFLAGS used during compilation])
 411
 412 #### Large File-Support (LFS) ####
 413
 414 AC_SYS_LARGEFILE
 415
 416 # Check for open64 to know if the current system does have open64() and similar functions
 417 AC_CHECK_FUNCS([open64])
 418
 419 #### [lib]iconv ####
 420
 421 AM_ICONV
 422
 423 IT_PROG_INTLTOOL([0.35.0])
 424 GETTEXT_PACKAGE=pulseaudio
 425 AC_SUBST([GETTEXT_PACKAGE])
 426 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 427 AM_GLIB_GNU_GETTEXT
 428
 429 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 430 AC_SUBST(pulselocaledir)
 431
 432 ###################################
 433 #      External libraries         #
 434 ###################################
 435
 436 #### X11 (optional) ####
 437
 438 HAVE_X11=0
 439
 440 # The macro tests the host, not the build target
 441 if test "x$os_is_win32" != "x1" ; then
 442     AC_PATH_XTRA
 443     test "x$no_x" != "xyes" && HAVE_X11=1
 444 fi
 445
 446 AC_SUBST(HAVE_X11)
 447 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 448 if test "x$HAVE_X11" = "x1" ; then
 449     AC_DEFINE([HAVE_X11], 1, [Have X11])
 450 fi
 451
 452 #### Capabilities (optional) ####
 453
 454 CAP_LIBS=''
 455
 456 AC_ARG_WITH(
 457         [caps],
 458         AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 459
 460 if test "x${with_caps}" != "xno"; then
 461     AC_SEARCH_LIBS([cap_init], [cap], [], [
 462                     if test "x${with_caps}" = "xyes" ; then
 463                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 464                     fi])
 465     AC_CHECK_HEADERS([sys/capability.h], [], [
 466                     if test "x${with_caps}" = "xyes" ; then
 467                         AC_MSG_ERROR([*** POSIX caps headers not found])
 468                     fi])
 469 fi
 470
 471 #### Valgrind (optional) ####
 472
 473 AC_CHECK_HEADERS([valgrind/memcheck.h])
 474
 475 #### pkg-config ####
 476
 477 # Check for pkg-config manually first, as if its not installed the
 478 # PKG_PROG_PKG_CONFIG macro won't be defined.
 479 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 480
 481 if test x"$have_pkg_config" = "xno"; then
 482     AC_MSG_ERROR(pkg-config is required to install this program)
 483 fi
 484
 485 PKG_PROG_PKG_CONFIG
 486
 487 #### Sound file ####
 488
 489 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 490 AC_SUBST(LIBSNDFILE_CFLAGS)
 491 AC_SUBST(LIBSNDFILE_LIBS)
 492
 493 PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ])
 494 AC_SUBST(LIBSPEEX_CFLAGS)
 495 AC_SUBST(LIBSPEEX_LIBS)
 496
 497 #### atomic-ops ###
 498
 499 AC_MSG_CHECKING([whether we need libatomic_ops])
 500 if test "x$need_libatomic_ops" = "xyes"; then
 501    AC_MSG_RESULT([yes])
 502    AC_CHECK_HEADERS([atomic_ops.h], [], [
 503    AC_MSG_ERROR([*** libatomic-ops headers not found])
 504    ])
 505
 506    # Win32 does not need the lib and breaks horribly if we try to include it
 507    if test "x$os_is_win32" != "x1" ; then
 508        LIBS="$LIBS -latomic_ops"
 509    fi
 510 else
 511    AC_MSG_RESULT([no])
 512 fi
 513
 514 #### Libsamplerate support (optional) ####
 515
 516 AC_ARG_ENABLE([samplerate],
 517     AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]),
 518         [
 519             case "${enableval}" in
 520                 yes) samplerate=yes ;;
 521                 no) samplerate=no ;;
 522                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 523             esac
 524         ],
 525         [samplerate=auto])
 526
 527 if test "x${samplerate}" != xno ; then
 528     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 529         HAVE_LIBSAMPLERATE=1,
 530         [
 531             HAVE_LIBSAMPLERATE=0
 532             if test "x$samplerate" = xyes ; then
 533                 AC_MSG_ERROR([*** Libsamplerate not found])
 534             fi
 535         ])
 536 else
 537     HAVE_LIBSAMPLERATE=0
 538 fi
 539
 540 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 541    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 542 fi
 543
 544 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 545 AC_SUBST(LIBSAMPLERATE_LIBS)
 546 AC_SUBST(HAVE_LIBSAMPLERATE)
 547 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 548
 549 #### OSS support (optional) ####
 550
 551 AC_ARG_ENABLE([oss],
 552     AS_HELP_STRING([--disable-oss],[Disable optional OSS support]),
 553         [
 554             case "${enableval}" in
 555                 yes) oss=yes ;;
 556                 no) oss=no ;;
 557                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 558             esac
 559         ],
 560         [oss=auto])
 561
 562 if test "x${oss}" != xno ; then
 563     AC_CHECK_HEADERS([sys/soundcard.h],
 564         [
 565             HAVE_OSS=1
 566             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 567         ],
 568         [
 569             HAVE_OSS=0
 570             if test "x$oss" = xyes ; then
 571                 AC_MSG_ERROR([*** OSS support not found])
 572             fi
 573         ])
 574 else
 575     HAVE_OSS=0
 576 fi
 577
 578 AC_SUBST(HAVE_OSS)
 579 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 580
 581
 582 #### ALSA support (optional) ####
 583
 584 AC_ARG_ENABLE([alsa],
 585     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]),
 586         [
 587             case "${enableval}" in
 588                 yes) alsa=yes ;;
 589                 no) alsa=no ;;
 590                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 591             esac
 592         ],
 593         [alsa=auto])
 594
 595 if test "x${alsa}" != xno ; then
 596     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.17 ],
 597         [
 598             HAVE_ALSA=1
 599             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 600         ],
 601         [
 602             HAVE_ALSA=0
 603             if test "x$alsa" = xyes ; then
 604                 AC_MSG_ERROR([*** Needed alsa >= 1.0.17 support not found])
 605             fi
 606         ])
 607 else
 608     HAVE_ALSA=0
 609 fi
 610
 611 AC_SUBST(ASOUNDLIB_CFLAGS)
 612 AC_SUBST(ASOUNDLIB_LIBS)
 613 AC_SUBST(HAVE_ALSA)
 614 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 615
 616 #### Solaris audio support (optional) ####
 617
 618 AC_ARG_ENABLE([solaris],
 619     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]),
 620         [
 621             case "${enableval}" in
 622                 yes) solaris=yes ;;
 623                 no) solaris=no ;;
 624                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 625             esac
 626         ],
 627         [solaris=auto])
 628
 629 if test "x${solaris}" != xno ; then
 630     AC_CHECK_HEADERS([sys/audio.h],
 631         [
 632             HAVE_SOLARIS=1
 633             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 634         ],
 635         [
 636             HAVE_SOLARIS=0
 637             if test "x$solaris" = xyes ; then
 638                 AC_MSG_ERROR([*** Solaris audio support not found])
 639             fi
 640         ])
 641 else
 642     HAVE_SOLARIS=0
 643 fi
 644
 645 AC_SUBST(HAVE_SOLARIS)
 646 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 647
 648 #### GLib 2 support (optional) ####
 649
 650 AC_ARG_ENABLE([glib2],
 651     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]),
 652         [
 653             case "${enableval}" in
 654                 yes) glib2=yes ;;
 655                 no) glib2=no ;;
 656                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 657             esac
 658         ],
 659         [glib2=auto])
 660
 661 if test "x${glib2}" != xno ; then
 662     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 663         HAVE_GLIB20=1,
 664         [
 665             HAVE_GLIB20=0
 666             if test "x$glib2" = xyes ; then
 667                 AC_MSG_ERROR([*** GLib 2 support not found])
 668             fi
 669         ])
 670 else
 671     HAVE_GLIB20=0
 672 fi
 673
 674 AC_SUBST(GLIB20_CFLAGS)
 675 AC_SUBST(GLIB20_LIBS)
 676 AC_SUBST(HAVE_GLIB20)
 677 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 678
 679 #### GConf support (optional) ####
 680
 681 AC_ARG_ENABLE([gconf],
 682     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]),
 683         [
 684             case "${enableval}" in
 685                 yes) gconf=yes ;;
 686                 no) gconf=no ;;
 687                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 688             esac
 689         ],
 690         [gconf=auto])
 691
 692 if test "x${gconf}" != xno ; then
 693     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 694         HAVE_GCONF=1,
 695         [
 696             HAVE_GCONF=0
 697             if test "x$gconf" = xyes ; then
 698                 AC_MSG_ERROR([*** GConf support not found])
 699             fi
 700         ])
 701 else
 702     HAVE_GCONF=0
 703 fi
 704
 705 AC_SUBST(GCONF_CFLAGS)
 706 AC_SUBST(GCONF_LIBS)
 707 AC_SUBST(HAVE_GCONF)
 708 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 709
 710 #### Avahi support (optional) ####
 711
 712 AC_ARG_ENABLE([avahi],
 713     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]),
 714         [
 715             case "${enableval}" in
 716                 yes) avahi=yes ;;
 717                 no) avahi=no ;;
 718                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 719             esac
 720         ],
 721         [avahi=auto])
 722
 723 if test "x${avahi}" != xno ; then
 724     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 725         HAVE_AVAHI=1,
 726         [
 727                 HAVE_AVAHI=0
 728                 if test "x$avahi" = xyes ; then
 729                         AC_MSG_ERROR([*** Avahi support not found])
 730                 fi
 731         ])
 732 else
 733     HAVE_AVAHI=0
 734 fi
 735
 736 AC_SUBST(AVAHI_CFLAGS)
 737 AC_SUBST(AVAHI_LIBS)
 738 AC_SUBST(HAVE_AVAHI)
 739 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 740
 741 ### LIBOIL ####
 742
 743 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 744 AC_SUBST(LIBOIL_CFLAGS)
 745 AC_SUBST(LIBOIL_LIBS)
 746
 747 ### JACK (optional) ####
 748
 749 AC_ARG_ENABLE([jack],
 750     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]),
 751         [
 752             case "${enableval}" in
 753                 yes) jack=yes ;;
 754                 no) jack=no ;;
 755                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 756             esac
 757         ],
 758         [jack=auto])
 759
 760 if test "x${jack}" != xno ; then
 761     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 762         HAVE_JACK=1,
 763         [
 764             HAVE_JACK=0
 765             if test "x$jack" = xyes ; then
 766                 AC_MSG_ERROR([*** JACK support not found])
 767             fi
 768         ])
 769 else
 770     HAVE_JACK=0
 771 fi
 772
 773 AC_SUBST(JACK_CFLAGS)
 774 AC_SUBST(JACK_LIBS)
 775 AC_SUBST(HAVE_JACK)
 776 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 777
 778 #### Async DNS support (optional) ####
 779
 780 AC_ARG_ENABLE([asyncns],
 781     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]),
 782         [
 783             case "${enableval}" in
 784                 yes) asyncns=yes ;;
 785                 no) asyncns=no ;;
 786                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 787             esac
 788         ],
 789         [asyncns=auto])
 790
 791 if test "x${asyncns}" != xno ; then
 792     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 793         HAVE_LIBASYNCNS=1,
 794         [
 795             HAVE_LIBASYNCNS=0
 796             if test "x$asyncns" = xyes ; then
 797                 AC_MSG_ERROR([*** Async DNS support not found])
 798             fi
 799         ])
 800 else
 801     HAVE_LIBASYNCNS=0
 802 fi
 803
 804 AC_SUBST(LIBASYNCNS_CFLAGS)
 805 AC_SUBST(LIBASYNCNS_LIBS)
 806 AC_SUBST(HAVE_LIBASYNCNS)
 807 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 808
 809 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 810    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 811 fi
 812
 813 #### TCP wrappers (optional) ####
 814
 815 AC_ARG_ENABLE([tcpwrap],
 816     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 817         [
 818             case "${enableval}" in
 819                 yes) tcpwrap=yes ;;
 820                 no) tcpwrap=no ;;
 821                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 822             esac
 823         ],
 824         [tcpwrap=auto])
 825
 826 if test "x${tcpwrap}" != xno ; then
 827     ACX_LIBWRAP
 828     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 829         AC_MSG_ERROR([*** TCP wrappers support not found])
 830     fi
 831 else
 832     LIBWRAP_LIBS=
 833 fi
 834
 835 AC_SUBST(LIBWRAP_LIBS)
 836
 837 #### LIRC support (optional) ####
 838
 839 AC_ARG_ENABLE([lirc],
 840     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]),
 841         [
 842             case "${enableval}" in
 843                 yes) lirc=yes ;;
 844                 no) lirc=no ;;
 845                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 846             esac
 847         ],
 848         [lirc=auto])
 849
 850 if test "x${lirc}" != xno ; then
 851     ACX_LIRC
 852     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 853         AC_MSG_ERROR([*** LIRC support not found])
 854     fi
 855 else
 856     HAVE_LIRC=0
 857 fi
 858
 859 AC_SUBST(LIRC_CFLAGS)
 860 AC_SUBST(LIRC_LIBS)
 861 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 862
 863 #### HAL support (optional) ####
 864
 865 AC_ARG_ENABLE([hal],
 866     AS_HELP_STRING([--disable-hal],[Disable optional HAL support]),
 867         [
 868             case "${enableval}" in
 869                 yes) hal=yes ;;
 870                 no) hal=no ;;
 871                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 872             esac
 873         ],
 874         [hal=auto])
 875 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 876     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 877         HAVE_HAL=1,
 878         [
 879             HAVE_HAL=0
 880             if test "x$hal" = xyes ; then
 881                 AC_MSG_ERROR([*** HAL support not found])
 882             fi
 883         ])
 884 else
 885     HAVE_HAL=0
 886 fi
 887
 888 AC_SUBST(HAL_CFLAGS)
 889 AC_SUBST(HAL_LIBS)
 890 AC_SUBST(HAVE_HAL)
 891 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 892
 893 #### BlueZ support (optional) ####
 894
 895 AC_ARG_ENABLE([bluez],
 896     AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]),
 897         [
 898             case "${enableval}" in
 899                 yes) bluez=yes ;;
 900                 no) bluez=no ;;
 901                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-bluez) ;;
 902             esac
 903         ],
 904         [bluez=auto])
 905 if test "x${bluez}" != xno ; then
 906     PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ],
 907         HAVE_BLUEZ=1,
 908         [
 909             HAVE_BLUEZ=0
 910             if test "x$bluez" = xyes ; then
 911                 AC_MSG_ERROR([*** BLUEZ support not found])
 912             fi
 913         ])
 914 else
 915     HAVE_BLUEZ=0
 916 fi
 917
 918 AC_SUBST(BLUEZ_CFLAGS)
 919 AC_SUBST(BLUEZ_LIBS)
 920 AC_SUBST(HAVE_BLUEZ)
 921 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 922
 923 #### D-Bus support (optional) ####
 924
 925 AC_ARG_ENABLE([dbus],
 926     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]),
 927         [
 928             case "${enableval}" in
 929                 yes) dbus=yes ;;
 930                 no) dbus=no ;;
 931                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 932             esac
 933         ],
 934         [dbus=auto])
 935
 936 if test "x$HAVE_HAL" = x1 ; then
 937    dbus=yes
 938 fi
 939
 940 if test "x${dbus}" != xno || test "x${bluez}" != xno || "x${hal}" != xno ; then
 941
 942     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 943         [
 944             HAVE_DBUS=1
 945             saved_LIBS="$LIBS"
 946             LIBS="$LIBS $DBUS_LIBS"
 947             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 948             LIBS="$saved_LIBS"
 949             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 950         ],
 951         [
 952             HAVE_DBUS=0
 953             if test "x$dbus" = xyes ; then
 954                 AC_MSG_ERROR([*** D-Bus support not found])
 955             fi
 956         ])
 957 else
 958     HAVE_DBUS=0
 959 fi
 960
 961 AC_SUBST(DBUS_CFLAGS)
 962 AC_SUBST(DBUS_LIBS)
 963 AC_SUBST(HAVE_DBUS)
 964 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 965
 966 #### PolicyKit support (optional) ####
 967
 968 AC_ARG_ENABLE([polkit],
 969     AS_HELP_STRING([--disable-polkit],[Disable optional PolicyKit support]),
 970         [
 971             case "${enableval}" in
 972                 yes) polkit=yes ;;
 973                 no) polkit=no ;;
 974                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-polkit) ;;
 975             esac
 976         ],
 977         [polkit=auto])
 978
 979 if test "x${polkit}" != xno ; then
 980
 981     PKG_CHECK_MODULES(POLKIT, [ polkit-dbus >= 0.7 ],
 982         [
 983             HAVE_POLKIT=1
 984             AC_DEFINE([HAVE_POLKIT], 1, [Have PolicyKit])
 985             policydir=`pkg-config polkit-dbus --variable prefix`/share/PolicyKit/policy/
 986             AC_SUBST(policydir)
 987         ],
 988         [
 989             HAVE_POLKIT=0
 990             if test "x$polkit" = xyes ; then
 991                 AC_MSG_ERROR([*** PolicyKit support not found])
 992             fi
 993         ])
 994 else
 995     HAVE_POLKIT=0
 996 fi
 997
 998 AC_SUBST(POLKIT_CFLAGS)
 999 AC_SUBST(POLKIT_LIBS)
1000 AC_SUBST(HAVE_POLKIT)
1001 AM_CONDITIONAL([HAVE_POLKIT], [test "x$HAVE_POLKIT" = x1])
1002
1003 ### Build and Install man pages ###
1004 AC_ARG_ENABLE(manpages,
1005         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
1006 [case "${enableval}" in
1007   yes) manpages=yes ;;
1008   no)  manpages=no ;;
1009   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
1010 esac],[manpages=yes])
1011
1012 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
1013
1014 #### PulseAudio system group & user  #####
1015
1016 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1017 if test -z "$with_system_user" ; then
1018     PA_SYSTEM_USER=pulse
1019 else
1020     PA_SYSTEM_USER=$with_system_user
1021 fi
1022 AC_SUBST(PA_SYSTEM_USER)
1023 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1024
1025 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1026 if test -z "$with_system_group" ; then
1027     PA_SYSTEM_GROUP=pulse
1028 else
1029     PA_SYSTEM_GROUP=$with_system_group
1030 fi
1031 AC_SUBST(PA_SYSTEM_GROUP)
1032 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1033
1034 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
1035 if test -z "$with_realtime_group" ; then
1036     PA_REALTIME_GROUP=pulse-rt
1037 else
1038     PA_REALTIME_GROUP=$with_realtime_group
1039 fi
1040 AC_SUBST(PA_REALTIME_GROUP)
1041 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
1042
1043 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1044 if test -z "$with_access_group" ; then
1045     PA_ACCESS_GROUP=pulse-access
1046 else
1047     PA_ACCESS_GROUP=$with_access_group
1048 fi
1049 AC_SUBST(PA_ACCESS_GROUP)
1050 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1051
1052 AC_ARG_ENABLE(
1053         per_user_esound_socket,
1054         AS_HELP_STRING([--disable-per-user-esound-socket], [Use global esound socket directory /tmp/.esd/socket.]),
1055         [
1056             case "${enableval}" in
1057                 yes) per_user_esound_socket=1 ;;
1058                 no) per_user_esound_socket=0 ;;
1059                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-per-user-esound-socket) ;;
1060             esac
1061         ],
1062         [per_user_esound_socket=1])
1063
1064 if test "x$per_user_esound_socket" = "x1"; then
1065    AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1066 fi
1067
1068 #### PulseAudio system runtime dir ####
1069 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1070 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1071 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1072 AC_SUBST(PA_SYSTEM_CONFIG_PATH)
1073 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1074 AC_SUBST(PA_SYSTEM_STATE_PATH)
1075
1076 ###################################
1077 #            Output               #
1078 ###################################
1079
1080 AC_ARG_ENABLE(
1081         [static-bins],
1082         AS_HELP_STRING([--enable-static-bins],[Statically link executables.]),
1083         [STATIC_BINS=1], [STATIC_BINS=0])
1084 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1085
1086 AC_ARG_WITH(
1087         [preopen-mods],
1088         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1089         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1090 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1091 if test "x$PREOPEN_MODS" != "xall" ; then
1092     tmpLIBS=""
1093     for mod in $PREOPEN_MODS; do
1094         tmpLIBS="$tmpLIBS module-$mod.la"
1095     done
1096     PREOPEN_MODS="$tmpLIBS"
1097     AC_SUBST(PREOPEN_MODS)
1098 fi
1099
1100 AC_ARG_WITH(
1101         [module-dir],
1102         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
1103         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
1104
1105 AC_SUBST(modlibexecdir)
1106
1107 AC_ARG_ENABLE(
1108         [force-preopen],
1109         AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
1110         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
1111 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
1112
1113 AC_CONFIG_FILES([
1114 Makefile
1115 src/Makefile
1116 man/Makefile
1117 libpulse.pc
1118 libpulse-simple.pc
1119 libpulse-browse.pc
1120 libpulse-mainloop-glib.pc
1121 doxygen/Makefile
1122 doxygen/doxygen.conf
1123 src/pulse/version.h
1124 po/Makefile.in
1125 ])
1126 AC_OUTPUT
1127
1128 # ==========================================================================
1129 ENABLE_X11=no
1130 if test "x$HAVE_X11" = "x1" ; then
1131    ENABLE_X11=yes
1132 fi
1133
1134 ENABLE_OSS=no
1135 if test "x$HAVE_OSS" = "x1" ; then
1136    ENABLE_OSS=yes
1137 fi
1138
1139 ENABLE_ALSA=no
1140 if test "x$HAVE_ALSA" = "x1" ; then
1141    ENABLE_ALSA=yes
1142 fi
1143
1144 ENABLE_SOLARIS=no
1145 if test "x$HAVE_SOLARIS" = "x1" ; then
1146    ENABLE_SOLARIS=yes
1147 fi
1148
1149 ENABLE_GLIB20=no
1150 if test "x$HAVE_GLIB20" = "x1" ; then
1151    ENABLE_GLIB20=yes
1152 fi
1153
1154 ENABLE_GCONF=no
1155 if test "x$HAVE_GCONF" = "x1" ; then
1156    ENABLE_GCONF=yes
1157 fi
1158
1159 ENABLE_AVAHI=no
1160 if test "x$HAVE_AVAHI" = "x1" ; then
1161    ENABLE_AVAHI=yes
1162 fi
1163
1164 ENABLE_JACK=no
1165 if test "x$HAVE_JACK" = "x1" ; then
1166    ENABLE_JACK=yes
1167 fi
1168
1169 ENABLE_LIBASYNCNS=no
1170 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
1171    ENABLE_LIBASYNCNS=yes
1172 fi
1173
1174 ENABLE_LIRC=no
1175 if test "x$HAVE_LIRC" = "x1" ; then
1176    ENABLE_LIRC=yes
1177 fi
1178
1179 ENABLE_HAL=no
1180 if test "x$HAVE_HAL" = "x1" ; then
1181    ENABLE_HAL=yes
1182 fi
1183
1184 ENABLE_TCPWRAP=no
1185 if test "x${LIBWRAP_LIBS}" != x ; then
1186    ENABLE_TCPWRAP=yes
1187 fi
1188
1189 ENABLE_LIBSAMPLERATE=no
1190 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
1191    ENABLE_LIBSAMPLERATE=yes
1192 fi
1193
1194 ENABLE_BLUEZ=no
1195 if test "x${HAVE_BLUEZ}" = "x1" ; then
1196    ENABLE_BLUEZ=yes
1197 fi
1198
1199 ENABLE_POLKIT=no
1200 if test "x${HAVE_POLKIT}" = "x1" ; then
1201    ENABLE_POLKIT=yes
1202 fi
1203
1204 ENABLE_PER_USER_ESOUND_SOCKET=no
1205 if test "x$per_user_esound_socket" = "x1" ; then
1206    ENABLE_PER_USER_ESOUND_SOCKET=yes
1207 fi
1208
1209 echo "
1210  ---{ $PACKAGE_NAME $VERSION }---
1211
1212     prefix:                        ${prefix}
1213     sysconfdir:                    ${sysconfdir}
1214     localstatedir:                 ${localstatedir}
1215     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1216     System State Path:             ${PA_SYSTEM_STATE_PATH}
1217     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1218     Compiler:                      ${CC}
1219     CFLAGS:                        ${CFLAGS}
1220     Have X11:                      ${ENABLE_X11}
1221     Enable OSS:                    ${ENABLE_OSS}
1222     Enable Alsa:                   ${ENABLE_ALSA}
1223     Enable Solaris:                ${ENABLE_SOLARIS}
1224     Enable GLib 2.0:               ${ENABLE_GLIB20}
1225     Enable GConf:                  ${ENABLE_GCONF}
1226     Enable Avahi:                  ${ENABLE_AVAHI}
1227     Enable Jack:                   ${ENABLE_JACK}
1228     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1229     Enable LIRC:                   ${ENABLE_LIRC}
1230     Enable HAL:                    ${ENABLE_HAL}
1231     Enable BlueZ:                  ${ENABLE_BLUEZ}
1232     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1233     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1234     Enable PolicyKit:              ${ENABLE_POLKIT}
1235     System User:                   ${PA_SYSTEM_USER}
1236     System Group:                  ${PA_SYSTEM_GROUP}
1237     Realtime Group:                ${PA_REALTIME_GROUP}
1238     Access Group:                  ${PA_ACCESS_GROUP}
1239     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1240 "